New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
seddta.F90 in branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/SED – NEMO

source: branches/CNRS/dev_r6270_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/SED/seddta.F90 @ 8003

Last change on this file since 8003 was 8003, checked in by aumont, 7 years ago

modification in the code to remove unnecessary parts such as kriest and non iomput options
  • Property svn:keywords set to Id
File size: 9.7 KB
Line 
1MODULE seddta
2   !!======================================================================
3   !!                     ***  MODULE  seddta  ***
4   !! Sediment data  :  read sediment input data from a file
5   !!=====================================================================
6#if defined key_sed
7   !! * Modules used
8   USE sed
9   USE sedarr
10   USE iom
11
12   IMPLICIT NONE
13   PRIVATE
14
15   !! * Routine accessibility
16   PUBLIC sed_dta   !
17
18   !! *  Module variables
19   REAL(wp), DIMENSION(:), ALLOCATABLE ::  smask       ! mask for sediments points
20   REAL(wp) ::  rsecday  ! number of second per a day
21   REAL(wp) ::  conv1    ! [m/day]--->[cm/s] 
22   REAL(wp) ::  conv2    ! [kg/m2/month]-->[g/cm2/s] ( 1 month has 30 days )
23
24   INTEGER ::  numbio
25
26#if defined key_sed_off
27   INTEGER ::  numoce
28#endif
29
30   !! $Id$
31CONTAINS
32
33   !!---------------------------------------------------------------------------
34   !!   sed_dta  : read the NetCDF data file in online version using module iom
35   !!---------------------------------------------------------------------------
36
37   SUBROUTINE sed_dta( kt )
38      !!----------------------------------------------------------------------
39      !!                   ***  ROUTINE sed_dta  ***
40      !!                   
41      !! ** Purpose :   Reads data from a netcdf file and
42      !!                initialization of rain and pore water (k=1) components
43      !!
44      !!
45      !!   History :
46      !!        !  04-10  (N. Emprin, M. Gehlen )  Original code
47      !!        !  06-04  (C. Ethe)  Re-organization ; Use of iom
48      !!----------------------------------------------------------------------
49
50      !! Arguments
51      INTEGER, INTENT(in) ::  kt    ! time-step
52
53      !! * Local declarations
54      INTEGER  ::  ji, jj, js, jw, ikt
55
56      REAL(wp), DIMENSION(:,:), ALLOCATABLE :: zdta
57      REAL(wp), DIMENSION(:)  , ALLOCATABLE :: zdtap, zdtag
58
59
60      !----------------------------------------------------------------------
61
62      ! Initialization of sediment variable
63      ! Spatial dimension is merged, and unity converted if needed
64      !-------------------------------------------------------------
65
66      WRITE(numsed,*)
67      WRITE(numsed,*) ' sed_dta : Bottom layer fields'
68      WRITE(numsed,*) ' ~~~~~~'
69      WRITE(numsed,*) ' Data from SMS model'
70      WRITE(numsed,*)
71
72
73      ! open file
74      IF( kt == nitsed000 ) THEN
75         WRITE(numsed,*) ' sed_dta : Sediment fields'
76         CALL iom_open ( 'data_bio_bot'     , numbio )
77#if defined key_sed_off
78         CALL iom_open( 'data_oce_bot', numoce)
79#endif
80         rsecday = 60.* 60. * 24.
81         conv1   = 1.0e+2 / rsecday 
82         conv2   = 1.0e+3 / ( 1.0e+4 * rsecday * 30. ) 
83
84         ! Compute sediment mask
85         ALLOCATE( zdta(jpi,jpj) ) 
86         DO jj = 1, jpj
87            DO ji = 1, jpi
88               ikt = MAX( INT( sbathy(ji,jj) ) - 1, 1 )
89               zdta(ji,jj) = tmask(ji,jj,ikt) 
90            ENDDO
91         ENDDO
92         ALLOCATE( smask(jpoce) )
93         smask(:) = 0.
94         CALL pack_arr( jpoce, smask(1:jpoce), zdta(1:jpi,1:jpj), iarroce(1:jpoce) )
95      ENDIF
96
97
98      ! Initialization of temporaries arrays 
99      ALLOCATE( zdtap(jpoce) )    ;   zdtap(:)    = 0. 
100      ALLOCATE( zdtag(jpoce) )    ;   zdtag(:)    = 0. 
101
102
103      IF( MOD( kt - 1, nfreq ) == 0 ) THEN
104         ! reading variables
105         WRITE(numsed,*)
106         WRITE(numsed,*) ' sed_dta : Bottom layer fields at time  kt = ', kt
107         ! reading variables
108         trc_data(:,:,:) = 0.
109#if ! defined key_sed_off
110         DO jj = 1,jpj
111            DO ji = 1, jpi
112               ikt = mbkt(ji,jj)
113               IF ( tmask(ji,jj,ikt) == 1 ) THEN
114                  trc_data(ji,jj,1)  = trn  (ji,jj,ikt,jptal)
115                  trc_data(ji,jj,2)  = trn  (ji,jj,ikt,jpdic)
116                  trc_data(ji,jj,3)  = trn  (ji,jj,ikt,jpno3) / 7.6
117                  trc_data(ji,jj,4)  = trn  (ji,jj,ikt,jppo4) / 122.
118                  trc_data(ji,jj,5)  = trn  (ji,jj,ikt,jpoxy)
119                  trc_data(ji,jj,6)  = trn  (ji,jj,ikt,jpsil)
120                  trc_data(ji,jj,7 ) = sinksil (ji,jj,ikt)
121                  trc_data(ji,jj,8 ) = sinking (ji,jj,ikt)
122                  trc_data(ji,jj,9 ) = sinking2(ji,jj,ikt)
123                  trc_data(ji,jj,10) = sinkcal (ji,jj,ikt)
124                  trc_data(ji,jj,11) = tsn     (ji,jj,ikt,jp_tem)
125                  trc_data(ji,jj,12) = tsn     (ji,jj,ikt,jp_sal)
126               ENDIF
127            ENDDO
128         ENDDO
129
130#else
131         CALL iom_get( numbio, jpdom_data, 'ALKBOT'     , trc_data(:,:,1 ) )
132         CALL iom_get( numbio, jpdom_data, 'DICBOT'     , trc_data(:,:,2 ) )
133         CALL iom_get( numbio, jpdom_data, 'NO3BOT'     , trc_data(:,:,3 ) )
134         CALL iom_get( numbio, jpdom_data, 'PO4BOT'     , trc_data(:,:,4 ) )
135         CALL iom_get( numbio, jpdom_data, 'O2BOT'      , trc_data(:,:,5 ) )
136         CALL iom_get( numbio, jpdom_data, 'SIBOT'      , trc_data(:,:,6 ) )
137         CALL iom_get( numbio, jpdom_data, 'OPALFLXBOT' , trc_data(:,:,7 ) ) 
138         CALL iom_get( numbio, jpdom_data, 'POCFLXBOT'  , trc_data(:,:,8 ) ) 
139         CALL iom_get( numbio, jpdom_data, 'GOCFLXBOT'  , trc_data(:,:,9 ) ) 
140         CALL iom_get( numbio, jpdom_data, 'CACO3FLXBOT', trc_data(:,:,10) ) 
141         CALL iom_get( numoce, jpdom_data, 'TBOT'       , trc_data(:,:,11) ) 
142         CALL iom_get( numoce, jpdom_data, 'SBOT'       , trc_data(:,:,12) ) 
143#endif
144
145         ! Pore water initial concentration [mol/l] in  k=1
146         !-------------------------------------------------
147
148          ! Alkalinity ( 1 umol = 10-6equivalent )
149         CALL pack_arr ( jpoce,  pwcp_dta(1:jpoce,jwalk), trc_data(1:jpi,1:jpj,1), iarroce(1:jpoce) )
150         ! DIC
151         CALL pack_arr ( jpoce,  pwcp_dta(1:jpoce,jwdic), trc_data(1:jpi,1:jpj,2), iarroce(1:jpoce) )
152         ! Nitrates (1 umol/l = 10-6 mol/l)
153         CALL pack_arr ( jpoce,  pwcp_dta(1:jpoce,jwno3), trc_data(1:jpi,1:jpj,3), iarroce(1:jpoce) )
154         ! Phosphates (1 umol/l = 10-6 mol/l)
155         CALL pack_arr ( jpoce,  pwcp_dta(1:jpoce,jwpo4), trc_data(1:jpi,1:jpj,4), iarroce(1:jpoce) )
156         ! Oxygen (1 umol/l = 10-6 mol/l)
157         CALL pack_arr ( jpoce,  pwcp_dta(1:jpoce,jwoxy), trc_data(1:jpi,1:jpj,5), iarroce(1:jpoce) )       
158         ! Silicic Acid [mol.l-1]
159         CALL pack_arr ( jpoce,  pwcp_dta(1:jpoce,jwsil), trc_data(1:jpi,1:jpj,6), iarroce(1:jpoce) )                 
160         ! DIC13 (mol/l)obtained from dc13 and DIC (12) and PDB
161         CALL iom_get ( numbio,jpdom_data,'DC13',zdta(:,:) )
162         CALL pack_arr ( jpoce,  pwcp_dta(1:jpoce,jwc13), zdta(1:jpi,1:jpj), iarroce(1:jpoce) )
163         pwcp_dta(1:jpoce,jwc13) = pdb * ( pwcp_dta(1:jpoce,jwc13) * 1.0e-3 + 1.0 )  &
164            &                          *   pwcp_dta(1:jpoce,jwdic)         
165         
166         !  Solid components :
167         !-----------------------
168         !  Sinking fluxes for OPAL in mol.m-2.s-1 ; conversion in mol.cm-2.s-1
169         CALL pack_arr ( jpoce, rainrm_dta(1:jpoce,jsopal), trc_data(1:jpi,1:jpj,7), iarroce(1:jpoce) ) 
170         rainrm_dta(1:jpoce,jsopal) = rainrm_dta(1:jpoce,jsopal) * 1e-4
171         !  Sinking fluxes for POC in mol.m-2.s-1 ; conversion in mol.cm-2.s-1
172         CALL pack_arr ( jpoce, zdtap(1:jpoce), trc_data(1:jpi,1:jpj,8) , iarroce(1:jpoce) )     
173         CALL pack_arr ( jpoce, zdtag(1:jpoce), trc_data(1:jpi,1:jpj,9) , iarroce(1:jpoce) )
174         rainrm_dta(1:jpoce,jspoc) =   ( zdtap(1:jpoce) +  zdtag(1:jpoce) ) * 1e-4
175         !  Sinking fluxes for Calcite in mol.m-2.s-1 ; conversion in mol.cm-2.s-1
176         CALL pack_arr ( jpoce,  rainrm_dta(1:jpoce,jscal), trc_data(1:jpi,1:jpj,10), iarroce(1:jpoce) )
177         rainrm_dta(1:jpoce,jscal) = rainrm_dta(1:jpoce,jscal) * 1e-4
178         ! vector temperature [°C] and salinity
179         CALL pack_arr ( jpoce,  temp(1:jpoce), trc_data(1:jpi,1:jpj,11), iarroce(1:jpoce) )
180         CALL pack_arr ( jpoce,  salt(1:jpoce), trc_data(1:jpi,1:jpj,12), iarroce(1:jpoce) )
181       
182         ! Clay rain rate in [mol/(cm**2.s)]
183         ! inputs data in [kg.m-2.mois-1] ---> 1e+3/(1e+4*60*24*60*60) [g.cm-2.s-1]   
184         ! divided after by molecular weight g.mol-1     
185         zdta(:,:)   = 0.
186         CALL iom_get( numbio, jpdom_data, 'CLAY', zdta(:,:) ) 
187         CALL pack_arr ( jpoce, rainrm_dta(1:jpoce,jsclay) , zdta(1:jpi,1:jpj), iarroce(1:jpoce) )     
188         rainrm_dta(1:jpoce,jsclay) = rainrm_dta(1:jpoce,jsclay) * conv2 / mol_wgt(jsclay)
189
190      ENDIF
191
192      ! sediment pore water at 1st layer (k=1)
193      DO jw = 1, jpwat
194         pwcp(1:jpoce,1,jw) = pwcp_dta(1:jpoce,jw) * smask(1:jpoce)
195      ENDDO
196
197      !  rain
198      DO js = 1, jpsol
199         rainrm(1:jpoce,js) = rainrm_dta(1:jpoce,js) * smask(1:jpoce)
200      ENDDO
201
202      ! Calculation of raintg of each sol. comp.: rainrm in [g/(cm**2.s)]
203      DO js = 1, jpsol
204         rainrg(1:jpoce,js) = rainrm(1:jpoce,js) *  mol_wgt(js)
205      ENDDO
206
207      ! Calculation of raintg = total massic flux rained in each cell (sum of sol. comp.)
208      raintg(:) = 0.
209      DO js = 1, jpsol
210         raintg(1:jpoce) = raintg(1:jpoce) + rainrg(1:jpoce,js)
211      ENDDO
212
213      ! computation of dzdep = total thickness of solid material rained [cm] in each cell
214      dzdep(1:jpoce) = raintg(1:jpoce) * rdtsed(2) 
215
216
217      DEALLOCATE( zdta ) 
218      DEALLOCATE( zdtap    ) ;  DEALLOCATE( zdtag    ) 
219
220      IF( kt == nitsedend )   THEN
221         CALL iom_close ( numbio )
222#if defined key_sed_off
223         CALL iom_close ( numoce )
224#endif
225      ENDIF
226     
227   END SUBROUTINE sed_dta
228
229#else
230   !!======================================================================
231   !! MODULE seddta  :   Dummy module
232   !!======================================================================
233   !! $Id$
234CONTAINS
235   SUBROUTINE sed_dta ( kt )
236     INTEGER, INTENT(in) :: kt
237     WRITE(*,*) 'sed_stp: You should not have seen this print! error?', kt 
238  END SUBROUTINE sed_dta
239#endif
240
241END MODULE seddta
Note: See TracBrowser for help on using the repository browser.