New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/DEV_r1784_3DF/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r1784_3DF/NEMO/OPA_SRC/TRA/traqsr.F90 @ 1806

Last change on this file since 1806 was 1806, checked in by cbricaud, 14 years ago

developement that is running with running with nemoref on 19022010

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 21.9 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_qsr      : trend due to the solar radiation penetration
16   !!   tra_qsr_init : solar radiation penetration initialization
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and active tracers
19   USE dom_oce         ! ocean space and time domain
20   USE sbc_oce         ! surface boundary condition: ocean
21   USE trc_oce         ! share SMS/Ocean variables
22   USE trdmod_oce      ! ocean variables trends
23   USE trdmod          ! ocean active tracers trends
24   USE in_out_manager  ! I/O manager
25   USE phycst          ! physical constants
26   USE prtctl          ! Print control
27   USE iom             ! I/O manager
28   USE fldread         ! read input fields
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_qsr        ! routine called by step.F90 (ln_traqsr=T)
34
35   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
36   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
37   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
38   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
39   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
40   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
41   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
42   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
43   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
44   REAL(wp), PUBLIC ::   rn_si2     = 61.8_wp   !: deepest depth of extinction (blue & 0.01 mg.m-3)     (RGB)
45   
46   ! Module variables
47   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
48   INTEGER ::   nksr   ! levels below which the light cannot penetrate ( depth larger than 391 m)
49   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
50
51   !! * Substitutions
52#  include "domzgr_substitute.h90"
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
56   !! $Id$
57   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE tra_qsr( kt )
63      !!----------------------------------------------------------------------
64      !!                  ***  ROUTINE tra_qsr  ***
65      !!
66      !! ** Purpose :   Compute the temperature trend due to the solar radiation
67      !!      penetration and add it to the general temperature trend.
68      !!
69      !! ** Method  : The profile of the solar radiation within the ocean is defined
70      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
71      !!      Considering the 2 wavebands case:
72      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
73      !!         The temperature trend associated with the solar radiation penetration
74      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
75      !!         At the bottom, boudary condition for the radiation is no flux :
76      !!      all heat which has not been absorbed in the above levels is put
77      !!      in the last ocean level.
78      !!         In z-coordinate case, the computation is only done down to the
79      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
80      !!      used for the computation are calculated one for once as they
81      !!      depends on k only.
82      !!
83      !! ** Action  : - update ta with the penetrative solar radiation trend
84      !!              - save the trend in ttrd ('key_trdtra')
85      !!
86      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
87      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
88      !!----------------------------------------------------------------------
89      USE oce, ONLY :   ztrdt => ua   ! use ua as 3D workspace   
90      USE oce, ONLY :   ztrds => va   ! use va as 3D workspace   
91      !!
92      INTEGER, INTENT(in) ::   kt     ! ocean time-step
93      !!
94      INTEGER  ::   ji, jj, jk           ! dummy loop indices
95      INTEGER  ::   irgb                 ! temporary integers
96      REAL(wp) ::   zchl, zcoef, zsi0r   ! temporary scalars
97      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
98      REAL(wp), DIMENSION(jpi,jpj)     ::   zekb, zekg, zekr            ! 2D workspace
99      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze0, ze1 , ze2, ze3, zea    ! 3D workspace
100      !!----------------------------------------------------------------------
101
102      IF( kt == nit000 ) THEN
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
105         IF(lwp) WRITE(numout,*) '~~~~~~~'
106         CALL tra_qsr_init
107         IF( .NOT.ln_traqsr )   RETURN
108      ENDIF
109
110      IF( l_trdtra ) THEN      ! Save ta and sa trends
111         ztrdt(:,:,:) = ta(:,:,:) 
112         ztrds(:,:,:) = 0.e0
113      ENDIF
114
115     
116      !                                           ! ============================================== !
117      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
118         !                                        ! ============================================== !
119         DO jk = 1, jpkm1
120            DO jj = 2, jpjm1
121               DO ji = fs_2, fs_jpim1   ! vector opt.
122                  ta(ji,jj,jk) = ta(ji,jj,jk) + ro0cpr * ( etot3(ji,jj,jk) - etot3(ji,jj,jk+1) ) / fse3t(ji,jj,jk) 
123               END DO
124            END DO
125         END DO
126         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
127         !                                        ! ============================================== !
128      ELSE                                        !  Ocean alone :
129         !                                        ! ============================================== !
130         !
131         !                                                ! ------------------------- !
132         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
133            !                                             ! ------------------------- !
134            ! Set chlorophyl concentration
135            IF( nn_chldta ==1 ) THEN                             !*  Variable Chlorophyll
136               !
137               CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
138               !         
139!CDIR COLLAPSE
140!CDIR NOVERRCHK
141               DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
142!CDIR NOVERRCHK
143                  DO ji = 1, jpi
144                     zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
145                     irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
146                     zekb(ji,jj) = rkrgb(1,irgb)
147                     zekg(ji,jj) = rkrgb(2,irgb)
148                     zekr(ji,jj) = rkrgb(3,irgb)
149                  END DO
150               END DO
151               !
152               zsi0r = 1.e0 / rn_si0
153               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
154               ze0(:,:,1) = rn_abs  * qsr(:,:)
155               ze1(:,:,1) = zcoef * qsr(:,:)
156               ze2(:,:,1) = zcoef * qsr(:,:)
157               ze3(:,:,1) = zcoef * qsr(:,:)
158               zea(:,:,1) =         qsr(:,:)
159               !
160               DO jk = 2, nksr+1
161!CDIR NOVERRCHK
162                  DO jj = 1, jpj
163!CDIR NOVERRCHK   
164                     DO ji = 1, jpi
165                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r     )
166                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
167                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
168                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
169                        ze0(ji,jj,jk) = zc0
170                        ze1(ji,jj,jk) = zc1
171                        ze2(ji,jj,jk) = zc2
172                        ze3(ji,jj,jk) = zc3
173                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
174                     END DO
175                  END DO
176               END DO
177               !
178               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
179                  ta(:,:,jk) = ta(:,:,jk) + ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) / fse3t(:,:,jk)
180               END DO
181               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
182               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
183               !
184            ELSE                                                 !*  Constant Chlorophyll
185               DO jk = 1, nksr
186                  ta(:,:,jk) = ta(:,:,jk) + etot3(:,:,jk) * qsr(:,:)
187               END DO
188            ENDIF
189
190         ENDIF
191         !                                                ! ------------------------- !
192         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
193            !                                             ! ------------------------- !
194            !
195            DO jk = 1, nksr
196               DO jj = 2, jpjm1
197                  DO ji = fs_2, fs_jpim1   ! vector opt.
198                     ta(ji,jj,jk) = ta(ji,jj,jk) + etot3(ji,jj,jk) * qsr(ji,jj)
199                  END DO
200               END DO
201            END DO
202            !
203         ENDIF
204         !
205      ENDIF
206
207      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
208         ztrdt(:,:,:) = ta(:,:,:) - ztrdt(:,:,:)
209         CALL trd_mod( ztrdt, ztrds, jptra_trd_qsr, 'TRA', kt )
210      ENDIF
211      !                       ! print mean trends (used for debugging)
212      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ta, clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
213      !
214   END SUBROUTINE tra_qsr
215
216
217   SUBROUTINE tra_qsr_init
218      !!----------------------------------------------------------------------
219      !!                  ***  ROUTINE tra_qsr_init  ***
220      !!
221      !! ** Purpose :   Initialization for the penetrative solar radiation
222      !!
223      !! ** Method  :   The profile of solar radiation within the ocean is set
224      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
225      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
226      !!      default values correspond to clear water (type I in Jerlov'
227      !!      (1968) classification.
228      !!         called by tra_qsr at the first timestep (nit000)
229      !!
230      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
231      !!
232      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
233      !!----------------------------------------------------------------------
234      INTEGER  ::   ji, jj, jk            ! dummy loop indices
235      INTEGER  ::   irgb, ierror          ! temporary integer
236      INTEGER  ::   ioptio, nqsr          ! temporary integer
237      REAL(wp) ::   zc0  , zc1            ! temporary scalars
238      REAL(wp) ::   zc2  , zc3  , zchl    !    -         -
239      REAL(wp) ::   zsi0r, zsi1r, zcoef   !    -         -
240      REAL(wp), DIMENSION(jpi,jpj)     ::   zekb, zekg, zekr              ! 2D workspace
241      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze0 , ze1 , ze2 , ze3 , zea   ! 3D workspace
242      !!
243      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
244      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
245      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,   &
246         &                  nn_chldta, rn_abs, rn_si0, rn_si1, rn_si2
247      !!----------------------------------------------------------------------
248
249      cn_dir = './'       ! directory in which the model is executed
250      ! ... default values (NB: frequency positive => hours, negative => months)
251      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
252      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
253      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
254      !
255      REWIND( numnam )            ! Read Namelist namtra_qsr : ratio and length of penetration
256      READ  ( numnam, namtra_qsr )
257      !
258      IF(lwp) THEN                ! control print
259         WRITE(numout,*)
260         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
261         WRITE(numout,*) '~~~~~~~~~~~~'
262         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
263         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
264         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
265         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
266         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
267         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
268         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
269         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
270         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
271         WRITE(numout,*) '      3 bands: longest depth of extinction         rn_si2 = ', rn_si2
272      ENDIF
273
274      IF( ln_traqsr ) THEN     ! control consistency
275         !                     
276         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
277            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
278            ln_qsr_bio = .FALSE.
279         ENDIF
280         !
281         ioptio = 0                      ! Parameter control
282         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
283         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
284         IF( ln_qsr_bio  )   ioptio = ioptio + 1
285         !
286         IF( ioptio /= 1 ) THEN
287            ln_qsr_rgb = .TRUE.
288            nn_chldta  = 0
289            ln_qsr_2bd = .FALSE.
290            ln_qsr_bio = .FALSE.
291            CALL ctl_warn( '          Choose ONE type of light penetration in namelist namtra_qsr',   &
292           &               ' otherwise, we force the model to run with RGB light penetration' )
293         ENDIF
294         !
295         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
296         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
297         IF( ln_qsr_2bd                      )   nqsr =  3
298         IF( ln_qsr_bio                      )   nqsr =  4
299         !
300         IF(lwp) THEN                   ! Print the choice
301            WRITE(numout,*)
302            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B  light penetration - Constant Chlorophyll'
303            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B  light penetration - Chl data '
304            IF( nqsr ==  3 )   WRITE(numout,*) '         2 band light penetration'
305            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
306         ENDIF
307         !
308      ENDIF
309      !                          ! ===================================== !
310      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
311         !                       ! ===================================== !
312         !
313         zsi0r = 1.e0 / rn_si0
314         zsi1r = 1.e0 / rn_si1
315         !                                ! ---------------------------------- !
316         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
317            !                             ! ---------------------------------- !
318            !
319            !                                ! level of light extinction
320            nksr = trc_oce_ext_lev( rn_si2, 0.33e2 )
321            IF(lwp) THEN
322               WRITE(numout,*)
323               WRITE(numout,*) '        level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
324            ENDIF
325            !
326            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
327!!gm            CALL trc_oce_rgb_read( rkrgb )           !* tabulated attenuation coef.
328            !
329            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
330               IF(lwp) WRITE(numout,*)
331               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
332               ALLOCATE( sf_chl(1), STAT=ierror )
333               IF( ierror > 0 ) THEN
334                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
335               ENDIF
336               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
337               ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
338               !                                        ! fill sf_chl with sn_chl and control print
339               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
340                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
341               !
342            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
343               IF(lwp) WRITE(numout,*)
344               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
345               IF(lwp) WRITE(numout,*) '        light distribution computed once for all'
346               !
347               zchl = 0.05                                 ! constant chlorophyll
348               irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
349               zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyl concentration
350               zekg(:,:) = rkrgb(2,irgb)
351               zekr(:,:) = rkrgb(3,irgb)
352               !
353               zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
354               ze0(:,:,1) = rn_abs
355               ze1(:,:,1) = zcoef
356               ze2(:,:,1) = zcoef 
357               ze3(:,:,1) = zcoef
358               zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
359               
360               DO jk = 2, nksr+1
361!CDIR NOVERRCHK
362                  DO jj = 1, jpj
363!CDIR NOVERRCHK   
364                     DO ji = 1, jpi
365                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r     )
366                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
367                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
368                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
369                        ze0(ji,jj,jk) = zc0                 
370                        ze1(ji,jj,jk) = zc1
371                        ze2(ji,jj,jk) = zc2     
372                        ze3(ji,jj,jk) = zc3
373                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
374                     END DO
375                  END DO
376               END DO 
377               !
378               DO jk = 1, nksr
379                  etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) / fse3t(:,:,jk)
380               END DO
381               etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
382            ENDIF
383            !
384         ENDIF
385            !                             ! ---------------------------------- !
386         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
387            !                             ! ---------------------------------- !
388            !
389            !                                ! level of light extinction
390            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
391            IF(lwp) THEN
392               WRITE(numout,*)
393               WRITE(numout,*) '        level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
394            ENDIF
395            !
396            DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
397               DO jj = 1, jpj                              ! top 400 meters
398                  DO ji = 1, jpi
399                     zc0 = rn_abs * EXP( -fsdepw(ji,jj,jk  )*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk  )*zsi1r )
400                     zc1 = rn_abs * EXP( -fsdepw(ji,jj,jk+1)*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk+1)*zsi1r )
401                     etot3(ji,jj,jk) = ro0cpr * (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) / fse3t(ji,jj,jk)
402                  END DO
403               END DO
404            END DO
405            etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
406            !
407         ENDIF
408         !                       ! ===================================== !
409      ELSE                       !        No light penetration           !                   
410         !                       ! ===================================== !
411         IF(lwp) THEN
412            WRITE(numout,*)
413            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
414            WRITE(numout,*) '~~~~~~~~~~~~'
415         ENDIF
416      ENDIF
417      !
418   END SUBROUTINE tra_qsr_init
419
420   !!======================================================================
421END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.