New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmort.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmort.F90 @ 7180

Last change on this file since 7180 was 7180, checked in by aumont, 7 years ago

various bug fixes on iron chemistry
  • Property svn:keywords set to Id
File size: 12.9 KB
Line 
1MODULE p4zmort
2   !!======================================================================
3   !!                         ***  MODULE p4zmort  ***
4   !! TOP :   PISCES Compute the mortality terms for phytoplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont)  Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_mort       :   Compute the mortality terms for phytoplankton
14   !!   p4z_mort_init  :   Initialize the mortality params for phytoplankton
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zprod         !  Primary productivity
20   USE p4zlim          !  Phytoplankton limitation terms
21   USE prtctl_trc      !  print control for debugging
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_mort   
27   PUBLIC   p4z_mort_init   
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC :: wchl    !:
31   REAL(wp), PUBLIC :: wchld   !:
32   REAL(wp), PUBLIC :: wchldm  !:
33   REAL(wp), PUBLIC :: mprat   !:
34   REAL(wp), PUBLIC :: mprat2  !:
35
36
37   !!* Substitution
38#  include "top_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44
45CONTAINS
46
47   SUBROUTINE p4z_mort( kt )
48      !!---------------------------------------------------------------------
49      !!                     ***  ROUTINE p4z_mort  ***
50      !!
51      !! ** Purpose :   Calls the different subroutine to initialize and compute
52      !!                the different phytoplankton mortality terms
53      !!
54      !! ** Method  : - ???
55      !!---------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt ! ocean time step
57      !!---------------------------------------------------------------------
58
59      CALL p4z_nano            ! nanophytoplankton
60
61      CALL p4z_diat            ! diatoms
62
63   END SUBROUTINE p4z_mort
64
65
66   SUBROUTINE p4z_nano
67      !!---------------------------------------------------------------------
68      !!                     ***  ROUTINE p4z_nano  ***
69      !!
70      !! ** Purpose :   Compute the mortality terms for nanophytoplankton
71      !!
72      !! ** Method  : - ???
73      !!---------------------------------------------------------------------
74      INTEGER  :: ji, jj, jk
75      REAL(wp) :: zsizerat, zcompaph
76      REAL(wp) :: zfactfe, zfactch, zprcaca, zfracal
77      REAL(wp) :: ztortp , zrespp , zmortp , zstep
78      CHARACTER (len=25) :: charout
79      !!---------------------------------------------------------------------
80      !
81      IF( nn_timing == 1 )  CALL timing_start('p4z_nano')
82      !
83      prodcal(:,:,:) = 0.  !: calcite production variable set to zero
84      DO jk = 1, jpkm1
85         DO jj = 1, jpj
86            DO ji = 1, jpi
87               zcompaph = MAX( ( trb(ji,jj,jk,jpphy) - 1e-8 ), 0.e0 )
88               zstep    = xstep
89# if defined key_degrad
90               zstep    = zstep * facvol(ji,jj,jk)
91# endif
92               !     When highly limited by macronutrients, very small cells
93               !     dominate the community. As a consequence, aggregation
94               !     due to turbulence is negligible. Mortality is also set
95               !     to 0
96               zsizerat = MIN(1., MAX( 0., (quotan(ji,jj,jk) - 0.2) / 0.3) ) * trb(ji,jj,jk,jpphy)
97               !     Squared mortality of Phyto similar to a sedimentation term during
98               !     blooms (Doney et al. 1996)
99               zrespp = wchl * 1.e6 * zstep * xdiss(ji,jj,jk) * zcompaph * zsizerat 
100
101               !     Phytoplankton mortality. This mortality loss is slightly
102               !     increased when nutrients are limiting phytoplankton growth
103               !     as observed for instance in case of iron limitation.
104               ztortp = mprat * xstep * zcompaph / ( xkmort + trb(ji,jj,jk,jpphy) ) * zsizerat
105
106               zmortp = zrespp + ztortp
107
108               !   Update the arrays TRA which contains the biological sources and sinks
109
110               zfactfe = trb(ji,jj,jk,jpnfe)/(trb(ji,jj,jk,jpphy)+rtrn)
111               zfactch = trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
112               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zmortp
113               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zmortp * zfactch
114               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zmortp * zfactfe
115               zprcaca = xfracal(ji,jj,jk) * zmortp
116               !
117               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
118               !
119               zfracal = 0.5 * xfracal(ji,jj,jk)
120               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
121               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
122               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
123#if defined key_kriest
124               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp
125               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ztortp * xkr_dnano + zrespp * xkr_ddiat
126               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp * zfactfe
127#else
128               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfracal * zmortp
129               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ( 1. - zfracal ) * zmortp
130               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + ( 1. - zfracal ) * zmortp
131               prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zfracal * zmortp
132               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ( 1. - zfracal ) * zmortp * zfactfe
133               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zfracal * zmortp * zfactfe
134#endif
135            END DO
136         END DO
137      END DO
138      !
139       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
140         WRITE(charout, FMT="('nano')")
141         CALL prt_ctl_trc_info(charout)
142         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
143       ENDIF
144      !
145      IF( nn_timing == 1 )  CALL timing_stop('p4z_nano')
146      !
147   END SUBROUTINE p4z_nano
148
149   SUBROUTINE p4z_diat
150      !!---------------------------------------------------------------------
151      !!                     ***  ROUTINE p4z_diat  ***
152      !!
153      !! ** Purpose :   Compute the mortality terms for diatoms
154      !!
155      !! ** Method  : - ???
156      !!---------------------------------------------------------------------
157      INTEGER  ::  ji, jj, jk
158      REAL(wp) ::  zfactfe,zfactsi,zfactch, zcompadi
159      REAL(wp) ::  zrespp2, ztortp2, zmortp2, zstep
160      REAL(wp) ::  zlim2, zlim1
161      CHARACTER (len=25) :: charout
162      !!---------------------------------------------------------------------
163      !
164      IF( nn_timing == 1 )  CALL timing_start('p4z_diat')
165      !
166
167      !    Aggregation term for diatoms is increased in case of nutrient
168      !    stress as observed in reality. The stressed cells become more
169      !    sticky and coagulate to sink quickly out of the euphotic zone
170      !     ------------------------------------------------------------
171
172      DO jk = 1, jpkm1
173         DO jj = 1, jpj
174            DO ji = 1, jpi
175
176               zcompadi = MAX( ( trb(ji,jj,jk,jpdia) - 1e-9), 0. )
177
178               !    Aggregation term for diatoms is increased in case of nutrient
179               !    stress as observed in reality. The stressed cells become more
180               !    sticky and coagulate to sink quickly out of the euphotic zone
181               !     ------------------------------------------------------------
182               zstep   = xstep
183# if defined key_degrad
184               zstep = zstep * facvol(ji,jj,jk)
185# endif
186               !  Phytoplankton respiration
187               !     ------------------------
188               zlim2   = xlimdia(ji,jj,jk) * xlimdia(ji,jj,jk)
189               zlim1   = 0.25 * ( 1. - zlim2 ) / ( 0.25 + zlim2 ) 
190               zrespp2 = 1.e6 * zstep * (  wchld + wchldm * zlim1 ) * xdiss(ji,jj,jk) * zcompadi * trb(ji,jj,jk,jpdia)
191
192               !     Phytoplankton mortality.
193               !     ------------------------
194               ztortp2 = mprat2 * zstep * trb(ji,jj,jk,jpdia)  / ( xkmort + trb(ji,jj,jk,jpdia) ) * zcompadi 
195
196               zmortp2 = zrespp2 + ztortp2
197
198               !   Update the arrays tra which contains the biological sources and sinks
199               !   ---------------------------------------------------------------------
200               zfactch = trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
201               zfactfe = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
202               zfactsi = trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
203               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zmortp2 
204               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zmortp2 * zfactch
205               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zmortp2 * zfactfe
206               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zmortp2 * zfactsi
207               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zmortp2 * zfactsi
208#if defined key_kriest
209               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortp2 
210               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ztortp2 * xkr_ddiat + zrespp2 * xkr_daggr
211               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zmortp2 * zfactfe
212#else
213               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zrespp2 + 0.5 * ztortp2
214               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + 0.5 * ztortp2
215               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + 0.5 * ztortp2
216               prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zrespp2 + 0.5 * ztortp2
217               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 0.5 * ztortp2 * zfactfe
218               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ( zrespp2 + 0.5 * ztortp2 ) * zfactfe
219#endif
220            END DO
221         END DO
222      END DO
223      !
224      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
225         WRITE(charout, FMT="('diat')")
226         CALL prt_ctl_trc_info(charout)
227         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
228      ENDIF
229      !
230      IF( nn_timing == 1 )  CALL timing_stop('p4z_diat')
231      !
232   END SUBROUTINE p4z_diat
233
234   SUBROUTINE p4z_mort_init
235
236      !!----------------------------------------------------------------------
237      !!                  ***  ROUTINE p4z_mort_init  ***
238      !!
239      !! ** Purpose :   Initialization of phytoplankton parameters
240      !!
241      !! ** Method  :   Read the nampismort namelist and check the parameters
242      !!      called at the first timestep
243      !!
244      !! ** input   :   Namelist nampismort
245      !!
246      !!----------------------------------------------------------------------
247
248      NAMELIST/nampismort/ wchl, wchld, wchldm, mprat, mprat2
249      INTEGER :: ios                 ! Local integer output status for namelist read
250
251      REWIND( numnatp_ref )              ! Namelist nampismort in reference namelist : Pisces phytoplankton
252      READ  ( numnatp_ref, nampismort, IOSTAT = ios, ERR = 901)
253901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismort in reference namelist', lwp )
254
255      REWIND( numnatp_cfg )              ! Namelist nampismort in configuration namelist : Pisces phytoplankton
256      READ  ( numnatp_cfg, nampismort, IOSTAT = ios, ERR = 902 )
257902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismort in configuration namelist', lwp )
258      IF(lwm) WRITE ( numonp, nampismort )
259
260      IF(lwp) THEN                         ! control print
261         WRITE(numout,*) ' '
262         WRITE(numout,*) ' Namelist parameters for phytoplankton mortality, nampismort'
263         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
264         WRITE(numout,*) '    quadratic mortality of phytoplankton      wchl      =', wchl
265         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchld     =', wchld
266         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchldm    =', wchldm
267         WRITE(numout,*) '    phytoplankton mortality rate              mprat     =', mprat
268         WRITE(numout,*) '    Diatoms mortality rate                    mprat2    =', mprat2
269      ENDIF
270
271   END SUBROUTINE p4z_mort_init
272
273#else
274   !!======================================================================
275   !!  Dummy module :                                   No PISCES bio-model
276   !!======================================================================
277CONTAINS
278   SUBROUTINE p4z_mort                    ! Empty routine
279   END SUBROUTINE p4z_mort
280#endif 
281
282   !!======================================================================
283END MODULE p4zmort
Note: See TracBrowser for help on using the repository browser.