New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zrem.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z/p5zrem.F90 @ 6841

Last change on this file since 6841 was 6841, checked in by aumont, 8 years ago

Various bug fixes + explicit gamma function for lability
  • Property svn:executable set to *
File size: 17.4 KB
Line 
1MODULE p5zrem
2   !!======================================================================
3   !!                         ***  MODULE p5zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11#if defined key_pisces_quota
12   !!----------------------------------------------------------------------
13   !!   'key_top'       and                                      TOP models
14   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
15   !!----------------------------------------------------------------------
16   !!   p5z_rem       :  Compute remineralization/dissolution of organic compounds
17   !!   p5z_rem_init  :  Initialisation of parameters for remineralisation
18   !!   p5z_rem_alloc :  Allocate remineralisation variables
19   !!----------------------------------------------------------------------
20   USE oce_trc         !  shared variables between ocean and passive tracers
21   USE trc             !  passive tracers common variables
22   USE sms_pisces      !  PISCES Source Minus Sink variables
23   USE p4zopt          !  optical model
24   USE p4zche          !  chemical model
25   USE p5zlim          ! Phytoplankton limitation factors
26   USE p5zprod         !  Production by phytoplankton
27   USE prtctl_trc      !  print control for debugging
28   USE iom             !  I/O manager
29
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   p5z_rem         ! called in p4zbio.F90
35   PUBLIC   p5z_rem_init    ! called in trcsms_pisces.F90
36   PUBLIC   p5z_rem_alloc
37
38   !! * Shared module variables
39   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of DOC
40   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of DON
41   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of DOP
42   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
43   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of BSi
44   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of BSi
45   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
46   REAL(wp), PUBLIC ::  oxymin     !: half saturation constant for anoxia
47   REAL(wp), PUBLIC ::  oxymin2    !: Minimum O2 concentration for oxic remin.
48   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
49   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
50
51
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitrc     !: denitrification array
53
54   !!* Substitution
55#  include "top_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
58   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE p5z_rem( kt, knt )
64      !!---------------------------------------------------------------------
65      !!                     ***  ROUTINE p5z_rem  ***
66      !!
67      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
68      !!
69      !! ** Method  : - ???
70      !!---------------------------------------------------------------------
71      !
72      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
73      !
74      INTEGER  ::   ji, jj, jk
75      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin 
76      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
77      REAL(wp) ::   zbactfer, zolimit
78      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
79      REAL(wp) ::   zonitr, zstep, zrfact2
80      CHARACTER (len=25) :: charout
81      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac 
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zwork1, zdepprod
83      !!---------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('p5z_rem')
86      !
87      ! Allocate temporary workspace
88      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
89      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zwork1 )
90
91      ! Initialisation of temprary arrys
92      zdepprod(:,:,:) = 1._wp
93      ztempbac(:,:)   = 0._wp
94
95      ! Computation of the mean phytoplankton concentration as
96      ! a crude estimate of the bacterial biomass
97      ! this parameterization has been deduced from a model version
98      ! that was modeling explicitely bacteria
99      ! -------------------------------------------------------
100      DO jk = 1, jpkm1
101         DO jj = 1, jpj
102            DO ji = 1, jpi
103               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
104               IF( fsdept(ji,jj,jk) < zdep ) THEN
105                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
106                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
107               ELSE
108                  zdepmin = MIN( 1., zdep / fsdept(ji,jj,jk) )
109                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
110                  zdepprod(ji,jj,jk) = zdepmin**0.273
111               ENDIF
112            END DO
113         END DO
114      END DO
115
116      DO jk = 1, jpkm1
117         DO jj = 1, jpj
118            DO ji = 1, jpi
119               ! denitrification factor computed from O2 levels
120               ! ----------------------------------------------
121               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( oxymin2 - trb(ji,jj,jk,jpoxy) )    &
122                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
123               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
124            END DO
125         END DO
126      END DO
127
128      DO jk = 1, jpkm1
129         DO jj = 1, jpj
130            DO ji = 1, jpi
131               zstep   = xstep
132# if defined key_degrad
133               zstep = zstep * facvol(ji,jj,jk)
134# endif
135               ! DOC ammonification. Depends on depth, phytoplankton biomass
136               ! and a limitation term which is supposed to be a parameterization
137               ! of the bacterial activity.
138               ! -----------------------------------------------------------------
139               zremik = zstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
140               zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
141
142               zremikc = xremikc * zremik
143               zremikn = xremikn / xremikc
144               zremikp = xremikp / xremikc
145
146               ! Ammonification in oxic waters with oxygen consumption
147               ! -----------------------------------------------------
148               zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
149               zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
150               zwork1(ji,jj,jk) = zolimic
151               zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
152               zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
153
154               ! Ammonification in suboxic waters with denitrification
155               ! -------------------------------------------------------
156               zolimit = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
157               denitrc(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
158               denitrc (ji,jj,jk) = MAX( 0.e0, denitrc (ji,jj,jk) )
159               zdenitrn  = zremikn * denitrc(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
160               zdenitrp  = zremikp * denitrc(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
161
162               ! Update of trends TRA
163               ! --------------------
164               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
165               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
166               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitrc(ji,jj,jk) * rdenit
167               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitrc(ji,jj,jk)
168               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
169               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
170               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
171               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitrc(ji,jj,jk)
172               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
173
174            END DO
175         END DO
176      END DO
177
178
179      DO jk = 1, jpkm1
180         DO jj = 1, jpj
181            DO ji = 1, jpi
182               zstep   = xstep
183# if defined key_degrad
184               zstep = zstep * facvol(ji,jj,jk)
185# endif
186               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
187               ! below 2 umol/L. Inhibited at strong light
188               ! ----------------------------------------------------------
189               zonitr  = nitrif * zstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
190               &         * ( 0.2 + 0.8 / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) )
191               zdenitnh4 = nitrif * zstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
192               !
193               ! Update of the tracers trends
194               ! ----------------------------
195               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
196               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
197               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
198               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
199            END DO
200         END DO
201      END DO
202
203      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
204        WRITE(charout, FMT="('rem1')")
205        CALL prt_ctl_trc_info(charout)
206        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
207      ENDIF
208
209      DO jk = 1, jpkm1
210         DO jj = 1, jpj
211            DO ji = 1, jpi
212
213               ! Bacterial uptake of iron. No iron is available in DOC. So
214               ! Bacteries are obliged to take up iron from the water. Some
215               ! studies (especially at Papa) have shown this uptake to be significant
216               ! ----------------------------------------------------------
217               zbactfer = feratb *  rfact2 * prmaxp(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
218                  &              * biron(ji,jj,jk) / ( xkferb + biron(ji,jj,jk) )    &
219                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
220#if defined key_kriest
221               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.05
222               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.05
223#else
224               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
225               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
226               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
227#endif
228            END DO
229         END DO
230      END DO
231
232      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
233        WRITE(charout, FMT="('rem2')")
234        CALL prt_ctl_trc_info(charout)
235        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
236      ENDIF
237
238      DO jk = 1, jpkm1
239         DO jj = 1, jpj
240            DO ji = 1, jpi
241               zstep   = xstep
242# if defined key_degrad
243               zstep = zstep * facvol(ji,jj,jk)
244# endif
245               ! Remineralization rate of BSi depedant on T and saturation
246               ! ---------------------------------------------------------
247               zsatur   = ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn )
248               zsatur   = MAX( rtrn, zsatur )
249               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
250               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
251               znusil2  = 0.225  * ( 1. + tsn(ji,jj,1,jp_tem) / 15.) + 0.775 * zsatur2
252
253               ! Two classes of BSi are considered : a labile fraction and
254               ! a more refractory one. The ratio between both fractions is
255               ! constant and specified in the namelist.
256               ! ----------------------------------------------------------
257               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) ) 
258               zdep     = MAX( 0., fsdept(ji,jj,jk) - zdep )
259               ztem     = MAX( tsn(ji,jj,1,jp_tem), 0. )
260               zfactdep = xsilab * EXP(-( xsiremlab - xsirem ) * znusil2 * zdep / wsbio2 ) * ztem / ( ztem + 10. )
261               zsiremin = ( xsiremlab * zfactdep + xsirem * ( 1. - zfactdep ) ) * zstep * znusil
262               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
263               !
264               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
265               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
266               !
267            END DO
268         END DO
269      END DO
270
271      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
272         WRITE(charout, FMT="('rem3')")
273         CALL prt_ctl_trc_info(charout)
274         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
275       ENDIF
276
277      IF( ln_diatrc .AND. lk_iomput .AND. knt == nrdttrc ) THEN
278          zrfact2 = 1.e3 * rfact2r
279          CALL iom_put( "REMIN" , zwork1(:,:,:) * tmask(:,:,:) * zrfact2 )  ! Remineralisation rate
280          CALL iom_put( "DENIT" , denitrc(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2  )  ! Denitrification
281      ENDIF
282
283      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
284         WRITE(charout, FMT="('rem4')")
285         CALL prt_ctl_trc_info(charout)
286         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
287      ENDIF
288      !
289      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
290      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zwork1 )
291      !
292      IF( nn_timing == 1 )  CALL timing_stop('p5z_rem')
293      !
294   END SUBROUTINE p5z_rem
295
296
297   SUBROUTINE p5z_rem_init
298      !!----------------------------------------------------------------------
299      !!                  ***  ROUTINE p5z_rem_init  ***
300      !!
301      !! ** Purpose :   Initialization of remineralization parameters
302      !!
303      !! ** Method  :   Read the nampisrem namelist and check the parameters
304      !!      called at the first timestep
305      !!
306      !! ** input   :   Namelist nampisrem
307      !!
308      !!----------------------------------------------------------------------
309      NAMELIST/nampisrem/ xremikc, xremikn, xremikp,   &
310      &                   nitrif, xsirem, xsiremlab, xsilab, oxymin, oxymin2,  &
311      &                   feratb, xkferb 
312      INTEGER :: ios                 ! Local integer output status for namelist read
313
314      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
315      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
316901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
317
318      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
319      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
320902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
321      IF(lwm) WRITE ( numonp, nampisrem )
322
323      IF(lwp) THEN                         ! control print
324         WRITE(numout,*) ' '
325         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
326         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
327         WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
328         WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
329         WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
330         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
331         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
332         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
333         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
334         WRITE(numout,*) '    half saturation constant for anoxia       oxymin    =', oxymin
335         WRITE(numout,*) '    Minimum O2 concentration for oxic remin.  oxymin2   =', oxymin2
336         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
337         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
338      ENDIF
339      !
340      nitrfac (:,:,:) = 0._wp
341      denitrc (:,:,:) = 0._wp
342      !
343   END SUBROUTINE p5z_rem_init
344
345
346   INTEGER FUNCTION p5z_rem_alloc()
347      !!----------------------------------------------------------------------
348      !!                     ***  ROUTINE p5z_rem_alloc  ***
349      !!----------------------------------------------------------------------
350      ALLOCATE( denitrc(jpi,jpj,jpk), STAT=p5z_rem_alloc )
351      !
352      IF( p5z_rem_alloc /= 0 )   CALL ctl_warn('p5z_rem_alloc: failed to allocate arrays')
353      !
354   END FUNCTION p5z_rem_alloc
355
356#else
357   !!======================================================================
358   !!  Dummy module :                                   No PISCES bio-model
359   !!======================================================================
360CONTAINS
361   SUBROUTINE p5z_rem                    ! Empty routine
362   END SUBROUTINE p5z_rem
363#endif 
364
365   !!======================================================================
366END MODULE p5zrem
Note: See TracBrowser for help on using the repository browser.