source: branches/2017/wrk_OMP_test_for_Silvia/NEMOGCM/NEMO/OPA_SRC/DOM/dom_omp.F90 @ 8279

MODULE dom_omp
   !!======================================================================
   !!                      ***  MODULE  domain_omp  ***
   !! OpenMP horizontal decoposition : OpenMP threads domain decomposition 
   !!======================================================================
   !! History :  4.0  !  2017-05  (S. Mocavero - F. Mele)  original code
   !!----------------------------------------------------------------------

   !!----------------------------------------------------------------------
   !!   tile_dec_2D  : initialize local threads indices
   !!----------------------------------------------------------------------

  USE par_oce        ! ocean space and time domain
  USE in_out_manager ! I/O manager

  IMPLICIT NONE

  INTEGER         :: jtni 
  INTEGER         :: jtnj
  INTEGER         :: jtnij

  INTEGER         :: tnarea
  INTEGER         :: tnareai
  INTEGER         :: tnareaj

  INTEGER,SAVE    :: tnldi,tnldj
  INTEGER,SAVE    :: tnlei,tnlej
!$OMP THREADPRIVATE(tnldi,tnldj,tnlei,tnlej)

CONTAINS
  SUBROUTINE tile_dec_2D
      !!----------------------------------------------------------------------
      !!                     ***  ROUTINE tile_dec_2D  ***
      !!                    
      !! ** Purpose :   read namomp namelists and initialize local threads indices
      !!
      !! ** input   : - namomp namelist
      !!----------------------------------------------------------------------
      INTEGER :: ii,jj
      INTEGER :: tnlci,tnlcj
      INTEGER :: omp_get_thread_num
      INTEGER :: omp_get_num_threads
      INTEGER :: ios
      !
      NAMELIST/namomp/ jtni
      !!----------------------------------------------------------------------
      REWIND( numnam_cfg )
      READ  ( numnam_cfg, namomp, IOSTAT = ios )

      CALL OMP_SET_DYNAMIC(.FALSE.)

!$OMP PARALLEL PRIVATE(tnarea,tnareai,tnareaj,ii,jj,tnlci,tnlcj)
!$OMP SINGLE
      jtnij = omp_get_num_threads()
        
      jtnj = jtnij / jtni          ! threads number along domain latitude
      IF((jtni.GT.jtnij).OR.(MOD(jtnij,jtni).NE.0)) THEN
         WRITE(*,*) ' tile_dec_2D: Error while setting OpenMP decomposition' 
         WRITE(*,*) ' -> disabled OpenMP decomposition on  direction' 
         jtni = 1
         jtnj = jtnij
      ENDIF
!$OMP END SINGLE

      tnarea = omp_get_thread_num()
      tnareai = MOD(tnarea, jtni)
      tnareaj = tnarea / jtni

      tnlei=0
      DO ii=0,tnareai
         tnldi=tnlei+1
         tnlci=jpi/jtni
         IF (MOD(jpi,jtni)>ii) tnlci=tnlci+1
         tnlei=tnldi+tnlci-1
      ENDDO

      tnlej=0
      DO jj=0,tnareaj
         tnldj=tnlej+1
         tnlcj=jpj/jtnj
         IF (MOD(jpj,jtnj)>jj) tnlcj=tnlcj+1
         tnlej=tnldj+tnlcj-1
      ENDDO

      IF(tnareai == 0) THEN
#if defined key_vectopt_loop
         tnldi = 1
#else
         tnldi = 2
#endif
      END IF

      IF(tnareaj == 0) THEN
         tnldj = 2
      END IF

      IF(tnareai == jtni-1) THEN
#if defined key_vectopt_loop
         tnlei = jpi
#else
         tnlei = jpim1
#endif
      ENDIF

      IF(tnareaj == jtnj-1) THEN
         tnlej = jpjm1
      ENDIF
!$OMP END PARALLEL

  END SUBROUTINE tile_dec_2D

END MODULE dom_omp