New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmeso.F90 in branches/CNRS/dev_r8832_PISCO/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r8832_PISCO/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 9450

Last change on this file since 9450 was 9450, checked in by aumont, 6 years ago

debug PISCES code
File size: 18.3 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
11   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zprod         !  production
17   USE prtctl_trc      !  print control for debugging
18   USE iom             !  I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_meso              ! called in p4zbio.F90
24   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
25
26   !! * Shared module variables
27   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
28   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
29   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
30   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
31   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
32   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
33   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
34   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
37   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
38   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
39   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
40   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
41   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
42   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
43   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
44   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
45
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
48   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
49   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE p4z_meso( kt, knt )
55      !!---------------------------------------------------------------------
56      !!                     ***  ROUTINE p4z_meso  ***
57      !!
58      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
63      INTEGER  :: ji, jj, jk
64      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
65      REAL(wp) :: zgraze2 , zdenom, zdenom2
66      REAL(wp) :: zfact   , zfood, zfoodlim, zproport
67      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal
68      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
69      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat, zgrasratn
70      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
71      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
72      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
73      CHARACTER (len=25) :: charout
74      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d, zfezoo2
75      REAL(wp), POINTER, DIMENSION(:,:,:) :: zz2ligprod
76
77      !!---------------------------------------------------------------------
78      !
79      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
80      !
81      CALL wrk_alloc( jpi, jpj, jpk, zgrazing, zfezoo2 )
82      zgrazing(:,:,:) = 0._wp
83      zfezoo2 (:,:,:) = 0._wp
84      !
85      IF (ln_ligand) THEN
86         CALL wrk_alloc( jpi, jpj, jpk, zz2ligprod )
87         zz2ligprod(:,:,:) = 0._wp
88      ENDIF
89
90      DO jk = 1, jpkm1
91         DO jj = 1, jpj
92            DO ji = 1, jpi
93               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
94               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
95
96               !  Respiration rates of both zooplankton
97               !  -------------------------------------
98               zrespz2   = resrat2 * zfact * trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
99                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
100
101               !  Zooplankton mortality. A square function has been selected with
102               !  no real reason except that it seems to be more stable and may mimic predation
103               !  ---------------------------------------------------------------
104               ztortz2   = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)  * (1. - nitrfac(ji,jj,jk) )
105               !
106               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
107               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
108               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
109               ! it is to predation by mesozooplankton
110               ! -------------------------------------------------------------------------------
111               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
112                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
113               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
114
115               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
116               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
117               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
118               zdenom2   = zdenom / ( zfood + rtrn )
119               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) 
120
121               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
122               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
123               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
124               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
125
126               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
127               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
128               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
129
130               !  Mesozooplankton flux feeding on GOC
131               !  ----------------------------------
132               !  ----------------------------------
133               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
134               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes) &
135               &           * (1. - nitrfac(ji,jj,jk))
136               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
137               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
138               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes) &
139               &           * (1. - nitrfac(ji,jj,jk))
140               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
141              !
142              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
143              ! Compute the proportion of filter feeders
144              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
145              ! Compute fractionation of aggregates. It is assumed that
146              ! diatoms based aggregates are more prone to fractionation
147              ! since they are more porous (marine snow instead of fecal pellets)
148              zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
149              zratio2   = zratio * zratio
150              zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
151               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
152               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
153              zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
154
155              zgrazffep = zproport * zgrazffep
156              zgrazffeg = zproport * zgrazffeg
157              zgrazfffp = zproport * zgrazfffp
158              zgrazfffg = zproport * zgrazfffg
159              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
160              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
161              &   + zgrazpoc + zgrazffep + zgrazffeg
162              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
163
164              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
165              zgrazing(ji,jj,jk) = zgraztot
166
167              !    Mesozooplankton efficiency
168              !    --------------------------
169               zgrasrat  =  ( zgraztotf +rtrn )/ ( zgraztot + rtrn )
170               zgrasratn =  ( zgraztotn +rtrn )/ ( zgraztot + rtrn )
171               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
172               zepsherv  = zepshert * MIN( epsher2, (1. - unass2) * zgrasrat / ferat3, (1. - unass2) * zgrasratn )
173               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) &
174                &       + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz2
175               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
176                &       + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz2 )
177               zgrapoc2  = zgraztot * unass2
178
179               !   Update the arrays TRA which contain the biological sources and sinks
180               zgrarsig  = zgrarem2 * sigma2
181               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
182               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
183               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
184               !
185               IF( ln_ligand ) THEN
186                  tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem2 - zgrarsig) * ldocz
187                  zz2ligprod(ji,jj,jk) = (zgrarem2 - zgrarsig) * ldocz
188               ENDIF
189               !
190               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
191               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
192               zfezoo2(ji,jj,jk) = zgrafer2
193               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
194               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
195
196               zmortz2 = ztortz2 + zrespz2
197               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz2 + zrespz2
198               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
199               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
200               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
201               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
202               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
203               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
204               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
205               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
206               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
207               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
208
209              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
210              prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac
211              conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
212              tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
213              prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2
214              consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac
215              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
216              tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
217                 &                + zgraztotf * unass2 - zfracfe
218              zfracal = trb(ji,jj,jk,jpcal) / (trb(ji,jj,jk,jppoc) + trb(ji,jj,jk,jpgoc) + rtrn )
219              zgrazcal = (zgrazffeg + zgrazpoc) * (1. - part2) * zfracal
220              ! calcite production
221              zprcaca = xfracal(ji,jj,jk) * zgrazn
222              prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
223              !
224              zprcaca = part2 * zprcaca
225              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrazcal - zprcaca
226              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * ( zgrazcal + zprcaca )
227              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) - zgrazcal + zprcaca
228            END DO
229         END DO
230      END DO
231      !
232      IF( lk_iomput .AND. knt == nrdttrc ) THEN
233         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
234         IF( iom_use( "GRAZ2" ) ) THEN
235            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
236            CALL iom_put( "GRAZ2", zw3d )
237         ENDIF
238         IF( iom_use( "PCAL" ) ) THEN
239            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
240            CALL iom_put( "PCAL", zw3d ) 
241         ENDIF
242         IF( iom_use( "FEZOO2" ) ) THEN
243            zw3d(:,:,:) = zfezoo2(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)   !
244            CALL iom_put( "FEZOO2", zw3d )
245         ENDIF
246         IF( iom_use( "LPRODZ2" ) .AND. ln_ligand )  THEN
247            zw3d(:,:,:) = zz2ligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:)
248            CALL iom_put( "LPRODZ2"  , zw3d )
249         ENDIF
250         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
251      ENDIF
252      !
253      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
254        WRITE(charout, FMT="('meso')")
255        CALL prt_ctl_trc_info(charout)
256        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
257      ENDIF
258      !
259      CALL wrk_dealloc( jpi, jpj, jpk, zgrazing, zfezoo2 )
260      IF ( ln_ligand ) CALL wrk_dealloc( jpi, jpj, jpk, zz2ligprod )
261      !
262      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
263      !
264   END SUBROUTINE p4z_meso
265
266   SUBROUTINE p4z_meso_init
267
268      !!----------------------------------------------------------------------
269      !!                  ***  ROUTINE p4z_meso_init  ***
270      !!
271      !! ** Purpose :   Initialization of mesozooplankton parameters
272      !!
273      !! ** Method  :   Read the nampismes namelist and check the parameters
274      !!      called at the first timestep (nittrc000)
275      !!
276      !! ** input   :   Namelist nampismes
277      !!
278      !!----------------------------------------------------------------------
279
280      NAMELIST/namp4zmes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
281         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
282         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
283      INTEGER :: ios                 ! Local integer output status for namelist read
284
285      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
286      READ  ( numnatp_ref, namp4zmes, IOSTAT = ios, ERR = 901)
287901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zmes in reference namelist', lwp )
288
289      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
290      READ  ( numnatp_cfg, namp4zmes, IOSTAT = ios, ERR = 902 )
291902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zmes in configuration namelist', lwp )
292      IF(lwm) WRITE ( numonp, namp4zmes )
293
294
295      IF(lwp) THEN                         ! control print
296         WRITE(numout,*) ' ' 
297         WRITE(numout,*) ' Namelist parameters for mesozooplankton, namp4zmes'
298         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
299         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
300         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
301         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
302         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
303         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
304         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
305         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
306         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
307         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
308         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
309         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
310         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
311         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
312         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
313         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
314         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
315         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
316         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
317      ENDIF
318
319
320   END SUBROUTINE p4z_meso_init
321
322   !!======================================================================
323END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.