New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zrem.F90 in branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zrem.F90 @ 5266

Last change on this file since 5266 was 5266, checked in by cetlod, 9 years ago

PISCES_QUOTA : First commits, see ticket #1516
  • Property svn:executable set to *
File size: 20.7 KB
Line 
1MODULE p5zrem
2   !!======================================================================
3   !!                         ***  MODULE p5zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces_quota
11   !!----------------------------------------------------------------------
12   !!   'key_top'       and                                      TOP models
13   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
14   !!----------------------------------------------------------------------
15   !!   p5z_rem       :  Compute remineralization/dissolution of organic compounds
16   !!   p5z_rem_init  :  Initialisation of parameters for remineralisation
17   !!   p5z_rem_alloc :  Allocate remineralisation variables
18   !!----------------------------------------------------------------------
19   USE oce_trc         !  shared variables between ocean and passive tracers
20   USE trc             !  passive tracers common variables
21   USE sms_pisces      !  PISCES Source Minus Sink variables
22   USE p4zopt          !  optical model
23   USE p4zche          !  chemical model
24   USE p5zprod         !  Growth rate of the 2 phyto groups
25   USE p5zmeso         !  Sources and sinks of mesozooplankton
26   USE p4zint          !  interpolation and computation of various fields
27   USE p5zlim
28   USE prtctl_trc      !  print control for debugging
29   USE iom             !  I/O manager
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p5z_rem         ! called in p4zbio.F90
36   PUBLIC   p5z_rem_init    ! called in trcsms_pisces.F90
37   PUBLIC   p5z_rem_alloc
38
39   !! * Shared module variables
40   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of POC
41   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of POC
42   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of POC
43   REAL(wp), PUBLIC ::  xremipc    !: remineralisation rate of DOC
44   REAL(wp), PUBLIC ::  xremipn    !: remineralisation rate of DOC
45   REAL(wp), PUBLIC ::  xremipp    !: remineralisation rate of DOC
46   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
47   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of POC
48   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of POC
49   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
50   REAL(wp), PUBLIC ::  oxymin     !: halk saturation constant for anoxia
51
52
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitrc     !: denitrification array
54
55   !!* Substitution
56#  include "top_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
59   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
60   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE p5z_rem( kt, jnt )
65      !!---------------------------------------------------------------------
66      !!                     ***  ROUTINE p5z_rem  ***
67      !!
68      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
69      !!
70      !! ** Method  : - ???
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
74      !
75      INTEGER  ::   ji, jj, jk
76      REAL(wp) ::   zremip, zremik, zremikc, zremikn, zremikp, zsiremin 
77      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
78      REAL(wp) ::   zbactfer, zopoc, zopon, zopop, zopoc2, zopon2, zopop2, zofer, zolimit
79      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
80#if ! defined key_kriest
81      REAL(wp) ::   zofer2
82#endif
83      REAL(wp) ::   zonitr, zstep, zrfact2
84      CHARACTER (len=25) :: charout
85      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac 
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zwork1, zdepprod
87      !!---------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('p5z_rem')
90      !
91      ! Allocate temporary workspace
92      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
93      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zwork1 )
94
95      ! Initialisation of temprary arrys
96      zdepprod(:,:,:) = 1._wp
97      ztempbac(:,:)   = 0._wp
98
99      ! Computation of the mean phytoplankton concentration as
100      ! a crude estimate of the bacterial biomass
101      ! this parameterization has been deduced from a model version
102      ! that was modeling explicitely bacteria
103      ! -------------------------------------------------------
104      DO jk = 1, jpkm1
105         DO jj = 1, jpj
106            DO ji = 1, jpi
107               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
108               IF( fsdept(ji,jj,jk) < zdep ) THEN
109                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trn(ji,jj,jk,jpzoo) + 2.* trn(ji,jj,jk,jpmes) ), 4.e-6 )
110                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
111               ELSE
112                  zdepmin = MIN( 1., zdep / fsdept(ji,jj,jk) )
113                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
114                  zdepprod(ji,jj,jk) = zdepmin**0.273
115               ENDIF
116            END DO
117         END DO
118      END DO
119
120      DO jk = 1, jpkm1
121         DO jj = 1, jpj
122            DO ji = 1, jpi
123               ! denitrification factor computed from O2 levels
124               ! ----------------------------------------------
125               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trn(ji,jj,jk,jpoxy) )    &
126                  &                                / ( oxymin + trn(ji,jj,jk,jpoxy) )  )
127               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
128            END DO
129         END DO
130      END DO
131
132      DO jk = 1, jpkm1
133         DO jj = 1, jpj
134            DO ji = 1, jpi
135               zstep   = xstep
136# if defined key_degrad
137               zstep = zstep * facvol(ji,jj,jk)
138# endif
139               ! DOC ammonification. Depends on depth, phytoplankton biomass
140               ! and a limitation term which is supposed to be a parameterization
141               ! of the bacterial activity.
142               ! -----------------------------------------------------------------
143               zremik = zstep / 1.e-6 * MAX(0.02, xlimbac(ji,jj,jk) ) * zdepbac(ji,jj,jk) 
144               zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
145
146               zremikc = xremikc * zremik
147               zremikn = xremikn * zremik * 1.0 / (5.6*rno3)
148               zremikp = xremikp * zremik * 1.0 / (75.0*po4r)
149
150               ! Ammonification in oxic waters with oxygen consumption
151               ! -----------------------------------------------------
152               zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trn(ji,jj,jk,jpdoc) 
153               zolimic = MAX( 0.e0, MIN( ( trn(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
154               zwork1(ji,jj,jk) = zolimic
155               zolimin = zolimic * trn(ji,jj,jk,jpdon) / ( trn(ji,jj,jk,jpdoc) + rtrn )
156               zolimip = zolimic * trn(ji,jj,jk,jpdop) / ( trn(ji,jj,jk,jpdoc) + rtrn ) 
157
158               ! Ammonification in suboxic waters with denitrification
159               ! -------------------------------------------------------
160               zolimit = zremikc * nitrfac(ji,jj,jk) * trn(ji,jj,jk,jpdoc)
161               denitrc(ji,jj,jk)  = MIN(  ( trn(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
162               denitrc (ji,jj,jk) = MAX( 0.e0, denitrc (ji,jj,jk) )
163               zdenitrn  = denitrc(ji,jj,jk) * trn(ji,jj,jk,jpdon) / ( trn(ji,jj,jk,jpdoc) + rtrn )
164               zdenitrp  = denitrc(ji,jj,jk) * trn(ji,jj,jk,jpdop) / ( trn(ji,jj,jk,jpdoc) + rtrn )
165
166               ! Update of trends TRA
167               ! --------------------
168               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
169               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
170               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitrc(ji,jj,jk) * rdenit
171               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitrc(ji,jj,jk)
172               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
173               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
174               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
175               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitrc(ji,jj,jk)
176               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
177
178            END DO
179         END DO
180      END DO
181
182
183      DO jk = 1, jpkm1
184         DO jj = 1, jpj
185            DO ji = 1, jpi
186               zstep   = xstep
187# if defined key_degrad
188               zstep = zstep * facvol(ji,jj,jk)
189# endif
190               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
191               ! below 2 umol/L. Inhibited at strong light
192               ! ----------------------------------------------------------
193               zonitr   = nitrif * zstep * trn(ji,jj,jk,jpnh4) * (0.2 + 0.8 / ( 1.+ emoy(ji,jj,jk) ) ) &
194               &          * ( 1.- nitrfac(ji,jj,jk) ) 
195               zdenitnh4 = nitrif * zstep * trn(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
196
197               ! Update of the tracers trends
198               ! ----------------------------
199               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
200               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
201               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
202               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
203            END DO
204         END DO
205      END DO
206
207      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
208        WRITE(charout, FMT="('rem1')")
209        CALL prt_ctl_trc_info(charout)
210        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
211      ENDIF
212
213      DO jk = 1, jpkm1
214         DO jj = 1, jpj
215            DO ji = 1, jpi
216
217               ! Bacterial uptake of iron. No iron is available in DOC. So
218               ! Bacteries are obliged to take up iron from the water. Some
219               ! studies (especially at Papa) have shown this uptake to be significant
220               ! ----------------------------------------------------------
221               zbactfer = ferat3 *  rfact2 * prmaxp(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
222                  &              * biron(ji,jj,jk) / ( 2E-10 + biron(ji,jj,jk) )    &
223                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
224#if defined key_kriest
225               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.05
226               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.05
227#else
228               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
229               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
230               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
231#endif
232            END DO
233         END DO
234      END DO
235
236      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
237        WRITE(charout, FMT="('rem2')")
238        CALL prt_ctl_trc_info(charout)
239        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
240      ENDIF
241
242      DO jk = 1, jpkm1
243         DO jj = 1, jpj
244            DO ji = 1, jpi
245               zstep   = xstep
246# if defined key_degrad
247               zstep = zstep * facvol(ji,jj,jk)
248# endif
249               ! POC disaggregation by turbulence and bacterial activity.
250               ! --------------------------------------------------------
251               zremip = zstep * tgfunc(ji,jj,jk) * ( 1.- 0.55 * nitrfac(ji,jj,jk) ) 
252
253               ! POC disaggregation rate is reduced in anoxic zone as shown by
254               ! sediment traps data. In oxic area, the exponent of the martin s
255               ! law is around -0.87. In anoxic zone, it is around -0.35. This
256               ! means a disaggregation constant about 0.5 the value in oxic zones
257               ! -----------------------------------------------------------------
258               zopoc  = xremipc * zremip * trn(ji,jj,jk,jppoc)
259               zopon  = xremipn * zremip * trn(ji,jj,jk,jppon)
260               zopop  = xremipp * zremip * trn(ji,jj,jk,jppop)
261               zofer  = xremipn * zremip * trn(ji,jj,jk,jpsfe)
262#if ! defined key_kriest
263               zopoc2 = xremipc * zremip * trn(ji,jj,jk,jpgoc)
264               zopon2 = xremipn * zremip * trn(ji,jj,jk,jpgon)
265               zopop2 = xremipp * zremip * trn(ji,jj,jk,jpgop)
266               zofer2 = xremipn * zremip * trn(ji,jj,jk,jpbfe)
267#else
268               zopoc2 = xremipc * zremip * trn(ji,jj,jk,jpnum)
269#endif
270
271               ! Update the appropriate tracers trends
272               ! -------------------------------------
273#if defined key_kriest
274               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zopoc
275               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) - zopon
276               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) - zopop
277               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zofer
278               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zopoc
279               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zopon
280               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zopop
281               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zofer
282               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zopoc2
283#else
284               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zopoc + zopoc2
285               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) - zopon + zopon2
286               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) - zopop + zopop2
287               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zofer + zofer2
288               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zopoc 
289               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zopon 
290               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zopop 
291               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zofer 
292               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) - zopoc2
293               tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) - zopon2
294               tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) - zopop2
295               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) - zofer2
296#endif
297            END DO
298         END DO
299      END DO
300
301      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
302        WRITE(charout, FMT="('rem3')")
303        CALL prt_ctl_trc_info(charout)
304        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
305      ENDIF
306
307      DO jk = 1, jpkm1
308         DO jj = 1, jpj
309            DO ji = 1, jpi
310               zstep   = xstep
311# if defined key_degrad
312               zstep = zstep * facvol(ji,jj,jk)
313# endif
314               ! Remineralization rate of BSi depedant on T and saturation
315               ! ---------------------------------------------------------
316               zsatur   = ( sio3eq(ji,jj,jk) - trn(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn )
317               zsatur   = MAX( rtrn, zsatur )
318               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
319               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
320               znusil2  = 0.225  * ( 1. + tsn(ji,jj,1,jp_tem) / 15.) + 0.775 * zsatur2
321
322               ! Two classes of BSi are considered : a labile fraction and
323               ! a more refractory one. The ratio between both fractions is
324               ! constant and specified in the namelist.
325               ! ----------------------------------------------------------
326               zdep     = MAX( hmld(ji,jj), heup(ji,jj) ) 
327               zdep     = MAX( 0., fsdept(ji,jj,jk) - zdep )
328               ztem     = MAX( tsn(ji,jj,1,jp_tem), 0. )
329               zfactdep = xsilab * EXP(-( xsiremlab - xsirem ) * znusil2 * zdep / wsbio2 ) * ztem / ( ztem + 10. )
330               zsiremin = ( xsiremlab * zfactdep + xsirem * ( 1. - zfactdep ) ) * zstep * znusil
331               zosil    = zsiremin * trn(ji,jj,jk,jpgsi)
332               !
333               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
334               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
335               !
336            END DO
337         END DO
338      END DO
339
340      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
341         WRITE(charout, FMT="('rem4')")
342         CALL prt_ctl_trc_info(charout)
343         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
344       ENDIF
345
346      IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) THEN
347          zrfact2 = 1.e3 * rfact2r
348          CALL iom_put( "REMIN" , zwork1(:,:,:) * tmask(:,:,:) * zrfact2 )  ! Remineralisation rate
349          CALL iom_put( "DENIT" , denitrc(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2  )  ! Denitrification
350      ENDIF
351
352      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
353         WRITE(charout, FMT="('rem6')")
354         CALL prt_ctl_trc_info(charout)
355         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
356      ENDIF
357      !
358      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
359      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zwork1 )
360      !
361      IF( nn_timing == 1 )  CALL timing_stop('p5z_rem')
362      !
363   END SUBROUTINE p5z_rem
364
365
366   SUBROUTINE p5z_rem_init
367      !!----------------------------------------------------------------------
368      !!                  ***  ROUTINE p5z_rem_init  ***
369      !!
370      !! ** Purpose :   Initialization of remineralization parameters
371      !!
372      !! ** Method  :   Read the nampisrem namelist and check the parameters
373      !!      called at the first timestep
374      !!
375      !! ** input   :   Namelist nampisrem
376      !!
377      !!----------------------------------------------------------------------
378      NAMELIST/nampisrem/ xremikc, xremikn, xremikp, xremipc, xremipn, xremipp,   &
379      &                   nitrif, xsirem, xsiremlab, xsilab, oxymin
380      INTEGER :: ios                 ! Local integer output status for namelist read
381
382      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
383      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
384901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
385
386      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
387      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
388902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
389      IF(lwm) WRITE ( numonp, nampisrem )
390
391      IF(lwp) THEN                         ! control print
392         WRITE(numout,*) ' '
393         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
394         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
395         WRITE(numout,*) '    remineralisation rate of POC              xremipc   =', xremipc
396         WRITE(numout,*) '    remineralisation rate of PON              xremipn   =', xremipn
397         WRITE(numout,*) '    remineralisation rate of POP              xremipp   =', xremipp
398         WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
399         WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
400         WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
401         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
402         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
403         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
404         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
405         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin    =', oxymin
406      ENDIF
407      !
408      nitrfac (:,:,:) = 0._wp
409      denitrc (:,:,:) = 0._wp
410      !
411   END SUBROUTINE p5z_rem_init
412
413
414   INTEGER FUNCTION p5z_rem_alloc()
415      !!----------------------------------------------------------------------
416      !!                     ***  ROUTINE p5z_rem_alloc  ***
417      !!----------------------------------------------------------------------
418      ALLOCATE( denitrc(jpi,jpj,jpk), STAT=p5z_rem_alloc )
419      !
420      IF( p5z_rem_alloc /= 0 )   CALL ctl_warn('p5z_rem_alloc: failed to allocate arrays')
421      !
422   END FUNCTION p5z_rem_alloc
423
424#else
425   !!======================================================================
426   !!  Dummy module :                                   No PISCES bio-model
427   !!======================================================================
428CONTAINS
429   SUBROUTINE p5z_rem                    ! Empty routine
430   END SUBROUTINE p5z_rem
431#endif 
432
433   !!======================================================================
434END MODULE p5zrem
Note: See TracBrowser for help on using the repository browser.