New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trasbc.F90 in branches/DEV_r1784_mid_year_merge_2010/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r1784_mid_year_merge_2010/NEMO/OPA_SRC/TRA/trasbc.F90 @ 2004

Last change on this file since 2004 was 2004, checked in by acc, 14 years ago

ticket #684 step 8: Add in changes from the trunk between revisions 1879 and the 3.2.1 tag (rev 1986)
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 12.4 KB
Line 
1MODULE trasbc
2   !!==============================================================================
3   !!                       ***  MODULE  trasbc  ***
4   !! Ocean active tracers:  surface boundary condition
5   !!==============================================================================
6   !! History :  8.2  !  98-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  01-02  (D. Ludicone)  sea ice and free surface
8   !!            8.5  !  02-06  (G. Madec)  F90: Free form and module
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_sbc      : update the tracer trend at ocean surface
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE sbc_oce         ! surface boundary condition: ocean
16   USE dom_oce         ! ocean space domain variables
17   USE phycst          ! physical constant
18   USE traqsr          ! solar radiation penetration
19   USE trdmod          ! ocean trends
20   USE trdmod_oce      ! ocean variables trends
21   USE in_out_manager  ! I/O manager
22   USE prtctl          ! Print control
23   USE sbcrnf          ! River runoff 
24   USE sbcmod          ! ln_rnf 
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   tra_sbc    ! routine called by step.F90
30
31   !! * Substitutions
32#  include "domzgr_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !!   OPA 9.0 , LOCEAN-IPSL (2005)
36   !! $Id$
37   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
38   !!----------------------------------------------------------------------
39
40CONTAINS
41
42   SUBROUTINE tra_sbc ( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE tra_sbc  ***
45      !!                   
46      !! ** Purpose :   Compute the tracer surface boundary condition trend of
47      !!      (flux through the interface, concentration/dilution effect)
48      !!      and add it to the general trend of tracer equations.
49      !!
50      !! ** Method :
51      !!      Following Roullet and Madec (2000), the air-sea flux can be divided
52      !!      into three effects: (1) Fext, external forcing;
53      !!      (2) Fwi, concentration/dilution effect due to water exchanged
54      !!         at the surface by evaporation, precipitations and runoff (E-P-R);
55      !!      (3) Fwe, tracer carried with the water that is exchanged.
56      !!
57      !!      Fext, flux through the air-sea interface for temperature and salt:
58      !!            - temperature : heat flux q (w/m2). If penetrative solar
59      !!         radiation q is only the non solar part of the heat flux, the
60      !!         solar part is added in traqsr.F routine.
61      !!            ta = ta + q /(rau0 rcp e3t)  for k=1
62      !!            - salinity    : no salt flux
63      !!
64      !!      The formulation for Fwb and Fwi vary according to the free
65      !!      surface formulation (linear or variable volume).
66      !!      * Linear free surface
67      !!            The surface freshwater flux modifies the ocean volume
68      !!         and thus the concentration of a tracer and the temperature.
69      !!         First order of the effect of surface freshwater exchange
70      !!         for salinity, it can be neglected on temperature (especially
71      !!         as the temperature of precipitations and runoffs is usually
72      !!         unknown).
73      !!            - temperature : we assume that the temperature of both
74      !!         precipitations and runoffs is equal to the SST, thus there
75      !!         is no additional flux since in this case, the concentration
76      !!         dilution effect is balanced by the net heat flux associated
77      !!         to the freshwater exchange (Fwe+Fwi=0):
78      !!            (Tp P - Te E) + SST (P-E) = 0 when Tp=Te=SST
79      !!            - salinity    : evaporation, precipitation and runoff
80      !!         water has a zero salinity (Fwe=0), thus only Fwi remains:
81      !!            sa = sa + emp * sn / e3t   for k=1
82      !!         where emp, the surface freshwater budget (evaporation minus
83      !!         precipitation minus runoff) given in kg/m2/s is divided
84      !!         by 1035 kg/m3 (density of ocena water) to obtain m/s.   
85      !!         Note: even though Fwe does not appear explicitly for
86      !!         temperature in this routine, the heat carried by the water
87      !!         exchanged through the surface is part of the total heat flux
88      !!         forcing and must be taken into account in the global heat
89      !!         balance).
90      !!      * nonlinear free surface (variable volume, lk_vvl)
91      !!         contrary to the linear free surface case, Fwi is properly
92      !!         taken into account by using the true layer thicknesses to       
93      !!         calculate tracer content and advection. There is no need to
94      !!         deal with it in this routine.
95      !!           - temperature: Fwe=SST (P-E+R) is added to Fext.
96      !!           - salinity:  Fwe = 0, there is no surface flux of salt.
97      !!
98      !! ** Action  : - Update the 1st level of (ta,sa) with the trend associated
99      !!                with the tracer surface boundary condition
100      !!              - save the trend it in ttrd ('key_trdtra')
101      !!----------------------------------------------------------------------
102      USE oce, ONLY :   ztrdt => ua   ! use ua as 3D workspace   
103      USE oce, ONLY :   ztrds => va   ! use va as 3D workspace   
104      !!
105      INTEGER, INTENT(in) ::   kt     ! ocean time-step index
106      !!
107      INTEGER  ::   ji, jj, jk           ! dummy loop indices 
108      REAL(wp) ::   zta, zsa             ! temporary scalars, adjustment to temperature and salinity 
109      REAL(wp) ::   zata, zasa           ! temporary scalars, calculations of automatic change to temp & sal due to vvl (done elsewhere) 
110      REAL(wp) ::   zsrau, zse3t, zdep   ! temporary scalars, 1/density, 1/height of box, 1/height of effected water column 
111      REAL(wp) ::   zdheat, zdsalt       ! total change of temperature and salinity 
112      !!----------------------------------------------------------------------
113
114      IF( kt == nit000 ) THEN
115         IF(lwp) WRITE(numout,*)
116         IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition'
117         IF(lwp) WRITE(numout,*) '~~~~~~~ '
118      ENDIF
119
120      zsrau = 1. / rau0             ! initialization
121#if defined key_zco
122      zse3t = 1. / e3t_0(1)
123#endif
124
125      IF( l_trdtra ) THEN           ! Save ta and sa trends
126         ztrdt(:,:,:) = ta(:,:,:) 
127         ztrds(:,:,:) = sa(:,:,:) 
128      ENDIF
129
130      IF( .NOT.ln_traqsr )   qsr(:,:) = 0.e0   ! no solar radiation penetration
131
132      ! Concentration dilution effect on (t,s) due to evapouration, precipitation and qns, but not river runoff 
133      DO jj = 2, jpj
134         DO ji = fs_2, fs_jpim1   ! vector opt.
135#if ! defined key_zco
136            zse3t = 1. / fse3t(ji,jj,1)
137#endif
138            IF( lk_vvl) THEN
139               zta =  ro0cpr * qns(ji,jj) * zse3t &                  ! temperature : heat flux
140                &    - emp(ji,jj) * zsrau * tn(ji,jj,1) * zse3t      ! & cooling/heating effet of EMP flux
141               zsa = ( emps(ji,jj) - emp(ji,jj) ) &
142                &                 * zsrau * sn(ji,jj,1)  * zse3t     ! concent./dilut. effect due to sea-ice
143                                                                     ! melt/formation and (possibly) SSS restoration
144            ELSE
145               zta =  ro0cpr * qns(ji,jj) * zse3t                    ! temperature : heat flux
146               zsa =  emps(ji,jj) * zsrau * sn(ji,jj,1) * zse3t      ! salinity :  concent./dilut. effect
147            ENDIF
148            ta(ji,jj,1) = ta(ji,jj,1) + zta                          ! add the trend to the general tracer trend
149            sa(ji,jj,1) = sa(ji,jj,1) + zsa
150         END DO
151      END DO
152
153      IF ( ln_rnf .AND. ln_rnf_att ) THEN 
154      ! Concentration / dilution effect on (t,s) due to river runoff 
155        DO jj=1,jpj 
156           DO ji=1,jpi 
157              rnf_dep(ji,jj)=0 
158              DO jk=1,rnf_mod_dep(ji,jj)                          ! recalculates rnf_dep to be the depth 
159                rnf_dep(ji,jj)=rnf_dep(ji,jj)+fse3t(ji,jj,jk)    ! in metres to the bottom of the relevant grid box 
160              ENDDO 
161              zdep = 1. / rnf_dep(ji,jj) 
162              zse3t= 1. / fse3t(ji,jj,1) 
163              IF ( rnf_tmp(ji,jj) == -999 )   rnf_tmp(ji,jj)=tn(ji,jj,1)        ! if not specified set runoff temp to be sst 
164 
165              IF ( rnf(ji,jj) .gt. 0.0 ) THEN 
166 
167                IF( lk_vvl) THEN 
168                  !!!indirect flux, concentration or dilution effect 
169                  !!!force a dilution effect in all levels; 
170                  zdheat=0.0 
171                  zdsalt=0.0 
172                  DO jk=1, rnf_mod_dep(ji,jj) 
173                    zta = -tn(ji,jj,jk) * rnf(ji,jj) * zsrau * zdep 
174                    zsa = -sn(ji,jj,jk) * rnf(ji,jj) * zsrau * zdep 
175                    ta(ji,jj,jk)=ta(ji,jj,jk)+zta 
176                    sa(ji,jj,jk)=sa(ji,jj,jk)+zsa 
177                    zdheat=zdheat+zta*fse3t(ji,jj,jk) 
178                    zdsalt=zdsalt+zsa*fse3t(ji,jj,jk) 
179                  ENDDO 
180                  !!!negate this total change in heat and salt content from top level 
181                  zta=-zdheat*zse3t 
182                  zsa=-zdsalt*zse3t 
183                  ta(ji,jj,1)=ta(ji,jj,1)+zta 
184                  sa(ji,jj,1)=sa(ji,jj,1)+zsa 
185   
186                  !!!direct flux 
187                  zta = rnf_tmp(ji,jj) * rnf(ji,jj) * zsrau * zdep 
188                  zsa = rnf_sal(ji,jj) * rnf(ji,jj) * zsrau * zdep 
189   
190                  DO jk=1, rnf_mod_dep(ji,jj) 
191                    ta(ji,jj,jk) = ta(ji,jj,jk) + zta 
192                    sa(ji,jj,jk) = sa(ji,jj,jk) + zsa 
193                  ENDDO 
194   
195                ELSE 
196                  DO jk=1, rnf_mod_dep(ji,jj) 
197                    zta = ( rnf_tmp(ji,jj)-tn(ji,jj,jk) ) * rnf(ji,jj) * zsrau * zdep 
198                    zsa = ( rnf_sal(ji,jj)-sn(ji,jj,jk) ) * rnf(ji,jj) * zsrau * zdep 
199                    ta(ji,jj,jk) = ta(ji,jj,jk) + zta 
200                    sa(ji,jj,jk) = sa(ji,jj,jk) + zsa 
201                  ENDDO 
202                ENDIF 
203 
204              ELSEIF (rnf(ji,jj) .lt. 0.) THEN   !! for use in baltic when flow is out of domain, want no change in temp and sal 
205 
206                IF( lk_vvl) THEN 
207                  !calculate automatic adjustment to sal and temp due to dilution/concentraion effect   
208                  zata = tn(ji,jj,1) * rnf(ji,jj) * zsrau * zse3t 
209                  zasa = sn(ji,jj,1) * rnf(ji,jj) * zsrau * zse3t 
210                  ta(ji,jj,1)=ta(ji,jj,1) + zata 
211                  sa(ji,jj,1)=sa(ji,jj,1) + zasa 
212                ENDIF 
213 
214              ENDIF 
215 
216           ENDDO 
217        ENDDO 
218
219      ELSE IF( ln_rnf ) THEN
220
221      ! Concentration dilution effect on (t,s) due to runoff without temperatue, salinity and depth attributes
222        DO jj = 2, jpj
223           DO ji = fs_2, fs_jpim1   ! vector opt.
224#if ! defined key_zco
225              zse3t = 1. / fse3t(ji,jj,1)
226#endif
227              IF( lk_vvl) THEN
228                 zta =  rnf(ji,jj) * zsrau * tn(ji,jj,1) * zse3t       ! & cooling/heating effect of runoff
229                 zsa = 0.e0                                            ! No salinity concent./dilut. effect
230              ELSE
231                 zta =  0.0                                            ! temperature : heat flux
232                 zsa =  - rnf(ji,jj) * zsrau * sn(ji,jj,1) * zse3t     ! salinity :  concent./dilut. effect
233              ENDIF
234              ta(ji,jj,1) = ta(ji,jj,1) + zta                          ! add the trend to the general tracer trend
235              sa(ji,jj,1) = sa(ji,jj,1) + zsa
236           END DO
237        END DO
238 
239      ENDIF 
240
241      IF( l_trdtra ) THEN      ! save the sbc trends for diagnostic
242         ztrdt(:,:,:) = ta(:,:,:) - ztrdt(:,:,:)
243         ztrds(:,:,:) = sa(:,:,:) - ztrds(:,:,:)
244         CALL trd_mod(ztrdt, ztrds, jptra_trd_nsr, 'TRA', kt)
245      ENDIF
246      !
247      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ta, clinfo1=' sbc  - Ta: ', mask1=tmask,   &
248         &                       tab3d_2=sa, clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
249      !
250   END SUBROUTINE tra_sbc
251
252   !!======================================================================
253END MODULE trasbc
Note: See TracBrowser for help on using the repository browser.