source: branches/CMIP5_IPSL/NEMO/TOP_SRC/PISCES/p4zprod.F90 @ 1808

Last change on this file since 1808 was 1808, checked in by cetlod, 11 years ago

update TOP_SRC component on CMIP5_IPSL branch to take into account bugfixes (ie vertical diffusion routines), re-organization of restart part, damping of passive tracers on closed seas for PISCES

  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 18.8 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_prod       : 
14   !!----------------------------------------------------------------------
15   USE trc
16   USE oce_trc         !
17   USE sms_pisces      !
18   USE prtctl_trc
19   USE p4zopt
20   USE p4zint
21   USE p4zlim
22   USE iom
23
24   USE lib_mpp
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod    ! called in p4zbio.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::   &
33     pislope   = 3.0_wp          ,  &  !:
34     pislope2  = 3.0_wp          ,  &  !:
35     excret    = 10.e-5_wp       , &   !:
36     excret2   = 0.05_wp         , &   !:
37     chlcnm    = 0.033_wp        , &   !:
38     chlcdm    = 0.05_wp         , &   !:
39     fecnm     = 10.E-6_wp       , &   !:
40     fecdm     = 15.E-6_wp       , &   !:
41     grosip    = 0.151_wp
42
43   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk)  ::        &
44     &                   prmax
45   
46   REAL(wp) ::   &
47      texcret                    ,  &  !: 1 - excret
48      texcret2                   ,  &  !: 1 - excret2       
49      rpis180                    ,  &  !: rpi / 180
50      tpp                              !: Total primary production
51
52   INTEGER  ::  nspyr                  !: number of timesteps per year
53
54   !!* Substitution
55#  include "top_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
58   !! $Id$
59   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61
62CONTAINS
63
64   SUBROUTINE p4z_prod( kt , jnt )
65      !!---------------------------------------------------------------------
66      !!                     ***  ROUTINE p4z_prod  ***
67      !!
68      !! ** Purpose :   Compute the phytoplankton production depending on
69      !!              light, temperature and nutrient availability
70      !!
71      !! ** Method  : - ???
72      !!---------------------------------------------------------------------
73      INTEGER, INTENT(in) :: kt, jnt
74      INTEGER  ::   ji, jj, jk
75      REAL(wp) ::   zsilfac, zfact
76      REAL(wp) ::   zprdiachl, zprbiochl, zsilim, ztn, zadap, zadap2
77      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zetot2, zmax, zproreg, zproreg2
78      REAL(wp) ::   zmxltst, zmxlday, zlim1
79      REAL(wp) ::   zpislopen  , zpislope2n
80      REAL(wp) ::   zrum, zcodel, zargu, zvol
81#if defined key_trc_diaadd && defined key_trc_dia3d
82      REAL(wp) ::   zrfact2
83#if  defined key_iomput
84      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zw3d
85#endif
86#endif
87      REAL(wp), DIMENSION(jpi,jpj)     ::   zmixnano   , zmixdiat, zstrn
88      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpislopead , zpislopead2
89      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprdia     , zprbio, zysopt
90      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprorca    , zprorcad, zprofed
91      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprofen   , zprochln, zprochld
92      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpronew    , zpronewd
93      CHARACTER (len=25) :: charout
94      !!---------------------------------------------------------------------
95
96
97      IF( ( kt * jnt ) == nittrc000  )   CALL p4z_prod_init      ! Initialization (first time-step only)
98
99
100      zprorca (:,:,:) = 0.0
101      zprorcad(:,:,:) = 0.0
102      zprofed(:,:,:) = 0.0
103      zprofen(:,:,:) = 0.0
104      zprochln(:,:,:) = 0.0
105      zprochld(:,:,:) = 0.0
106      zpronew (:,:,:) = 0.0
107      zpronewd(:,:,:) = 0.0
108      zprdia  (:,:,:) = 0.0
109      zprbio  (:,:,:) = 0.0
110      zysopt  (:,:,:) = 0.0
111
112      ! Computation of the optimal production
113
114# if defined key_off_degrad
115      prmax(:,:,:) = 0.6 / rday * tgfunc(:,:,:) * facvol(:,:,:)
116# else
117      prmax(:,:,:) = 0.6 / rday * tgfunc(:,:,:)
118# endif
119
120      ! compute the day length depending on latitude and the day
121      IF(lwp) write(numout,*)
122      IF(lwp) write(numout,*) 'p4zday : - Julian day ', nday_year
123      IF(lwp) write(numout,*) '~~~~~~'
124
125      IF( nleapy == 1 .AND. MOD( nyear, 4 ) == 0 ) THEN
126         zrum = FLOAT( nday_year - 80 ) / 366.
127      ELSE
128         zrum = FLOAT( nday_year - 80 ) / 365.
129      ENDIF
130      zcodel = ASIN(  SIN( zrum * rpi * 2. ) * SIN( rpis180 * 23.5 )  )
131
132      ! day length in hours
133      zstrn(:,:) = 0.
134      DO jj = 1, jpj
135         DO ji = 1, jpi
136            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rpis180 )
137            zargu = MAX( -1., MIN(  1., zargu ) )
138            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rpis180 / 15. )
139         END DO
140      END DO
141
142
143!CDIR NOVERRCHK
144      DO jk = 1, jpkm1
145!CDIR NOVERRCHK
146         DO jj = 1, jpj
147!CDIR NOVERRCHK
148            DO ji = 1, jpi
149
150               ! Computation of the P-I slope for nanos and diatoms
151               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
152                   ztn    = MAX( 0., tn(ji,jj,jk) - 15. )
153                   zadap  = 0.+ 1.* ztn / ( 2.+ ztn )
154                   zadap2 = 0.e0
155
156                   zfact  = EXP( -0.21 * emoy(ji,jj,jk) )
157
158                   zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * zfact )
159                   zpislopead2(ji,jj,jk) = pislope2 * ( 1.+ zadap2 * zfact )
160
161                   zpislopen = zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch)                 &
162                     &         / ( trn(ji,jj,jk,jpphy) * 12.                   + rtrn )   &
163                     &         / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
164
165                   zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)                &
166                     &          / ( trn(ji,jj,jk,jpdia) * 12.                   + rtrn )   &
167                     &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
168
169                   ! Computation of production function
170                   zprbio(ji,jj,jk) = prmax(ji,jj,jk) * &
171                     &                (  1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
172                   zprdia(ji,jj,jk) = prmax(ji,jj,jk) * &
173                     &                (  1.- EXP( -zpislope2n * ediat(ji,jj,jk) )  )
174               ENDIF
175            END DO
176         END DO
177      END DO
178
179
180      DO jk = 1, jpkm1
181         DO jj = 1, jpj
182            DO ji = 1, jpi
183
184                IF( etot(ji,jj,jk) > 1.E-3 ) THEN
185                   !    Si/C of diatoms
186                   !    ------------------------
187                   !    Si/C increases with iron stress and silicate availability
188                   !    Si/C is arbitrariliy increased for very high Si concentrations
189                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
190
191                  zlim1  = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi1 )
192                  zlim   = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
193
194                  zsilim = MIN( zprdia(ji,jj,jk)    / ( rtrn + prmax(ji,jj,jk) ),                 &
195                  &          trn(ji,jj,jk,jpfer) / ( concdfe(ji,jj,jk) + trn(ji,jj,jk,jpfer) ),   &
196                  &          trn(ji,jj,jk,jppo4) / ( concdnh4 + trn(ji,jj,jk,jppo4) ),            &
197                  &          zlim )
198                  zsilfac = 5.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim1 - 0.5 ) )  ) + 1.e0
199                  zsiborn = MAX( 0.e0, ( trn(ji,jj,jk,jpsil) - 15.e-6 ) )
200                  zsilfac2 = 1.+ 3.* zsiborn / ( zsiborn + xksi2 )
201                  zsilfac = MIN( 6.4,zsilfac * zsilfac2)
202                  zysopt(ji,jj,jk) = grosip * zlim1 * zsilfac
203
204              ENDIF
205            END DO
206         END DO
207      END DO
208
209      !  Computation of the limitation term due to
210      !  A mixed layer deeper than the euphotic depth
211      DO jj = 1, jpj
212         DO ji = 1, jpi
213            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
214            zmxlday = zmxltst**2 / rday
215            zmixnano(ji,jj) = 1.- zmxlday / ( 1.+ zmxlday )
216            zmixdiat(ji,jj) = 1.- zmxlday / ( 3.+ zmxlday )
217         END DO
218      END DO
219 
220      !  Mixed-layer effect on production                                                                               
221      DO jk = 1, jpkm1
222         DO jj = 1, jpj
223            DO ji = 1, jpi
224               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
225                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
226                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
227               ENDIF
228            END DO
229         END DO
230      END DO
231
232
233      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
234      zstrn(:,:) = 24. / zstrn(:,:)
235
236!CDIR NOVERRCHK
237      DO jk = 1, jpkm1
238!CDIR NOVERRCHK
239         DO jj = 1, jpj
240!CDIR NOVERRCHK
241            DO ji = 1, jpi
242
243               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
244                  !     Computation of the various production terms for nanophyto.
245                  zetot2 = enano(ji,jj,jk) * zstrn(ji,jj)
246                  zmax = MAX( 0.1, xlimphy(ji,jj,jk) )
247                  zpislopen = zpislopead(ji,jj,jk)          &
248                  &         * trn(ji,jj,jk,jpnch) / ( rtrn + trn(ji,jj,jk,jpphy) * 12.)         &
249                  &         / ( prmax(ji,jj,jk) * rday * zmax + rtrn )
250
251                  zprbiochl = prmax(ji,jj,jk) * (  1.- EXP( -zpislopen * zetot2 )  )
252
253                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trn(ji,jj,jk,jpphy) * rfact2
254
255                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk)    &
256                  &             / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
257                  zprod = rday * zprorca(ji,jj,jk) * zprbiochl * trn(ji,jj,jk,jpphy) *zmax
258
259                  zprofen(ji,jj,jk) = (fecnm)**2 * zprod / chlcnm            &
260                  &              / (  zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnfe) + rtrn  )
261
262                  zprochln(ji,jj,jk) = chlcnm * 144. * zprod                  &
263                  &              / (  zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnch) + rtrn  )
264               ENDIF
265            END DO
266         END DO
267      END DO
268
269!CDIR NOVERRCHK
270      DO jk = 1, jpkm1
271!CDIR NOVERRCHK
272         DO jj = 1, jpj
273!CDIR NOVERRCHK
274            DO ji = 1, jpi
275               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
276                  !  Computation of the various production terms for diatoms
277                  zetot2 = ediat(ji,jj,jk) * zstrn(ji,jj)
278                  zmax = MAX( 0.1, xlimdia(ji,jj,jk) )
279                  zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)        &
280                  &           / ( rtrn + trn(ji,jj,jk,jpdia) * 12.)        &
281                  &           / ( prmax(ji,jj,jk) * rday * zmax + rtrn )
282
283                  zprdiachl = prmax(ji,jj,jk) * (  1.- EXP( -zetot2 * zpislope2n )  )
284
285                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trn(ji,jj,jk,jpdia) * rfact2
286
287                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk)     &
288                  &              / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
289
290                  zprod = rday * zprorcad(ji,jj,jk) * zprdiachl * trn(ji,jj,jk,jpdia) * zmax
291
292                  zprofed(ji,jj,jk) = (fecdm)**2 * zprod / chlcdm                   &
293                  &              / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdfe) + rtrn )
294
295                  zprochld(ji,jj,jk) = chlcdm * 144. * zprod       &
296                  &              / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdch) + rtrn )
297
298               ENDIF
299            END DO
300         END DO
301      END DO
302      !
303
304      !   Update the arrays TRA which contain the biological sources and sinks
305      DO jk = 1, jpkm1
306         DO jj = 1, jpj
307           DO ji =1 ,jpi
308              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
309              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
310              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
311              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
312              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
313              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
314              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
315              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
316              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
317              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
318              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
319              tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
320              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + &
321              &                     excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
322              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
323              &                    + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
324              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) &
325              &                     - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
326              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) &
327              &                     - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
328              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
329              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) &
330              &                    + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
331          END DO
332        END DO
333     END DO
334
335     ! Total primary production per year
336     DO jk = 1, jpkm1
337        DO jj = 1, jpj
338          DO ji = 1, jpi
339             zvol = cvol(ji,jj,jk)
340#if defined key_off_degrad
341             zvol = zvol * facvol(ji,jj,jk)
342#endif
343             tpp  = tpp + ( zprorca(ji,jj,jk) + zprorcad(ji,jj,jk) ) &
344                          * zvol * tmask(ji,jj,jk) * tmask_i(ji,jj)
345          END DO
346        END DO
347      END DO
348
349
350      IF( MOD( kt, nspyr ) == 0 .AND. jnt == nrdttrc ) THEN
351        IF( lk_mpp ) CALL mpp_sum( tpp )
352        WRITE(numout,*) 'Total PP :'
353        WRITE(numout,*) '-------------------- : ',tpp * 12. / 1.E12
354        WRITE(numout,*) '(GtC/an)'
355        tpp = 0.
356      ENDIF
357
358#if defined key_trc_diaadd && defined key_trc_dia3d
359      zrfact2 = 1.e3 * rfact2r
360      !   Supplementary diagnostics
361#  if ! defined key_iomput
362      trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zrfact2 * tmask(:,:,:)
363      trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
364      trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
365      trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
366      trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
367      trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
368#if ! defined key_kriest
369      trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
370#endif
371
372# else
373      zw3d(:,:,:) = zprorca (:,:,:) * zrfact2 * tmask(:,:,:)
374      IF( jnt == nrdttrc ) CALL iom_put( "PPPHY" , zw3d )
375      zw3d(:,:,:) = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
376      IF( jnt == nrdttrc ) CALL iom_put( "PPPHY2", zw3d )
377      zw3d(:,:,:) = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
378      IF( jnt == nrdttrc ) CALL iom_put( "PPNEWN" , zw3d )
379      zw3d(:,:,:) = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
380      IF( jnt == nrdttrc ) CALL iom_put( "PPNEWD", zw3d )
381      zw3d(:,:,:) = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
382      IF( jnt == nrdttrc ) CALL iom_put( "PBSi"  , zw3d )
383      zw3d(:,:,:) = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
384      IF( jnt == nrdttrc ) CALL iom_put( "PFeD"  , zw3d )
385      zw3d(:,:,:) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
386      IF( jnt == nrdttrc ) CALL iom_put( "PFeN"  , zw3d )
387# endif
388#endif
389
390       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
391         WRITE(charout, FMT="('prod')")
392         CALL prt_ctl_trc_info(charout)
393         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
394       ENDIF
395
396   END SUBROUTINE p4z_prod
397
398   SUBROUTINE p4z_prod_init
399
400      !!----------------------------------------------------------------------
401      !!                  ***  ROUTINE p4z_prod_init  ***
402      !!
403      !! ** Purpose :   Initialization of phytoplankton production parameters
404      !!
405      !! ** Method  :   Read the nampisprod namelist and check the parameters
406      !!      called at the first timestep (nittrc000)
407      !!
408      !! ** input   :   Namelist nampisprod
409      !!
410      !!----------------------------------------------------------------------
411
412      NAMELIST/nampisprod/ pislope, pislope2, excret, excret2, chlcnm, chlcdm,   &
413         &              fecnm, fecdm, grosip
414
415      REWIND( numnat )                     ! read numnat
416      READ  ( numnat, nampisprod )
417
418      IF(lwp) THEN                         ! control print
419         WRITE(numout,*) ' '
420         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
421         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
422         WRITE(numout,*) '    mean Si/C ratio                           grosip    =', grosip
423         WRITE(numout,*) '    P-I slope                                 pislope   =', pislope
424         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret    =', excret
425         WRITE(numout,*) '    excretion ratio of diatoms                excret2   =', excret2
426         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2  =', pislope2
427         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm    =', chlcnm
428         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm    =', chlcdm
429         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm     =', fecnm
430         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm     =', fecdm
431      ENDIF
432
433      ! number of timesteps per year
434      nspyr  = INT( nyear_len(1) * rday / rdt )
435
436      rpis180   = rpi / 180.
437      texcret   = 1.0 - excret
438      texcret2  = 1.0 - excret2
439      tpp       = 0.
440
441   END SUBROUTINE p4z_prod_init
442
443
444
445#else
446   !!======================================================================
447   !!  Dummy module :                                   No PISCES bio-model
448   !!======================================================================
449CONTAINS
450   SUBROUTINE p4z_prod                    ! Empty routine
451   END SUBROUTINE p4z_prod
452#endif 
453
454   !!======================================================================
455END MODULE  p4zprod
Note: See TracBrowser for help on using the repository browser.