New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in branches/CNRS/dev_r8832_PISCO/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r8832_PISCO/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zrem.F90 @ 9461

Last change on this file since 9461 was 9461, checked in by aumont, 6 years ago

bug fixes in iron cycle
File size: 18.7 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
11   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
12   !!   p4z_rem_alloc :  Allocate remineralisation variables
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zche          !  chemical model
18   USE p4zlim
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_rem         ! called in p4zbio.F90
27   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
28   PUBLIC   p4z_rem_alloc
29
30   !! * Shared module variables
31   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of DOC
32   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of DON
33   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of DOP
34   REAL(wp), PUBLIC ::  xremik     !: remineralisation rate of POC
35   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
36   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of POC
37   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of POC
38   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
39   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
40   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
41
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
43
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
46   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE p4z_rem( kt, knt )
52      !!---------------------------------------------------------------------
53      !!                     ***  ROUTINE p4z_rem  ***
54      !!
55      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
56      !!
57      !! ** Method  : - ???
58      !!---------------------------------------------------------------------
59      !
60      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
61      !
62      INTEGER  ::   ji, jj, jk
63      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
64      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
65      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
66      REAL(wp) ::   zammonic, zoxyrem
67      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
68      CHARACTER (len=25) :: charout
69      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac
70      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zolimi, zdepprod, zfacsi, zw3d, zfacsib
71      REAL(wp), POINTER, DIMENSION(:,:,:) :: zfebact, zdepeff
72      !!---------------------------------------------------------------------
73      !
74      IF( nn_timing == 1 )  CALL timing_start('p4z_rem')
75      !
76      ! Allocate temporary workspace
77      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
78      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi, zfacsi, zfacsib, zfebact, zdepeff )
79
80      ! Initialisation of temprary arrys
81      zdepprod(:,:,:) = 1._wp
82      zdepeff (:,:,:) = 0.3_wp
83      ztempbac(:,:)   = 0._wp
84      zfebact (:,:,:) = 0._wp
85      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
86      zfacsi(:,:,:)   = xsilab
87
88      ! Computation of the mean phytoplankton concentration as
89      ! a crude estimate of the bacterial biomass
90      ! this parameterization has been deduced from a model version
91      ! that was modeling explicitely bacteria
92      ! -------------------------------------------------------
93      DO jk = 1, jpkm1
94         DO jj = 1, jpj
95            DO ji = 1, jpi
96               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
97               IF( gdept_n(ji,jj,jk) < zdep ) THEN
98                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
99                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
100               ELSE
101                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
102                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
103                  zdepprod(ji,jj,jk) = zdepmin**0.273
104                  zdepeff (ji,jj,jk) = 0.3 * zdepmin**0.3
105               ENDIF
106            END DO
107         END DO
108      END DO
109
110      IF( ln_p4z ) THEN
111         DO jk = 1, jpkm1
112            DO jj = 1, jpj
113               DO ji = 1, jpi
114                  ! DOC ammonification. Depends on depth, phytoplankton biomass
115                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
116                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
117                  zremik = MAX( zremik, 2.74e-4 * xstep )
118                  ! Ammonification in oxic waters with oxygen consumption
119                  ! -----------------------------------------------------
120                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
121                  zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
122                  ! Ammonification in suboxic waters with denitrification
123                  ! -------------------------------------------------------
124                  zammonic = zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
125                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
126                  zoxyrem           = zammonic *        nitrfac2(ji,jj,jk)
127                  !
128                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
129                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
130                  zoxyrem           = MAX( 0.e0, zoxyrem  )
131
132                  !
133                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
134                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
135                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
136                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyrem
137                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
138                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyrem
139                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk) + zoxyrem    &
140                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
141               END DO
142            END DO
143         END DO
144      ELSE
145         DO jk = 1, jpkm1
146            DO jj = 1, jpj
147               DO ji = 1, jpi
148                  ! DOC ammonification. Depends on depth, phytoplankton biomass
149                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
150                  ! -----------------------------------------------------------------
151                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
152                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
153
154                  zremikc = xremikc * zremik
155                  zremikn = xremikn / xremikc
156                  zremikp = xremikp / xremikc
157
158                  ! Ammonification in oxic waters with oxygen consumption
159                  ! -----------------------------------------------------
160                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
161                  zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
162                  zolimi(ji,jj,jk) = zolimic
163                  zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
164                  zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
165
166                  ! Ammonification in suboxic waters with denitrification
167                  ! -------------------------------------------------------
168                  zolimit = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
169                  denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
170                  denitr(ji,jj,jk) = MAX( 0.e0, denitr(ji,jj,jk) )
171                  zdenitrn  = zremikn * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
172                  zdenitrp  = zremikp * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
173
174                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
175                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
176                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
177                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitr(ji,jj,jk)
178                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
179                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
180                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
181                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk)
182                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
183               END DO
184            END DO
185         END DO
186         !
187      ENDIF
188
189
190      DO jk = 1, jpkm1
191         DO jj = 1, jpj
192            DO ji = 1, jpi
193               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
194               ! below 2 umol/L. Inhibited at strong light
195               ! ----------------------------------------------------------
196               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
197               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
198               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
199               ! Update of the tracers trends
200               ! ----------------------------
201               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
202               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
203               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
204               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
205            END DO
206         END DO
207      END DO
208
209       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
210         WRITE(charout, FMT="('rem1')")
211         CALL prt_ctl_trc_info(charout)
212         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
213       ENDIF
214
215      DO jk = 1, jpkm1
216         DO jj = 1, jpj
217            DO ji = 1, jpi
218
219               ! Bacterial uptake of iron. No iron is available in DOC. So
220               ! Bacteries are obliged to take up iron from the water. Some
221               ! studies (especially at Papa) have shown this uptake to be significant
222               ! ----------------------------------------------------------
223               zbactfer = feratb *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
224                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
225                  &              * zdepprod(ji,jj,jk) * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk)
226               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.33
227               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.25
228               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.08
229               zfebact(ji,jj,jk)   = zbactfer * 0.33
230               blim(ji,jj,jk)      =  xlimbacl(ji,jj,jk) * zdepbac(ji,jj,jk) / 1.e-6 * zdepprod(ji,jj,jk)
231            END DO
232         END DO
233      END DO
234
235       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
236         WRITE(charout, FMT="('rem2')")
237         CALL prt_ctl_trc_info(charout)
238         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
239       ENDIF
240
241      ! Initialization of the array which contains the labile fraction
242      ! of bSi. Set to a constant in the upper ocean
243      ! ---------------------------------------------------------------
244
245      DO jk = 1, jpkm1
246         DO jj = 1, jpj
247            DO ji = 1, jpi
248               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
249               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
250               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
251               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
252               ! Remineralization rate of BSi depedant on T and saturation
253               ! ---------------------------------------------------------
254               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
255                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
256                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
257                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
258                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
259                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
260               ENDIF
261               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
262               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
263               !
264               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
265               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
266               !
267            END DO
268         END DO
269      END DO
270
271      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
272         WRITE(charout, FMT="('rem3')")
273         CALL prt_ctl_trc_info(charout)
274         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
275       ENDIF
276
277      IF( knt == nrdttrc ) THEN
278          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
279          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
280          !
281          IF( iom_use( "REMIN" ) )  THEN
282              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
283              CALL iom_put( "REMIN"  , zw3d )
284          ENDIF
285          IF( iom_use( "DENIT" ) )  THEN
286              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
287              CALL iom_put( "DENIT"  , zw3d )
288          ENDIF
289          !
290          IF( iom_use( "BACT" ) )  THEN
291               zw3d(:,:,:) = zdepbac(:,:,:) * 1.E6 * tmask(:,:,:)  ! Bacterial biomass
292               CALL iom_put( "BACT", zw3d )
293          ENDIF
294          IF( iom_use( "FEBACT" ) )  THEN
295               zw3d(:,:,:) = zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2   ! Bacterial iron consumption
296               CALL iom_put( "FEBACT" , zw3d ) 
297          ENDIF
298          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
299       ENDIF
300      !
301      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
302      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi, zfacsi, zfacsib, zfebact, zdepeff )
303      !
304      IF( nn_timing == 1 )  CALL timing_stop('p4z_rem')
305      !
306   END SUBROUTINE p4z_rem
307
308
309   SUBROUTINE p4z_rem_init
310      !!----------------------------------------------------------------------
311      !!                  ***  ROUTINE p4z_rem_init  ***
312      !!
313      !! ** Purpose :   Initialization of remineralization parameters
314      !!
315      !! ** Method  :   Read the nampisrem namelist and check the parameters
316      !!      called at the first timestep
317      !!
318      !! ** input   :   Namelist nampisrem
319      !!
320      !!----------------------------------------------------------------------
321      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
322         &                xremikc, xremikn, xremikp
323      INTEGER :: ios                 ! Local integer output status for namelist read
324
325      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
326      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
327901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
328
329      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
330      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
331902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
332      IF(lwm) WRITE ( numonp, nampisrem )
333
334      IF(lwp) THEN                         ! control print
335         WRITE(numout,*) ' '
336         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
337         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
338         IF( ln_p4z ) THEN
339            WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
340         ELSE
341            WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
342            WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
343            WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
344         ENDIF
345         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
346         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
347         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
348         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
349         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
350         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
351      ENDIF
352      !
353      denitr  (:,:,:) = 0._wp
354      !
355   END SUBROUTINE p4z_rem_init
356
357
358   INTEGER FUNCTION p4z_rem_alloc()
359      !!----------------------------------------------------------------------
360      !!                     ***  ROUTINE p4z_rem_alloc  ***
361      !!----------------------------------------------------------------------
362      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
363      !
364      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
365      !
366   END FUNCTION p4z_rem_alloc
367
368   !!======================================================================
369END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.