New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlys.F90 @ 5288

Last change on this file since 5288 was 5288, checked in by aumont, 9 years ago

various bug fixes and updates of PISCES quota

File size: 10.3 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
14   !!----------------------------------------------------------------------
15#if defined key_pisces || defined key_pisces_quota
16   !!----------------------------------------------------------------------
17   !!   'key_pisces*'                                       PISCES bio-model
18   !!----------------------------------------------------------------------
19   !!   p4z_lys        :   Compute the CaCO3 dissolution
20   !!   p4z_lys_init   :   Read the namelist parameters
21   !!----------------------------------------------------------------------
22   USE oce_trc         !  shared variables between ocean and passive tracers
23   USE trc             !  passive tracers common variables
24   USE sms_pisces      !  PISCES Source Minus Sink variables
25   USE prtctl_trc      !  print control for debugging
26   USE iom             !  I/O manager
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
32   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
33
34   !! * Shared module variables
35   REAL(wp), PUBLIC :: kdca !: diss. rate constant calcite
36   REAL(wp), PUBLIC :: nca  !: order of reaction for calcite dissolution
37
38   !! * Module variables
39   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
40 
41   INTEGER  :: rmtss                      !: number of seconds per month
42
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
45   !! $Id: p4zlys.F90 3321 2012-03-05 17:10:55Z cetlod $
46   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48
49CONTAINS
50
51   SUBROUTINE p4z_lys( kt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_lys  ***
54      !!
55      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
56      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
57      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
58      !!
59      !! ** Method  : - ???
60      !!---------------------------------------------------------------------
61      !
62      INTEGER, INTENT(in) ::   kt ! ocean time step
63      INTEGER  ::   ji, jj, jk, jn
64      REAL(wp) ::   zalk, zdic, zph, zah2
65      REAL(wp) ::   zdispot, zfact, zcalcon, zalka, zaldi
66      REAL(wp) ::   zomegaca, zexcess, zexcess0
67      REAL(wp) ::   zrfact2
68      CHARACTER (len=25) :: charout
69      REAL(wp), POINTER, DIMENSION(:,:,:) :: zco3, zcaldiss   
70      !!---------------------------------------------------------------------
71      !
72      IF( nn_timing == 1 )  CALL timing_start('p4z_lys')
73      !
74      CALL wrk_alloc( jpi, jpj, jpk, zco3, zcaldiss )
75      !
76      zco3    (:,:,:) = 0.
77      zcaldiss(:,:,:) = 0.
78      !     -------------------------------------------
79      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
80      !     -------------------------------------------
81     
82      DO jn = 1, 5                               !  BEGIN OF ITERATION
83         !
84!CDIR NOVERRCHK
85         DO jk = 1, jpkm1
86!CDIR NOVERRCHK
87            DO jj = 1, jpj
88!CDIR NOVERRCHK
89               DO ji = 1, jpi
90                  zfact = rhop(ji,jj,jk) / 1000. + rtrn
91                  zph  = hi(ji,jj,jk) * tmask(ji,jj,jk) / zfact + ( 1.-tmask(ji,jj,jk) ) * 1.e-9 ! [H+]
92                  zdic  = trn(ji,jj,jk,jpdic) / zfact
93                  zalka = trn(ji,jj,jk,jptal) / zfact
94                  ! CALCULATE [ALK]([CO3--], [HCO3-])
95                  zalk  = zalka - ( akw3(ji,jj,jk) / zph - zph + borat(ji,jj,jk) / ( 1. + zph / akb3(ji,jj,jk) ) )
96                  ! CALCULATE [H+] and [CO3--]
97                  zaldi = zdic - zalk
98                  zah2  = SQRT( zaldi * zaldi + 4.* ( zalk * ak23(ji,jj,jk) / ak13(ji,jj,jk) ) * ( zdic + zaldi ) )
99                  zah2  = 0.5 * ak13(ji,jj,jk) / zalk * ( zaldi + zah2 )
100                  !
101                  zco3(ji,jj,jk) = zalk / ( 2. + zah2 / ak23(ji,jj,jk) ) * zfact
102                  hi(ji,jj,jk)   = zah2 * zfact
103               END DO
104            END DO
105         END DO
106         !
107      END DO 
108
109      !     ---------------------------------------------------------
110      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
111      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
112      !        MGCO3)
113      !     ---------------------------------------------------------
114
115      DO jk = 1, jpkm1
116         DO jj = 1, jpj
117            DO ji = 1, jpi
118
119               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
120               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
121               zcalcon  = calcon * ( tsn(ji,jj,jk,jp_sal) / 35._wp )
122               zfact    = rhop(ji,jj,jk) / 1000._wp
123               zomegaca = ( zcalcon * zco3(ji,jj,jk) * zfact ) / aksp(ji,jj,jk) 
124
125               ! SET DEGREE OF UNDER-/SUPERSATURATION
126               excess(ji,jj,jk) = 1._wp - zomegaca
127               zexcess0 = MAX( 0., excess(ji,jj,jk) )
128               zexcess  = zexcess0**nca
129
130               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
131               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
132               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
133               zdispot = kdca * zexcess * trn(ji,jj,jk,jpcal)
134# if defined key_degrad
135               zdispot = zdispot * facvol(ji,jj,jk)
136# endif
137              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
138              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
139              zcaldiss(ji,jj,jk)  = zdispot / rmtss  ! calcite dissolution
140              zco3(ji,jj,jk)      = zco3(ji,jj,jk) + zcaldiss(ji,jj,jk) * rfact
141              !
142              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
143              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
144              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
145            END DO
146         END DO
147      END DO
148      !
149      IF( ln_diatrc )  THEN
150         !
151         IF( lk_iomput ) THEN
152            zrfact2 = 1.e3 * rfact2r
153            CALL iom_put( "PH"    , -1. * LOG10( hi(:,:,:) )                * tmask(:,:,:) )
154            CALL iom_put( "CO3"   ,        zco3    (:,:,:) * 1e+3           * tmask(:,:,:) )
155            CALL iom_put( "CO3sat",        aksp    (:,:,:) * 1e+3 / calcon  * tmask(:,:,:) )
156            CALL iom_put( "DCAL"  ,        zcaldiss(:,:,:) * zrfact2        * tmask(:,:,:) )
157         ELSE
158            trc3d(:,:,:,jp_pcs0_3d    ) = -1. * LOG10( hi(:,:,:) ) * tmask(:,:,:)
159            trc3d(:,:,:,jp_pcs0_3d + 1) = zco3(:,:,:)              * tmask(:,:,:)
160            trc3d(:,:,:,jp_pcs0_3d + 2) = aksp(:,:,:) / calcon     * tmask(:,:,:)
161         ENDIF
162         !
163      ENDIF
164      !
165      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
166        WRITE(charout, FMT="('lys ')")
167        CALL prt_ctl_trc_info(charout)
168        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
169      ENDIF
170      !
171      CALL wrk_dealloc( jpi, jpj, jpk, zco3, zcaldiss )
172      !
173      IF( nn_timing == 1 )  CALL timing_stop('p4z_lys')
174      !
175   END SUBROUTINE p4z_lys
176
177   SUBROUTINE p4z_lys_init
178
179      !!----------------------------------------------------------------------
180      !!                  ***  ROUTINE p4z_lys_init  ***
181      !!
182      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
183      !!
184      !! ** Method  :   Read the nampiscal namelist and check the parameters
185      !!      called at the first timestep (nittrc000)
186      !!
187      !! ** input   :   Namelist nampiscal
188      !!
189      !!----------------------------------------------------------------------
190      INTEGER  ::  ji, jj, jk
191      INTEGER  ::  ios                 ! Local integer output status for namelist read
192      REAL(wp) ::  zcaralk, zbicarb, zco3
193      REAL(wp) ::  ztmas, ztmas1
194
195      NAMELIST/nampiscal/ kdca, nca
196      !!----------------------------------------------------------------------
197
198      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
199      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
200901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in reference namelist', lwp )
201
202      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
203      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
204902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in configuration namelist', lwp )
205      IF(lwm) WRITE ( numonp, nampiscal )
206
207      IF(lwp) THEN                         ! control print
208         WRITE(numout,*) ' '
209         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
210         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
211         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
212         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
213      ENDIF
214
215      ! Number of seconds per month
216      rmtss =  nyear_len(1) * rday / raamo
217      !
218   END SUBROUTINE p4z_lys_init
219
220#else
221   !!======================================================================
222   !!  Dummy module :                                   No PISCES bio-model
223   !!======================================================================
224CONTAINS
225   SUBROUTINE p4z_lys( kt )                   ! Empty routine
226      INTEGER, INTENT( in ) ::   kt
227      WRITE(*,*) 'p4z_lys: You should not have seen this print! error?', kt
228   END SUBROUTINE p4z_lys
229#endif 
230   !!======================================================================
231END MODULE  p4zlys
Note: See TracBrowser for help on using the repository browser.