New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zrem.F90 @ 8003

Last change on this file since 8003 was 8003, checked in by aumont, 7 years ago

modification in the code to remove unnecessary parts such as kriest and non iomput options
File size: 16.8 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2016-03  (O. Aumont) Quota model and reorganization
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   'key_top'       and                                      TOP models
14   !!   'key_pisces'                                       PISCES bio-model
15   !!----------------------------------------------------------------------
16   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
17   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
18   !!   p4z_rem_alloc :  Allocate remineralisation variables
19   !!----------------------------------------------------------------------
20   USE oce_trc         !  shared variables between ocean and passive tracers
21   USE trc             !  passive tracers common variables
22   USE sms_pisces      !  PISCES Source Minus Sink variables
23   USE p4zopt          !  optical model
24   USE p4zche          !  chemical model
25   USE p4zlim          ! Phytoplankton limitation factors
26   USE p4zprod         !  Growth rate of the 2 phyto groups
27   USE p4zsink         !  Sinking of particles
28   USE prtctl_trc      !  print control for debugging
29   USE iom             !  I/O manager
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p4z_rem         ! called in p4zbio.F90
36   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
37   PUBLIC   p4z_rem_alloc
38
39   !! * Shared module variables
40   REAL(wp), PUBLIC ::  xremik     !: remineralisation rate of DOC
41   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
42   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of BSi
43   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of BSi
44   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
45   REAL(wp), PUBLIC ::  oxymin     !: halk saturation constant for anoxia
46   REAL(wp), PUBLIC ::  oxymin2    !: Minimum O2 concentration for oxic remin.
47   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
48   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
49
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
51
52
53   !!* Substitution
54#  include "top_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
57   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE p4z_rem( kt, jnt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_rem  ***
65      !!
66      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      !
71      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
72      !
73      INTEGER  ::   ji, jj, jk
74      REAL(wp) ::   zremik, zsiremin 
75      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
76      REAL(wp) ::   zbactfer, zolimit, zdenitnh4
77      REAL(wp) ::   zosil, ztem,ztoto,zpuis
78      REAL(wp) ::   zonitr, zstep, zrfact2
79      CHARACTER (len=25) :: charout
80      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zdepprod, zdepeff, zfacsi, zfacsib
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: znitr, zolimi,  zfebact
83      !!---------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('p4z_rem')
86      !
87      ! Allocate temporary workspace
88      CALL wrk_alloc( jpi, jpj,      ztempbac )
89      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zdepeff, zfacsi, zfacsib )
90      CALL wrk_alloc( jpi, jpj, jpk, zolimi, znitr, zfebact )
91
92      ! Initialization of local variables
93      ! ---------------------------------
94
95      ! Initialisation of temprary arrys
96      zdepprod(:,:,:) = 1._wp
97      zdepeff (:,:,:) = 0.4_wp
98      ztempbac(:,:)   = 0._wp
99      zfebact (:,:,:) = 0._wp
100      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
101      zfacsi(:,:,:)   = xsilab 
102
103      ! Computation of the mean phytoplankton concentration as
104      ! a crude estimate of the bacterial biomass
105      ! this parameterization has been deduced from a model version
106      ! that was modeling explicitely bacteria
107      ! -------------------------------------------------------
108      DO jk = 1, jpkm1
109         DO jj = 1, jpj
110            DO ji = 1, jpi
111               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
112               IF( fsdept(ji,jj,jk) < zdep ) THEN
113                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
114                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
115               ELSE
116                  zdepmin = MIN( 1., zdep / fsdept(ji,jj,jk) )
117                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
118                  zdepprod(ji,jj,jk) = zdepmin**0.273
119!                  zdepeff (ji,jj,jk) = 0.3 * zdepmin**0.3
120               ENDIF
121            END DO
122         END DO
123      END DO
124
125      DO jk = 1, jpkm1
126         DO jj = 1, jpj
127            DO ji = 1, jpi
128               ! denitrification factor computed from O2 levels
129               ! ----------------------------------------------
130               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( oxymin2 - trb(ji,jj,jk,jpoxy) )    &
131                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
132               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
133            END DO
134         END DO
135      END DO
136
137      DO jk = 1, jpkm1
138         DO jj = 1, jpj
139            DO ji = 1, jpi
140               zstep   = xstep
141               ! DOC ammonification. Depends on depth, phytoplankton biomass
142               ! and a limitation term which is supposed to be a parameterization
143               !     of the bacterial activity.
144               zremik = xremik * zstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
145               zremik = MAX( zremik, 2.74e-4 * xstep )
146               ! Ammonification in oxic waters with oxygen consumption
147               ! -----------------------------------------------------
148               zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
149               zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
150               ! Ammonification in suboxic waters with denitrification
151               ! -------------------------------------------------------
152               denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit,   &
153                  &                     zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)  )
154               !
155               zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
156               denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
157               ! Update of the tracers trends
158               ! ----------------------------
159               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
160               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
161               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
162               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk)
163               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
164               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
165               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk)    &
166               &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
167            END DO
168         END DO
169      END DO
170
171
172      DO jk = 1, jpkm1
173         DO jj = 1, jpj
174            DO ji = 1, jpi
175               zstep   = xstep
176               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
177               ! below 2 umol/L. Inhibited at strong light
178               ! ----------------------------------------------------------
179               zonitr  = nitrif * zstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
180               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) )
181               zdenitnh4 = nitrif * zstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
182               ! Update of the tracers trends
183               ! ----------------------------
184               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
185               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
186               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
187               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
188               znitr(ji,jj,jk) = zonitr
189            END DO
190         END DO
191      END DO
192
193      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
194         WRITE(charout, FMT="('rem1')")
195         CALL prt_ctl_trc_info(charout)
196         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
197      ENDIF
198
199      DO jk = 1, jpkm1
200         DO jj = 1, jpj
201            DO ji = 1, jpi
202
203               ! Bacterial uptake of iron. No iron is available in DOC. So
204               ! Bacteries are obliged to take up iron from the water. Some
205               ! studies (especially at Papa) have shown this uptake to be significant
206               ! ----------------------------------------------------------
207               zbactfer = feratb *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
208                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
209                  &              * zdepprod(ji,jj,jk) * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk)
210               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.39
211               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.3
212               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.09
213               zfebact(ji,jj,jk)   = zbactfer * 0.39
214            END DO
215         END DO
216      END DO
217
218      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
219         WRITE(charout, FMT="('rem2')")
220         CALL prt_ctl_trc_info(charout)
221         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
222      ENDIF
223
224      ! Initialization of the array which contains the labile fraction
225      ! of bSi. Set to a constant in the upper ocean
226      ! ---------------------------------------------------------------
227
228      DO jk = 1, jpkm1
229         DO jj = 1, jpj
230            DO ji = 1, jpi
231               zstep   = xstep
232               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
233               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
234               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
235               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
236
237               ! Remineralization rate of BSi depedant on T and saturation
238               ! ---------------------------------------------------------
239               IF ( fsdept(ji,jj,jk) > zdep ) THEN
240                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
241                  &                   * znusil * fse3t(ji,jj,jk) / wsbio4(ji,jj,jk) )
242                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
243                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
244                  &                   * znusil * fse3t(ji,jj,jk) / wsbio4(ji,jj,jk) )
245               ENDIF
246               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * zstep * znusil
247               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
248               !
249               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
250               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
251            END DO
252         END DO
253      END DO
254               
255
256      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
257         WRITE(charout, FMT="('rem3')")
258         CALL prt_ctl_trc_info(charout)
259         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
260       ENDIF
261
262      IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) THEN
263          zrfact2 = 1.e3 * rfact2r
264          CALL iom_put( "REMIN" , zolimi(:,:,:) * tmask(:,:,:) * zrfact2 )  ! Remineralisation rate
265          CALL iom_put( "DENIT" , denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2  )  ! Denitrification
266          CALL iom_put( "NIT"   , znitr(:,:,:) * rno3 * tmask(:,:,:) * zrfact2 )  !
267          CALL iom_put( "BACT", zdepbac(:,:,:) * 1.E6 * tmask(:,:,:) )  ! Bacterial biomass
268          CALL iom_put( "FEBACT" , zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2  )  ! Denitrification
269
270      ENDIF
271      !
272      CALL wrk_dealloc( jpi, jpj,      ztempbac )
273      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zdepeff, zfacsi, zfacsib )
274      CALL wrk_dealloc( jpi, jpj, jpk,  zolimi, znitr, zfebact )
275      !
276      IF( nn_timing == 1 )  CALL timing_stop('p4z_rem')
277      !
278   END SUBROUTINE p4z_rem
279
280
281   SUBROUTINE p4z_rem_init
282      !!----------------------------------------------------------------------
283      !!                  ***  ROUTINE p4z_rem_init  ***
284      !!
285      !! ** Purpose :   Initialization of remineralization parameters
286      !!
287      !! ** Method  :   Read the nampisrem namelist and check the parameters
288      !!      called at the first timestep
289      !!
290      !! ** input   :   Namelist nampisrem
291      !!
292      !!----------------------------------------------------------------------
293      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab,   &
294      &                   oxymin, oxymin2, feratb, xkferb
295      INTEGER :: ios                 ! Local integer output status for namelist read
296
297      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
298      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
299901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
300
301      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
302      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
303902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
304      IF(lwm) WRITE ( numonp, nampisrem )
305
306      IF(lwp) THEN                         ! control print
307         WRITE(numout,*) ' '
308         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
309         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
310         WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
311         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
312         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
313         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
314         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
315         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin    =', oxymin
316         WRITE(numout,*) '    Minimum O2 concentration for oxic remin.  oxymin2   =', oxymin2
317         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
318         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
319      ENDIF
320      !
321      nitrfac (:,:,:) = 0._wp
322      denitr  (:,:,:) = 0._wp
323
324   END SUBROUTINE p4z_rem_init
325
326
327   INTEGER FUNCTION p4z_rem_alloc()
328      !!----------------------------------------------------------------------
329      !!                     ***  ROUTINE p4z_rem_alloc  ***
330      !!----------------------------------------------------------------------
331      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
332      !
333      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
334      !
335   END FUNCTION p4z_rem_alloc
336
337#else
338   !!======================================================================
339   !!  Dummy module :                                   No PISCES bio-model
340   !!======================================================================
341CONTAINS
342   SUBROUTINE p4z_rem                    ! Empty routine
343   END SUBROUTINE p4z_rem
344#endif 
345
346   !!======================================================================
347END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.