New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcnxt.F90 in branches/2017/nemo_v3_6_STABLE_trdtrc/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2017/nemo_v3_6_STABLE_trdtrc/NEMOGCM/NEMO/TOP_SRC/TRP/trcnxt.F90 @ 8471

Last change on this file since 8471 was 8471, checked in by jpalmier, 7 years ago

JPALM -- #1933 -- add and correct passive tracer trends - needs improvements and testing
  • Property svn:keywords set to Id
File size: 13.5 KB
Line 
1MODULE trcnxt
2   !!======================================================================
3   !!                       ***  MODULE  trcnxt  ***
4   !! Ocean passive tracers:  time stepping on passives tracers
5   !!======================================================================
6   !! History :  7.0  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-02  (M. Levy)   passive tracers
9   !!                 !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
10   !!            8.0  !  1996-04  (A. Weaver)  Euler forward step
11   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
12   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!                 !  2002-08  (G. Madec)  F90: Free form and module
14   !!                 !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
15   !!                 !  2004-03  (C. Ethe) passive tracers
16   !!                 !  2007-02  (C. Deltel) Diagnose ML trends for passive tracers
17   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
18   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
19   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
20   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
21   !!----------------------------------------------------------------------
22#if defined key_top
23   !!----------------------------------------------------------------------
24   !!   'key_top'                                                TOP models
25   !!----------------------------------------------------------------------
26   !!   trc_nxt     : time stepping on passive tracers
27   !!----------------------------------------------------------------------
28   USE oce_trc         ! ocean dynamics and tracers variables
29   USE domvvl          ! variable volume 
30   USE trc             ! ocean passive tracers variables
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32   USE prtctl_trc      ! Print control for debbuging
33   USE trcnam_trp      ! passive tracers transport namelist variables
34   USE trd_oce
35   USE trdtra
36   USE tranxt
37# if defined key_agrif
38   USE agrif_top_interp
39# endif
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   trc_nxt          ! routine called by step.F90
45   PUBLIC   trc_nxt_alloc    ! routine called by nemogcm.F90
46
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt
48   REAL(wp)  ::  rfact1, rfact2
49
50   !! * Substitutions
51#  include "domzgr_substitute.h90"
52#  include "vectopt_loop_substitute.h90"
53   !!----------------------------------------------------------------------
54   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
55   !! $Id$
56   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
57   !!----------------------------------------------------------------------
58
59CONTAINS
60
61   INTEGER FUNCTION trc_nxt_alloc()
62      !!----------------------------------------------------------------------
63      !!                   ***  ROUTINE trc_nxt_alloc  ***
64      !!----------------------------------------------------------------------
65      ALLOCATE( r2dt(jpk), STAT=trc_nxt_alloc )
66      !
67      IF( trc_nxt_alloc /= 0 )   CALL ctl_warn('trc_nxt_alloc : failed to allocate array')
68      !
69   END FUNCTION trc_nxt_alloc
70
71
72   SUBROUTINE trc_nxt( kt )
73      !!----------------------------------------------------------------------
74      !!                   ***  ROUTINE trcnxt  ***
75      !!
76      !! ** Purpose :   Compute the passive tracers fields at the
77      !!      next time-step from their temporal trends and swap the fields.
78      !!
79      !! ** Method  :   Apply lateral boundary conditions on (ua,va) through
80      !!      call to lbc_lnk routine
81      !!   default:
82      !!      arrays swap
83      !!         (trn) = (tra) ; (tra) = (0,0)
84      !!         (trb) = (trn)
85      !!
86      !!   For Arakawa or TVD Scheme :
87      !!      A Asselin time filter applied on now tracers (trn) to avoid
88      !!      the divergence of two consecutive time-steps and tr arrays
89      !!      to prepare the next time_step:
90      !!         (trb) = (trn) + atfp [ (trb) + (tra) - 2 (trn) ]
91      !!         (trn) = (tra) ; (tra) = (0,0)
92      !!
93      !!
94      !! ** Action  : - update trb, trn
95      !!----------------------------------------------------------------------
96      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
97      !
98      INTEGER  ::   jk, jn   ! dummy loop indices
99      REAL(wp) ::   zfact            ! temporary scalar
100      CHARACTER (len=22) :: charout
101      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  ztrdt 
102      !!----------------------------------------------------------------------
103      !
104      IF( nn_timing == 1 )  CALL timing_start('trc_nxt')
105      !
106      IF( kt == nittrc000 .AND. lwp ) THEN
107         WRITE(numout,*)
108         WRITE(numout,*) 'trc_nxt : time stepping on passive tracers'
109      ENDIF
110
111#if defined key_agrif
112      CALL Agrif_trc                   ! AGRIF zoom boundaries
113#endif
114      ! Update after tracer on domain lateral boundaries
115      DO jn = 1, jptra
116         CALL lbc_lnk( tra(:,:,:,jn), 'T', 1. )   
117      END DO
118
119
120#if defined key_bdy
121!!      CALL bdy_trc( kt )               ! BDY open boundaries
122#endif
123
124
125      ! set time step size (Euler/Leapfrog)
126      IF( (neuler == 0 .AND. kt == nittrc000) .OR. ln_top_euler ) THEN  ;  r2dt(:) =     rdttrc(:)   !    (Euler)
127      ELSEIF( kt <= nittrc000 + nn_dttrc )     THEN  ;  r2dt(:) = 2.* rdttrc(:)   ! at nit000 or nit000+1 (Leapfrog)
128      ENDIF
129
130      ! trends computation initialisation
131      IF( l_trdtrc )  THEN
132         CALL wrk_alloc( jpi, jpj, jpk, jptra, ztrdt )  !* store now fields before applying the Asselin filter
133         ztrdt(:,:,jpk,:) = 0._wp
134         IF( ln_trcldf_iso ) THEN                       ! diagnose the "pure" Kz diffusive trend
135            DO jn = 1, jptra
136               CALL trd_tra( kt, 'TRC', jn, jptra_zdfp, ztrdt(:,:,:,jn) )
137            ENDDO
138         ENDIF
139         ! total trend for the non-time-filtered variables.
140         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn
141         ! cancel from tsn terms
142         IF( lk_vvl ) THEN
143            DO jn = 1, jptra
144               DO jk = 1, jpkm1
145                  zfact = 1.0 / rdttrc(jk)
146                  ztrdt(:,:,jk,jn) = ( tra(:,:,jk,jn)*fse3t_a(:,:,jk) / fse3t_n(:,:,jk) - &
147                                       trn(:,:,jk,jn) ) * zfact
148               END DO
149            END DO
150         ELSE
151            DO jn = 1, jptra
152               DO jk = 1, jpkm1
153                  zfact = 1.0 / rdttrc(jk)
154                  ztrdt(:,:,jk,jn) = ( tra(:,:,jk,jn) - trn(:,:,jk,jn) ) * zfact
155               END DO
156            END DO
157         END IF
158         DO jn = 1, jptra
159            CALL trd_tra( kt, 'TRC', jn, jptra_tot, ztrdt(:,:,:,jn) )
160         ENDDO
161         IF( .NOT.lk_vvl )  THEN
162            ! Store now fields before applying the Asselin filter
163            ! in order to calculate Asselin filter trend later.
164            ztrdt(:,:,:,:)  = trn(:,:,:,:)
165         ENDIF
166      ENDIF
167      ! Leap-Frog + Asselin filter time stepping
168      IF( (neuler == 0 .AND. kt == nittrc000) .OR. ln_top_euler ) THEN        ! Euler time-stepping (only swap)
169         !                                                ! (only swap)
170         DO jn = 1, jptra
171            DO jk = 1, jpkm1
172               trn(:,:,jk,jn) = tra(:,:,jk,jn)
173            END DO
174         END DO
175         IF (l_trdtrc.AND.lk_vvl) THEN      ! Zero Asselin filter contribution
176                                            ! must be explicitly written out since for vvl
177                                            ! Asselin filter is output by
178                                            ! tra_nxt_vvl that is not called on
179                                            ! this time step
180            ztrdt(:,:,:,:) = 0._wp
181            DO jn = 1, jptra
182               CALL trd_tra( kt, 'TRC', jn, jptra_atf, ztrdt(:,:,:,jn) )
183            ENDDO
184         END IF
185
186         !                                             
187      ELSE
188         IF( .NOT. lk_offline ) THEN ! Leap-Frog + Asselin filter time stepping
189            IF( lk_vvl ) THEN   ;   CALL tra_nxt_vvl( kt, nittrc000, rdttrc, 'TRC', trb, trn, tra,      &
190              &                                                                sbc_trc, sbc_trc_b, jptra )      ! variable volume level (vvl)
191            ELSE                ;   CALL tra_nxt_fix( kt, nittrc000,         'TRC', trb, trn, tra, jptra )      ! fixed    volume level
192            ENDIF
193         ELSE
194                                    CALL trc_nxt_off( kt )       ! offline
195         ENDIF
196      ENDIF
197
198      ! trends computation
199      IF( l_trdtrc.AND..NOT.lk_vvl) THEN                                      ! trends
200         DO jn = 1, jptra
201            DO jk = 1, jpkm1
202               zfact = 1.e0 / r2dt(jk) 
203               ztrdt(:,:,jk,jn) = ( trb(:,:,jk,jn) - ztrdt(:,:,jk,jn) ) * zfact 
204            END DO
205            CALL trd_tra( kt, 'TRC', jn, jptra_atf, ztrdt(:,:,:,jn) )
206         END DO
207      END IF
208      !
209      IF( l_trdtrc)  CALL wrk_dealloc( jpi, jpj, jpk, jptra, ztrdt ) 
210      !
211      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
212         WRITE(charout, FMT="('nxt')")
213         CALL prt_ctl_trc_info(charout)
214         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
215      ENDIF
216      !
217      IF( nn_timing == 1 )  CALL timing_stop('trc_nxt')
218      !
219   END SUBROUTINE trc_nxt
220
221   SUBROUTINE trc_nxt_off( kt )
222      !!----------------------------------------------------------------------
223      !!                   ***  ROUTINE tra_nxt_vvl  ***
224      !!
225      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
226      !!                and swap the tracer fields.
227      !!
228      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
229      !!              - save in (ta,sa) a thickness weighted average over the three
230      !!             time levels which will be used to compute rdn and thus the semi-
231      !!             implicit hydrostatic pressure gradient (ln_dynhpg_imp = T)
232      !!              - swap tracer fields to prepare the next time_step.
233      !!                This can be summurized for tempearture as:
234      !!             ztm = ( e3t_n*tn + rbcp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )   ln_dynhpg_imp = T
235      !!                  /( e3t_n    + rbcp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )   
236      !!             ztm = 0                                                       otherwise
237      !!             tb  = ( e3t_n*tn + atfp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )
238      !!                  /( e3t_n    + atfp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )
239      !!             tn  = ta
240      !!             ta  = zt        (NB: reset to 0 after eos_bn2 call)
241      !!
242      !! ** Action  : - (tb,sb) and (tn,sn) ready for the next time step
243      !!              - (ta,sa) time averaged (t,s)   (ln_dynhpg_imp = T)
244      !!----------------------------------------------------------------------
245      INTEGER         , INTENT(in   )                               ::  kt       ! ocean time-step index
246      !!     
247      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
248      REAL(wp) ::   ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
249      REAL(wp) ::   ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d   !   -      -
250      !!----------------------------------------------------------------------
251      !
252      IF( kt == nittrc000 )  THEN
253         IF(lwp) WRITE(numout,*)
254         IF(lwp) WRITE(numout,*) 'trc_nxt_off : time stepping'
255         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
256         IF( lk_vvl ) THEN
257           rfact1 = atfp * rdttrc(1)
258           rfact2 = rfact1 / rau0
259         ENDIF
260      ENDIF
261      !
262      DO jn = 1, jptra     
263         DO jk = 1, jpkm1
264            DO jj = 1, jpj
265               DO ji = 1, jpi
266                  ze3t_b = fse3t_b(ji,jj,jk)
267                  ze3t_n = fse3t_n(ji,jj,jk)
268                  ze3t_a = fse3t_a(ji,jj,jk)
269                  !                                         ! tracer content at Before, now and after
270                  ztc_b  = trb(ji,jj,jk,jn) * ze3t_b
271                  ztc_n  = trn(ji,jj,jk,jn) * ze3t_n
272                  ztc_a  = tra(ji,jj,jk,jn) * ze3t_a
273                  !
274                  ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
275                  ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
276                  !
277                  ze3t_f = ze3t_n + atfp * ze3t_d
278                  ztc_f  = ztc_n  + atfp * ztc_d
279                  !
280                  IF( lk_vvl .AND. jk == mikt(ji,jj) ) THEN           ! first level
281                     ze3t_f = ze3t_f - rfact2 * ( emp_b(ji,jj)      - emp(ji,jj)   ) 
282                     ztc_f  = ztc_f  - rfact1 * ( sbc_trc(ji,jj,jn) - sbc_trc_b(ji,jj,jn) )
283                  ENDIF
284
285                  ze3t_f = 1.e0 / ze3t_f
286                  trb(ji,jj,jk,jn) = ztc_f * ze3t_f       ! ptb <-- ptn filtered
287                  trn(ji,jj,jk,jn) = tra(ji,jj,jk,jn)     ! ptn <-- pta
288                  !
289               END DO
290            END DO
291         END DO
292         !
293      END DO
294      !
295   END SUBROUTINE trc_nxt_off
296#else
297   !!----------------------------------------------------------------------
298   !!   Default option                                         Empty module
299   !!----------------------------------------------------------------------
300CONTAINS
301   SUBROUTINE trc_nxt( kt ) 
302      INTEGER, INTENT(in) :: kt
303      WRITE(*,*) 'trc_nxt: You should not have seen this print! error?', kt
304   END SUBROUTINE trc_nxt
305#endif
306   !!======================================================================
307END MODULE trcnxt
Note: See TracBrowser for help on using the repository browser.