1 | MODULE p4zligand |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zligand *** |
---|
4 | !! TOP : PISCES Compute remineralization/dissolution of organic ligands |
---|
5 | !!========================================================================= |
---|
6 | !! History : 3.6 ! 2016-03 (O. Aumont, A. Tagliabue) Quota model and reorganization |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | #if defined key_pisces || defined key_pisces_quota |
---|
9 | # if defined key_ligand |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_top' and TOP models |
---|
12 | !! 'key_pisces*' and PISCES bio-model |
---|
13 | !! 'key_ligand' Ligand submodel |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! p4z_ligand : Compute remineralization/dissolution of organic ligands |
---|
16 | !! p4z_ligand_init : Initialisation of parameters for remineralisation |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
19 | USE trc ! passive tracers common variables |
---|
20 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
21 | USE p4zopt ! optical model |
---|
22 | USE prtctl_trc ! print control for debugging |
---|
23 | |
---|
24 | IMPLICIT NONE |
---|
25 | PRIVATE |
---|
26 | |
---|
27 | PUBLIC p4z_ligand ! called in p4zbio.F90 |
---|
28 | PUBLIC p4z_ligand_init ! called in trcsms_pisces.F90 |
---|
29 | |
---|
30 | !! * Shared module variables |
---|
31 | REAL(wp), PUBLIC :: rlgw !: lifetime (years) of weak ligands |
---|
32 | REAL(wp), PUBLIC :: rlgs !: lifetime (years) of strong ligands |
---|
33 | REAL(wp), PUBLIC :: rlig !: Remin ligand production |
---|
34 | REAL(wp), PUBLIC :: prlgw !: Photochemical of weak ligand |
---|
35 | REAL(wp), PUBLIC :: rfep !: Dissolution rate of FeP |
---|
36 | |
---|
37 | |
---|
38 | !!* Substitution |
---|
39 | # include "top_substitute.h90" |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
42 | !! $Id: p4zligand.F90 3160 2011-11-20 14:27:18Z cetlod $ |
---|
43 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | CONTAINS |
---|
46 | |
---|
47 | SUBROUTINE p4z_ligand( kt, jnt ) |
---|
48 | !!--------------------------------------------------------------------- |
---|
49 | !! *** ROUTINE p4z_ligand *** |
---|
50 | !! |
---|
51 | !! ** Purpose : Compute remineralization/scavenging of organic ligands |
---|
52 | !! |
---|
53 | !! ** Method : - ??? |
---|
54 | !!--------------------------------------------------------------------- |
---|
55 | ! |
---|
56 | INTEGER, INTENT(in) :: kt, jnt ! ocean time step |
---|
57 | ! |
---|
58 | INTEGER :: ji, jj, jk |
---|
59 | REAL(wp) :: zlgwp, zlgwpr, zlgwr, zlablgw, zrfepa, zfepr |
---|
60 | REAL(wp) :: zstep, zstep2, zrfact2 |
---|
61 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zligrem, zligpr, zrligprod |
---|
62 | CHARACTER (len=25) :: charout |
---|
63 | !!--------------------------------------------------------------------- |
---|
64 | ! |
---|
65 | IF( nn_timing == 1 ) CALL timing_start('p4z_ligand') |
---|
66 | ! |
---|
67 | CALL wrk_alloc( jpi, jpj, jpk, zligrem, zligpr, zrligprod ) |
---|
68 | ! |
---|
69 | ! ------------------------------------------------------------------ |
---|
70 | ! Remineralization of iron ligands |
---|
71 | ! ------------------------------------------------------------------ |
---|
72 | DO jk = 1, jpkm1 |
---|
73 | DO jj = 1, jpj |
---|
74 | DO ji = 1, jpi |
---|
75 | ! ---------------------------------------------------------- |
---|
76 | ! zstep converts per day to per timestep |
---|
77 | ! zstep for the yearly rates |
---|
78 | ! --------------------------------------------------------- |
---|
79 | zstep = xstep |
---|
80 | # if defined key_degrad |
---|
81 | zstep = zstep * facvol(ji,jj,jk) |
---|
82 | # endif |
---|
83 | zstep2 = zstep / 365. ! per year |
---|
84 | ! production from remineralisation of organic matter |
---|
85 | zlgwp = orem(ji,jj,jk) * rlig |
---|
86 | ! decay of weak ligand |
---|
87 | ! This is based on the idea that as LGW is lower |
---|
88 | ! there is a larger fraction of refractory OM |
---|
89 | zlgwr = max( rlgs , rlgw * exp( -2 * (trn(ji,jj,jk,jplgw)*1e9) ) ) ! years |
---|
90 | zlgwr = 1. / zlgwr * tgfunc(ji,jj,jk) * zstep2 * trn(ji,jj,jk,jplgw) |
---|
91 | ! photochem loss of weak ligand |
---|
92 | zlgwpr = prlgw * zstep * etot(ji,jj,jk) * trn(ji,jj,jk,jplgw) * (1. - fr_i(ji,jj)) |
---|
93 | tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zlgwp - zlgwr - zlgwpr |
---|
94 | zligrem(ji,jj,jk) = zlgwr |
---|
95 | zligpr(ji,jj,jk) = zlgwpr |
---|
96 | zrligprod(ji,jj,jk) = zlgwp |
---|
97 | END DO |
---|
98 | END DO |
---|
99 | END DO |
---|
100 | |
---|
101 | ! ---------------------------------------------------------- |
---|
102 | ! Dissolution of nanoparticle Fe |
---|
103 | ! ---------------------------------------------------------- |
---|
104 | |
---|
105 | DO jk = 1, jpkm1 |
---|
106 | DO jj = 1, jpj |
---|
107 | DO ji = 1, jpi |
---|
108 | ! dissolution rate is maximal in the presence of light and |
---|
109 | ! lower in the aphotici zone |
---|
110 | ! ! 25 Wm-2 constant |
---|
111 | zrfepa = rfep * (1- EXP(-etot(ji,jj,jk) / 25. ) ) * (1.- fr_i(ji,jj)) |
---|
112 | zrfepa = MAX( (zrfepa / 10.0), zrfepa ) ! min of 10 days lifetime |
---|
113 | zfepr = rfep * zstep * trn(ji,jj,jk,jpfep) |
---|
114 | tra(ji,jj,jk,jpfep) = tra(ji,jj,jk,jpfep) - zfepr |
---|
115 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zfepr |
---|
116 | END DO |
---|
117 | END DO |
---|
118 | END DO |
---|
119 | |
---|
120 | ! Output of some diagnostics variables |
---|
121 | ! --------------------------------- |
---|
122 | IF( ln_diatrc .AND. lk_iomput ) THEN |
---|
123 | IF( jnt == nrdttrc ) THEN |
---|
124 | CALL iom_put("LIGREM" , zligrem(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) ) |
---|
125 | CALL iom_put("LIGPR" , zligpr(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) ) |
---|
126 | CALL iom_put("LPRODR" , zrligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) ) |
---|
127 | ENDIF |
---|
128 | ENDIF |
---|
129 | |
---|
130 | CALL wrk_dealloc( jpi, jpj, jpk, zligrem, zligpr, zrligprod ) |
---|
131 | |
---|
132 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
133 | WRITE(charout, FMT="('ligand1')") |
---|
134 | CALL prt_ctl_trc_info(charout) |
---|
135 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
---|
136 | ENDIF |
---|
137 | ! |
---|
138 | IF( nn_timing == 1 ) CALL timing_stop('p4z_ligand') |
---|
139 | ! |
---|
140 | END SUBROUTINE p4z_ligand |
---|
141 | |
---|
142 | |
---|
143 | SUBROUTINE p4z_ligand_init |
---|
144 | !!---------------------------------------------------------------------- |
---|
145 | !! *** ROUTINE p4z_ligand_init *** |
---|
146 | !! |
---|
147 | !! ** Purpose : Initialization of remineralization parameters |
---|
148 | !! |
---|
149 | !! ** Method : Read the nampislig namelist and check the parameters |
---|
150 | !! called at the first timestep |
---|
151 | !! |
---|
152 | !! ** input : Namelist nampislig |
---|
153 | !! |
---|
154 | !!---------------------------------------------------------------------- |
---|
155 | NAMELIST/nampislig/ rlgw, prlgw, rlgs, rfep, rlig |
---|
156 | INTEGER :: ios ! Local integer output status for namelist read |
---|
157 | |
---|
158 | REWIND( numnatp_ref ) ! Namelist nampislig in reference namelist : Pisces remineralization |
---|
159 | READ ( numnatp_ref, nampislig, IOSTAT = ios, ERR = 901) |
---|
160 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislig in reference namelist', lwp ) |
---|
161 | |
---|
162 | REWIND( numnatp_cfg ) ! Namelist nampislig in configuration namelist : Pisces remineralization |
---|
163 | READ ( numnatp_cfg, nampislig, IOSTAT = ios, ERR = 902 ) |
---|
164 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislig in configuration namelist', lwp ) |
---|
165 | IF(lwm) WRITE ( numonp, nampislig ) |
---|
166 | |
---|
167 | IF(lwp) THEN ! control print |
---|
168 | WRITE(numout,*) ' ' |
---|
169 | WRITE(numout,*) ' Namelist parameters for ligands, nampislig' |
---|
170 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
---|
171 | WRITE(numout,*) ' Dissolution rate of FeP rfep =', rfep |
---|
172 | WRITE(numout,*) ' Lifetime (years) of weak ligands rlgw =', rlgw |
---|
173 | WRITE(numout,*) ' Remin ligand production per unit C rlig =', rlig |
---|
174 | WRITE(numout,*) ' Photolysis of weak ligand prlgw =', prlgw |
---|
175 | WRITE(numout,*) ' Lifetime (years) of strong ligands rlgs =', rlgs |
---|
176 | ENDIF |
---|
177 | ! |
---|
178 | END SUBROUTINE p4z_ligand_init |
---|
179 | |
---|
180 | # else |
---|
181 | !!====================================================================== |
---|
182 | !! Dummy module : No ligands sub-model |
---|
183 | !!====================================================================== |
---|
184 | CONTAINS |
---|
185 | SUBROUTINE p4z_ligand(kt, jnt) ! Empty routine |
---|
186 | INTEGER, INTENT(in) :: kt, jnt ! ocean time step |
---|
187 | END SUBROUTINE p4z_ligand |
---|
188 | # endif |
---|
189 | #else |
---|
190 | !!====================================================================== |
---|
191 | !! Dummy module : No PISCES bio-model |
---|
192 | !!====================================================================== |
---|
193 | CONTAINS |
---|
194 | SUBROUTINE p4z_ligand ! Empty routine |
---|
195 | END SUBROUTINE p4z_ligand |
---|
196 | #endif |
---|
197 | |
---|
198 | !!====================================================================== |
---|
199 | END MODULE p4zligand |
---|