| 1 | MODULE p4zmicro |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zmicro *** |
|---|
| 4 | !! TOP : PISCES Compute the sources/sinks for microzooplankton |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
|---|
| 7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 8 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | !! p4z_micro : Compute the sources/sinks for microzooplankton |
|---|
| 11 | !! p4z_micro_init : Initialize and read the appropriate namelist |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 14 | USE trc ! passive tracers common variables |
|---|
| 15 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 16 | USE p4zlim ! Co-limitations |
|---|
| 17 | USE p4zprod ! production |
|---|
| 18 | USE iom ! I/O manager |
|---|
| 19 | USE prtctl_trc ! print control for debugging |
|---|
| 20 | |
|---|
| 21 | IMPLICIT NONE |
|---|
| 22 | PRIVATE |
|---|
| 23 | |
|---|
| 24 | PUBLIC p4z_micro ! called in p4zbio.F90 |
|---|
| 25 | PUBLIC p4z_micro_init ! called in trcsms_pisces.F90 |
|---|
| 26 | |
|---|
| 27 | !! * Shared module variables |
|---|
| 28 | REAL(wp), PUBLIC :: part !: part of calcite not dissolved in microzoo guts |
|---|
| 29 | REAL(wp), PUBLIC :: xpref2c !: microzoo preference for POC |
|---|
| 30 | REAL(wp), PUBLIC :: xpref2p !: microzoo preference for nanophyto |
|---|
| 31 | REAL(wp), PUBLIC :: xpref2d !: microzoo preference for diatoms |
|---|
| 32 | REAL(wp), PUBLIC :: xthreshdia !: diatoms feeding threshold for microzooplankton |
|---|
| 33 | REAL(wp), PUBLIC :: xthreshphy !: nanophyto threshold for microzooplankton |
|---|
| 34 | REAL(wp), PUBLIC :: xthreshpoc !: poc threshold for microzooplankton |
|---|
| 35 | REAL(wp), PUBLIC :: xthresh !: feeding threshold for microzooplankton |
|---|
| 36 | REAL(wp), PUBLIC :: resrat !: exsudation rate of microzooplankton |
|---|
| 37 | REAL(wp), PUBLIC :: mzrat !: microzooplankton mortality rate |
|---|
| 38 | REAL(wp), PUBLIC :: grazrat !: maximal microzoo grazing rate |
|---|
| 39 | REAL(wp), PUBLIC :: xkgraz !: non assimilated fraction of P by microzoo |
|---|
| 40 | REAL(wp), PUBLIC :: unass !: Efficicency of microzoo growth |
|---|
| 41 | REAL(wp), PUBLIC :: sigma1 !: Fraction of microzoo excretion as DOM |
|---|
| 42 | REAL(wp), PUBLIC :: epsher !: half sturation constant for grazing 1 |
|---|
| 43 | |
|---|
| 44 | |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 47 | !! $Id: p4zmicro.F90 3160 2011-11-20 14:27:18Z cetlod $ |
|---|
| 48 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | |
|---|
| 51 | CONTAINS |
|---|
| 52 | |
|---|
| 53 | SUBROUTINE p4z_micro( kt, knt ) |
|---|
| 54 | !!--------------------------------------------------------------------- |
|---|
| 55 | !! *** ROUTINE p4z_micro *** |
|---|
| 56 | !! |
|---|
| 57 | !! ** Purpose : Compute the sources/sinks for microzooplankton |
|---|
| 58 | !! |
|---|
| 59 | !! ** Method : - ??? |
|---|
| 60 | !!--------------------------------------------------------------------- |
|---|
| 61 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 62 | INTEGER, INTENT(in) :: knt |
|---|
| 63 | ! |
|---|
| 64 | INTEGER :: ji, jj, jk |
|---|
| 65 | REAL(wp) :: zcompadi, zcompaz , zcompaph, zcompapoc |
|---|
| 66 | REAL(wp) :: zgraze , zdenom, zdenom2 |
|---|
| 67 | REAL(wp) :: zfact , zfood, zfoodlim |
|---|
| 68 | REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf |
|---|
| 69 | REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz |
|---|
| 70 | REAL(wp) :: zrespz, ztortz, zgrasrat, zgrasratn |
|---|
| 71 | REAL(wp) :: zgrazp, zgrazm, zgrazsd |
|---|
| 72 | REAL(wp) :: zgrazmf, zgrazsf, zgrazpf |
|---|
| 73 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d, zfezoo |
|---|
| 74 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zzligprod |
|---|
| 75 | CHARACTER (len=25) :: charout |
|---|
| 76 | !!--------------------------------------------------------------------- |
|---|
| 77 | ! |
|---|
| 78 | IF( nn_timing == 1 ) CALL timing_start('p4z_micro') |
|---|
| 79 | ! |
|---|
| 80 | CALL wrk_alloc( jpi, jpj, jpk, zgrazing, zfezoo ) |
|---|
| 81 | IF (ln_ligand) THEN |
|---|
| 82 | CALL wrk_alloc( jpi, jpj, jpk, zzligprod ) |
|---|
| 83 | zzligprod(:,:,:) = 0._wp |
|---|
| 84 | ENDIF |
|---|
| 85 | ! |
|---|
| 86 | DO jk = 1, jpkm1 |
|---|
| 87 | DO jj = 1, jpj |
|---|
| 88 | DO ji = 1, jpi |
|---|
| 89 | zcompaz = MAX( ( trb(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 ) |
|---|
| 90 | zfact = xstep * tgfunc2(ji,jj,jk) * zcompaz |
|---|
| 91 | |
|---|
| 92 | ! Respiration rates of both zooplankton |
|---|
| 93 | ! ------------------------------------- |
|---|
| 94 | zrespz = resrat * zfact * trb(ji,jj,jk,jpzoo) / ( xkmort + trb(ji,jj,jk,jpzoo) ) & |
|---|
| 95 | & + resrat * zfact * 3. * nitrfac(ji,jj,jk) |
|---|
| 96 | |
|---|
| 97 | ! Zooplankton mortality. A square function has been selected with |
|---|
| 98 | ! no real reason except that it seems to be more stable and may mimic predation. |
|---|
| 99 | ! --------------------------------------------------------------- |
|---|
| 100 | ztortz = mzrat * 1.e6 * zfact * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk)) |
|---|
| 101 | |
|---|
| 102 | zcompadi = MIN( MAX( ( trb(ji,jj,jk,jpdia) - xthreshdia ), 0.e0 ), xsizedia ) |
|---|
| 103 | zcompaph = MAX( ( trb(ji,jj,jk,jpphy) - xthreshphy ), 0.e0 ) |
|---|
| 104 | zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthreshpoc ), 0.e0 ) |
|---|
| 105 | |
|---|
| 106 | ! Microzooplankton grazing |
|---|
| 107 | ! ------------------------ |
|---|
| 108 | zfood = xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi |
|---|
| 109 | zfoodlim = MAX( 0. , zfood - min(xthresh,0.5*zfood) ) |
|---|
| 110 | zdenom = zfoodlim / ( xkgraz + zfoodlim ) |
|---|
| 111 | zdenom2 = zdenom / ( zfood + rtrn ) |
|---|
| 112 | zgraze = grazrat * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpzoo) * (1. - nitrfac(ji,jj,jk)) |
|---|
| 113 | |
|---|
| 114 | zgrazp = zgraze * xpref2p * zcompaph * zdenom2 |
|---|
| 115 | zgrazm = zgraze * xpref2c * zcompapoc * zdenom2 |
|---|
| 116 | zgrazsd = zgraze * xpref2d * zcompadi * zdenom2 |
|---|
| 117 | |
|---|
| 118 | zgrazpf = zgrazp * trb(ji,jj,jk,jpnfe) / (trb(ji,jj,jk,jpphy) + rtrn) |
|---|
| 119 | zgrazmf = zgrazm * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn) |
|---|
| 120 | zgrazsf = zgrazsd * trb(ji,jj,jk,jpdfe) / (trb(ji,jj,jk,jpdia) + rtrn) |
|---|
| 121 | ! |
|---|
| 122 | zgraztot = zgrazp + zgrazm + zgrazsd |
|---|
| 123 | zgraztotf = zgrazpf + zgrazsf + zgrazmf |
|---|
| 124 | zgraztotn = zgrazp * quotan(ji,jj,jk) + zgrazm + zgrazsd * quotad(ji,jj,jk) |
|---|
| 125 | |
|---|
| 126 | ! Grazing by microzooplankton |
|---|
| 127 | zgrazing(ji,jj,jk) = zgraztot |
|---|
| 128 | |
|---|
| 129 | ! Various remineralization and excretion terms |
|---|
| 130 | ! -------------------------------------------- |
|---|
| 131 | zgrasrat = ( zgraztotf + rtrn ) / ( zgraztot + rtrn ) |
|---|
| 132 | zgrasratn = ( zgraztotn + rtrn ) / ( zgraztot + rtrn ) |
|---|
| 133 | zepshert = MIN( 1., zgrasratn, zgrasrat / ferat3) |
|---|
| 134 | zepsherv = zepshert * MIN( epsher, (1. - unass) * zgrasrat / ferat3, (1. - unass) * zgrasratn ) |
|---|
| 135 | zgrafer = zgraztot * MAX( 0. , ( 1. - unass ) * zgrasrat - ferat3 * zepsherv ) |
|---|
| 136 | zgrarem = zgraztot * ( 1. - zepsherv - unass ) |
|---|
| 137 | zgrapoc = zgraztot * unass |
|---|
| 138 | |
|---|
| 139 | ! Update of the TRA arrays |
|---|
| 140 | ! ------------------------ |
|---|
| 141 | zgrarsig = zgrarem * sigma1 |
|---|
| 142 | tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig |
|---|
| 143 | tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig |
|---|
| 144 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem - zgrarsig |
|---|
| 145 | ! |
|---|
| 146 | IF( ln_ligand ) THEN |
|---|
| 147 | tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem - zgrarsig) * ldocz |
|---|
| 148 | zzligprod(ji,jj,jk) = (zgrarem - zgrarsig) * ldocz |
|---|
| 149 | ENDIF |
|---|
| 150 | ! |
|---|
| 151 | tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig |
|---|
| 152 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer |
|---|
| 153 | zfezoo(ji,jj,jk) = zgrafer |
|---|
| 154 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc |
|---|
| 155 | prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zgrapoc |
|---|
| 156 | tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass |
|---|
| 157 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig |
|---|
| 158 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig |
|---|
| 159 | ! Update the arrays TRA which contain the biological sources and sinks |
|---|
| 160 | ! -------------------------------------------------------------------- |
|---|
| 161 | zmortz = ztortz + zrespz |
|---|
| 162 | tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + zepsherv * zgraztot |
|---|
| 163 | tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp |
|---|
| 164 | tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd |
|---|
| 165 | tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp * trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn) |
|---|
| 166 | tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trb(ji,jj,jk,jpdch)/(trb(ji,jj,jk,jpdia)+rtrn) |
|---|
| 167 | tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn) |
|---|
| 168 | tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazsd * trb(ji,jj,jk,jpdsi)/(trb(ji,jj,jk,jpdia)+rtrn) |
|---|
| 169 | tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf |
|---|
| 170 | tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf |
|---|
| 171 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm |
|---|
| 172 | prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zmortz |
|---|
| 173 | conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazm |
|---|
| 174 | tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz - zgrazmf |
|---|
| 175 | ! |
|---|
| 176 | ! calcite production |
|---|
| 177 | zprcaca = xfracal(ji,jj,jk) * zgrazp |
|---|
| 178 | prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo) |
|---|
| 179 | ! |
|---|
| 180 | zprcaca = part * zprcaca |
|---|
| 181 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca |
|---|
| 182 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca |
|---|
| 183 | tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca |
|---|
| 184 | END DO |
|---|
| 185 | END DO |
|---|
| 186 | END DO |
|---|
| 187 | ! |
|---|
| 188 | IF( lk_iomput ) THEN |
|---|
| 189 | IF( knt == nrdttrc ) THEN |
|---|
| 190 | CALL wrk_alloc( jpi, jpj, jpk, zw3d ) |
|---|
| 191 | IF( iom_use( "GRAZ1" ) ) THEN |
|---|
| 192 | zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) ! Total grazing of phyto by zooplankton |
|---|
| 193 | CALL iom_put( "GRAZ1", zw3d ) |
|---|
| 194 | ENDIF |
|---|
| 195 | IF( iom_use( "FEZOO" ) ) THEN |
|---|
| 196 | zw3d(:,:,:) = zfezoo(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) ! |
|---|
| 197 | CALL iom_put( "FEZOO", zw3d ) |
|---|
| 198 | ENDIF |
|---|
| 199 | IF( iom_use( "LPRODZ" ) .AND. ln_ligand ) THEN |
|---|
| 200 | zw3d(:,:,:) = zzligprod(:,:,:) * 1e9 * 1.e+3 * rfact2r * tmask(:,:,:) |
|---|
| 201 | CALL iom_put( "LPRODZ" , zw3d ) |
|---|
| 202 | ENDIF |
|---|
| 203 | CALL wrk_dealloc( jpi, jpj, jpk, zw3d ) |
|---|
| 204 | ENDIF |
|---|
| 205 | ENDIF |
|---|
| 206 | ! |
|---|
| 207 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 208 | WRITE(charout, FMT="('micro')") |
|---|
| 209 | CALL prt_ctl_trc_info(charout) |
|---|
| 210 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
|---|
| 211 | ENDIF |
|---|
| 212 | ! |
|---|
| 213 | CALL wrk_dealloc( jpi, jpj, jpk, zgrazing, zfezoo ) |
|---|
| 214 | IF (ln_ligand) CALL wrk_dealloc( jpi, jpj, jpk, zzligprod ) |
|---|
| 215 | ! |
|---|
| 216 | IF( nn_timing == 1 ) CALL timing_stop('p4z_micro') |
|---|
| 217 | ! |
|---|
| 218 | END SUBROUTINE p4z_micro |
|---|
| 219 | |
|---|
| 220 | |
|---|
| 221 | SUBROUTINE p4z_micro_init |
|---|
| 222 | |
|---|
| 223 | !!---------------------------------------------------------------------- |
|---|
| 224 | !! *** ROUTINE p4z_micro_init *** |
|---|
| 225 | !! |
|---|
| 226 | !! ** Purpose : Initialization of microzooplankton parameters |
|---|
| 227 | !! |
|---|
| 228 | !! ** Method : Read the nampiszoo namelist and check the parameters |
|---|
| 229 | !! called at the first timestep (nittrc000) |
|---|
| 230 | !! |
|---|
| 231 | !! ** input : Namelist nampiszoo |
|---|
| 232 | !! |
|---|
| 233 | !!---------------------------------------------------------------------- |
|---|
| 234 | |
|---|
| 235 | NAMELIST/namp4zzoo/ part, grazrat, resrat, mzrat, xpref2c, xpref2p, & |
|---|
| 236 | & xpref2d, xthreshdia, xthreshphy, xthreshpoc, & |
|---|
| 237 | & xthresh, xkgraz, epsher, sigma1, unass |
|---|
| 238 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 239 | |
|---|
| 240 | REWIND( numnatp_ref ) ! Namelist nampiszoo in reference namelist : Pisces microzooplankton |
|---|
| 241 | READ ( numnatp_ref, namp4zzoo, IOSTAT = ios, ERR = 901) |
|---|
| 242 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in reference namelist', lwp ) |
|---|
| 243 | |
|---|
| 244 | REWIND( numnatp_cfg ) ! Namelist nampiszoo in configuration namelist : Pisces microzooplankton |
|---|
| 245 | READ ( numnatp_cfg, namp4zzoo, IOSTAT = ios, ERR = 902 ) |
|---|
| 246 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zzoo in configuration namelist', lwp ) |
|---|
| 247 | IF(lwm) WRITE ( numonp, namp4zzoo ) |
|---|
| 248 | |
|---|
| 249 | IF(lwp) THEN ! control print |
|---|
| 250 | WRITE(numout,*) ' ' |
|---|
| 251 | WRITE(numout,*) ' Namelist parameters for microzooplankton, namp4zzoo' |
|---|
| 252 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
|---|
| 253 | WRITE(numout,*) ' part of calcite not dissolved in microzoo guts part =', part |
|---|
| 254 | WRITE(numout,*) ' microzoo preference for POC xpref2c =', xpref2c |
|---|
| 255 | WRITE(numout,*) ' microzoo preference for nano xpref2p =', xpref2p |
|---|
| 256 | WRITE(numout,*) ' microzoo preference for diatoms xpref2d =', xpref2d |
|---|
| 257 | WRITE(numout,*) ' diatoms feeding threshold for microzoo xthreshdia =', xthreshdia |
|---|
| 258 | WRITE(numout,*) ' nanophyto feeding threshold for microzoo xthreshphy =', xthreshphy |
|---|
| 259 | WRITE(numout,*) ' poc feeding threshold for microzoo xthreshpoc =', xthreshpoc |
|---|
| 260 | WRITE(numout,*) ' feeding threshold for microzooplankton xthresh =', xthresh |
|---|
| 261 | WRITE(numout,*) ' exsudation rate of microzooplankton resrat =', resrat |
|---|
| 262 | WRITE(numout,*) ' microzooplankton mortality rate mzrat =', mzrat |
|---|
| 263 | WRITE(numout,*) ' maximal microzoo grazing rate grazrat =', grazrat |
|---|
| 264 | WRITE(numout,*) ' non assimilated fraction of P by microzoo unass =', unass |
|---|
| 265 | WRITE(numout,*) ' Efficicency of microzoo growth epsher =', epsher |
|---|
| 266 | WRITE(numout,*) ' Fraction of microzoo excretion as DOM sigma1 =', sigma1 |
|---|
| 267 | WRITE(numout,*) ' half sturation constant for grazing 1 xkgraz =', xkgraz |
|---|
| 268 | ENDIF |
|---|
| 269 | |
|---|
| 270 | END SUBROUTINE p4z_micro_init |
|---|
| 271 | |
|---|
| 272 | !!====================================================================== |
|---|
| 273 | END MODULE p4zmicro |
|---|
