New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zsed.F90 in branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zsed.F90 @ 5288

Last change on this file since 5288 was 5288, checked in by aumont, 9 years ago

various bug fixes and updates of PISCES quota
  • Property svn:executable set to *
File size: 24.1 KB
Line 
1MODULE p5zsed
2   !!======================================================================
3   !!                         ***  MODULE p5zsed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
11   !!----------------------------------------------------------------------
12#if defined key_pisces_quota
13   !!----------------------------------------------------------------------
14   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
15   !!----------------------------------------------------------------------
16   !!   p5z_sed        :  Compute loss of organic matter in the sediments
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p5zsink         !  vertical flux of particulate matter due to sinking
22   USE p4zopt          !  optical model
23   USE p5zlim          !  Co-limitations of differents nutrients
24   USE p5zrem          !  Remineralisation of organic matter
25   USE p4zsbc          !  External source of nutrients
26   USE p4zint          !  interpolation and computation of various fields
27   USE iom             !  I/O manager
28   USE prtctl_trc      !  print control for debugging
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   p5z_sed   
34
35   !! * Module variables
36   REAL(wp) :: ryyss                    !: number of seconds per year
37   REAL(wp) :: r1_ryyss                 !: inverse of ryyss
38   REAL(wp) :: r1_rday                  !: inverse of rday
39
40   INTEGER ::  numnit 
41
42
43   !!* Substitution
44#  include "top_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Header:$
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p5z_sed( kt, jnt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p5z_sed  **
55      !!
56      !! ** Purpose :   Compute loss of organic matter in the sediments. This
57      !!              is by no way a sediment model. The loss is simply
58      !!              computed to balance the inout from rivers and dust
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      !
63      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
64      INTEGER  ::   ji, jj, jk, ikt
65#if ! defined key_sed
66      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
67      REAL(wp) ::   zrivalk, zrivsil, zrivno3
68#endif
69      REAL(wp) ::  zwflux, zfminus, zfplus
70      REAL(wp) ::  zlim, zfact, zfactcal
71      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
72      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
73      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
74      REAL(wp) ::  ztrfer, ztrdp, zwdust, zlight, zmudia, ztemp
75      REAL(wp) ::  zrdenittot, zsdenittot, znitrpottot, xdiano3, xdianh4
76      !
77      CHARACTER (len=25) :: charout
78      REAL(wp), POINTER, DIMENSION(:,:  ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4
79      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
80      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrpo4, ztrdop, znitrpot, zirondep, zsoufer
82      !!---------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('p5z_sed')
85      !
86      IF( kt == nittrc000 .AND. jnt == 1 )  THEN
87         ryyss    = nyear_len(1) * rday    ! number of seconds per year and per month
88         r1_rday  = 1. / rday
89         r1_ryyss = 1. / ryyss
90         IF( ln_check_mass .AND. lwp)  &
91           &  CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
92      ENDIF
93      !
94      ! Allocate temporary workspace
95      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
96      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
97      CALL wrk_alloc( jpi, jpj, jpk, ztrpo4, ztrdop, znitrpot, zsoufer )
98
99      zdenit2d(:,:) = 0.e0
100      zbureff (:,:) = 0.e0
101      zwork1  (:,:) = 0.e0
102      zwork2  (:,:) = 0.e0
103      zwork3  (:,:) = 0.e0
104      zwork4  (:,:) = 0.e0
105
106      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
107      ! ----------------------------------------------------
108      IF( ln_ironice ) THEN 
109         !                                             
110         CALL wrk_alloc( jpi, jpj, zironice )
111         !                                             
112         DO jj = 1, jpj
113            DO ji = 1, jpi
114               zdep    = rfact2 / fse3t(ji,jj,1)
115               zwflux  = fmmflx(ji,jj) / 1000._wp
116               zfminus = MIN( 0._wp, -zwflux ) * trn(ji,jj,1,jpfer) * zdep
117               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
118               zironice(ji,jj) =  zfplus + zfminus
119            END DO
120         END DO
121         !
122         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + zironice(:,:) 
123         !                                             
124         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
125            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
126         CALL wrk_dealloc( jpi, jpj, zironice )
127         !                                             
128      ENDIF
129
130      ! Add the external input of nutrients from dust deposition
131      ! ----------------------------------------------------------
132      IF( ln_dust ) THEN
133         !                                             
134         CALL wrk_alloc( jpi, jpj,      zpdep, zsidep )
135         CALL wrk_alloc( jpi, jpj, jpk, zirondep      )
136         !                                              ! Iron and Si deposition at the surface
137         IF( ln_solub ) THEN
138            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2    &
139            &        / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
140         ELSE
141            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2    &
142            &        / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
143         ENDIF
144         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 28.1 
145         zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 31. / po4r 
146         !                                              ! Iron solubilization of particles in the water column
147         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
148         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
149         DO jk = 2, jpkm1
150            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2  &
151            &   * EXP( -fsdept(:,:,jk) / 540. )
152         END DO
153         !                                              ! Iron solubilization of particles in the water column
154         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep   (:,:)
155         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep  (:,:)
156         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) 
157         !                                             
158         IF( ln_diatrc ) THEN
159            zfact = 1.e+3 * rfact2r
160            IF( lk_iomput ) THEN
161               IF( jnt == nrdttrc ) THEN
162                  CALL iom_put( "Irondep", zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
163                  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
164               ENDIF
165            ELSE
166               trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1)
167            ENDIF
168         ENDIF
169         CALL wrk_dealloc( jpi, jpj,      zpdep, zsidep )
170         CALL wrk_dealloc( jpi, jpj, jpk, zirondep      )
171         !                                             
172      ENDIF
173     
174      ! Add the external input of nutrients from river
175      ! ----------------------------------------------------------
176      IF( ln_river ) THEN
177         trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + rivdip(:,:) * rfact2
178         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + rivdin(:,:) * rfact2
179         trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2
180         trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + rivdsi(:,:) * rfact2
181         trn(:,:,1,jpdic) = trn(:,:,1,jpdic) + rivdic(:,:) * rfact2
182         trn(:,:,1,jptal) = trn(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2
183      ENDIF
184     
185      ! Add the external input of nutrients from nitrogen deposition
186      ! ----------------------------------------------------------
187      IF( ln_ndepo ) THEN
188         trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2
189         trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
190      ENDIF
191
192      ! Add the external input of iron from sediment mobilization
193      ! ------------------------------------------------------
194      IF( ln_ironsed ) THEN
195         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
196         !
197         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
198            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
199      ENDIF
200
201      ! Add the external input of iron from hydrothermal vents
202      ! ------------------------------------------------------
203      IF( ln_hydrofe ) THEN
204         trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
205         !
206         IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc )   &
207            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
208      ENDIF
209
210
211      ! OA: Warning, the following part is necessary, especially with Kriest
212      ! to avoid CFL problems above the sediments
213      ! --------------------------------------------------------------------
214      DO jj = 1, jpj
215         DO ji = 1, jpi
216            ikt  = mbkt(ji,jj)
217            zdep = fse3t(ji,jj,ikt) / xstep
218            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
219            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
220            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
221         END DO
222      END DO
223
224#if ! defined key_sed
225      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
226      ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
227      ! -------------------------------------------------------
228      DO jj = 1, jpj
229         DO ji = 1, jpi
230           IF( tmask(ji,jj,1) == 1 ) THEN
231              ikt = mbkt(ji,jj)
232# if defined key_kriest
233              zflx =    trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)    * 1E3 * 1E6 / 1E4
234# else
235              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
236                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
237#endif
238              zflx  = LOG10( MAX( 1E-3, zflx ) )
239              zo2   = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) )
240              zno3  = LOG10( MAX( 1.  , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
241              zdep  = LOG10( fsdepw(ji,jj,ikt+1) )
242              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
243              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
244              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
245              !
246              zflx = (  trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
247                &     + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
248              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
249           ENDIF
250         END DO
251      END DO 
252
253      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
254      ! First, the total loss is computed.
255      ! The factor for calcite comes from the alkalinity effect
256      ! -------------------------------------------------------------
257      DO jj = 1, jpj
258         DO ji = 1, jpi
259            IF( tmask(ji,jj,1) == 1 ) THEN
260               ikt = mbkt(ji,jj) 
261# if defined key_kriest
262               zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwscal (ji,jj)
263               zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj)
264# else
265               zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
266               zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
267# endif
268               ! For calcite, burial efficiency is made a function of saturation
269               zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
270               zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
271               zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
272            ENDIF
273         END DO
274      END DO
275      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
276      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
277      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
278#endif
279
280      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
281      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
282      ! ------------------------------------------------------
283#if ! defined key_sed
284      zrivsil =  MAX(0., 1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn ) )
285#endif
286
287      DO jj = 1, jpj
288         DO ji = 1, jpi
289            ikt  = mbkt(ji,jj)
290            zdep = xstep / fse3t(ji,jj,ikt)
291            zws4 = zwsbio4(ji,jj) * zdep
292            zwsc = zwscal (ji,jj) * zdep
293# if defined key_kriest
294            zsiloss = trn(ji,jj,ikt,jpgsi) * zws4
295# else
296            zsiloss = trn(ji,jj,ikt,jpgsi) * zwsc
297# endif
298            zcaloss = trn(ji,jj,ikt,jpcal) * zwsc
299            !
300            trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss
301            trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss
302#if ! defined key_sed
303            trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
304            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
305            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
306            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
307            trn(ji,jj,ikt,jptal) =  trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
308            trn(ji,jj,ikt,jpdic) =  trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk
309#endif
310         END DO
311      END DO
312
313      DO jj = 1, jpj
314         DO ji = 1, jpi
315            ikt     = mbkt(ji,jj)
316            zdep    = xstep / fse3t(ji,jj,ikt)
317            zws4 = zwsbio4(ji,jj) * zdep
318            zws3 = zwsbio3(ji,jj) * zdep
319            zrivno3 = 1. - zbureff(ji,jj)
320# if ! defined key_kriest
321            trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zws4
322            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
323            trn(ji,jj,ikt,jpgon) = trn(ji,jj,ikt,jpgon) - trn(ji,jj,ikt,jpgon) * zws4
324            trn(ji,jj,ikt,jppon) = trn(ji,jj,ikt,jppon) - trn(ji,jj,ikt,jppon) * zws3
325            trn(ji,jj,ikt,jpgop) = trn(ji,jj,ikt,jpgop) - trn(ji,jj,ikt,jpgop) * zws4
326            trn(ji,jj,ikt,jppop) = trn(ji,jj,ikt,jppop) - trn(ji,jj,ikt,jppop) * zws3
327            trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zws4
328            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
329            zwstpoc              =  trn(ji,jj,ikt,jpgoc) * zws4 + trn(ji,jj,ikt,jppoc) * zws3 
330            zwstpop              =  trn(ji,jj,ikt,jpgop) * zws4 + trn(ji,jj,ikt,jppop) * zws3
331            zwstpon              =  trn(ji,jj,ikt,jpgon) * zws4 + trn(ji,jj,ikt,jppon) * zws3
332# else
333            trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zws4
334            trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3
335            trn(ji,jj,ikt,jppon) = trn(ji,jj,ikt,jppon) - trn(ji,jj,ikt,jppon) * zws3
336            trn(ji,jj,ikt,jppop) = trn(ji,jj,ikt,jppop) - trn(ji,jj,ikt,jppop) * zws3
337            trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3
338            zwstpop = trn(ji,jj,ikt,jppop) * zws3
339            zwstpon = trn(ji,jj,ikt,jppon) * zws3
340            zwstpoc = trn(ji,jj,ikt,jppoc) * zws3 
341# endif
342
343#if ! defined key_sed
344            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
345            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
346            zpdenit  = MIN( 0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
347            z1pdenit = zwstpoc * zrivno3 - zpdenit
348            zolimit = MIN( ( trn(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
349            zdenitt = MIN(  0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
350            trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
351            trn(ji,jj,ikt,jpdon) = trn(ji,jj,ikt,jpdon) + (z1pdenit - zolimit - zdenitt) * zwstpon / (zwstpoc + rtrn)
352            trn(ji,jj,ikt,jpdop) = trn(ji,jj,ikt,jpdop) + (z1pdenit - zolimit - zdenitt) * zwstpop / (zwstpoc + rtrn)
353            trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + (zpdenit + zolimit + zdenitt) * zwstpop / (zwstpoc + rtrn)
354            trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + (zpdenit + zolimit + zdenitt) * zwstpon / (zwstpoc + rtrn)
355            trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
356            trn(ji,jj,ikt,jpoxy) = trn(ji,jj,ikt,jpoxy) - zolimit * o2ut
357            trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * (zolimit + zpdenit + zdenitt ) * zwstpon / (zwstpoc + rtrn)   &
358            &   + rno3 * rdenit * (zpdenit + zdenitt)
359            trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
360            zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt)
361#endif
362         END DO
363      END DO
364
365      ! Nitrogen fixation process
366      ! Small source iron from particulate inorganic iron
367      !-----------------------------------
368      DO jk = 1, jpkm1
369         DO jj = 1, jpj
370            DO ji = 1, jpi
371               !                      ! Potential nitrogen fixation dependant on temperature and iron
372               ztemp = tsn(ji,jj,jk,jp_tem)
373               zmudia = max(0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637) * 7.625
374               !       Potential nitrogen fixation dependant on
375               !       temperature and iron
376               xdianh4 = trn(ji,jj,jk,jpnh4) / ( concnnh4 + trn(ji,jj,jk,jpnh4) )
377               xdiano3 = trn(ji,jj,jk,jpno3) / ( concnno3 + trn(ji,jj,jk,jpno3) ) * (1. - xdianh4)
378               zlim = ( 1.- xdiano3 - xdianh4 )
379               IF( zlim <= 0.1 )   zlim = 0.01
380#if defined key_degrad
381               zfact = zlim * rfact2 * facvol(ji,jj,jk)
382#else
383               zfact = zlim * rfact2
384#endif
385               ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
386               ztrpo4(ji,jj,jk) = trn(ji,jj,jk,jppo4) / ( 1E-6 + trn(ji,jj,jk,jppo4) )
387               ztrdop(ji,jj,jk) = trn(ji,jj,jk,jpdop) / ( 1E-6 + trn(ji,jj,jk,jpdop) ) * (1. - ztrpo4(ji,jj,jk))
388               ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
389               zlight =  ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) ) 
390               znitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight
391               zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk))
392            END DO
393         END DO
394      END DO
395
396      ! Nitrogen change due to nitrogen fixation
397      ! ----------------------------------------
398      DO jk = 1, jpkm1
399         DO jj = 1, jpj
400            DO ji = 1, jpi
401               zfact = znitrpot(ji,jj,jk) * nitrfix
402               trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) + zfact / 3.0
403               trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3 * zfact / 3.0
404               trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
405               &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
406               trn(ji,jj,jk,jpdon) = trn(ji,jj,jk,jpdon) + zfact * 1.0 / 3.0
407               trn(ji,jj,jk,jpdoc) = trn(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0
408               trn(ji,jj,jk,jpdop) = trn(ji,jj,jk,jpdop) + 16.0 / 46.0 * zfact / 3.0  &
409               &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
410               &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
411               trn(ji,jj,jk,jppoc) = trn(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0
412               trn(ji,jj,jk,jppon) = trn(ji,jj,jk,jppon) + zfact * 1.0 / 3.0 * 2.0 /3.0
413               trn(ji,jj,jk,jppop) = trn(ji,jj,jk,jppop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
414               trn(ji,jj,jk,jpgoc) = trn(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0
415               trn(ji,jj,jk,jpgon) = trn(ji,jj,jk,jpgon) + zfact * 1.0 / 3.0 * 1.0 /3.0
416               trn(ji,jj,jk,jpgop) = trn(ji,jj,jk,jpgop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
417               trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
418               trn(ji,jj,jk,jpfer) = trn(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0 
419               trn(ji,jj,jk,jpsfe) = trn(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
420               trn(ji,jj,jk,jpbfe) = trn(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
421               trn(ji,jj,jk,jpfer) = trn(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
422           END DO
423         END DO
424      END DO
425
426 
427      IF( ln_check_mass ) THEN
428        ! Global budget of N SMS : denitrification in the water column and in the sediment
429         !                          nitrogen fixation by the diazotrophs
430         ! --------------------------------------------------------------------------------
431         zrdenittot   = glob_sum ( denitrc(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
432         zsdenittot   = glob_sum ( zwork4(:,:)   * e1e2t(:,:) )
433         znitrpottot  = glob_sum ( znitrpot(:,:,:) * nitrfix              * cvol(:,:,:) )
434         IF( kt == nitend .AND. jnt == nrdttrc ) THEN
435            zfact = 1.e+3 * rfact2r * rno3 * ryyss * 14. / 1e12
436            IF(lwp) WRITE(numnit,9100) ndastp, znitrpottot * nitrfix * zfact, zrdenittot * zfact , zsdenittot * zfact
437         ENDIF
438       ENDIF
439      !
440      IF( ln_diatrc ) THEN
441         zfact = 1.e+3 * rfact2r
442         IF( lk_iomput ) THEN
443            IF( jnt == nrdttrc ) THEN
444               CALL iom_put( "Nfix"  , znitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
445               CALL iom_put( "Sdenit", zwork4(:,:)               * rno3 * zfact * tmask(:,:,1) )  ! Nitrate reduction in the sediments
446            ENDIF
447         ELSE
448            trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * zfact * fse3t(:,:,1) * tmask(:,:,1)
449         ENDIF
450      ENDIF
451      !
452      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
453         WRITE(charout, fmt="('sed ')")
454         CALL prt_ctl_trc_info(charout)
455         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
456      ENDIF
457      !
458      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
459      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
460      CALL wrk_dealloc( jpi, jpj, jpk, ztrpo4, ztrdop, znitrpot, zsoufer )
461      !
462      IF( nn_timing == 1 )  CALL timing_stop('p5z_sed')
463      !
464 9100  FORMAT(i8,3f10.5)
465      !
466   END SUBROUTINE p5z_sed
467
468#else
469   !!======================================================================
470   !!  Dummy module :                                   No PISCES bio-model
471   !!======================================================================
472CONTAINS
473   SUBROUTINE p5z_sed                         ! Empty routine
474   END SUBROUTINE p5z_sed
475#endif 
476
477   !!======================================================================
478END MODULE  p5zsed
Note: See TracBrowser for help on using the repository browser.