source: branches/CMIP5_IPSL/NEMO/TOP_SRC/PISCES/p4zmicro.F90 @ 1808

Last change on this file since 1808 was 1808, checked in by cetlod, 11 years ago

update TOP_SRC component on CMIP5_IPSL branch to take into account bugfixes (ie vertical diffusion routines), re-organization of restart part, damping of passive tracers on closed seas for PISCES

  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 12.7 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
14   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
15   !!----------------------------------------------------------------------
16   USE trc
17   USE oce_trc         !
18   USE trc         !
19   USE sms_pisces      !
20   USE prtctl_trc
21   USE p4zint
22   USE p4zsink
23   USE iom
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_micro    ! called in p4zbio.F90
29
30   !! * Shared module variables
31   REAL(wp), PUBLIC ::   &
32      xpref2c = 0.0_wp       ,  &  !:
33      xpref2p = 0.5_wp       ,  &  !:
34      xpref2d = 0.5_wp       ,  &  !:
35      resrat  = 0.03_wp      ,  &  !:
36      mzrat   = 0.0_wp       ,  &  !:
37      grazrat = 4.0_wp       ,  &  !:
38      xkgraz  = 20E-6_wp     ,  &  !:
39      unass   = 0.3_wp       ,  &  !:
40      sigma1  = 0.6_wp       ,  &  !:
41      epsher  = 0.33_wp
42
43
44   !!* Substitution
45#  include "top_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
48   !! $Id$
49   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE p4z_micro( kt,jnt )
55      !!---------------------------------------------------------------------
56      !!                     ***  ROUTINE p4z_micro  ***
57      !!
58      !! ** Purpose :   Compute the sources/sinks for microzooplankton
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
63      INTEGER  :: ji, jj, jk
64      REAL(wp) :: zcompadi, zcompadi2, zcompaz , zcompaph, zcompapoc
65      REAL(wp) :: zgraze  , zdenom  , zdenom2
66      REAL(wp) :: zfact   , zstep   , zinano , zidiat, zipoc
67      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
68      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zrespz,ztortz
69      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazp, zgrazm, zgrazsd
70      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazmf, zgrazsf, zgrazpf
71      CHARACTER (len=25) :: charout
72#if defined key_trc_diaadd && defined key_trc_dia3d && defined key_iomput
73      REAL(wp) :: zrfact2
74      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zw3d
75#endif
76
77      !!---------------------------------------------------------------------
78
79      IF( ( kt * jnt ) == nittrc000  )   CALL p4z_micro_init      ! Initialization (first time-step only)
80
81      zrespz (:,:,:) = 0.
82      ztortz (:,:,:) = 0.
83      zgrazp (:,:,:) = 0.
84      zgrazm (:,:,:) = 0.
85      zgrazsd(:,:,:) = 0.
86      zgrazmf(:,:,:) = 0.
87      zgrazsf(:,:,:) = 0.
88      zgrazpf(:,:,:) = 0.
89
90
91      zstep = rfact2 / rday      ! Time step duration for biology
92
93      DO jk = 1, jpkm1
94         DO jj = 1, jpj
95            DO ji = 1, jpi
96
97               zcompaz = MAX( ( trn(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
98# if defined key_off_degrad
99               zfact   = zstep * tgfunc(ji,jj,jk) * zcompaz *facvol(ji,jj,jk)
100# else
101               zfact   = zstep * tgfunc(ji,jj,jk) * zcompaz
102# endif
103
104!     Respiration rates of both zooplankton
105!     -------------------------------------
106
107               zrespz(ji,jj,jk) = resrat * zfact  * ( 1.+ 3.* nitrfac(ji,jj,jk) )     &
108                  &            * trn(ji,jj,jk,jpzoo) / ( xkmort + trn(ji,jj,jk,jpzoo) )
109
110!     Zooplankton mortality. A square function has been selected with
111!     no real reason except that it seems to be more stable and may
112!     mimic predation.
113!     ---------------------------------------------------------------
114               ztortz(ji,jj,jk) = mzrat * 1.e6 * zfact * trn(ji,jj,jk,jpzoo)
115
116            END DO
117         END DO
118      END DO
119
120
121 
122      DO jk = 1,jpkm1
123         DO jj = 1,jpj
124            DO ji = 1,jpi
125               zcompadi  = MAX( ( trn(ji,jj,jk,jpdia) - 1.e-8 ), 0.e0 )
126               zcompadi2 = MIN( zcompadi, 5.e-7 )
127               zcompaph  = MAX( ( trn(ji,jj,jk,jpphy) - 2.e-7 ), 0.e0 )
128               zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - 1.e-8 ), 0.e0 )
129               
130               !     Microzooplankton grazing
131               !     ------------------------
132               zdenom2 = 1./ ( xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi2 + rtrn )
133
134               zgraze = grazrat * zstep * tgfunc(ji,jj,jk)     &
135# if defined key_off_degrad
136                  &      * facvol(ji,jj,jk)         &
137# endif
138                  &      * trn(ji,jj,jk,jpzoo)
139
140               zinano = xpref2p * zcompaph  * zdenom2
141               zipoc  = xpref2c * zcompapoc * zdenom2
142               zidiat = xpref2d * zcompadi2 * zdenom2
143
144               zdenom = 1./ ( xkgraz + zinano * zcompaph + zipoc * zcompapoc + zidiat * zcompadi2 )
145
146               zgrazp(ji,jj,jk)  = zgraze * zinano * zcompaph * zdenom
147               zgrazm(ji,jj,jk)  = zgraze * zipoc  * zcompapoc * zdenom
148               zgrazsd(ji,jj,jk) = zgraze * zidiat * zcompadi2 * zdenom
149
150               zgrazpf (ji,jj,jk) = zgrazp(ji,jj,jk)  * trn(ji,jj,jk,jpnfe) / (trn(ji,jj,jk,jpphy) + rtrn)
151               zgrazmf(ji,jj,jk)  = zgrazm(ji,jj,jk)  * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
152               zgrazsf(ji,jj,jk)  = zgrazsd(ji,jj,jk) * trn(ji,jj,jk,jpdfe) / (trn(ji,jj,jk,jpdia) + rtrn)
153
154            END DO
155         END DO
156      END DO
157     
158
159      DO jk = 1,jpkm1
160         DO jj = 1,jpj
161            DO ji = 1,jpi
162!    Various remineralization and excretion terms
163!    --------------------------------------------
164
165               zgrarem = (  zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk)  + zgrazsd(ji,jj,jk)  ) &
166                  &          * ( 1.- epsher - unass )
167               zgrafer = (  zgrazpf(ji,jj,jk) + zgrazsf(ji,jj,jk)  + zgrazmf(ji,jj,jk)  ) &
168                  &        * ( 1.- epsher - unass ) + epsher *  &
169                  &  ( zgrazm(ji,jj,jk)  * MAX((trn(ji,jj,jk,jpsfe) /(trn(ji,jj,jk,jppoc)+ rtrn)-ferat3),0.e0) &
170                  &   + zgrazp(ji,jj,jk)  * MAX((trn(ji,jj,jk,jpnfe)/(trn(ji,jj,jk,jpphy)+ rtrn)-ferat3),0.e0) &
171                  &   + zgrazsd(ji,jj,jk) * MAX((trn(ji,jj,jk,jpdfe)/(trn(ji,jj,jk,jpdia)+ rtrn)-ferat3),0.e0 )  )
172               zgrapoc = (  zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk) + zgrazsd(ji,jj,jk)  ) * unass
173
174               !  Update of the TRA arrays
175               !  ------------------------
176
177               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarem * sigma1
178               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarem * sigma1
179               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem * (1.-sigma1)
180               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem * sigma1
181               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
182               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
183               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem * sigma1
184#if defined key_kriest
185               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc * xkr_ddiat
186#endif
187            END DO
188         END DO
189      END DO
190
191!
192!   Update the arrays TRA which contain the biological sources and sinks
193!   --------------------------------------------------------------------
194
195      DO jk = 1, jpkm1
196         DO jj = 1, jpj
197            DO ji = 1, jpi
198
199               zmortz = ztortz(ji,jj,jk) + zrespz(ji,jj,jk)
200               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz  &
201                 &     + epsher * ( zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk) + zgrazsd(ji,jj,jk))
202               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp(ji,jj,jk)
203               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd(ji,jj,jk)
204               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp(ji,jj,jk)  &
205                 &     * trn(ji,jj,jk,jpnch)/(trn(ji,jj,jk,jpphy)+rtrn)
206               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd(ji,jj,jk) &
207                 &     * trn(ji,jj,jk,jpdch)/(trn(ji,jj,jk,jpdia)+rtrn)
208               tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) - zgrazsd(ji,jj,jk) &
209                 &     * trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)
210               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zgrazsd(ji,jj,jk) &
211                 &     * trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)
212               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf(ji,jj,jk)
213               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf(ji,jj,jk)
214               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm(ji,jj,jk)
215               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz   &
216                 &     + unass * ( zgrazpf(ji,jj,jk) + zgrazsf (ji,jj,jk)) &
217                 &     - (1.-unass) * zgrazmf(ji,jj,jk)
218               zprcaca = xfracal(ji,jj,jk) * unass * zgrazp(ji,jj,jk)
219#if defined key_trc_dia3d
220               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
221#endif
222               zprcaca = part * zprcaca
223               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
224               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
225               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
226#if defined key_kriest
227               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ( zmortz - zgrazm(ji,jj,jk) ) * xkr_ddiat
228#endif
229            END DO
230         END DO
231      END DO
232      !
233#if defined key_trc_diaadd && defined key_trc_dia3d && defined key_iomput
234      zrfact2 = 1.e3 * rfact2r
235      zw3d(:,:,:) = ( zgrazp(:,:,:) + zgrazm(:,:,:) + zgrazsd(:,:,:) ) * zrfact2 * tmask(:,:,:)
236      IF( jnt == nrdttrc ) CALL iom_put( "Graz" , zw3d )
237#endif
238
239       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
240         WRITE(charout, FMT="('micro')")
241         CALL prt_ctl_trc_info(charout)
242         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
243       ENDIF
244
245   END SUBROUTINE p4z_micro
246
247
248   SUBROUTINE p4z_micro_init
249
250      !!----------------------------------------------------------------------
251      !!                  ***  ROUTINE p4z_micro_init  ***
252      !!
253      !! ** Purpose :   Initialization of microzooplankton parameters
254      !!
255      !! ** Method  :   Read the nampiszoo namelist and check the parameters
256      !!      called at the first timestep (nittrc000)
257      !!
258      !! ** input   :   Namelist nampiszoo
259      !!
260      !!----------------------------------------------------------------------
261
262      NAMELIST/nampiszoo/ grazrat,resrat,mzrat,xpref2c, xpref2p, &
263         &             xpref2d, xkgraz, epsher, sigma1, unass
264
265      REWIND( numnat )                     ! read numnat
266      READ  ( numnat, nampiszoo )
267
268      IF(lwp) THEN                         ! control print
269         WRITE(numout,*) ' '
270         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszoo'
271         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
272         WRITE(numout,*) '    zoo preference for POC                    xpref2c    =', xpref2c
273         WRITE(numout,*) '    zoo preference for nano                   xpref2p    =', xpref2p
274         WRITE(numout,*) '    zoo preference for diatoms                xpref2d    =', xpref2d
275         WRITE(numout,*) '    exsudation rate of microzooplankton       resrat    =', resrat
276         WRITE(numout,*) '    microzooplankton mortality rate           mzrat     =', mzrat
277         WRITE(numout,*) '    maximal microzoo grazing rate             grazrat   =', grazrat
278         WRITE(numout,*) '    non assimilated fraction of P by microzoo unass     =', unass
279         WRITE(numout,*) '    Efficicency of microzoo growth            epsher    =', epsher
280         WRITE(numout,*) '    Fraction of microzoo excretion as DOM     sigma1    =', sigma1
281         WRITE(numout,*) '    half sturation constant for grazing 1     xkgraz    =', xkgraz
282      ENDIF
283
284   END SUBROUTINE p4z_micro_init
285
286#else
287   !!======================================================================
288   !!  Dummy module :                                   No PISCES bio-model
289   !!======================================================================
290CONTAINS
291   SUBROUTINE p4z_micro                    ! Empty routine
292   END SUBROUTINE p4z_micro
293#endif 
294
295   !!======================================================================
296END MODULE  p4zmicro
Note: See TracBrowser for help on using the repository browser.