New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zrem.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z/p5zrem.F90 @ 8003

Last change on this file since 8003 was 8003, checked in by aumont, 7 years ago

modification in the code to remove unnecessary parts such as kriest and non iomput options
  • Property svn:executable set to *
File size: 17.7 KB
Line 
1MODULE p5zrem
2   !!======================================================================
3   !!                         ***  MODULE p5zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11#if defined key_pisces_quota
12   !!----------------------------------------------------------------------
13   !!   'key_top'       and                                      TOP models
14   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
15   !!----------------------------------------------------------------------
16   !!   p5z_rem       :  Compute remineralization/dissolution of organic compounds
17   !!   p5z_rem_init  :  Initialisation of parameters for remineralisation
18   !!   p5z_rem_alloc :  Allocate remineralisation variables
19   !!----------------------------------------------------------------------
20   USE oce_trc         !  shared variables between ocean and passive tracers
21   USE trc             !  passive tracers common variables
22   USE sms_pisces      !  PISCES Source Minus Sink variables
23   USE p4zopt          !  optical model
24   USE p4zche          !  chemical model
25   USE p5zlim          ! Phytoplankton limitation factors
26   USE p5zsink         !  Sinking of particles
27   USE p5zprod         !  Production by phytoplankton
28   USE prtctl_trc      !  print control for debugging
29   USE iom             !  I/O manager
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   p5z_rem         ! called in p4zbio.F90
36   PUBLIC   p5z_rem_init    ! called in trcsms_pisces.F90
37   PUBLIC   p5z_rem_alloc
38
39   !! * Shared module variables
40   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of DOC
41   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of DON
42   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of DOP
43   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
44   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of BSi
45   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of BSi
46   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
47   REAL(wp), PUBLIC ::  oxymin     !: half saturation constant for anoxia
48   REAL(wp), PUBLIC ::  oxymin2    !: Minimum O2 concentration for oxic remin.
49   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
50   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
51
52
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitrc     !: denitrification array
54
55   !!* Substitution
56#  include "top_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
59   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
60   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE p5z_rem( kt, knt )
65      !!---------------------------------------------------------------------
66      !!                     ***  ROUTINE p5z_rem  ***
67      !!
68      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
69      !!
70      !! ** Method  : - ???
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
74      !
75      INTEGER  ::   ji, jj, jk
76      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin 
77      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
78      REAL(wp) ::   zbactfer, zolimit, zonitr, zstep, zrfact2
79      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
80      CHARACTER (len=25) :: charout
81      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac 
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zdepprod, zdepeff, zfacsi, zfacsib
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: znitr, zfebact, zwork1
84      !!---------------------------------------------------------------------
85      !
86      IF( nn_timing == 1 )  CALL timing_start('p5z_rem')
87      !
88      ! Allocate temporary workspace
89      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
90      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zdepeff, zfacsi, zfacsib)
91      CALL wrk_alloc( jpi, jpj, jpk, znitr, zfebact, zwork1 )
92
93      ! Initialisation of temprary arrys
94      zdepprod(:,:,:) = 1._wp
95      zdepeff (:,:,:) = 0.3_wp
96      ztempbac(:,:)   = 0._wp
97      zfebact (:,:,:) = 0._wp
98      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
99      zfacsi(:,:,:)   = xsilab
100
101      ! Computation of the mean phytoplankton concentration as
102      ! a crude estimate of the bacterial biomass
103      ! this parameterization has been deduced from a model version
104      ! that was modeling explicitely bacteria
105      ! -------------------------------------------------------
106      DO jk = 1, jpkm1
107         DO jj = 1, jpj
108            DO ji = 1, jpi
109               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
110               IF( fsdept(ji,jj,jk) < zdep ) THEN
111                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
112                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
113               ELSE
114                  zdepmin = MIN( 1., zdep / fsdept(ji,jj,jk) )
115                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
116                  zdepprod(ji,jj,jk) = zdepmin**0.273
117                  zdepeff (ji,jj,jk) = 0.3 * zdepmin**0.3
118               ENDIF
119            END DO
120         END DO
121      END DO
122
123      DO jk = 1, jpkm1
124         DO jj = 1, jpj
125            DO ji = 1, jpi
126               ! denitrification factor computed from O2 levels
127               ! ----------------------------------------------
128               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( oxymin2 - trb(ji,jj,jk,jpoxy) )    &
129                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
130               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
131            END DO
132         END DO
133      END DO
134
135      DO jk = 1, jpkm1
136         DO jj = 1, jpj
137            DO ji = 1, jpi
138               zstep   = xstep
139               ! DOC ammonification. Depends on depth, phytoplankton biomass
140               ! and a limitation term which is supposed to be a parameterization
141               ! of the bacterial activity.
142               ! -----------------------------------------------------------------
143               zremik = zstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
144               zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
145
146               zremikc = xremikc * zremik
147               zremikn = xremikn / xremikc
148               zremikp = xremikp / xremikc
149
150               ! Ammonification in oxic waters with oxygen consumption
151               ! -----------------------------------------------------
152               zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
153               zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
154               zwork1(ji,jj,jk) = zolimic
155               zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
156               zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
157
158               ! Ammonification in suboxic waters with denitrification
159               ! -------------------------------------------------------
160               zolimit = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
161               denitrc(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
162               denitrc (ji,jj,jk) = MAX( 0.e0, denitrc (ji,jj,jk) )
163               zdenitrn  = zremikn * denitrc(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
164               zdenitrp  = zremikp * denitrc(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
165
166               ! Update of trends TRA
167               ! --------------------
168               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
169               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
170               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitrc(ji,jj,jk) * rdenit
171               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitrc(ji,jj,jk)
172               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
173               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
174               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
175               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitrc(ji,jj,jk)
176               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
177
178            END DO
179         END DO
180      END DO
181
182
183      DO jk = 1, jpkm1
184         DO jj = 1, jpj
185            DO ji = 1, jpi
186               zstep   = xstep
187               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
188               ! below 2 umol/L. Inhibited at strong light
189               ! ----------------------------------------------------------
190               zonitr  = nitrif * zstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
191               &         * ( 0.2 + 0.8 / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) )
192               zdenitnh4 = nitrif * zstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk) 
193               !
194               ! Update of the tracers trends
195               ! ----------------------------
196               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
197               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
198               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
199               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
200               znitr(ji,jj,jk) = zonitr
201            END DO
202         END DO
203      END DO
204
205      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
206        WRITE(charout, FMT="('rem1')")
207        CALL prt_ctl_trc_info(charout)
208        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
209      ENDIF
210
211      DO jk = 1, jpkm1
212         DO jj = 1, jpj
213            DO ji = 1, jpi
214
215               ! Bacterial uptake of iron. No iron is available in DOC. So
216               ! Bacteries are obliged to take up iron from the water. Some
217               ! studies (especially at Papa) have shown this uptake to be significant
218               ! ----------------------------------------------------------
219               zbactfer = feratb *  rfact2 * prmaxp(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
220                  &              * biron(ji,jj,jk) / ( xkferb + biron(ji,jj,jk) )    &
221                  &              * zdepprod(ji,jj,jk) * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk)
222               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.39
223               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.3
224               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.09
225               zfebact(ji,jj,jk)   = zbactfer * 0.39
226            END DO
227         END DO
228      END DO
229
230      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
231        WRITE(charout, FMT="('rem2')")
232        CALL prt_ctl_trc_info(charout)
233        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
234      ENDIF
235
236      ! Initialization of the array which contains the labile fraction
237      ! of bSi. Set to a constant in the upper ocean
238      ! ---------------------------------------------------------------
239
240      DO jk = 1, jpkm1
241         DO jj = 1, jpj
242            DO ji = 1, jpi
243               zstep   = xstep
244               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
245               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
246               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
247               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
248
249               ! Remineralization rate of BSi depedant on T and saturation
250               ! ---------------------------------------------------------
251               IF ( fsdept(ji,jj,jk) > zdep ) THEN
252                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
253                  &                   * znusil * fse3t(ji,jj,jk) / wsbio4(ji,jj,jk) )
254                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
255                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
256                  &                   * znusil * fse3t(ji,jj,jk) / wsbio4(ji,jj,jk) )
257               ENDIF
258               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * zstep * znusil
259               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
260               !
261               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
262               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
263            END DO
264         END DO
265      END DO
266
267      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
268         WRITE(charout, FMT="('rem3')")
269         CALL prt_ctl_trc_info(charout)
270         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
271       ENDIF
272
273      IF( ln_diatrc .AND. lk_iomput .AND. knt == nrdttrc ) THEN
274          zrfact2 = 1.e3 * rfact2r
275          CALL iom_put( "REMIN" , zwork1(:,:,:) * tmask(:,:,:) * zrfact2 )  ! Remineralisation rate
276          CALL iom_put( "DENIT" , denitrc(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zrfact2  )  ! Denitrification
277          CALL iom_put( "NIT"   , znitr(:,:,:) * rno3 * tmask(:,:,:) * zrfact2 )  !
278          CALL iom_put( "BACT", zdepbac(:,:,:) * 1.E6 * tmask(:,:,:) )  ! Bacterial biomass
279          CALL iom_put( "FEBACT" , zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2  )  ! Denitrification
280      ENDIF
281      !
282      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
283      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zdepeff, zfacsi, zfacsib )
284      CALL wrk_dealloc( jpi, jpj, jpk, zwork1, zfebact, znitr )
285      !
286      IF( nn_timing == 1 )  CALL timing_stop('p5z_rem')
287      !
288   END SUBROUTINE p5z_rem
289
290
291   SUBROUTINE p5z_rem_init
292      !!----------------------------------------------------------------------
293      !!                  ***  ROUTINE p5z_rem_init  ***
294      !!
295      !! ** Purpose :   Initialization of remineralization parameters
296      !!
297      !! ** Method  :   Read the nampisrem namelist and check the parameters
298      !!      called at the first timestep
299      !!
300      !! ** input   :   Namelist nampisrem
301      !!
302      !!----------------------------------------------------------------------
303      NAMELIST/nampisrem/ xremikc, xremikn, xremikp,   &
304      &                   nitrif, xsirem, xsiremlab, xsilab, oxymin, oxymin2,  &
305      &                   feratb, xkferb 
306      INTEGER :: ios                 ! Local integer output status for namelist read
307
308      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
309      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
310901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
311
312      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
313      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
314902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
315      IF(lwm) WRITE ( numonp, nampisrem )
316
317      IF(lwp) THEN                         ! control print
318         WRITE(numout,*) ' '
319         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
320         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
321         WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
322         WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
323         WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
324         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
325         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
326         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
327         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
328         WRITE(numout,*) '    half saturation constant for anoxia       oxymin    =', oxymin
329         WRITE(numout,*) '    Minimum O2 concentration for oxic remin.  oxymin2   =', oxymin2
330         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
331         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
332      ENDIF
333      !
334      nitrfac (:,:,:) = 0._wp
335      denitrc (:,:,:) = 0._wp
336      !
337   END SUBROUTINE p5z_rem_init
338
339
340   INTEGER FUNCTION p5z_rem_alloc()
341      !!----------------------------------------------------------------------
342      !!                     ***  ROUTINE p5z_rem_alloc  ***
343      !!----------------------------------------------------------------------
344      ALLOCATE( denitrc(jpi,jpj,jpk), STAT=p5z_rem_alloc )
345      !
346      IF( p5z_rem_alloc /= 0 )   CALL ctl_warn('p5z_rem_alloc: failed to allocate arrays')
347      !
348   END FUNCTION p5z_rem_alloc
349
350#else
351   !!======================================================================
352   !!  Dummy module :                                   No PISCES bio-model
353   !!======================================================================
354CONTAINS
355   SUBROUTINE p5z_rem                    ! Empty routine
356   END SUBROUTINE p5z_rem
357#endif 
358
359   !!======================================================================
360END MODULE p5zrem
Note: See TracBrowser for help on using the repository browser.