New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zsed.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P5Z/p5zsed.F90 @ 8003

Last change on this file since 8003 was 8003, checked in by aumont, 7 years ago

modification in the code to remove unnecessary parts such as kriest and non iomput options

  • Property svn:executable set to *
File size: 23.9 KB
Line 
1MODULE p5zsed
2   !!======================================================================
3   !!                         ***  MODULE p5zsed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
11   !!----------------------------------------------------------------------
12#if defined key_pisces_quota
13   !!----------------------------------------------------------------------
14   !!   'key_pisces_quota'     PISCES bio-model with variable stoichiometry
15   !!----------------------------------------------------------------------
16   !!   p5z_sed        :  Compute loss of organic matter in the sediments
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p5zsink         !  vertical flux of particulate matter due to sinking
22   USE p4zopt          !  optical model
23   USE p5zlim          !  Co-limitations of differents nutrients
24   USE p5zrem          !  Remineralisation of organic matter
25   USE p4zsbc          !  External source of nutrients
26   USE p4zint          !  interpolation and computation of various fields
27   USE iom             !  I/O manager
28   USE prtctl_trc      !  print control for debugging
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   p5z_sed   
34   PUBLIC   p5z_sed_alloc
35
36   !! * Module variables
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
39   REAL(wp) :: r1_rday                  !: inverse of rday
40
41   !!* Substitution
42#  include "top_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
45   !! $Header:$
46   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE p5z_sed( kt, knt )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE p5z_sed  **
53      !!
54      !! ** Purpose :   Compute loss of organic matter in the sediments. This
55      !!              is by no way a sediment model. The loss is simply
56      !!              computed to balance the inout from rivers and dust
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      !
61      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
62      INTEGER  ::   ji, jj, jk, ikt, jn
63#if ! defined key_sed
64      REAL(wp) ::   zsumsedsi, zsumsedpo4, zsumsedcal
65      REAL(wp) ::   zrivalk, zrivsil, zrivno3
66#endif
67      REAL(wp) ::  zwflux, zfminus, zfplus
68      REAL(wp) ::  zlim, zfact, zfactcal
69      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit
70      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
71      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
72      REAL(wp) ::  ztrfer, ztrdp, zwdust, zlight, zmudia, ztemp
73      REAL(wp) ::  xdiano3, xdianh4
74      !
75      CHARACTER (len=25) :: charout
76      REAL(wp), POINTER, DIMENSION(:,:  ) :: zsidep, zwork1, zwork2, zwork3, zwork4
77      REAL(wp), POINTER, DIMENSION(:,:  ) :: zdenit2d, zironice, zbureff
78      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsbio3, zwsbio4, zwscal
79      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zsoufer, zpdep
80#if defined key_ligand
81      REAL(wp) ::  zwssfep
82      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwsfep
83#endif
84      !!---------------------------------------------------------------------
85      !
86      IF( nn_timing == 1 )  CALL timing_start('p5z_sed')
87      !
88      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
89      !
90      ! Allocate temporary workspace
91      CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
92      CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
93      CALL wrk_alloc( jpi, jpj, jpk, ztrpo4, ztrdop, zsoufer )
94#if defined key_ligand
95      CALL wrk_alloc( jpi, jpj, zwsfep )
96#endif
97
98
99      zdenit2d(:,:) = 0.e0
100      zbureff (:,:) = 0.e0
101      zwork1  (:,:) = 0.e0
102      zwork2  (:,:) = 0.e0
103      zwork3  (:,:) = 0.e0
104      zwork4  (:,:) = 0.e0
105
106      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
107      ! ----------------------------------------------------
108      IF( ln_ironice ) THEN 
109         !                                             
110         CALL wrk_alloc( jpi, jpj, zironice )
111         !                                             
112         DO jj = 1, jpj
113            DO ji = 1, jpi
114               zdep    = rfact2 / fse3t(ji,jj,1)
115               zwflux  = fmmflx(ji,jj) / 1000._wp
116               zfminus = MIN( 0._wp, -zwflux ) * trb(ji,jj,1,jpfer) * zdep
117               zfplus  = MAX( 0._wp, -zwflux ) * icefeinput * zdep
118               zironice(ji,jj) =  zfplus + zfminus
119            END DO
120         END DO
121         !
122         trb(:,:,1,jpfer) = trb(:,:,1,jpfer) + zironice(:,:) 
123         !                                             
124         IF( ln_diatrc .AND. lk_iomput .AND. knt == nrdttrc )   &
125            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
126         CALL wrk_dealloc( jpi, jpj, zironice )
127         !                                             
128      ENDIF
129
130      ! Add the external input of nutrients from dust deposition
131      ! ----------------------------------------------------------
132      IF( ln_dust ) THEN
133         !                                             
134         CALL wrk_alloc( jpi, jpj,      zsidep )
135         CALL wrk_alloc( jpi, jpj, jpk, zpdep, zirondep      )
136         !                                              ! Iron and Si deposition at the surface
137         IF( ln_solub ) THEN
138            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2    &
139            &        / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
140         ELSE
141            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2    &
142            &        / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss 
143         ENDIF
144         zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 28.1 
145         zpdep (:,:,1) = 0.2 * 0.023 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 31. / po4r 
146         !                                              ! Iron solubilization of particles in the water column
147         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
148         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
149         DO jk = 2, jpkm1
150            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2  &
151            &   * EXP( -fsdept(:,:,jk) / 540. )
152            zpdep(:,:,jk) = dust(:,:) * mfrac * 0.023 * zwdust * rfact2  &
153            &   * EXP( -fsdept(:,:,jk) / 540. )
154         END DO
155         !                                              ! Iron solubilization of particles in the water column
156         trb(:,:,:,jppo4) = trb(:,:,:,jppo4) + zpdep   (:,:,:)
157         trb(:,:,1,jpsil) = trb(:,:,1,jpsil) + zsidep  (:,:)
158         trb(:,:,:,jpfer) = trb(:,:,:,jpfer) + zirondep(:,:,:) 
159         !                                             
160         IF( ln_diatrc ) THEN
161            zfact = 1.e+3 * rfact2r
162            IF( lk_iomput ) THEN
163               IF( knt == nrdttrc ) THEN
164                  CALL iom_put( "Irondep", zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
165                  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
166               ENDIF
167            ELSE
168               trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1)
169            ENDIF
170         ENDIF
171         CALL wrk_dealloc( jpi, jpj,      zsidep )
172         CALL wrk_dealloc( jpi, jpj, jpk, zpdep, zirondep      )
173         !                                             
174      ENDIF
175     
176      ! Add the external input of nutrients from river
177      ! ----------------------------------------------------------
178      IF( ln_river ) THEN
179         trb(:,:,1,jppo4) = trb(:,:,1,jppo4) + rivdip(:,:) * rfact2
180         trb(:,:,1,jpdop) = trb(:,:,1,jpdop) + rivdop(:,:) * rfact2
181         trb(:,:,1,jpno3) = trb(:,:,1,jpno3) + rivdin(:,:) * rfact2
182         trb(:,:,1,jpdon) = trb(:,:,1,jpdon) + rivdon(:,:) * rfact2
183         trb(:,:,1,jpfer) = trb(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2
184         trb(:,:,1,jpsil) = trb(:,:,1,jpsil) + rivdsi(:,:) * rfact2
185         trb(:,:,1,jpdic) = trb(:,:,1,jpdic) + rivdic(:,:) * rfact2
186         trb(:,:,1,jpdoc) = trb(:,:,1,jpdoc) + rivdoc(:,:) * rfact2
187         trb(:,:,1,jptal) = trb(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2
188      ENDIF
189
190      ! Add the external input of nutrients from nitrogen deposition
191      ! ----------------------------------------------------------
192      IF( ln_ndepo ) THEN
193         trb(:,:,1,jpno3) = trb(:,:,1,jpno3) + nitdep(:,:) * rfact2
194         trb(:,:,1,jptal) = trb(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2
195      ENDIF
196
197      ! Add the external input of iron from sediment mobilization
198      ! ------------------------------------------------------
199      IF( ln_ironsed ) THEN
200         trb(:,:,:,jpfer) = trb(:,:,:,jpfer) + ironsed(:,:,:) * rfact2
201#if defined key_ligand
202         trn(:,:,:,jpfep) = trn(:,:,:,jpfep) + (ironsed(:,:,:) * fep_rats ) * rfact2
203#endif
204         !
205         IF( ln_diatrc .AND. lk_iomput .AND. knt == nrdttrc )   &
206            &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
207      ENDIF
208
209      ! Add the external input of iron from hydrothermal vents
210      ! ------------------------------------------------------
211      IF( ln_hydrofe ) THEN
212         trb(:,:,:,jpfer) = trb(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2
213#if defined key_ligand
214         trn(:,:,:,jpfep) = trn(:,:,:,jpfep) + ( hydrofe(:,:,:) * fep_rath ) * rfact2
215         trn(:,:,:,jplgw) = trn(:,:,:,jplgw) + ( hydrofe(:,:,:) * hydrolig ) * rfact2
216#endif
217         !
218         IF( ln_diatrc .AND. lk_iomput .AND. knt == nrdttrc )   &
219            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
220      ENDIF
221
222      ! OA: Warning, the following part is necessary, especially with Kriest
223      ! to avoid CFL problems above the sediments
224      ! --------------------------------------------------------------------
225      DO jj = 1, jpj
226         DO ji = 1, jpi
227            ikt  = mbkt(ji,jj)
228            zdep = fse3t(ji,jj,ikt) / xstep
229            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
230            zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) )
231            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
232#if defined key_ligand
233            zwsfep(ji,jj)  = MIN( 0.99 * zdep, wsfep(ji,jj,ikt)  )
234#endif
235         END DO
236      END DO
237
238#if ! defined key_sed
239      ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
240      ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
241      ! -------------------------------------------------------
242      DO jj = 1, jpj
243         DO ji = 1, jpi
244           IF( tmask(ji,jj,1) == 1 ) THEN
245              ikt = mbkt(ji,jj)
246              zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
247                &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
248              zflx  = LOG10( MAX( 1E-3, zflx ) )
249              zo2   = LOG10( MAX( 10. , trb(ji,jj,ikt,jpoxy) * 1E6 ) )
250              zno3  = LOG10( MAX( 1.  , trb(ji,jj,ikt,jpno3) * 1E6 * rno3 ) )
251              zdep  = LOG10( fsdepw(ji,jj,ikt+1) )
252              zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
253              &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
254              zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
255              !
256              zflx = (  trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj)   &
257                &     + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6
258              zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
259           ENDIF
260         END DO
261      END DO 
262
263      ! Loss of biogenic silicon, Caco3 organic carbon in the sediments.
264      ! First, the total loss is computed.
265      ! The factor for calcite comes from the alkalinity effect
266      ! -------------------------------------------------------------
267      DO jj = 1, jpj
268         DO ji = 1, jpi
269            IF( tmask(ji,jj,1) == 1 ) THEN
270               ikt = mbkt(ji,jj) 
271               zwork1(ji,jj) = trb(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj)
272               zwork2(ji,jj) = trb(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trb(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) 
273               ! For calcite, burial efficiency is made a function of saturation
274               zfactcal      = MIN( excess(ji,jj,ikt), 0.2 )
275               zfactcal      = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
276               zwork3(ji,jj) = trb(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal
277            ENDIF
278         END DO
279      END DO
280      zsumsedsi  = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday
281      zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday
282      zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday
283#endif
284
285      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
286      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
287      ! ------------------------------------------------------
288#if ! defined key_sed
289      zrivsil =  MAX(0., 1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn ) )
290#endif
291
292      DO jj = 1, jpj
293         DO ji = 1, jpi
294            ikt  = mbkt(ji,jj)
295            zdep = xstep / fse3t(ji,jj,ikt)
296            zws4 = zwsbio4(ji,jj) * zdep
297            zwsc = zwscal (ji,jj) * zdep
298            zsiloss = trb(ji,jj,ikt,jpgsi) * zwsc
299            zcaloss = trb(ji,jj,ikt,jpcal) * zwsc
300            !
301            trb(ji,jj,ikt,jpgsi) = trb(ji,jj,ikt,jpgsi) - zsiloss
302            trb(ji,jj,ikt,jpcal) = trb(ji,jj,ikt,jpcal) - zcaloss
303#if ! defined key_sed
304            trb(ji,jj,ikt,jpsil) = trb(ji,jj,ikt,jpsil) + zsiloss * zrivsil 
305            zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
306            zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
307            zrivalk  =  1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn )
308            trb(ji,jj,ikt,jptal) =  trb(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0
309            trb(ji,jj,ikt,jpdic) =  trb(ji,jj,ikt,jpdic) + zcaloss * zrivalk
310#endif
311         END DO
312      END DO
313
314
315      DO jj = 1, jpj
316         DO ji = 1, jpi
317            ikt     = mbkt(ji,jj)
318            zdep    = xstep / fse3t(ji,jj,ikt)
319            zws4 = zwsbio4(ji,jj) * zdep
320            zws3 = zwsbio3(ji,jj) * zdep
321#if defined key_ligand
322            zwssfep = zwsfep(ji,jj) * zdep
323#endif
324            zrivno3 = 1. - zbureff(ji,jj)
325            trb(ji,jj,ikt,jpgoc) = trb(ji,jj,ikt,jpgoc) - trb(ji,jj,ikt,jpgoc) * zws4
326            trb(ji,jj,ikt,jppoc) = trb(ji,jj,ikt,jppoc) - trb(ji,jj,ikt,jppoc) * zws3
327            trb(ji,jj,ikt,jpgon) = trb(ji,jj,ikt,jpgon) - trb(ji,jj,ikt,jpgon) * zws4
328            trb(ji,jj,ikt,jppon) = trb(ji,jj,ikt,jppon) - trb(ji,jj,ikt,jppon) * zws3
329            trb(ji,jj,ikt,jpgop) = trb(ji,jj,ikt,jpgop) - trb(ji,jj,ikt,jpgop) * zws4
330            trb(ji,jj,ikt,jppop) = trb(ji,jj,ikt,jppop) - trb(ji,jj,ikt,jppop) * zws3
331            trb(ji,jj,ikt,jpbfe) = trb(ji,jj,ikt,jpbfe) - trb(ji,jj,ikt,jpbfe) * zws4
332            trb(ji,jj,ikt,jpsfe) = trb(ji,jj,ikt,jpsfe) - trb(ji,jj,ikt,jpsfe) * zws3
333            zwstpoc              = trb(ji,jj,ikt,jpgoc) * zws4 + trb(ji,jj,ikt,jppoc) * zws3 
334            zwstpop              = trb(ji,jj,ikt,jpgop) * zws4 + trb(ji,jj,ikt,jppop) * zws3
335            zwstpon              = trb(ji,jj,ikt,jpgon) * zws4 + trb(ji,jj,ikt,jppon) * zws3
336#   if defined key_ligand
337            trn(ji,jj,ikt,jpfep) = trn(ji,jj,ikt,jpfep) - trn(ji,jj,ikt,jpfep) * zwssfep
338#   endif
339
340#if ! defined key_sed
341            ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification
342            ! in the sediments and just above the sediments. Not very clever, but simpliest option.
343            zpdenit  = MIN( 0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
344            zpdenit = MAX( 0., zpdenit )
345            z1pdenit = zwstpoc * zrivno3 - zpdenit
346            zolimit = MIN( ( trb(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
347            zdenitt = MIN(  0.5 * ( trb(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) )
348            zolimit = MAX( 0., zolimit )
349            zdenitt = MAX( 0., zdenitt )
350            trb(ji,jj,ikt,jpdoc) = trb(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt
351            trb(ji,jj,ikt,jpdon) = trb(ji,jj,ikt,jpdon) + (z1pdenit - zolimit - zdenitt) * zwstpon / (zwstpoc + rtrn)
352            trb(ji,jj,ikt,jpdop) = trb(ji,jj,ikt,jpdop) + (z1pdenit - zolimit - zdenitt) * zwstpop / (zwstpoc + rtrn)
353            trb(ji,jj,ikt,jppo4) = trb(ji,jj,ikt,jppo4) + (zpdenit + zolimit + zdenitt) * zwstpop / (zwstpoc + rtrn)
354            trb(ji,jj,ikt,jpnh4) = trb(ji,jj,ikt,jpnh4) + (zpdenit + zolimit + zdenitt) * zwstpon / (zwstpoc + rtrn)
355            trb(ji,jj,ikt,jpno3) = trb(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt)
356            trb(ji,jj,ikt,jpoxy) = trb(ji,jj,ikt,jpoxy) - zolimit * o2ut
357            trb(ji,jj,ikt,jptal) = trb(ji,jj,ikt,jptal) + rno3 * (zolimit + zpdenit + zdenitt ) * zwstpon / (zwstpoc + rtrn)   &
358            &   + rno3 * rdenit * (zpdenit + zdenitt)
359            trb(ji,jj,ikt,jpdic) = trb(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt
360            zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt)
361#endif
362         END DO
363      END DO
364
365      ! Nitrogen fixation process
366      ! Small source iron from particulate inorganic iron
367      !-----------------------------------
368      DO jk = 1, jpkm1
369         DO jj = 1, jpj
370            DO ji = 1, jpi
371               !                      ! Potential nitrogen fixation dependant on temperature and iron
372               ztemp = tsn(ji,jj,jk,jp_tem)
373               zmudia = max(0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637) * 7.625
374               !       Potential nitrogen fixation dependant on
375               !       temperature and iron
376               xdianh4 = trb(ji,jj,jk,jpnh4) / ( concnnh4 + trb(ji,jj,jk,jpnh4) )
377               xdiano3 = trb(ji,jj,jk,jpno3) / ( concnno3 + trb(ji,jj,jk,jpno3) ) * (1. - xdianh4)
378               zlim = ( 1.- xdiano3 - xdianh4 )
379               IF( zlim <= 0.1 )   zlim = 0.01
380               zfact = zlim * rfact2
381               ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
382               ztrpo4(ji,jj,jk) = trb(ji,jj,jk,jppo4) / ( 1E-6 + trb(ji,jj,jk,jppo4) )
383               ztrdop(ji,jj,jk) = trb(ji,jj,jk,jpdop) / ( 1E-6 + trb(ji,jj,jk,jpdop) ) * (1. - ztrpo4(ji,jj,jk))
384               ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
385               zlight =  ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) ) * (1. - fr_i(ji,jj)) 
386               nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight
387               zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk))
388            END DO
389         END DO
390      END DO
391
392      ! Nitrogen change due to nitrogen fixation
393      ! ----------------------------------------
394      DO jk = 1, jpkm1
395         DO jj = 1, jpj
396            DO ji = 1, jpi
397               zfact = nitrpot(ji,jj,jk) * nitrfix
398               trb(ji,jj,jk,jpnh4) = trb(ji,jj,jk,jpnh4) + zfact / 3.0
399               trb(ji,jj,jk,jptal) = trb(ji,jj,jk,jptal) + rno3 * zfact / 3.0
400               trb(ji,jj,jk,jppo4) = trb(ji,jj,jk,jppo4) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
401               &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
402               trb(ji,jj,jk,jpdon) = trb(ji,jj,jk,jpdon) + zfact * 1.0 / 3.0
403               trb(ji,jj,jk,jpdoc) = trb(ji,jj,jk,jpdoc) + zfact * 1.0 / 3.0
404               trb(ji,jj,jk,jpdop) = trb(ji,jj,jk,jpdop) + 16.0 / 46.0 * zfact / 3.0  &
405               &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
406               &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
407               trb(ji,jj,jk,jppoc) = trb(ji,jj,jk,jppoc) + zfact * 1.0 / 3.0 * 2.0 / 3.0
408               trb(ji,jj,jk,jppon) = trb(ji,jj,jk,jppon) + zfact * 1.0 / 3.0 * 2.0 /3.0
409               trb(ji,jj,jk,jppop) = trb(ji,jj,jk,jppop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
410               trb(ji,jj,jk,jpgoc) = trb(ji,jj,jk,jpgoc) + zfact * 1.0 / 3.0 * 1.0 / 3.0
411               trb(ji,jj,jk,jpgon) = trb(ji,jj,jk,jpgon) + zfact * 1.0 / 3.0 * 1.0 /3.0
412               trb(ji,jj,jk,jpgop) = trb(ji,jj,jk,jpgop) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
413               trb(ji,jj,jk,jpoxy) = trb(ji,jj,jk,jpoxy) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
414               trb(ji,jj,jk,jpfer) = trb(ji,jj,jk,jpfer) - 30E-6 * zfact * 1.0 / 3.0 
415               trb(ji,jj,jk,jpsfe) = trb(ji,jj,jk,jpsfe) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
416               trb(ji,jj,jk,jpbfe) = trb(ji,jj,jk,jpbfe) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
417               trb(ji,jj,jk,jpfer) = trb(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
418           END DO
419         END DO
420      END DO
421      !
422      IF( lk_iomput ) THEN
423         IF( knt == nrdttrc ) THEN
424            zfact = 1.e+3 * rfact2r * rno3  !  conversion from molC/l/kt  to molN/m3/s
425            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * zfact * tmask(:,:,:) )  ! nitrogen fixation
426            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
427               zwork1(:,:) = 0.
428               DO jk = 1, jpkm1
429                 zwork1(:,:) = zwork1(:,:) + nitrpot(:,:,jk) * nitrfix * zfact * fse3t(:,:,jk) * tmask(:,:,jk)
430               ENDDO
431               CALL iom_put( "INTNFIX" , zwork1 )
432            ENDIF
433         ENDIF
434      ELSE
435         IF( ln_diatrc )  &
436            &  trc2d(:,:,jp_pcs0_2d + 12) = nitrpot(:,:,1) * nitrfix * rno3 * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1)
437      ENDIF
438      !
439      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
440         WRITE(charout, fmt="('sed ')")
441         CALL prt_ctl_trc_info(charout)
442      ENDIF
443      !
444      CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff )
445      CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal )
446      CALL wrk_dealloc( jpi, jpj, jpk, ztrpo4, ztrdop, zsoufer )
447#if defined key_ligand
448      CALL wrk_dealloc( jpi, jpj, zwsfep )
449#endif
450      !
451      IF( nn_timing == 1 )  CALL timing_stop('p5z_sed')
452      !
453 9100  FORMAT(i8,3f10.5)
454      !
455   END SUBROUTINE p5z_sed
456
457   INTEGER FUNCTION p5z_sed_alloc()
458      !!----------------------------------------------------------------------
459      !!                     ***  ROUTINE p4z_sed_alloc  ***
460      !!----------------------------------------------------------------------
461      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p5z_sed_alloc )
462      !
463      IF( p5z_sed_alloc /= 0 )   CALL ctl_warn('p5z_sed_alloc: failed to allocate arrays')
464      !
465   END FUNCTION p5z_sed_alloc
466
467#else
468   !!======================================================================
469   !!  Dummy module :                                   No PISCES bio-model
470   !!======================================================================
471CONTAINS
472   SUBROUTINE p5z_sed                         ! Empty routine
473   END SUBROUTINE p5z_sed
474#endif 
475
476   !!======================================================================
477END MODULE  p5zsed
Note: See TracBrowser for help on using the repository browser.