New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zlim.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z/p5zlim.F90 @ 7617

Last change on this file since 7617 was 7617, checked in by aumont, 7 years ago

update diagnostics + changes in quota code
  • Property svn:executable set to *
File size: 36.4 KB
Line 
1MODULE p5zlim
2   !!======================================================================
3   !!                         ***  MODULE p5zlim  ***
4   !! TOP :   PISCES with variable stoichiometry
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-04  (O. Aumont, C. Ethe) Limitation for iron modelled in quota
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11#if defined key_pisces_quota
12   !!----------------------------------------------------------------------
13   !!   'key_pisces_quota'            PISCES bio-model with variable stoichiometry
14   !!----------------------------------------------------------------------
15   !!   p5z_lim        :   Compute the nutrients limitation terms
16   !!   p5z_lim_init   :   Read the namelist
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! Shared ocean-passive tracers variables
19   USE trc             ! Tracers defined
20   USE sms_pisces      ! PISCES variables
21   USE p4zopt          ! Optical
22   USE iom             !  I/O manager
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC p5z_lim   
28   PUBLIC p5z_lim_init   
29   PUBLIC p5z_lim_alloc
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::  concnno3    !:  NO3, PO4 half saturation   
33   REAL(wp), PUBLIC ::  concpno3    !:  NO3, PO4 half saturation   
34   REAL(wp), PUBLIC ::  concdno3    !:  Phosphate half saturation for diatoms 
35   REAL(wp), PUBLIC ::  concnnh4    !:  NH4 half saturation for phyto 
36   REAL(wp), PUBLIC ::  concpnh4    !:  NH4 half saturation for phyto 
37   REAL(wp), PUBLIC ::  concdnh4    !:  NH4 half saturation for diatoms
38   REAL(wp), PUBLIC ::  concnpo4    !:  NH4 half saturation for diatoms
39   REAL(wp), PUBLIC ::  concppo4    !:  NH4 half saturation for diatoms
40   REAL(wp), PUBLIC ::  concdpo4    !:  NH4 half saturation for diatoms
41   REAL(wp), PUBLIC ::  concnfer    !:  Iron half saturation for nanophyto
42   REAL(wp), PUBLIC ::  concpfer    !:  Iron half saturation for nanophyto
43   REAL(wp), PUBLIC ::  concdfer    !:  Iron half saturation for diatoms 
44   REAL(wp), PUBLIC ::  concbno3    !:  NO3 half saturation  for bacteria
45   REAL(wp), PUBLIC ::  concbnh4    !:  NH4 half saturation for bacteria
46   REAL(wp), PUBLIC ::  concbpo4    !:  PO4 half saturation for bacteria
47   REAL(wp), PUBLIC ::  xsizedia    !:  Minimum size criteria for diatoms
48   REAL(wp), PUBLIC ::  xsizepic    !:  Minimum size criteria for diatoms
49   REAL(wp), PUBLIC ::  xsizephy    !:  Minimum size criteria for nanophyto
50   REAL(wp), PUBLIC ::  xsizern     !:  Size ratio for nanophytoplankton
51   REAL(wp), PUBLIC ::  xsizerp     !:  Size ratio for nanophytoplankton
52   REAL(wp), PUBLIC ::  xsizerd     !:  Size ratio for diatoms
53   REAL(wp), PUBLIC ::  xksi1       !:  half saturation constant for Si uptake
54   REAL(wp), PUBLIC ::  xksi2       !:  half saturation constant for Si/C
55   REAL(wp), PUBLIC ::  xkdoc       !:  2nd half-sat. of DOC remineralization 
56   REAL(wp), PUBLIC ::  concbfe     !:  Fe half saturation for bacteria
57   REAL(wp), PUBLIC ::  qfnopt      !:  optimal Fe quota for nanophyto
58   REAL(wp), PUBLIC ::  qfpopt      !:  optimal Fe quota for nanophyto
59   REAL(wp), PUBLIC ::  qfdopt      !:  optimal Fe quota for diatoms
60   REAL(wp), PUBLIC ::  caco3r      !:  mean rainratio
61   REAL(wp), PUBLIC ::  qnnmin      !:  optimal Fe quota for diatoms
62   REAL(wp), PUBLIC ::  qnnmax      !:  optimal Fe quota for diatoms
63   REAL(wp), PUBLIC ::  qpnmin      !:  optimal Fe quota for diatoms
64   REAL(wp), PUBLIC ::  qpnmax      !:  optimal Fe quota for diatoms
65   REAL(wp), PUBLIC ::  qnpmin      !:  optimal Fe quota for diatoms
66   REAL(wp), PUBLIC ::  qnpmax      !:  optimal Fe quota for diatoms
67   REAL(wp), PUBLIC ::  qppmin      !:  optimal Fe quota for diatoms
68   REAL(wp), PUBLIC ::  qppmax      !:  optimal Fe quota for diatoms
69   REAL(wp), PUBLIC ::  qndmin      !:  optimal Fe quota for diatoms
70   REAL(wp), PUBLIC ::  qndmax      !:  optimal Fe quota for diatoms
71   REAL(wp), PUBLIC ::  qpdmin      !:  optimal Fe quota for diatoms
72   REAL(wp), PUBLIC ::  qpdmax      !:  optimal Fe quota for diatoms
73   REAL(wp), PUBLIC ::  qfnmax      !:  optimal Fe quota for diatoms
74   REAL(wp), PUBLIC ::  qfpmax      !:  optimal Fe quota for diatoms
75   REAL(wp), PUBLIC ::  qfdmax      !:  optimal Fe quota for diatoms
76   REAL(wp), PUBLIC ::  zpsinh4
77   REAL(wp), PUBLIC ::  zpsino3
78   REAL(wp), PUBLIC ::  zpsiuptk
79
80   !!*  Allometric variations of the quotas
81   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqnnmin    !: ???
82   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqnnmax    !: ???
83   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqpnmin    !: ???
84   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqpnmax    !: ???
85   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqnpmin    !: ???
86   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqnpmax    !: ???
87   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqppmin    !: ???
88   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqppmax    !: ???
89   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqndmin    !: ???
90   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqndmax    !: ???
91   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqpdmin    !: ???
92   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:,:)  ::   xqpdmax    !: ???
93
94   !!* Phytoplankton limitation terms
95   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanono3   !: ???
96   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatno3   !: ???
97   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanonh4   !: ???
98   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatnh4   !: ???
99   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanopo4   !: ???
100   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatpo4   !: ???
101   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimphy    !: ???
102   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimdia    !: ???
103   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimnfe    !: ???
104   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimdfe    !: ???
105   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimsi     !: ???
106   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimsi2    !: ???
107   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimbac    !: ??
108   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimbacl   !: ??
109   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpicono3   !: ???
110   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpiconh4   !: ???
111   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpicopo4   !: ???
112   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanodop   !: ???
113   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpicodop   !: ???
114   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatdop   !: ???
115   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xnanofer   !: ???
116   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xpicofer   !: ???
117   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xdiatfer   !: ???
118   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimpic    !: ???
119   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xlimpfe    !: ???
120   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   fvnuptk
121   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   fvpuptk
122   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   fvduptk
123   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xbactnh4   !: ???
124   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:)  ::   xbactno3   !: ???
125
126   ! Coefficient for iron limitation
127   REAL(wp) ::  xcoef1   = 0.00167  / 55.85
128   REAL(wp) ::  xcoef2   = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5
129   REAL(wp) ::  xcoef3   = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 
130   !!* Substitution
131#  include "top_substitute.h90"
132   !!----------------------------------------------------------------------
133   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
134   !! $Id: p4zlim.F90 3160 2011-11-20 14:27:18Z cetlod $
135   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
136   !!----------------------------------------------------------------------
137
138CONTAINS
139
140   SUBROUTINE p5z_lim( kt, knt )
141      !!---------------------------------------------------------------------
142      !!                     ***  ROUTINE p5z_lim  ***
143      !!
144      !! ** Purpose :   Compute the co-limitations by the various nutrients
145      !!              for the various phytoplankton species
146      !!
147      !! ** Method  : - ???
148      !!---------------------------------------------------------------------
149      !
150      INTEGER, INTENT(in)  :: kt, knt
151      !
152      INTEGER  ::   ji, jj, jk
153      REAL(wp) ::   zlim1, zlim2, zlim3, zlim4, zno3, zferlim
154      REAL(wp) ::   z1_trndia, z1_trnpic, z1_trnphy, ztem1, ztem2, zetot1
155      REAL(wp) ::   zratio, zration, zratiof, znutlim, zfalim
156      REAL(wp) ::   zconc1d, zconc1dnh4, zconc0n, zconc0nnh4, zconc0npo4, zconc0dpo4
157      REAL(wp) ::   zconc0p, zconc0pnh4, zconc0ppo4, zconcpfe, zconcnfe, zconcdfe
158      REAL(wp) ::   fanano, fananop, fananof, fadiat, fadiatp, fadiatf
159      REAL(wp) ::   fapico, fapicop, fapicof
160      REAL(wp) ::   zrpho, zrass, zcoef, zfuptk, zratchl
161      REAL(wp) ::   zfvn, zfvp, zfvf, zsizen, zsizep, zsized, znanochl, zpicochl, zdiatchl
162      REAL(wp) ::   zqfemn, zqfemp, zqfemd
163      !!---------------------------------------------------------------------
164      !
165      IF( nn_timing == 1 )  CALL timing_start('p5z_lim')
166      !
167      zratchl = 6.0
168      !
169      DO jk = 1, jpkm1
170         DO jj = 1, jpj
171            DO ji = 1, jpi
172               !
173               ! Tuning of the iron concentration to a minimum level that is set to the detection limit
174               !-------------------------------------
175               zno3    = trb(ji,jj,jk,jpno3) / 40.e-6
176               zferlim = MAX( 3e-11 * zno3 * zno3, 5e-12 )
177               zferlim = MIN( zferlim, 7e-11 )
178               trb(ji,jj,jk,jpfer) = MAX( trb(ji,jj,jk,jpfer), zferlim )
179
180               ! Computation of the mean relative size of each community
181               ! -------------------------------------------------------
182               z1_trnphy   = 1. / ( trb(ji,jj,jk,jpphy) + rtrn )
183               z1_trnpic   = 1. / ( trb(ji,jj,jk,jppic) + rtrn )
184               z1_trndia   = 1. / ( trb(ji,jj,jk,jpdia) + rtrn )
185               znanochl = trb(ji,jj,jk,jpnch) * z1_trnphy
186               zpicochl = trb(ji,jj,jk,jppch) * z1_trnpic
187               zdiatchl = trb(ji,jj,jk,jpdch) * z1_trndia
188
189               ! Computation of a variable Ks for iron on diatoms taking into account
190               ! that increasing biomass is made of generally bigger cells
191               !------------------------------------------------
192               zsized            = sized(ji,jj,jk)**0.81
193               zconcdfe          = concdfer * zsized
194               zconc1d           = concdno3 * zsized
195               zconc1dnh4        = concdnh4 * zsized
196               zconc0dpo4        = concdpo4 * zsized
197
198               zsizep            = 1.
199               zconcpfe          = concpfer * zsizep
200               zconc0p           = concpno3 * zsizep
201               zconc0pnh4        = concpnh4 * zsizep
202               zconc0ppo4        = concppo4 * zsizep
203
204               zsizen            = 1.
205               zconcnfe          = concnfer * zsizen
206               zconc0n           = concnno3 * zsizen
207               zconc0nnh4        = concnnh4 * zsizen
208               zconc0npo4        = concnpo4 * zsizen
209
210               ! Allometric variations of the minimum and maximum quotas
211               ! From Talmy et al. (2014) and Maranon et al. (2013)
212               ! -------------------------------------------------------
213               xqnnmin(ji,jj,jk) = qnnmin
214               xqnnmax(ji,jj,jk) = qnnmax
215               xqndmin(ji,jj,jk) = qndmin * sized(ji,jj,jk)**(-0.27) 
216               xqndmax(ji,jj,jk) = qndmax
217               xqnpmin(ji,jj,jk) = qnpmin
218               xqnpmax(ji,jj,jk) = qnpmax
219
220               ! Computation of the optimal allocation parameters
221               ! Based on the different papers by Pahlow et al., and Smith et al.
222               ! -----------------------------------------------------------------
223               znutlim = MAX( trb(ji,jj,jk,jpnh4) / zconc0nnh4,    &
224                 &         trb(ji,jj,jk,jpno3) / zconc0n)
225               fanano = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
226               znutlim = trb(ji,jj,jk,jppo4) / zconc0npo4
227               fananop = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
228               znutlim = biron(ji,jj,jk) / zconcnfe
229               fananof = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
230               znutlim = MAX( trb(ji,jj,jk,jpnh4) / zconc0pnh4,    &
231                 &         trb(ji,jj,jk,jpno3) / zconc0p)
232               fapico = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
233               znutlim = trb(ji,jj,jk,jppo4) / zconc0ppo4
234               fapicop = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
235               znutlim = biron(ji,jj,jk) / zconcpfe
236               fapicof = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
237               znutlim = MAX( trb(ji,jj,jk,jpnh4) / zconc1dnh4,    &
238                 &         trb(ji,jj,jk,jpno3) / zconc1d )
239               fadiat = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
240               znutlim = trb(ji,jj,jk,jppo4) / zconc0dpo4
241               fadiatp = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
242               znutlim = biron(ji,jj,jk) / zconcdfe
243               fadiatf = MAX(0.01, MIN(0.99, 1. / ( SQRT(znutlim) + 1.) ) )
244               !
245               ! Michaelis-Menten Limitation term for nutrients Small bacteria
246               ! -------------------------------------------------------------
247               xbactnh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) / ( concbnh4 + trb(ji,jj,jk,jpnh4) )
248               xbactno3(ji,jj,jk) = trb(ji,jj,jk,jpno3) / ( concbno3 + trb(ji,jj,jk,jpno3) ) * (1. - xbactnh4(ji,jj,jk))
249               !
250               zlim1    = xbactno3(ji,jj,jk) + xbactnh4(ji,jj,jk)
251               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concbpo4)
252               zlim3    = biron(ji,jj,jk) / ( concbfe + biron(ji,jj,jk) )
253               zlim4    = trb(ji,jj,jk,jpdoc) / ( xkdoc   + trb(ji,jj,jk,jpdoc) )
254               xlimbacl(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
255               xlimbac (ji,jj,jk) = xlimbacl(ji,jj,jk) * zlim4
256               !
257               ! Michaelis-Menten Limitation term for nutrients Small flagellates
258               ! -----------------------------------------------
259               zfalim = (1.-fanano) / fanano
260               xnanonh4(ji,jj,jk) = (1. - fanano) * trb(ji,jj,jk,jpnh4) / ( zfalim * zconc0nnh4 + trb(ji,jj,jk,jpnh4) )
261               xnanono3(ji,jj,jk) = (1. - fanano) * trb(ji,jj,jk,jpno3) / ( zfalim * zconc0n + trb(ji,jj,jk,jpno3) )  &
262               &                    * (1. - xnanonh4(ji,jj,jk))
263               !
264               zfalim = (1.-fananop) / fananop
265               xnanopo4(ji,jj,jk) = (1. - fananop) * trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zfalim * zconc0npo4 )
266               xnanodop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdop) + xkdoc )   &
267               &                    * ( 1.0 - xnanopo4(ji,jj,jk) )
268               xnanodop(ji,jj,jk) = 0.
269               !
270               zfalim = (1.-fananof) / fananof
271               xnanofer(ji,jj,jk) = (1. - fananof) * biron(ji,jj,jk) / ( biron(ji,jj,jk) + zfalim * zconcnfe )
272               !
273               zratiof   = trb(ji,jj,jk,jpnfe) * z1_trnphy
274               zqfemn = xcoef1 * znanochl + xcoef2 + xcoef3 * xnanono3(ji,jj,jk)
275               !
276               zration = trb(ji,jj,jk,jpnph) * z1_trnphy
277               zration = MIN(xqnnmax(ji,jj,jk), MAX( 2. * xqnnmin(ji,jj,jk), zration ))
278               fvnuptk(ji,jj,jk) = 1. / zpsiuptk * rno3 * 2. * xqnnmin(ji,jj,jk) / (zration + rtrn)  &
279               &                   * MAX(0., (1. - zratchl * znanochl / 12. ) )
280               !
281               zlim1    = max(0., (zration - 2. * xqnnmin(ji,jj,jk) )  &
282               &          / (xqnnmax(ji,jj,jk) - 2. * xqnnmin(ji,jj,jk) ) ) * xqnnmax(ji,jj,jk)  &
283               &          / (zration + rtrn)
284               zlim3    = MAX( 0.,( zratiof - zqfemn ) / qfnopt ) 
285               xlimnfe(ji,jj,jk) = MIN( 1., zlim3 )
286               xlimphy(ji,jj,jk) = MIN( 1., zlim1, zlim3 )
287               !
288               ! Michaelis-Menten Limitation term for nutrients picophytoplankton
289               ! ----------------------------------------------------------------
290               zfalim = (1.-fapico) / fapico 
291               xpiconh4(ji,jj,jk) = (1. - fapico) * trb(ji,jj,jk,jpnh4) / ( zfalim * zconc0pnh4 + trb(ji,jj,jk,jpnh4) )
292               xpicono3(ji,jj,jk) = (1. - fapico) * trb(ji,jj,jk,jpno3) / ( zfalim * zconc0p + trb(ji,jj,jk,jpno3) )  &
293               &                    * (1. - xpiconh4(ji,jj,jk))
294               !
295               zfalim = (1.-fapicop) / fapicop 
296               xpicopo4(ji,jj,jk) = (1. - fapicop) * trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zfalim * zconc0ppo4 )
297               xpicodop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdop) + xkdoc )   &
298               &                    * ( 1.0 - xpicopo4(ji,jj,jk) )
299               xpicodop(ji,jj,jk) = 0.
300               !
301               zfalim = (1.-fapicof) / fapicof
302               xpicofer(ji,jj,jk) = (1. - fapicof) * biron(ji,jj,jk) / ( biron(ji,jj,jk) + zfalim * zconcpfe )
303               !
304               zratiof   = trb(ji,jj,jk,jppfe) * z1_trnpic
305               zqfemp = xcoef1 * zpicochl + xcoef2 + xcoef3 * xpicono3(ji,jj,jk)
306               !
307               zration   = trb(ji,jj,jk,jpnpi) * z1_trnpic
308               zration = MIN(xqnpmax(ji,jj,jk), MAX( 2. * xqnpmin(ji,jj,jk), zration ))
309               fvpuptk(ji,jj,jk) = 1. / zpsiuptk * rno3 * 2. * xqnpmin(ji,jj,jk) / (zration + rtrn)  &
310               &                   * MAX(0., (1. - zratchl * zpicochl / 12. ) ) 
311               !
312               zlim1    = max(0., (zration - 2. * xqnpmin(ji,jj,jk) )  &
313               &          / (xqnpmax(ji,jj,jk) - 2. * xqnpmin(ji,jj,jk) ) ) * xqnpmax(ji,jj,jk)  &
314               &          / (zration + rtrn)
315               zlim3    = MAX( 0.,( zratiof - zqfemp ) / qfpopt )
316               xlimpfe(ji,jj,jk) = MIN( 1., zlim3 )
317               xlimpic(ji,jj,jk) = MIN( 1., zlim1, zlim3 )
318               !
319               !   Michaelis-Menten Limitation term for nutrients Diatoms
320               !   ------------------------------------------------------
321               zfalim = (1.-fadiat) / fadiat 
322               xdiatnh4(ji,jj,jk) = (1. - fadiat) * trb(ji,jj,jk,jpnh4) / ( zfalim * zconc1dnh4 + trb(ji,jj,jk,jpnh4) )
323               xdiatno3(ji,jj,jk) = (1. - fadiat) * trb(ji,jj,jk,jpno3) / ( zfalim * zconc1d + trb(ji,jj,jk,jpno3) )  &
324               &                    * (1. - xdiatnh4(ji,jj,jk))
325               !
326               zfalim = (1.-fadiatp) / fadiatp
327               xdiatpo4(ji,jj,jk) = (1. - fadiatp) * trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zfalim * zconc0dpo4 )
328               xdiatdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdop) + xkdoc )  &
329               &                    * ( 1.0 - xdiatpo4(ji,jj,jk) )
330               xdiatdop(ji,jj,jk) = 0.
331               !
332               zfalim = (1.-fadiatf) / fadiatf
333               xdiatfer(ji,jj,jk) = (1. - fadiatf) * biron(ji,jj,jk) / ( biron(ji,jj,jk) + zfalim * zconcdfe )
334               !
335               zratiof   = trb(ji,jj,jk,jpdfe) * z1_trndia
336               zqfemd = xcoef1 * zdiatchl + xcoef2 + xcoef3 * xdiatno3(ji,jj,jk)
337               !
338               zration   = trb(ji,jj,jk,jpndi) * z1_trndia
339               zration = MIN(xqndmax(ji,jj,jk), MAX( 2. * xqndmin(ji,jj,jk), zration ))
340               fvduptk(ji,jj,jk) = 1. / zpsiuptk * rno3 * 2. * xqndmin(ji,jj,jk) / (zration + rtrn)   &
341               &                   * MAX(0., (1. - zratchl * zdiatchl / 12. ) ) 
342               !
343               zlim1    = max(0., (zration - 2. * xqndmin(ji,jj,jk) )    &
344               &          / (xqndmax(ji,jj,jk) - 2. * xqndmin(ji,jj,jk) ) )   &
345               &          * xqndmax(ji,jj,jk) / (zration + rtrn)
346               zlim3    = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi(ji,jj) )
347               zlim4    = MAX( 0., ( zratiof - zqfemd ) / qfdopt )
348               xlimdfe(ji,jj,jk) = MIN( 1., zlim4 )
349               xlimdia(ji,jj,jk) = MIN( 1., zlim1, zlim3, zlim4 )
350               xlimsi(ji,jj,jk)  = MIN( 1., zlim3, zlim4 )
351               xlimsi2(ji,jj,jk)  = MIN( 1., zlim1, zlim4 )
352            END DO
353         END DO
354      END DO
355      !
356      ! Compute the phosphorus quota values. It is based on Litchmann et al., 2004 and Daines et al, 2013.
357      ! The relative contribution of three fonctional pools are computed: light harvesting apparatus,
358      ! nutrient uptake pool and assembly machinery. DNA is assumed to represent 1% of the dry mass of
359      ! phytoplankton (see Daines et al., 2013).
360      ! --------------------------------------------------------------------------------------------------
361      DO jk = 1, jpkm1
362         DO jj = 1, jpj
363            DO ji = 1, jpi
364               ! Size estimation of nanophytoplankton
365               ! ------------------------------------
366               zfvn = 2. * fvnuptk(ji,jj,jk)
367               sizen(ji,jj,jk) = MAX(1., MIN(xsizern, 1.0 / ( MAX(rtrn, zfvn) ) ) )
368               ! N/P ratio of nanophytoplankton
369               ! ------------------------------
370               zfuptk = 0.23 * zfvn
371               zrpho = 2.24 * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpnph) * rno3 * 15. + rtrn )
372               zrass = (1. - 0.2 - zrpho - zfuptk)
373               xqpnmax(ji,jj,jk) = ( zfuptk + zrpho ) * 0.0128 * 16. + zrass * 1./ 7.2 * 16. + 0.13
374               xqpnmax(ji,jj,jk) = xqpnmax(ji,jj,jk) * trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn )
375               xqpnmin(ji,jj,jk) = qpnmin
376
377               ! Size estimation of picophytoplankton
378               ! ------------------------------------
379               zfvn = 2. * fvpuptk(ji,jj,jk)
380               sizep(ji,jj,jk) = MAX(1., MIN(xsizerp, 1.0 / ( MAX(rtrn, zfvn) ) ) )
381
382               ! N/P ratio of picophytoplankton
383               ! ------------------------------
384               zfuptk = 0.35 * zfvn
385               zrpho = 2.24 * trb(ji,jj,jk,jppch) / ( trb(ji,jj,jk,jpnpi) * rno3 * 15. + rtrn )
386               zrass = (1. - 0.4 - zrpho - zfuptk)
387               xqppmax(ji,jj,jk) =  (zrpho + zfuptk) * 0.0128 * 16. + zrass * 1./ 10.9 * 16. + 0.13
388               xqppmax(ji,jj,jk) = xqppmax(ji,jj,jk) * trb(ji,jj,jk,jpnpi) / ( trb(ji,jj,jk,jppic) + rtrn )
389               xqppmin(ji,jj,jk) = qppmin
390
391               ! Size estimation of diatoms
392               ! --------------------------
393               zfvn = 2. * fvduptk(ji,jj,jk)
394               sized(ji,jj,jk) = MAX(1., MIN(xsizerd, 1.0 / ( MAX(rtrn, zfvn) ) ) )
395!               zcoef = trb(ji,jj,jk,jpdia) - MIN(xsizedia, trb(ji,jj,jk,jpdia) )
396!               sized(ji,jj,jk) = 1. + xsizerd * zcoef *1E6 / ( 1. + zcoef * 1E6 )
397
398               ! N/P ratio of diatoms
399               ! --------------------
400               zfuptk = 0.2 * zfvn
401               zrpho = 2.24 * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpndi) * rno3 * 15. + rtrn )
402               zrass = 1. - 0.2 - zrpho - zfuptk
403               xqpdmax(ji,jj,jk) = ( zfuptk + zrpho ) * 0.0128 * 16. + zrass * 1./ 7.2 * 16. + 0.13
404               xqpdmax(ji,jj,jk) = xqpdmax(ji,jj,jk) * trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn )
405               xqpdmin(ji,jj,jk) = qpdmin * sized(ji,jj,jk)**(-0.27)
406            END DO
407         END DO
408      END DO
409
410      ! Compute the fraction of nanophytoplankton that is made of calcifiers
411      ! --------------------------------------------------------------------
412      DO jk = 1, jpkm1
413         DO jj = 1, jpj
414            DO ji = 1, jpi
415               zlim1 =  trb(ji,jj,jk,jpnh4) / ( trb(ji,jj,jk,jpnh4) + concnnh4 ) + trb(ji,jj,jk,jpno3)    &
416               &        / ( trb(ji,jj,jk,jpno3) + concnno3 ) * ( 1.0 - trb(ji,jj,jk,jpnh4)   &
417               &        / ( trb(ji,jj,jk,jpnh4) + concnnh4 ) )
418               zlim2  = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concnpo4 )
419               zlim3  = trb(ji,jj,jk,jpfer) / ( trb(ji,jj,jk,jpfer) +  5.E-11 ) 
420               ztem1  = MAX( 0., tsn(ji,jj,jk,jp_tem) )
421               ztem2  = tsn(ji,jj,jk,jp_tem) - 10.
422               zetot1 = MAX( 0., etot(ji,jj,jk) - 1.) / ( 4. + etot(ji,jj,jk) ) * 20. / ( 20. + etot(ji,jj,jk) ) 
423
424!               xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 )                  &
425               xfracal(ji,jj,jk) = caco3r                 &
426               &                   * ztem1 / ( 1. + ztem1 ) * MAX( 1., trb(ji,jj,jk,jpphy)*1E6 )   &
427                  &                * ( 1. + EXP(-ztem2 * ztem2 / 25. ) )         &
428                  &                * zetot1 * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) )
429               xfracal(ji,jj,jk) = MAX( 0.02, MIN( 0.8 , xfracal(ji,jj,jk) ) )
430            END DO
431         END DO
432      END DO
433      !
434      IF( lk_iomput .AND. knt == nrdttrc ) THEN        ! save output diagnostics
435        IF( iom_use( "xfracal" ) ) CALL iom_put( "xfracal", xfracal(:,:,:) * tmask(:,:,:) )  ! euphotic layer deptht
436        IF( iom_use( "LNnut"   ) ) CALL iom_put( "LNnut"  , xlimphy(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
437        IF( iom_use( "LPnut"   ) ) CALL iom_put( "LPnut"  , xlimpic(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
438        IF( iom_use( "LDnut"   ) ) CALL iom_put( "LDnut"  , xlimdia(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
439        IF( iom_use( "LNFe"    ) ) CALL iom_put( "LNFe"   , xlimnfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
440        IF( iom_use( "LPFe"    ) ) CALL iom_put( "LPFe"   , xlimpfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
441        IF( iom_use( "LDFe"    ) ) CALL iom_put( "LDFe"   , xlimdfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
442        IF( iom_use( "SIZEN"   ) ) CALL iom_put( "SIZEN"  , sizen(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
443        IF( iom_use( "SIZEP"   ) ) CALL iom_put( "SIZEP"  , sizep(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
444        IF( iom_use( "SIZED"   ) ) CALL iom_put( "SIZED"  , sized(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
445        IF( iom_use( "QPNMAX"   ) ) CALL iom_put( "QPNMAX"  , xqpnmax(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
446        IF( iom_use( "QPPMAX"   ) ) CALL iom_put( "QPPMAX"  , xqppmax(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
447        IF( iom_use( "QPDMAX"   ) ) CALL iom_put( "QPDMAX"  , xqpdmax(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
448      ENDIF
449      !
450      IF( nn_timing == 1 )  CALL timing_stop('p5z_lim')
451      !
452   END SUBROUTINE p5z_lim
453
454   SUBROUTINE p5z_lim_init
455
456      !!----------------------------------------------------------------------
457      !!                  ***  ROUTINE p5z_lim_init  ***
458      !!
459      !! ** Purpose :   Initialization of nutrient limitation parameters
460      !!
461      !! ** Method  :   Read the nampislim and nampisquota namelists and check
462      !!      the parameters called at the first timestep (nittrc000)
463      !!
464      !! ** input   :   Namelist nampislim
465      !!
466      !!----------------------------------------------------------------------
467
468      NAMELIST/nampislim/ concnno3, concpno3, concdno3, concnnh4, concpnh4, concdnh4,  &
469         &                concnfer, concpfer, concdfer, concbfe, concnpo4, concppo4,   &
470         &                concdpo4, concbno3, concbnh4, concbpo4, xsizedia, xsizepic,  &
471         &                xsizephy, xsizern, xsizerp, xsizerd, xksi1, xksi2, xkdoc,    &
472         &                caco3r
473
474      NAMELIST/nampisquota/ qnnmin, qnnmax, qpnmin, qpnmax, qnpmin, qnpmax, qppmin,      &
475         &                  qppmax, qndmin, qndmax, qpdmin, qpdmax, qfnmax, qfpmax, qfdmax,  &
476         &                  qfnopt, qfpopt, qfdopt
477 
478
479      INTEGER :: ios                 ! Local integer output status for namelist read
480
481      REWIND( numnatp_ref )              ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters
482      READ  ( numnatp_ref, nampislim, IOSTAT = ios, ERR = 901)
483901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in reference namelist', lwp )
484
485      REWIND( numnatp_cfg )              ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters
486      READ  ( numnatp_cfg, nampislim, IOSTAT = ios, ERR = 902 )
487902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in configuration namelist', lwp )
488      IF(lwm) WRITE ( numonp, nampislim )
489
490      IF(lwp) THEN                         ! control print
491         WRITE(numout,*) ' '
492         WRITE(numout,*) ' Namelist parameters for nutrient limitations, nampislim'
493         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
494         WRITE(numout,*) '    mean rainratio                           caco3r    = ', caco3r
495         WRITE(numout,*) '    NO3 half saturation of nanophyto         concnno3  = ', concnno3
496         WRITE(numout,*) '    NO3 half saturation of picophyto         concpno3  = ', concpno3
497         WRITE(numout,*) '    NO3 half saturation of diatoms           concdno3  = ', concdno3
498         WRITE(numout,*) '    NH4 half saturation for phyto            concnnh4  = ', concnnh4
499         WRITE(numout,*) '    NH4 half saturation for pico             concpnh4  = ', concpnh4
500         WRITE(numout,*) '    NH4 half saturation for diatoms          concdnh4  = ', concdnh4
501         WRITE(numout,*) '    PO4 half saturation for phyto            concnpo4  = ', concnpo4
502         WRITE(numout,*) '    PO4 half saturation for pico             concppo4  = ', concppo4
503         WRITE(numout,*) '    PO4 half saturation for diatoms          concdpo4  = ', concdpo4
504         WRITE(numout,*) '    half saturation constant for Si uptake   xksi1     = ', xksi1
505         WRITE(numout,*) '    half saturation constant for Si/C        xksi2     = ', xksi2
506         WRITE(numout,*) '    half-sat. of DOC remineralization        xkdoc     = ', xkdoc
507         WRITE(numout,*) '    Iron half saturation for nanophyto       concnfer  = ', concnfer
508         WRITE(numout,*) '    Iron half saturation for picophyto       concpfer  = ', concpfer
509         WRITE(numout,*) '    Iron half saturation for diatoms         concdfer  = ', concdfer
510         WRITE(numout,*) '    size ratio for nanophytoplankton         xsizern   = ', xsizern
511         WRITE(numout,*) '    size ratio for picophytoplankton         xsizerp   = ', xsizerp
512         WRITE(numout,*) '    size ratio for diatoms                   xsizerd   = ', xsizerd
513         WRITE(numout,*) '    NO3 half saturation of bacteria          concbno3  = ', concbno3
514         WRITE(numout,*) '    NH4 half saturation for bacteria         concbnh4  = ', concbnh4
515         WRITE(numout,*) '    Minimum size criteria for diatoms        xsizedia  = ', xsizedia
516         WRITE(numout,*) '    Minimum size criteria for picophyto      xsizepic  = ', xsizepic
517         WRITE(numout,*) '    Minimum size criteria for nanophyto      xsizephy  = ', xsizephy
518         WRITE(numout,*) '    Fe half saturation for bacteria          concbfe   = ', concbfe
519      ENDIF
520
521      REWIND( numnatp_ref )              ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters
522      READ  ( numnatp_ref, nampisquota, IOSTAT = ios, ERR = 903)
523903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisquota in reference namelist', lwp )
524
525      REWIND( numnatp_cfg )              ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters
526      READ  ( numnatp_cfg, nampisquota, IOSTAT = ios, ERR = 904 )
527904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisquota in configuration namelist', lwp )
528      IF(lwm) WRITE ( numonp, nampisquota )
529
530      IF(lwp) THEN                         ! control print
531         WRITE(numout,*) ' '
532         WRITE(numout,*) ' Namelist parameters for nutrient limitations, nampisquota'
533         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
534         WRITE(numout,*) '    optimal Fe quota for nano.               qfnopt    = ', qfnopt
535         WRITE(numout,*) '    optimal Fe quota for pico.               qfpopt    = ', qfpopt
536         WRITE(numout,*) '    Optimal Fe quota for diatoms             qfdopt    = ', qfdopt
537         WRITE(numout,*) '    Minimal N quota for nano                 qnnmin    = ', qnnmin
538         WRITE(numout,*) '    Maximal N quota for nano                 qnnmax    = ', qnnmax
539         WRITE(numout,*) '    Minimal P quota for nano                 qpnmin    = ', qpnmin
540         WRITE(numout,*) '    Maximal P quota for nano                 qpnmax    = ', qpnmax
541         WRITE(numout,*) '    Minimal N quota for pico                 qnpmin    = ', qnpmin
542         WRITE(numout,*) '    Maximal N quota for pico                 qnpmax    = ', qnpmax
543         WRITE(numout,*) '    Minimal P quota for pico                 qppmin    = ', qppmin
544         WRITE(numout,*) '    Maximal P quota for pico                 qppmax    = ', qppmax
545         WRITE(numout,*) '    Minimal N quota for diatoms              qndmin    = ', qndmin
546         WRITE(numout,*) '    Maximal N quota for diatoms              qndmax    = ', qndmax
547         WRITE(numout,*) '    Minimal P quota for diatoms              qpdmin    = ', qpdmin
548         WRITE(numout,*) '    Maximal P quota for diatoms              qpdmax    = ', qpdmax
549         WRITE(numout,*) '    Minimal P quota for nanophyto.           qfnmax    = ', qfnmax
550         WRITE(numout,*) '    Minimal P quota for picophyto.           qfpmax    = ', qfpmax
551         WRITE(numout,*) '    Maximal P quota for diatoms              qfdmax    = ', qfdmax
552      ENDIF
553
554      zpsino3 = 2.3 * rno3
555      zpsinh4 = 1.8 * rno3
556      zpsiuptk = 2.3 * rno3
557
558   END SUBROUTINE p5z_lim_init
559
560   INTEGER FUNCTION p5z_lim_alloc()
561      !!----------------------------------------------------------------------
562      !!                     ***  ROUTINE p5z_lim_alloc  ***
563      !!----------------------------------------------------------------------
564      USE lib_mpp , ONLY: ctl_warn
565      INTEGER ::   ierr(2)        ! Local variables
566      !!----------------------------------------------------------------------
567      ierr(:) = 0
568
569      !*  Biological arrays for phytoplankton growth
570      ALLOCATE( xpicono3(jpi,jpj,jpk), xpiconh4(jpi,jpj,jpk),       &
571         &      xpicopo4(jpi,jpj,jpk), xpicodop(jpi,jpj,jpk),       &
572         &      xnanodop(jpi,jpj,jpk), xdiatdop(jpi,jpj,jpk),       &
573         &      xnanono3(jpi,jpj,jpk), xdiatno3(jpi,jpj,jpk),       &
574         &      xnanonh4(jpi,jpj,jpk), xdiatnh4(jpi,jpj,jpk),       &
575         &      xnanopo4(jpi,jpj,jpk), xdiatpo4(jpi,jpj,jpk),       &
576         &      xbactnh4(jpi,jpj,jpk), xbactno3(jpi,jpj,jpk),       &
577         &      xlimphy (jpi,jpj,jpk), xlimdia (jpi,jpj,jpk),       &
578         &      xlimnfe (jpi,jpj,jpk), xlimdfe (jpi,jpj,jpk),       &
579         &      xlimbac (jpi,jpj,jpk), xlimbacl(jpi,jpj,jpk),       &
580         &      xnanofer(jpi,jpj,jpk), xdiatfer(jpi,jpj,jpk),       &
581         &      xpicofer(jpi,jpj,jpk), xlimpfe (jpi,jpj,jpk),       &
582         &      fvnuptk (jpi,jpj,jpk), fvduptk (jpi,jpj,jpk),       &
583         &      fvpuptk (jpi,jpj,jpk), xlimpic (jpi,jpj,jpk),       &
584         &      xlimsi  (jpi,jpj,jpk), xlimsi2 (jpi,jpj,jpk),       STAT=ierr(1) )
585
586      !*  Minimum/maximum quotas of phytoplankton
587      ALLOCATE( xqnnmin (jpi,jpj,jpk), xqnnmax(jpi,jpj,jpk),       &
588         &      xqpnmin (jpi,jpj,jpk), xqpnmax(jpi,jpj,jpk),       &
589         &      xqnpmin (jpi,jpj,jpk), xqnpmax(jpi,jpj,jpk),       &
590         &      xqppmin (jpi,jpj,jpk), xqppmax(jpi,jpj,jpk),       &
591         &      xqndmin (jpi,jpj,jpk), xqndmax(jpi,jpj,jpk),       &
592         &      xqpdmin (jpi,jpj,jpk), xqpdmax(jpi,jpj,jpk),     STAT=ierr(2) )
593      !
594      p5z_lim_alloc = MAXVAL( ierr )
595      !
596      IF( p5z_lim_alloc /= 0 ) CALL ctl_warn('p5z_lim_alloc : failed to allocate arrays.')
597      !
598   END FUNCTION p5z_lim_alloc
599
600#else
601   !!======================================================================
602   !!  Dummy module :                                   No PISCES bio-model
603   !!======================================================================
604CONTAINS
605   SUBROUTINE p5z_lim                   ! Empty routine
606   END SUBROUTINE p5z_lim
607#endif 
608
609   !!======================================================================
610END MODULE  p5zlim
Note: See TracBrowser for help on using the repository browser.