New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zrem.F90 @ 7617

Last change on this file since 7617 was 7617, checked in by aumont, 7 years ago

update diagnostics + changes in quota code
File size: 16.7 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2016-03  (O. Aumont) Quota model and reorganization
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_top'       and                                      TOP models
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
17   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
18   !!   p4z_rem_alloc :  Allocate remineralisation variables
19   !!----------------------------------------------------------------------
20   USE oce_trc         !  shared variables between ocean and passive tracers
21   USE trc             !  passive tracers common variables
22   USE sms_pisces      !  PISCES Source Minus Sink variables
23   USE p4zopt          !  optical model
24   USE p4zche          !  chemical model
25   USE p4zlim          ! Phytoplankton limitation factors
26   USE p4zprod         !  Growth rate of the 2 phyto groups
27   USE p4zsink         !  Sinking of particles
28   USE prtctl_trc      !  print control for debugging
29   USE iom             !  I/O manager
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p4z_rem         ! called in p4zbio.F90
36   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
37   PUBLIC   p4z_rem_alloc
38
39   !! * Shared module variables
40   REAL(wp), PUBLIC ::  xremik     !: remineralisation rate of DOC
41   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
42   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of BSi
43   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of BSi
44   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
45   REAL(wp), PUBLIC ::  oxymin     !: halk saturation constant for anoxia
46   REAL(wp), PUBLIC ::  oxymin2    !: Minimum O2 concentration for oxic remin.
47   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
48   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
49
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
51
52
53   !!* Substitution
54#  include "top_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
57   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE p4z_rem( kt, jnt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_rem  ***
65      !!
66      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      !
71      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
72      !
73      INTEGER  ::   ji, jj, jk
74      REAL(wp) ::   zremik, zsiremin 
75      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
76      REAL(wp) ::   zbactfer, zolimit, zdenitnh4
77      REAL(wp) ::   zosil, ztem,ztoto,zpuis
78      REAL(wp) ::   zonitr, zstep, zrfact2
79      CHARACTER (len=25) :: charout
80      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib, znitr
82      !!---------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('p4z_rem')
85      !
86      ! Allocate temporary workspace
87      CALL wrk_alloc( jpi, jpj,      ztempbac )
88      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi, znitr, zfacsi, zfacsib )
89
90      ! Initialization of local variables
91      ! ---------------------------------
92
93      ! Initialisation of temprary arrys
94      zdepprod(:,:,:) = 1._wp
95      ztempbac(:,:)   = 0._wp
96      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
97      zfacsi(:,:,:)   = xsilab 
98
99      ! Computation of the mean phytoplankton concentration as
100      ! a crude estimate of the bacterial biomass
101      ! this parameterization has been deduced from a model version
102      ! that was modeling explicitely bacteria
103      ! -------------------------------------------------------
104      DO jk = 1, jpkm1
105         DO jj = 1, jpj
106            DO ji = 1, jpi
107               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
108               IF( fsdept(ji,jj,jk) < zdep ) THEN
109                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
110                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
111               ELSE
112                  zdepmin = MIN( 1., zdep / fsdept(ji,jj,jk) )
113                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
114                  zdepprod(ji,jj,jk) = zdepmin**0.273
115               ENDIF
116            END DO
117         END DO
118      END DO
119
120      DO jk = 1, jpkm1
121         DO jj = 1, jpj
122            DO ji = 1, jpi
123               ! denitrification factor computed from O2 levels
124               ! ----------------------------------------------
125               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( oxymin2 - trb(ji,jj,jk,jpoxy) )    &
126                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
127               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
128            END DO
129         END DO
130      END DO
131
132      DO jk = 1, jpkm1
133         DO jj = 1, jpj
134            DO ji = 1, jpi
135               zstep   = xstep
136# if defined key_degrad
137               zstep = zstep * facvol(ji,jj,jk)
138# endif
139               ! DOC ammonification. Depends on depth, phytoplankton biomass
140               ! and a limitation term which is supposed to be a parameterization
141               !     of the bacterial activity.
142               zremik = xremik * zstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
143               zremik = MAX( zremik, 2.74e-4 * xstep )
144               ! Ammonification in oxic waters with oxygen consumption
145               ! -----------------------------------------------------
146               zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
147               zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
148               ! Ammonification in suboxic waters with denitrification
149               ! -------------------------------------------------------
150               denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit,   &
151                  &                     zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)  )
152               !
153               zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
154               denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
155               ! Update of the tracers trends
156               ! ----------------------------
157               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
158               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
159               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
160               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk)
161               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
162               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
163               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk)    &
164               &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
165            END DO
166         END DO
167      END DO
168
169
170      DO jk = 1, jpkm1
171         DO jj = 1, jpj
172            DO ji = 1, jpi
173               zstep   = xstep
174# if defined key_degrad
175               zstep = zstep * facvol(ji,jj,jk)
176# endif
177               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
178               ! below 2 umol/L. Inhibited at strong light
179               ! ----------------------------------------------------------
180               zonitr  = nitrif * zstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
181               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) )
182               zdenitnh4 = nitrif * zstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
183               ! Update of the tracers trends
184               ! ----------------------------
185               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
186               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
187               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
188               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
189               znitr(ji,jj,jk) = zonitr
190            END DO
191         END DO
192      END DO
193
194      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
195         WRITE(charout, FMT="('rem1')")
196         CALL prt_ctl_trc_info(charout)
197         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
198      ENDIF
199
200      DO jk = 1, jpkm1
201         DO jj = 1, jpj
202            DO ji = 1, jpi
203
204               ! Bacterial uptake of iron. No iron is available in DOC. So
205               ! Bacteries are obliged to take up iron from the water. Some
206               ! studies (especially at Papa) have shown this uptake to be significant
207               ! ----------------------------------------------------------
208               zbactfer = feratb *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
209                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
210                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
211#if defined key_kriest
212               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.05
213               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.05
214#else
215               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
216               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
217               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
218#endif
219            END DO
220         END DO
221      END DO
222
223      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
224         WRITE(charout, FMT="('rem2')")
225         CALL prt_ctl_trc_info(charout)
226         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
227      ENDIF
228
229      ! Initialization of the array which contains the labile fraction
230      ! of bSi. Set to a constant in the upper ocean
231      ! ---------------------------------------------------------------
232
233      DO jk = 1, jpkm1
234         DO jj = 1, jpj
235            DO ji = 1, jpi
236               zstep   = xstep
237# if defined key_degrad
238               zstep = zstep * facvol(ji,jj,jk)
239# endif
240               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
241               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
242               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
243               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
244
245               ! Remineralization rate of BSi depedant on T and saturation
246               ! ---------------------------------------------------------
247               IF ( fsdept(ji,jj,jk) > zdep ) THEN
248                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
249                  &                   * znusil * fse3t(ji,jj,jk) / wsbio4(ji,jj,jk) )
250                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
251                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
252                  &                   * znusil * fse3t(ji,jj,jk) / wsbio4(ji,jj,jk) )
253               ENDIF
254               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * zstep * znusil
255               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
256               !
257               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
258               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
259            END DO
260         END DO
261      END DO
262               
263
264      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
265         WRITE(charout, FMT="('rem3')")
266         CALL prt_ctl_trc_info(charout)
267         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
268       ENDIF
269
270      IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) THEN
271          zrfact2 = 1.e3 * rfact2r
272          CALL iom_put( "REMIN" , zolimi(:,:,:) * tmask(:,:,:) * zrfact2 )  ! Remineralisation rate
273          CALL iom_put( "DENIT" , denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2  )  ! Denitrification
274          CALL iom_put( "NIT"   , znitr(:,:,:) * rno3 * tmask(:,:,:) * zrfact2 )  !
275          CALL iom_put( "BACT", zdepbac(:,:,:) * 1.E6 * tmask(:,:,:) )  ! Bacterial biomass
276
277      ENDIF
278      !
279      CALL wrk_dealloc( jpi, jpj,      ztempbac )
280      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi, zfacsi, zfacsib, znitr )
281      !
282      IF( nn_timing == 1 )  CALL timing_stop('p4z_rem')
283      !
284   END SUBROUTINE p4z_rem
285
286
287   SUBROUTINE p4z_rem_init
288      !!----------------------------------------------------------------------
289      !!                  ***  ROUTINE p4z_rem_init  ***
290      !!
291      !! ** Purpose :   Initialization of remineralization parameters
292      !!
293      !! ** Method  :   Read the nampisrem namelist and check the parameters
294      !!      called at the first timestep
295      !!
296      !! ** input   :   Namelist nampisrem
297      !!
298      !!----------------------------------------------------------------------
299      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab,   &
300      &                   oxymin, oxymin2, feratb, xkferb
301      INTEGER :: ios                 ! Local integer output status for namelist read
302
303      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
304      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
305901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
306
307      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
308      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
309902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
310      IF(lwm) WRITE ( numonp, nampisrem )
311
312      IF(lwp) THEN                         ! control print
313         WRITE(numout,*) ' '
314         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
315         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
316         WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
317         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
318         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
319         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
320         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
321         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin    =', oxymin
322         WRITE(numout,*) '    Minimum O2 concentration for oxic remin.  oxymin2   =', oxymin2
323         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
324         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
325      ENDIF
326      !
327      nitrfac (:,:,:) = 0._wp
328      denitr  (:,:,:) = 0._wp
329
330   END SUBROUTINE p4z_rem_init
331
332
333   INTEGER FUNCTION p4z_rem_alloc()
334      !!----------------------------------------------------------------------
335      !!                     ***  ROUTINE p4z_rem_alloc  ***
336      !!----------------------------------------------------------------------
337      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
338      !
339      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
340      !
341   END FUNCTION p4z_rem_alloc
342
343#else
344   !!======================================================================
345   !!  Dummy module :                                   No PISCES bio-model
346   !!======================================================================
347CONTAINS
348   SUBROUTINE p4z_rem                    ! Empty routine
349   END SUBROUTINE p4z_rem
350#endif 
351
352   !!======================================================================
353END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.