New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in branches/2017/dev_r8789_sbc/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2017/dev_r8789_sbc/NEMOGCM/NEMO/OPA_SRC/TRA/trasbc.F90 @ 8794

Last change on this file since 8794 was 8794, checked in by charris, 6 years ago

Changes to correctly deal with sea surface height increments both with and without vvl.
  • Property svn:keywords set to Id
File size: 13.5 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  OPA  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!  NEMO      1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
10   !!             -   !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.6  !  2014-11  (P. Mathiot) isf melting forcing
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_sbc       : update the tracer trend at ocean surface
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and active tracers
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE dom_oce        ! ocean space domain variables
20   USE phycst         ! physical constant
21   USE eosbn2         ! Equation Of State
22   USE sbcmod         ! ln_rnf 
23   USE sbcrnf         ! River runoff 
24   USE sbcisf         ! Ice shelf   
25   USE iscplini       ! Ice sheet coupling
26   USE traqsr         ! solar radiation penetration
27   USE trd_oce        ! trends: ocean variables
28   USE trdtra         ! trends manager: tracers
29#if defined key_asminc   
30   USE asminc         ! Assimilation increment
31#endif
32   !
33   USE in_out_manager ! I/O manager
34   USE prtctl         ! Print control
35   USE iom            ! xIOS server
36   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
37   USE wrk_nemo       ! Memory Allocation
38   USE timing         ! Timing
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   tra_sbc   ! routine called by step.F90
44
45   !! * Substitutions
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_sbc ( kt )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_sbc  ***
57      !!                   
58      !! ** Purpose :   Compute the tracer surface boundary condition trend of
59      !!      (flux through the interface, concentration/dilution effect)
60      !!      and add it to the general trend of tracer equations.
61      !!
62      !! ** Method :   The (air+ice)-sea flux has two components:
63      !!      (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface);
64      !!      (2) Fwe , tracer carried with the water that is exchanged with air+ice.
65      !!               The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe,
66      !!             they are simply added to the tracer trend (tsa).
67      !!               In linear free surface case (ln_linssh=T), the volume of the
68      !!             ocean does not change with the water exchanges at the (air+ice)-sea
69      !!             interface. Therefore another term has to be added, to mimic the
70      !!             concentration/dilution effect associated with water exchanges.
71      !!
72      !! ** Action  : - Update tsa with the surface boundary condition trend
73      !!              - send trends to trdtra module for further diagnostics(l_trdtra=T)
74      !!----------------------------------------------------------------------
75      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
76      !
77      INTEGER  ::   ji, jj, jk, jn        ! dummy loop indices 
78      INTEGER  ::   ikt, ikb              ! local integers
79      REAL(wp) ::   zfact, z1_e3t, zdep   ! local scalar
80      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdt, ztrds
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('tra_sbc')
84      !
85      IF( kt == nit000 ) THEN
86         IF(lwp) WRITE(numout,*)
87         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
88         IF(lwp) WRITE(numout,*) '~~~~~~~ '
89      ENDIF
90      !
91      IF( l_trdtra ) THEN                    !* Save ta and sa trends
92         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) 
93         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
94         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
95      ENDIF
96      !
97!!gm  This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist)
98      IF( .NOT.ln_traqsr ) THEN     ! no solar radiation penetration
99         qns(:,:) = qns(:,:) + qsr(:,:)      ! total heat flux in qns
100         qsr(:,:) = 0._wp                     ! qsr set to zero
101      ENDIF
102
103      !----------------------------------------
104      !        EMP, SFX and QNS effects
105      !----------------------------------------
106      !                             !==  Set before sbc tracer content fields  ==!
107      IF( kt == nit000 ) THEN             !* 1st time-step
108         IF( ln_rstart .AND.    &               ! Restart: read in restart file
109              & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN
110            IF(lwp) WRITE(numout,*) '          nit000-1 sbc tracer content field read in the restart file'
111            zfact = 0.5_wp
112            sbc_tsc(:,:,:) = 0._wp
113            CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) )   ! before heat content sbc trend
114            CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) )   ! before salt content sbc trend
115         ELSE                                   ! No restart or restart not found: Euler forward time stepping
116            zfact = 1._wp
117            sbc_tsc(:,:,:) = 0._wp
118            sbc_tsc_b(:,:,:) = 0._wp
119         ENDIF
120      ELSE                                !* other time-steps: swap of forcing fields
121         zfact = 0.5_wp
122         sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:)
123      ENDIF
124      !                             !==  Now sbc tracer content fields  ==!
125      DO jj = 2, jpj
126         DO ji = fs_2, fs_jpim1   ! vector opt.
127            sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj)   ! non solar heat flux
128            sbc_tsc(ji,jj,jp_sal) = r1_rau0     * sfx(ji,jj)   ! salt flux due to freezing/melting
129         END DO
130      END DO
131      IF( ln_linssh ) THEN                !* linear free surface 
132         DO jj = 2, jpj                         !==>> add concentration/dilution effect due to constant volume cell
133            DO ji = fs_2, fs_jpim1   ! vector opt.
134               sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem)
135               sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal)
136            END DO
137         END DO                                 !==>> output c./d. term
138         IF( iom_use('emp_x_sst') )   CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) )
139         IF( iom_use('emp_x_sss') )   CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) )
140      ENDIF
141      !
142      DO jn = 1, jpts               !==  update tracer trend  ==!
143         DO jj = 2, jpj
144            DO ji = fs_2, fs_jpim1   ! vector opt. 
145               tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1)
146            END DO
147         END DO
148      END DO
149      !                 
150      IF( lrst_oce ) THEN           !==  write sbc_tsc in the ocean restart file  ==!
151         CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) )
152         CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) )
153      ENDIF
154      !
155      !----------------------------------------
156      !       Ice Shelf effects (ISF)
157      !     tbl treated as in Losh (2008) JGR
158      !----------------------------------------
159      !
160!!gm BUG ?   Why no differences between non-linear and linear free surface ?
161!!gm         probably taken into account in r1_hisf_tbl : to be verified
162      IF( ln_isf ) THEN
163         zfact = 0.5_wp
164         DO jj = 2, jpj
165            DO ji = fs_2, fs_jpim1
166               !
167               ikt = misfkt(ji,jj)
168               ikb = misfkb(ji,jj)
169               !
170               ! level fully include in the ice shelf boundary layer
171               ! sign - because fwf sign of evapo (rnf sign of precip)
172               DO jk = ikt, ikb - 1
173               ! compute trend
174                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                                &
175                     &           + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
176                     &           * r1_hisf_tbl(ji,jj)
177               END DO
178   
179               ! level partially include in ice shelf boundary layer
180               ! compute trend
181               tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem)                                                 &
182                  &              + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) )             &
183                  &              * r1_hisf_tbl(ji,jj) * ralpha(ji,jj)
184
185            END DO
186         END DO
187      END IF
188      !
189      !----------------------------------------
190      !        River Runoff effects
191      !----------------------------------------
192      !
193      IF( ln_rnf ) THEN         ! input of heat and salt due to river runoff
194         zfact = 0.5_wp
195         DO jj = 2, jpj 
196            DO ji = fs_2, fs_jpim1
197               IF( rnf(ji,jj) /= 0._wp ) THEN
198                  zdep = zfact / h_rnf(ji,jj)
199                  DO jk = 1, nk_rnf(ji,jj)
200                                        tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)                                 &
201                                           &                 +  ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep
202                     IF( ln_rnf_sal )   tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)                                 &
203                                           &                 +  ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep 
204                  END DO
205               ENDIF
206            END DO 
207         END DO 
208      ENDIF
209
210      IF( iom_use('rnf_x_sst') )   CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) )   ! runoff term on sst
211      IF( iom_use('rnf_x_sss') )   CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) )   ! runoff term on sss
212
213#if defined key_asminc
214      !
215      !----------------------------------------
216      !        Assmilation effects
217      !----------------------------------------
218      !
219      IF( ln_sshinc ) THEN         ! input of heat and salt due to assimilation
220          !
221         ! Only required for vvl case (without vvl all the ssh increment is added to the surface layer and because the extra
222         ! water added by assimilation is always assumed to have the same T/S as the layer it is added to, and no additional T/S
223         ! content is explicitly added into qns/sfx due to ssh_iau, there is no need to include a compensating term to adjust
224         ! for it here)
225         !
226         IF( .NOT. ln_linssh ) THEN
227            DO jj = 2, jpj 
228               DO ji = fs_2, fs_jpim1
229                  zdep = ssh_iau(ji,jj) / ( ht_0(ji,jj) + 1.0 - ssmask(ji, jj) )
230                  DO jk = 1, jpkm1
231                     tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem)   &
232                                           &            + tsn(ji,jj,jk,jp_tem) * zdep * ( e3t_0(ji,jj,jk) / e3t_n(ji,jj,jk) )
233                     tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal)   &
234                                           &            + tsn(ji,jj,jk,jp_sal) * zdep * ( e3t_0(ji,jj,jk) / e3t_n(ji,jj,jk) )
235                  END DO
236               END DO 
237            END DO 
238         ENDIF
239         !
240      ENDIF
241#endif
242
243      !
244      !----------------------------------------
245      !        Ice Sheet coupling imbalance correction to have conservation
246      !----------------------------------------
247      !
248      IF( ln_iscpl .AND. ln_hsb) THEN         ! input of heat and salt due to river runoff
249         DO jk = 1,jpk
250            DO jj = 2, jpj 
251               DO ji = fs_2, fs_jpim1
252                  zdep = 1._wp / e3t_n(ji,jj,jk) 
253                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem)                       &
254                      &                                         * zdep
255                  tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal)                       &
256                      &                                         * zdep 
257               END DO 
258            END DO 
259         END DO
260      ENDIF
261
262      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
263         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
264         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
265         CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt )
266         CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds )
267         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) 
268      ENDIF
269      !
270      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc  - Ta: ', mask1=tmask,   &
271         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
272      !
273      IF( nn_timing == 1 )  CALL timing_stop('tra_sbc')
274      !
275   END SUBROUTINE tra_sbc
276
277   !!======================================================================
278END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.