source: branches/CMIP5_IPSL/NEMO/TOP_SRC/PISCES/p4zmicro.F90 @ 1830

Last change on this file since 1830 was 1830, checked in by cetlod, 11 years ago

Computation of additional diagnostics for PISCES model ( under CPP key key_diaar5 )

  • needed for AR5 outputs (vertical inventories, passive tracers at surface,… )
  • new output file with suffix dbio_T
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 12.5 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
14   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
15   !!----------------------------------------------------------------------
16   USE trc
17   USE oce_trc         !
18   USE trc         !
19   USE sms_pisces      !
20   USE prtctl_trc
21   USE p4zint
22   USE p4zsink
23   USE iom
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_micro    ! called in p4zbio.F90
29
30   !! * Shared module variables
31   REAL(wp), PUBLIC ::   &
32      xpref2c = 0.0_wp       ,  &  !:
33      xpref2p = 0.5_wp       ,  &  !:
34      xpref2d = 0.5_wp       ,  &  !:
35      resrat  = 0.03_wp      ,  &  !:
36      mzrat   = 0.0_wp       ,  &  !:
37      grazrat = 4.0_wp       ,  &  !:
38      xkgraz  = 20E-6_wp     ,  &  !:
39      unass   = 0.3_wp       ,  &  !:
40      sigma1  = 0.6_wp       ,  &  !:
41      epsher  = 0.33_wp
42
43
44   !!* Substitution
45#  include "top_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
48   !! $Id$
49   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE p4z_micro( kt,jnt )
55      !!---------------------------------------------------------------------
56      !!                     ***  ROUTINE p4z_micro  ***
57      !!
58      !! ** Purpose :   Compute the sources/sinks for microzooplankton
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
63      INTEGER  :: ji, jj, jk
64      REAL(wp) :: zcompadi, zcompadi2, zcompaz , zcompaph, zcompapoc
65      REAL(wp) :: zgraze  , zdenom  , zdenom2
66      REAL(wp) :: zfact   , zstep   , zinano , zidiat, zipoc
67      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
68      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zrespz,ztortz
69      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazp, zgrazm, zgrazsd
70      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazmf, zgrazsf, zgrazpf
71      CHARACTER (len=25) :: charout
72
73      !!---------------------------------------------------------------------
74
75      IF( ( kt * jnt ) == nittrc000  )   CALL p4z_micro_init      ! Initialization (first time-step only)
76
77      zrespz (:,:,:) = 0.
78      ztortz (:,:,:) = 0.
79      zgrazp (:,:,:) = 0.
80      zgrazm (:,:,:) = 0.
81      zgrazsd(:,:,:) = 0.
82      zgrazmf(:,:,:) = 0.
83      zgrazsf(:,:,:) = 0.
84      zgrazpf(:,:,:) = 0.
85
86#if defined key_trc_dia3d
87      grazing(:,:,:) = 0.  !: Initialisation of  grazing
88#endif
89
90      zstep = rfact2 / rday      ! Time step duration for biology
91
92      DO jk = 1, jpkm1
93         DO jj = 1, jpj
94            DO ji = 1, jpi
95
96               zcompaz = MAX( ( trn(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
97# if defined key_off_degrad
98               zfact   = zstep * tgfunc(ji,jj,jk) * zcompaz *facvol(ji,jj,jk)
99# else
100               zfact   = zstep * tgfunc(ji,jj,jk) * zcompaz
101# endif
102
103!     Respiration rates of both zooplankton
104!     -------------------------------------
105
106               zrespz(ji,jj,jk) = resrat * zfact  * ( 1.+ 3.* nitrfac(ji,jj,jk) )     &
107                  &            * trn(ji,jj,jk,jpzoo) / ( xkmort + trn(ji,jj,jk,jpzoo) )
108
109!     Zooplankton mortality. A square function has been selected with
110!     no real reason except that it seems to be more stable and may
111!     mimic predation.
112!     ---------------------------------------------------------------
113               ztortz(ji,jj,jk) = mzrat * 1.e6 * zfact * trn(ji,jj,jk,jpzoo)
114
115            END DO
116         END DO
117      END DO
118
119
120 
121      DO jk = 1,jpkm1
122         DO jj = 1,jpj
123            DO ji = 1,jpi
124               zcompadi  = MAX( ( trn(ji,jj,jk,jpdia) - 1.e-8 ), 0.e0 )
125               zcompadi2 = MIN( zcompadi, 5.e-7 )
126               zcompaph  = MAX( ( trn(ji,jj,jk,jpphy) - 2.e-7 ), 0.e0 )
127               zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - 1.e-8 ), 0.e0 )
128               
129               !     Microzooplankton grazing
130               !     ------------------------
131               zdenom2 = 1./ ( xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi2 + rtrn )
132
133               zgraze = grazrat * zstep * tgfunc(ji,jj,jk)     &
134# if defined key_off_degrad
135                  &      * facvol(ji,jj,jk)         &
136# endif
137                  &      * trn(ji,jj,jk,jpzoo)
138
139               zinano = xpref2p * zcompaph  * zdenom2
140               zipoc  = xpref2c * zcompapoc * zdenom2
141               zidiat = xpref2d * zcompadi2 * zdenom2
142
143               zdenom = 1./ ( xkgraz + zinano * zcompaph + zipoc * zcompapoc + zidiat * zcompadi2 )
144
145               zgrazp(ji,jj,jk)  = zgraze * zinano * zcompaph * zdenom
146               zgrazm(ji,jj,jk)  = zgraze * zipoc  * zcompapoc * zdenom
147               zgrazsd(ji,jj,jk) = zgraze * zidiat * zcompadi2 * zdenom
148
149               zgrazpf (ji,jj,jk) = zgrazp(ji,jj,jk)  * trn(ji,jj,jk,jpnfe) / (trn(ji,jj,jk,jpphy) + rtrn)
150               zgrazmf(ji,jj,jk)  = zgrazm(ji,jj,jk)  * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
151               zgrazsf(ji,jj,jk)  = zgrazsd(ji,jj,jk) * trn(ji,jj,jk,jpdfe) / (trn(ji,jj,jk,jpdia) + rtrn)
152
153            END DO
154         END DO
155      END DO
156     
157#if defined key_trc_dia3d
158      ! Grazing by microzooplankton
159      grazing(:,:,:) = grazing(:,:,:) + zgrazp(:,:,:) + zgrazm(:,:,:) + zgrazsd(:,:,:) 
160#endif
161
162      DO jk = 1,jpkm1
163         DO jj = 1,jpj
164            DO ji = 1,jpi
165!    Various remineralization and excretion terms
166!    --------------------------------------------
167
168               zgrarem = (  zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk)  + zgrazsd(ji,jj,jk)  ) &
169                  &          * ( 1.- epsher - unass )
170               zgrafer = (  zgrazpf(ji,jj,jk) + zgrazsf(ji,jj,jk)  + zgrazmf(ji,jj,jk)  ) &
171                  &        * ( 1.- epsher - unass ) + epsher *  &
172                  &  ( zgrazm(ji,jj,jk)  * MAX((trn(ji,jj,jk,jpsfe) /(trn(ji,jj,jk,jppoc)+ rtrn)-ferat3),0.e0) &
173                  &   + zgrazp(ji,jj,jk)  * MAX((trn(ji,jj,jk,jpnfe)/(trn(ji,jj,jk,jpphy)+ rtrn)-ferat3),0.e0) &
174                  &   + zgrazsd(ji,jj,jk) * MAX((trn(ji,jj,jk,jpdfe)/(trn(ji,jj,jk,jpdia)+ rtrn)-ferat3),0.e0 )  )
175               zgrapoc = (  zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk) + zgrazsd(ji,jj,jk)  ) * unass
176
177               !  Update of the TRA arrays
178               !  ------------------------
179
180               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarem * sigma1
181               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarem * sigma1
182               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem * (1.-sigma1)
183               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem * sigma1
184               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
185               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc
186               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem * sigma1
187#if defined key_kriest
188               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc * xkr_ddiat
189#endif
190            END DO
191         END DO
192      END DO
193
194!
195!   Update the arrays TRA which contain the biological sources and sinks
196!   --------------------------------------------------------------------
197
198      DO jk = 1, jpkm1
199         DO jj = 1, jpj
200            DO ji = 1, jpi
201
202               zmortz = ztortz(ji,jj,jk) + zrespz(ji,jj,jk)
203               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz  &
204                 &     + epsher * ( zgrazp(ji,jj,jk) + zgrazm(ji,jj,jk) + zgrazsd(ji,jj,jk))
205               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp(ji,jj,jk)
206               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd(ji,jj,jk)
207               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp(ji,jj,jk)  &
208                 &     * trn(ji,jj,jk,jpnch)/(trn(ji,jj,jk,jpphy)+rtrn)
209               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd(ji,jj,jk) &
210                 &     * trn(ji,jj,jk,jpdch)/(trn(ji,jj,jk,jpdia)+rtrn)
211               tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) - zgrazsd(ji,jj,jk) &
212                 &     * trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)
213               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zgrazsd(ji,jj,jk) &
214                 &     * trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)
215               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf(ji,jj,jk)
216               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf(ji,jj,jk)
217               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm(ji,jj,jk)
218               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz   &
219                 &     + unass * ( zgrazpf(ji,jj,jk) + zgrazsf (ji,jj,jk)) &
220                 &     - (1.-unass) * zgrazmf(ji,jj,jk)
221               zprcaca = xfracal(ji,jj,jk) * unass * zgrazp(ji,jj,jk)
222#if defined key_trc_dia3d
223               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
224#endif
225               zprcaca = part * zprcaca
226               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
227               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
228               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
229#if defined key_kriest
230               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ( zmortz - zgrazm(ji,jj,jk) ) * xkr_ddiat
231#endif
232            END DO
233         END DO
234      END DO
235      !
236      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
237         WRITE(charout, FMT="('micro')")
238         CALL prt_ctl_trc_info(charout)
239         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
240      ENDIF
241
242   END SUBROUTINE p4z_micro
243
244
245   SUBROUTINE p4z_micro_init
246
247      !!----------------------------------------------------------------------
248      !!                  ***  ROUTINE p4z_micro_init  ***
249      !!
250      !! ** Purpose :   Initialization of microzooplankton parameters
251      !!
252      !! ** Method  :   Read the nampiszoo namelist and check the parameters
253      !!      called at the first timestep (nittrc000)
254      !!
255      !! ** input   :   Namelist nampiszoo
256      !!
257      !!----------------------------------------------------------------------
258
259      NAMELIST/nampiszoo/ grazrat,resrat,mzrat,xpref2c, xpref2p, &
260         &             xpref2d, xkgraz, epsher, sigma1, unass
261
262      REWIND( numnat )                     ! read numnat
263      READ  ( numnat, nampiszoo )
264
265      IF(lwp) THEN                         ! control print
266         WRITE(numout,*) ' '
267         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszoo'
268         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
269         WRITE(numout,*) '    zoo preference for POC                    xpref2c    =', xpref2c
270         WRITE(numout,*) '    zoo preference for nano                   xpref2p    =', xpref2p
271         WRITE(numout,*) '    zoo preference for diatoms                xpref2d    =', xpref2d
272         WRITE(numout,*) '    exsudation rate of microzooplankton       resrat    =', resrat
273         WRITE(numout,*) '    microzooplankton mortality rate           mzrat     =', mzrat
274         WRITE(numout,*) '    maximal microzoo grazing rate             grazrat   =', grazrat
275         WRITE(numout,*) '    non assimilated fraction of P by microzoo unass     =', unass
276         WRITE(numout,*) '    Efficicency of microzoo growth            epsher    =', epsher
277         WRITE(numout,*) '    Fraction of microzoo excretion as DOM     sigma1    =', sigma1
278         WRITE(numout,*) '    half sturation constant for grazing 1     xkgraz    =', xkgraz
279      ENDIF
280
281   END SUBROUTINE p4z_micro_init
282
283#else
284   !!======================================================================
285   !!  Dummy module :                                   No PISCES bio-model
286   !!======================================================================
287CONTAINS
288   SUBROUTINE p4z_micro                    ! Empty routine
289   END SUBROUTINE p4z_micro
290#endif 
291
292   !!======================================================================
293END MODULE  p4zmicro
Note: See TracBrowser for help on using the repository browser.