New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in branches/CNRS/dev_r8832_PISCO/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r8832_PISCO/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zprod.F90 @ 9450

Last change on this file since 9450 was 9450, checked in by aumont, 6 years ago

debug PISCES code
  • Property svn:executable set to *
File size: 37.7 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
12   !!   p5z_prod_init  :   Initialization of the parameters for growth
13   !!   p5z_prod_alloc :   Allocate variables for growth
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE p4zlim          !  Co-limitations of differents nutrients
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p5z_prod         ! called in p5zbio.F90
26   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
27   PUBLIC   p5z_prod_alloc
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC ::  pislopen        !:
31   REAL(wp), PUBLIC ::  pislopep        !:
32   REAL(wp), PUBLIC ::  pisloped        !:
33   REAL(wp), PUBLIC ::  xadap           !:
34   REAL(wp), PUBLIC ::  excretn         !:
35   REAL(wp), PUBLIC ::  excretp         !:
36   REAL(wp), PUBLIC ::  excretd         !:
37   REAL(wp), PUBLIC ::  bresp           !:
38   REAL(wp), PUBLIC ::  thetanpm        !:
39   REAL(wp), PUBLIC ::  thetannm        !:
40   REAL(wp), PUBLIC ::  thetandm        !:
41   REAL(wp), PUBLIC ::  chlcmin         !:
42   REAL(wp), PUBLIC ::  grosip          !:
43
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxn   !: optimal production = f(temperature)
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxp   !: optimal production = f(temperature)
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxd   !: optimal production = f(temperature)
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen
48   
49   REAL(wp) :: r1_rday                !: 1 / rday
50   REAL(wp) :: texcretn               !: 1 - excret
51   REAL(wp) :: texcretp               !: 1 - excretp
52   REAL(wp) :: texcretd               !: 1 - excret2       
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
57   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE p5z_prod( kt , knt )
62      !!---------------------------------------------------------------------
63      !!                     ***  ROUTINE p5z_prod  ***
64      !!
65      !! ** Purpose :   Compute the phytoplankton production depending on
66      !!              light, temperature and nutrient availability
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      !
71      INTEGER, INTENT(in) :: kt, knt
72      !
73      INTEGER  ::   ji, jj, jk
74      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
75      REAL(wp) ::   zration, zratiop, zratiof, zmax, zmax2, zsilim, ztn, zadap
76      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zrat
77      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
78      REAL(wp) ::   zprnutmax, zdocprod, zprochln, zprochld, zprochlp
79      REAL(wp) ::   zpislopen, zpislopep, zpisloped, thetannm_n, thetandm_n, thetanpm_n
80      REAL(wp) ::   zratiosi, zquotasi, grosip2
81      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup
82      REAL(wp) ::   zfact, zrfact2
83      CHARACTER (len=25) :: charout
84      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixpico, zmixdiat, zstrn
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopeadn, zpislopeadp, zpislopeadd
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprbio, zprpic, zprdia, zysopt
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprchln, zprchlp, zprchld
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcap, zprorcad 
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprofed, zprofep, zprofen
90      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpronewn, zpronewp, zpronewd
91      REAL(wp), POINTER, DIMENSION(:,:,:) :: zproregn, zproregp, zproregd
92      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpropo4n, zpropo4p, zpropo4d
93      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprodopn, zprodopp, zprodopd
94      REAL(wp), POINTER, DIMENSION(:,:,:) :: zrespn, zrespp, zrespd, zprnut
95      REAL(wp), POINTER, DIMENSION(:,:,:) :: zcroissn, zcroissp, zcroissd
96      REAL(wp), POINTER, DIMENSION(:,:,:) :: zmxl_fac, zmxl_chl
97      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpligprod1, zpligprod2
98      REAL(wp), POINTER, DIMENSION(:,:,:) :: zw3d
99      REAL(wp), POINTER, DIMENSION(:,:  ) :: zw2d
100      !!---------------------------------------------------------------------
101      !
102      IF( nn_timing == 1 )  CALL timing_start('p5z_prod')
103      !
104      !  Allocate temporary workspace
105      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
106      CALL wrk_alloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
107      CALL wrk_alloc( jpi, jpj, jpk, zpislopeadn, zpislopeadp, zpislopeadd, zysopt ) 
108      CALL wrk_alloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
109      CALL wrk_alloc( jpi, jpj, jpk, zprofed, zprofep, zprofen )
110      CALL wrk_alloc( jpi, jpj, jpk, zpronewn, zpronewp, zpronewd, zproregn, zproregp, zproregd )
111      CALL wrk_alloc( jpi, jpj, jpk, zpropo4n, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
112      CALL wrk_alloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
113      CALL wrk_alloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
114      IF( ln_ligand ) THEN
115         CALL wrk_alloc( jpi, jpj, jpk, zpligprod1, zpligprod2 )
116      ENDIF
117      !
118      zprorcan(:,:,:) = 0._wp ; zprorcap(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp
119      zprofed (:,:,:) = 0._wp ; zprofep (:,:,:) = 0._wp ; zprofen (:,:,:) = 0._wp
120      zpronewn(:,:,:) = 0._wp ; zpronewp(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp
121      zproregn(:,:,:) = 0._wp ; zproregp(:,:,:) = 0._wp ; zproregd(:,:,:) = 0._wp 
122      zpropo4n(:,:,:) = 0._wp ; zpropo4p(:,:,:) = 0._wp ; zpropo4d(:,:,:) = 0._wp
123      zprdia  (:,:,:) = 0._wp ; zprpic  (:,:,:) = 0._wp ; zprbio  (:,:,:) = 0._wp
124      zysopt  (:,:,:) = 0._wp
125      zrespn  (:,:,:) = 0._wp ; zrespp  (:,:,:) = 0._wp ; zrespd  (:,:,:) = 0._wp 
126
127      ! Computation of the optimal production
128      prmaxn(:,:,:) = ( 0.8_wp * (1. + zpsino3 * qnpmax ) ) * r1_rday * tgfunc(:,:,:)
129      prmaxp(:,:,:) = 0.5 / 0.8 * prmaxn(:,:,:) 
130      prmaxd(:,:,:) = prmaxn(:,:,:) 
131      zprnut(:,:,:) = 0.8_wp * r1_rday * tgfunc(:,:,:)
132
133      ! Assign the reference growth rate used in implicit formulations
134      prmax(:,:,:)  = zprnut(:,:,:)
135
136      ! compute the day length depending on latitude and the day
137      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
138      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
139
140      ! day length in hours
141      zstrn(:,:) = 0.
142      DO jj = 1, jpj
143         DO ji = 1, jpi
144            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
145            zargu = MAX( -1., MIN(  1., zargu ) )
146            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
147         END DO
148      END DO
149
150         ! Impact of the day duration on phytoplankton growth
151      DO jk = 1, jpkm1
152         DO jj = 1 ,jpj
153            DO ji = 1, jpi
154               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
155                  zval = MAX( 1., zstrn(ji,jj) )
156                  IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
157                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
158                  ENDIF
159                  zmxl_chl(ji,jj,jk) = zval / 24.
160                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
161               ENDIF
162            END DO
163         END DO
164      END DO
165
166      zprbio(:,:,:) = prmaxn(:,:,:) * zmxl_fac(:,:,:)
167      zprdia(:,:,:) = prmaxd(:,:,:) * zmxl_fac(:,:,:)
168      zprpic(:,:,:) = prmaxp(:,:,:) * zmxl_fac(:,:,:)
169
170
171      ! Maximum light intensity
172      zdaylen(:,:) = MAX(1., zstrn(:,:)) / 24.
173      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
174
175      DO jk = 1, jpkm1
176         DO jj = 1, jpj
177            DO ji = 1, jpi
178               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
179                  ! Computation of the P-I slope for nanos and diatoms
180                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
181                  zadap       = xadap * ztn / ( 2.+ ztn )
182                  !
183                  zpislopeadn(ji,jj,jk) = pislopen * trb(ji,jj,jk,jpnch)    &
184                  &                       /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
185                  zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.25 * epico(ji,jj,jk) ) )   &
186                  &                       * trb(ji,jj,jk,jppch) /( trb(ji,jj,jk,jppic) * 12. + rtrn)
187                  zpislopeadd(ji,jj,jk) = pisloped * trb(ji,jj,jk,jpdch)    &
188                     &                    /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
189                  !
190                  zpislopen = zpislopeadn(ji,jj,jk) / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
191                  zpislopep = zpislopeadp(ji,jj,jk) / ( zprpic(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
192                  zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
193
194                  ! Computation of production function for Carbon
195                  !  ---------------------------------------------
196                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
197                  zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) )  )
198                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
199
200                  ! Computation of production function for Chlorophyll
201                  !  -------------------------------------------------
202                  zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
203                  zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
204                  zpislopep = zpislopep * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
205                  zprchln(ji,jj,jk) = prmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
206                  zprchlp(ji,jj,jk) = prmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) )  )
207                  zprchld(ji,jj,jk) = prmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
208               ENDIF
209            END DO
210         END DO
211      END DO
212
213      DO jk = 1, jpkm1
214         DO jj = 1, jpj
215            DO ji = 1, jpi
216
217                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
218                  !    Si/C of diatoms
219                  !    ------------------------
220                  !    Si/C increases with iron stress and silicate availability
221                  !    Si/C is arbitrariliy increased for very high Si concentrations
222                  !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
223                  IF (gphit(ji,jj) < -30 ) THEN
224                    zsilfac2 = 1. + zsiborn / ( zsiborn + xksi2**3 )
225                  ELSE
226                    zsilfac2 = 1. 
227                  ENDIF
228                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmaxd(ji,jj,jk) + rtrn ), xlimsi2(ji,jj,jk) )
229                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
230                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
231                  zratiosi = trb(ji,jj,jk,jpndi)
232                  grosip2 = zsilfac2 * grosip
233                  zquotasi = MIN( grosip2, trn(ji,jj,jk,jpdsi) / (zratiosi + rtrn ) )
234                  zysopt(ji,jj,jk) = 1./3. * zratiosi * zlim * MAX(0.0, grosip2 - zquotasi)
235                  zysopt(ji,jj,jk) = zysopt(ji,jj,jk) * 1.005 * zsilim**3 / (0.005 + zsilim**3 )
236              ENDIF
237            END DO
238         END DO
239      END DO
240
241      !  Sea-ice effect on production                                                                               
242      DO jk = 1, jpkm1
243         DO jj = 1, jpj
244            DO ji = 1, jpi
245               zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
246               zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
247               zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
248               zprnut(ji,jj,jk)  = zprnut(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
249            END DO
250         END DO
251      END DO
252
253      ! Computation of the various production terms of nanophytoplankton
254      DO jk = 1, jpkm1
255         DO jj = 1, jpj
256            DO ji = 1, jpi
257               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
258                  !  production terms for nanophyto.
259                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
260                  !
261                  zration = trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn )
262                  zratiop = trb(ji,jj,jk,jppph) / ( trb(ji,jj,jk,jpphy) + rtrn )
263                  zratiof = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
264                  zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpphy) * rfact2
265                  ! Uptake of nitrogen
266                  zrat = MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) ) 
267                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
268                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
269                  &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) + rtrn ), xlimnfe(ji,jj,jk) ) )
270                  zpronewn(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xnanono3(ji,jj,jk)
271                  zproregn(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
272                  ! Uptake of phosphorus
273                  zrat = MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
274                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
275                  zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk)
276                  zpropo4n(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
277                  zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
278                  ! Uptake of iron
279                  zrat = MIN( 1., zratiof / qfnmax )
280                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
281                  zprofmax = zprnutmax * qfnmax * zmax
282                  zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk) * ( 3. - 2.4 * xlimnfe(ji,jj,jk)    &
283                  &          / ( xlimnfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
284                  &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
285               ENDIF
286            END DO
287         END DO
288      END DO
289
290      ! Computation of the various production terms of picophytoplankton
291      DO jk = 1, jpkm1
292         DO jj = 1, jpj
293            DO ji = 1, jpi
294               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
295                  !  production terms for picophyto.
296                  zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * trb(ji,jj,jk,jppic) * rfact2
297                  !
298                  zration = trb(ji,jj,jk,jpnpi) / ( trb(ji,jj,jk,jppic) + rtrn )
299                  zratiop = trb(ji,jj,jk,jpppi) / ( trb(ji,jj,jk,jppic) + rtrn )
300                  zratiof = trb(ji,jj,jk,jppfe) / ( trb(ji,jj,jk,jppic) + rtrn )
301                  zprnutmax = zprnut(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jppic) * rfact2
302                  ! Uptake of nitrogen
303                  zrat = MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
304                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
305                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
306                  &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) + rtrn ), xlimpfe(ji,jj,jk) ) )
307                  zpronewp(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xpicono3(ji,jj,jk) 
308                  zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
309                  ! Uptake of phosphorus
310                  zrat = MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
311                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
312                  zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk)
313                  zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
314                  zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
315                  ! Uptake of iron
316                  zrat = MIN( 1., zratiof / qfpmax )
317                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
318                  zprofmax = zprnutmax * qfpmax * zmax
319                  zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk) * ( 3. - 2.4 * xlimpfe(ji,jj,jk)   &
320                  &          / ( xlimpfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
321                  &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
322               ENDIF
323            END DO
324         END DO
325      END DO
326
327      ! Computation of the various production terms of diatoms
328      DO jk = 1, jpkm1
329         DO jj = 1, jpj
330            DO ji = 1, jpi
331               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
332                  !  production terms for diatomees
333                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
334                  ! Computation of the respiration term according to pahlow
335                  ! & oschlies (2013)
336                  !
337                  zration = trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn )
338                  zratiop = trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn )
339                  zratiof = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
340                  zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpdia) * rfact2
341                  ! Uptake of nitrogen
342                  zrat = MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
343                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
344                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
345                  &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) ) )
346                  zpronewd(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xdiatno3(ji,jj,jk)
347                  zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
348                  ! Uptake of phosphorus
349                  zrat = MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
350                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
351                  zpropmax = zprnutmax * zmax * xlimsi(ji,jj,jk)
352                  zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
353                  zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
354                  ! Uptake of iron
355                  zrat = MIN( 1., zratiof / qfdmax )
356                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
357                  zprofmax = zprnutmax * qfdmax * zmax
358                  zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk) * ( 3. - 2.4 * xlimdfe(ji,jj,jk)     &
359                  &          / ( xlimdfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
360                  &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
361               ENDIF
362            END DO
363         END DO
364      END DO
365
366      DO jk = 1, jpkm1
367         DO jj = 1, jpj
368            DO ji = 1, jpi
369               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
370                     !  production terms for nanophyto. ( chlorophyll )
371                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
372                  zprod = rday * (zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
373                  thetannm_n   = MIN ( thetannm, ( thetannm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
374                  &               * (1. - 1.14 / 43.4 * 20.))
375                  thetannm_n = thetannm
376                  zprochln = thetannm_n * zprod / ( zpislopeadn(ji,jj,jk) * znanotot + rtrn )
377                  zprochln = MAX(zprochln, chlcmin * 12. * zprorcan (ji,jj,jk) )
378                     !  production terms for picophyto. ( chlorophyll )
379                  zpicotot = epico(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
380                  zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
381                  thetanpm_n   = MIN ( thetanpm, ( thetanpm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
382                  &               * (1. - 1.14 / 43.4 * 20.))
383                  thetanpm_n = thetanpm
384                  zprochlp = thetanpm_n * zprod / ( zpislopeadp(ji,jj,jk) * zpicotot + rtrn )
385                  zprochlp = MAX(zprochlp, chlcmin * 12. * zprorcap(ji,jj,jk) )
386                  !  production terms for diatomees ( chlorophyll )
387                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
388                  zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
389                  thetandm_n   = MIN ( thetandm, ( thetandm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
390                  &               * (1. - 1.14 / 43.4 * 20.))
391                  thetandm_n = thetandm
392                  zprochld = thetandm_n * zprod / ( zpislopeadd(ji,jj,jk) * zdiattot + rtrn )
393                  zprochld = MAX(zprochld, chlcmin * 12. * zprorcad(ji,jj,jk) )
394                  !   Update the arrays TRA which contain the Chla sources and sinks
395                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
396                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
397                  tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) + zprochlp * texcretp
398               ENDIF
399            END DO
400         END DO
401      END DO
402
403      !   Update the arrays TRA which contain the biological sources and sinks
404      DO jk = 1, jpkm1
405         DO jj = 1, jpj
406           DO ji =1 ,jpi
407              zprontot = zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)
408              zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
409              zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
410              zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
411              &          + excretp * zprorcap(ji,jj,jk)
412              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zpropo4n(ji,jj,jk) - zpropo4d(ji,jj,jk)  &
413              &                     - zpropo4p(ji,jj,jk)
414              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)  &
415              &                     - zpronewp(ji,jj,jk)
416              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproregn(ji,jj,jk) - zproregd(ji,jj,jk)  &
417              &                     - zproregp(ji,jj,jk)
418              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn    &
419                 &                  - zpsino3 * zpronewn(ji,jj,jk) - zpsinh4 * zproregn(ji,jj,jk)   &
420                 &                  - zrespn(ji,jj,jk) 
421              zcroissn(ji,jj,jk) = tra(ji,jj,jk,jpphy) / rfact2/ (trb(ji,jj,jk,jpphy) + rtrn)
422              tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) + zprontot * texcretn
423              tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) + zpropo4n(ji,jj,jk) * texcretn   &
424              &                     + zprodopn(ji,jj,jk) * texcretn
425              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
426              tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) + zprorcap(ji,jj,jk) * texcretp     &
427                 &                  - zpsino3 * zpronewp(ji,jj,jk) - zpsinh4 * zproregp(ji,jj,jk)   &
428                 &                  - zrespp(ji,jj,jk) 
429              zcroissp(ji,jj,jk) = tra(ji,jj,jk,jppic) / rfact2/ (trb(ji,jj,jk,jppic) + rtrn)
430              tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) + zproptot * texcretp
431              tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) + zpropo4p(ji,jj,jk) * texcretp   &
432              &                     + zprodopp(ji,jj,jk) * texcretp
433              tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) + zprofep(ji,jj,jk) * texcretp
434              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd   &
435                 &                  - zpsino3 * zpronewd(ji,jj,jk) - zpsinh4 * zproregd(ji,jj,jk)   &
436                 &                  - zrespd(ji,jj,jk) 
437              zcroissd(ji,jj,jk) = tra(ji,jj,jk,jpdia) / rfact2 / (trb(ji,jj,jk,jpdia) + rtrn)
438              tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) + zprodtot * texcretd
439              tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) + zpropo4d(ji,jj,jk) * texcretd   &
440              &                     + zprodopd(ji,jj,jk) * texcretd
441              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
442              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
443              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
444              &                     + excretp * zprorcap(ji,jj,jk)
445              tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + excretd * zprodtot + excretn * zprontot   &
446              &                     + excretp * zproptot
447              tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + excretd * zpropo4d(ji,jj,jk) + excretn * zpropo4n(ji,jj,jk)   &
448              &    - texcretn * zprodopn(ji,jj,jk) - texcretd * zprodopd(ji,jj,jk) + excretp * zpropo4p(ji,jj,jk)     &
449              &    - texcretp * zprodopp(ji,jj,jk)
450              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)   &
451                 &                + zproregp(ji,jj,jk) ) + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk)           &
452                 &                + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk) )   &
453                 &                - o2ut * ( zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) )
454              zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
455              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
456              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
457              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) - zprorcap(ji,jj,jk)  &
458              &                     + zpsino3 * zpronewn(ji,jj,jk) + zpsinh4 * zproregn(ji,jj,jk)   &
459              &                     + zpsino3 * zpronewp(ji,jj,jk) + zpsinh4 * zproregp(ji,jj,jk)   &
460              &                     + zpsino3 * zpronewd(ji,jj,jk) + zpsinh4 * zproregd(ji,jj,jk)  &
461              &                     + zrespn(ji,jj,jk) + zrespd(ji,jj,jk) + zrespp(ji,jj,jk) 
462              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk)  &
463              &                     + zpronewp(ji,jj,jk) ) - rno3 * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)     &
464              &                     + zproregp(ji,jj,jk) ) 
465          END DO
466        END DO
467     END DO
468     !
469     IF( ln_ligand ) THEN
470         DO jk = 1, jpkm1
471            DO jj = 1, jpj
472              DO ji =1 ,jpi
473                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) + excretp * zprorcap(ji,jj,jk)
474                 zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
475                 tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
476                 zpligprod1(ji,jj,jk) = zdocprod * ldocp
477                 zpligprod2(ji,jj,jk) = zfeup * plig(ji,jj,jk) * lthet
478              END DO
479           END DO
480        END DO
481     ENDIF
482
483
484     ! Total primary production per year
485
486    ! Total primary production per year
487    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
488      & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
489
490    IF( lk_iomput ) THEN
491       IF( knt == nrdttrc ) THEN
492          CALL wrk_alloc( jpi, jpj,      zw2d )
493          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
494          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
495          !
496          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) .OR. iom_use( "PPPHYP" ) )  THEN
497              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
498              CALL iom_put( "PPPHYN"  , zw3d )
499              !
500              zw3d(:,:,:) = zprorcap(:,:,:) * zfact * tmask(:,:,:)  ! primary production by picophyto
501              CALL iom_put( "PPPHYP"  , zw3d )
502              !
503              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
504              CALL iom_put( "PPPHYD"  , zw3d )
505          ENDIF
506          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) .OR. iom_use( "PPNEWP" ) )  THEN
507              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
508              CALL iom_put( "PPNEWN"  , zw3d )
509              !
510              zw3d(:,:,:) = zpronewp(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by picophyto
511              CALL iom_put( "PPNEWP"  , zw3d )
512              !
513              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
514              CALL iom_put( "PPNEWD"  , zw3d )
515          ENDIF
516          IF( iom_use( "PBSi" ) )  THEN
517              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
518              CALL iom_put( "PBSi"  , zw3d )
519          ENDIF
520          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) .OR. iom_use( "PFeP" ) )  THEN
521              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
522              CALL iom_put( "PFeN"  , zw3d )
523              !
524              zw3d(:,:,:) = zprofep(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by picophyto
525              CALL iom_put( "PFeP"  , zw3d )
526              !
527              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
528              CALL iom_put( "PFeD"  , zw3d )
529          ENDIF
530          IF( iom_use( "Mumax" ) )  THEN
531              zw3d(:,:,:) = prmaxn(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
532              CALL iom_put( "Mumax"  , zw3d )
533          ENDIF
534          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) .OR. iom_use( "MuP" ) )  THEN
535              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
536              CALL iom_put( "MuN"  , zw3d )
537              !
538              zw3d(:,:,:) = zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:)  ! Realized growth rate for picophyto
539              CALL iom_put( "MuP"  , zw3d )
540              !
541              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
542              CALL iom_put( "MuD"  , zw3d )
543          ENDIF
544          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) .OR. iom_use( "LPlight" ) )  THEN
545              zw3d(:,:,:) = zprbio (:,:,:) / (prmaxn(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
546              CALL iom_put( "LNlight"  , zw3d )
547              !
548              zw3d(:,:,:) = zprpic (:,:,:) / (prmaxp(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
549              CALL iom_put( "LPlight"  , zw3d )
550              !
551              zw3d(:,:,:) =  zprdia (:,:,:) / (prmaxd(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
552              CALL iom_put( "LDlight"  , zw3d )
553          ENDIF
554          IF( iom_use( "MunetN" ) .OR. iom_use( "MunetD" ) .OR. iom_use( "MunetP" ) )  THEN
555              zw3d(:,:,:) = zcroissn(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for nanophyto
556              CALL iom_put( "MunetN"  , zw3d )
557              !
558              zw3d(:,:,:) = zcroissp(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for picophyto
559              CALL iom_put( "MunetP"  , zw3d )
560              !
561              zw3d(:,:,:) = zcroissd(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for diatomes
562              CALL iom_put( "MunetD"  , zw3d )
563              !
564          ENDIF
565          IF( iom_use( "LPRODP" ) )  THEN
566              zw3d(:,:,:) = zpligprod1(:,:,:) * 1e9 * zfact * tmask(:,:,:)
567              CALL iom_put( "LPRODP"  , zw3d )
568          ENDIF
569          IF( iom_use( "LDETP" ) )  THEN
570              zw3d(:,:,:) = zpligprod2(:,:,:) * 1e9 * zfact * tmask(:,:,:)
571              CALL iom_put( "LDETP"  , zw3d )
572          ENDIF
573          !
574          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
575          !
576          CALL wrk_dealloc( jpi, jpj,      zw2d )
577          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
578       ENDIF
579     ENDIF
580
581      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
582         WRITE(charout, FMT="('prod')")
583         CALL prt_ctl_trc_info(charout)
584         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
585      ENDIF
586      !
587      CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
588      CALL wrk_dealloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
589      CALL wrk_dealloc( jpi, jpj, jpk, zpislopeadn, zpislopeadp, zpislopeadd, zysopt )                           
590      CALL wrk_dealloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
591      CALL wrk_dealloc( jpi, jpj, jpk, zprofed, zprofep, zprofen ) 
592      CALL wrk_dealloc( jpi, jpj, jpk, zpronewn, zpronewp, zpronewd, zproregn, zproregp, zproregd )
593      CALL wrk_dealloc( jpi, jpj, jpk, zpropo4n, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
594      CALL wrk_dealloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
595      CALL wrk_dealloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
596      IF( ln_ligand ) THEN
597         CALL wrk_dealloc( jpi, jpj, jpk, zpligprod1, zpligprod2 )
598      ENDIF
599      !
600      IF( nn_timing == 1 )  CALL timing_stop('p5z_prod')
601      !
602   END SUBROUTINE p5z_prod
603
604
605   SUBROUTINE p5z_prod_init
606      !!----------------------------------------------------------------------
607      !!                  ***  ROUTINE p5z_prod_init  ***
608      !!
609      !! ** Purpose :   Initialization of phytoplankton production parameters
610      !!
611      !! ** Method  :   Read the nampisprod namelist and check the parameters
612      !!      called at the first timestep (nittrc000)
613      !!
614      !! ** input   :   Namelist nampisprod
615      !!----------------------------------------------------------------------
616      !
617      NAMELIST/namp5zprod/ pislopen, pislopep, pisloped, excretn, excretp, excretd,     &
618         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, bresp, xadap
619
620      INTEGER :: ios                 ! Local integer output status for namelist read
621      !!----------------------------------------------------------------------
622
623      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
624      READ  ( numnatp_ref, namp5zprod, IOSTAT = ios, ERR = 901)
625901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in reference namelist', lwp )
626
627      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
628      READ  ( numnatp_cfg, namp5zprod, IOSTAT = ios, ERR = 902 )
629902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in configuration namelist', lwp )
630      IF(lwm) WRITE ( numonp, namp5zprod )
631
632      IF(lwp) THEN                         ! control print
633         WRITE(numout,*) ' '
634         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp5zprod'
635         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
636         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
637         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
638         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
639         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
640         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
641         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
642         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
643         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
644         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
645         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
646         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
647         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
648         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
649      ENDIF
650      !
651      r1_rday   = 1._wp / rday 
652      texcretn  = 1._wp - excretn
653      texcretp  = 1._wp - excretp
654      texcretd  = 1._wp - excretd
655      tpp       = 0._wp
656      !
657   END SUBROUTINE p5z_prod_init
658
659
660   INTEGER FUNCTION p5z_prod_alloc()
661      !!----------------------------------------------------------------------
662      !!                     ***  ROUTINE p5z_prod_alloc  ***
663      !!----------------------------------------------------------------------
664      ALLOCATE( prmaxn(jpi,jpj,jpk), prmaxp(jpi,jpj,jpk), prmaxd(jpi,jpj,jpk),  &
665      &          zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
666      !
667      IF( p5z_prod_alloc /= 0 ) CALL ctl_warn('p5z_prod_alloc : failed to allocate arrays.')
668      !
669   END FUNCTION p5z_prod_alloc
670   !!======================================================================
671END MODULE  p5zprod
Note: See TracBrowser for help on using the repository browser.