Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

sbcmod.F90 @ 1859

Last change on this file since 1859 was 1859, checked in by gm, 14 years ago
ticket:#665 step 2 & 3: heat content in qns & new forcing terms
Property svn:keywords set to `Id`
File size: 15.3 KB

Line
1	MODULE sbcmod
2	!!======================================================================
3	!! * MODULE sbcmod *
4	!! Surface module : provide to the ocean its surface boundary condition
5	!!======================================================================
6	!! History : 3.0 ! 2007-06 (G. Madec) Original code
7	!! 3.1 ! 2008-08 (S. Masson, E. .... ) coupled interface
8	!! 3.3 ! 2010-05 (Y. Aksenov G. Madec) salt flux + heat associated with emp
9	!!----------------------------------------------------------------------
10
11	!!----------------------------------------------------------------------
12	!! sbc_init : read namsbc namelist
13	!! sbc : surface ocean momentum, heat and freshwater boundary conditions
14	!!----------------------------------------------------------------------
15	USE oce ! ocean dynamics and tracers
16	USE dom_oce ! ocean space and time domain
17	USE phycst ! physical constants
18
19	USE sbc_oce ! Surface boundary condition: ocean fields
20	USE sbc_ice ! Surface boundary condition: ice fields
21	USE sbcssm ! surface boundary condition: sea-surface mean variables
22	USE sbcana ! surface boundary condition: analytical formulation
23	USE sbcflx ! surface boundary condition: flux formulation
24	USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO
25	USE sbcblk_core ! surface boundary condition: bulk formulation : CORE
26	USE sbcice_if ! surface boundary condition: ice-if sea-ice model
27	USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model
28	USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model
29	USE sbccpl ! surface boundary condition: coupled florulation
30	USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode?
31	USE sbcssr ! surface boundary condition: sea surface restoring
32	USE sbcrnf ! surface boundary condition: runoffs
33	USE sbcfwb ! surface boundary condition: freshwater budget
34	USE closea ! closed sea
35
36	USE prtctl ! Print control (prt_ctl routine)
37	USE restart ! ocean restart
38	USE iom
39	USE in_out_manager ! I/O manager
40
41	IMPLICIT NONE
42	PRIVATE
43
44	PUBLIC sbc ! routine called by step.F90
45	PUBLIC sbc_init ! routine called by opa.F90
46
47	INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations)
48
49	!! * Substitutions
50	# include "domzgr_substitute.h90"
51	!!----------------------------------------------------------------------
52	!! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
53	!! $Id$
54	!! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
55	!!----------------------------------------------------------------------
56
57	CONTAINS
58
59	SUBROUTINE sbc_init
60	!!---------------------------------------------------------------------
61	!! * ROUTINE sbc_init *
62	!!
63	!! ** Purpose : Initialisation of the ocean surface boundary computation
64	!!
65	!! ** Method : Read the namsbc namelist and set derived parameters
66	!!
67	!! ** Action : - read namsbc parameters
68	!! - nsbc: type of sbc
69	!!----------------------------------------------------------------------
70	INTEGER :: icpt ! temporary integer
71	!!
72	NAMELIST/namsbc/ nn_fsbc, ln_ana, ln_flx, ln_blk_clio, ln_blk_core, ln_cpl, &
73	& nn_ice , ln_dm2dc, ln_rnf, ln_ssr, nn_fwb, nn_ico_cpl
74	!!----------------------------------------------------------------------
75
76	IF(lwp) THEN
77	WRITE(numout,*)
78	WRITE(numout,*) 'sbc_init : surface boundary condition setting'
79	WRITE(numout,*) '~~~~~~~~ '
80	ENDIF
81
82	REWIND( numnam ) ! Read Namelist namsbc
83	READ ( numnam, namsbc )
84
85	! overwrite namelist parameter using CPP key information
86	!!gm here no overwrite, test all option via namelist change: require more incore memory
87	!!gm IF( lk_sbc_cpl ) THEN ; ln_cpl = .TRUE. ; ELSE ; ln_cpl = .FALSE. ; ENDIF
88
89	IF( Agrif_Root() ) THEN
90	IF( lk_lim2 ) nn_ice = 2
91	IF( lk_lim3 ) nn_ice = 3
92	ENDIF
93	!
94	IF( cp_cfg == 'gyre' ) THEN
95	ln_ana = .TRUE.
96	nn_ice = 0
97	ENDIF
98
99	! Control print
100	IF(lwp) THEN
101	WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)'
102	WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc
103	WRITE(numout,*) ' Type of sbc : '
104	WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana
105	WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx
106	WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio
107	WRITE(numout,*) ' CLIO bulk formulation ln_blk_core = ', ln_blk_core
108	WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl
109	WRITE(numout,*) ' Misc. options of sbc : '
110	WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice
111	WRITE(numout,*) ' ice-ocean stress computation (=0/1/2) nn_ico_cpl = ', nn_ico_cpl
112	WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc
113	WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf
114	WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr
115	WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb
116	WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea
117	ENDIF
118
119	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
120	ln_rnf_mouth = .false.
121	nkrnf = 0
122	rnfmsk (:,:) = 0.e0
123	rnfmsk_z(:) = 0.e0
124	ENDIF
125	IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero
126
127	emps(:,:) = 0.e0 ! the salt flux will be computed (i.e. will be non-zero) only if
128	! ! sea-ice is present, or lk_vvl=F, or surface salt restoring is used.
129
130	! ! restartability
131	IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. &
132	MOD( nstock , nn_fsbc) /= 0 ) THEN
133	WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, &
134	& ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
135	CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
136	ENDIF
137	!
138	IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) &
139	& CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
140	!
141	IF( nn_ice == 2 .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) &
142	& CALL ctl_stop( 'sea-ice model requires a bulk formulation or coupled configuration' )
143
144	! Choice of the Surface Boudary Condition (set nsbc)
145	icpt = 0
146	IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation
147	IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation
148	IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation
149	IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation
150	IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation
151	IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation
152	IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations
153
154	IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
155	WRITE(numout,*)
156	WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option '
157	WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)'
158	WRITE(numout,*) ' We stop'
159	nstop = nstop + 1
160	ENDIF
161	IF(lwp) THEN
162	WRITE(numout,*)
163	IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions'
164	IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation'
165	IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation'
166	IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation'
167	IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation'
168	IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation'
169	IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation'
170	ENDIF
171	!
172	END SUBROUTINE sbc_init
173
174
175	SUBROUTINE sbc( kt )
176	!!---------------------------------------------------------------------
177	!! * ROUTINE sbc *
178	!!
179	!! ** Purpose : provide at each time-step the ocean surface boundary
180	!! condition (momentum, heat and freshwater fluxes)
181	!!
182	!! ** Method : blah blah to be written ?????????
183	!! CAUTION : never mask the surface stress field (tke sbc)
184	!!
185	!! ** Action : - set the ocean surface boundary condition, i.e.
186	!! utau, vtau, qns, qsr, emp, emps, qrp, erp
187	!! - updte the ice fraction : fr_i
188	!!----------------------------------------------------------------------
189	INTEGER, INTENT(in) :: kt ! ocean time step
190	!!---------------------------------------------------------------------
191
192	CALL iom_setkt( kt + nn_fsbc - 1 ) ! in sbc, iom_put is called every nn_fsbc time step
193	!
194	! ocean to sbc mean sea surface variables (ss._m)
195	! ---------------------------------------
196	CALL sbc_ssm( kt ) ! sea surface mean currents (at U- and V-points),
197	! ! temperature and salinity (at T-point) over nf_sbc time-step
198	! ! (i.e. sst_m, sss_m, ssu_m, ssv_m)
199
200	! sbc formulation
201	! ---------------
202
203	SELECT CASE( nsbc ) ! Compute ocean surface boundary condition
204	! ! (i.e. utau,vtau, qns, qsr, emp, emps)
205	CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration
206	CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc
207	CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation
208	CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean
209	CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean
210	CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation
211	CASE( -1 )
212	CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations
213	CALL sbc_gyre ( kt ) !
214	CALL sbc_flx ( kt ) !
215	CALL sbc_blk_clio( kt ) !
216	CALL sbc_blk_core( kt ) !
217	CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) !
218	END SELECT
219
220	! Misc. Options
221	! -------------
222
223	!!gm IF( ln_dm2dc ) CALL sbc_dcy( kt ) ! Daily mean qsr distributed over the Diurnal Cycle
224
225	SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas
226	CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model)
227	!
228	CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM 2.0 ice model
229	!
230	CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc, nn_ico_cpl) ! LIM 3.0 ice model
231	END SELECT
232
233	IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes
234
235	IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term
236
237	IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget
238
239	IF( nclosea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain
240	! ! (update freshwater fluxes)
241	!
242	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
243	CALL iom_put( "emp" , emp ) ! upward water flux
244	CALL iom_put( "emps" , emps ) ! c/d water flux
245	CALL iom_put( "qns+qsr", qns + qsr ) ! total heat flux (caution if ln_dm2dc=true, to be
246	CALL iom_put( "qns" , qns ) ! solar heat flux moved after the call to iom_setkt)
247	CALL iom_put( "qsr" , qsr ) ! solar heat flux moved after the call to iom_setkt)
248	IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction
249	ENDIF
250	!
251	CALL iom_setkt( kt ) ! iom_put outside of sbc is called at every time step
252	!
253	CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at
254	CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice)
255	CALL iom_put( "taum", taum ) ! wind stress module
256	CALL iom_put( "wspd", wndm ) ! wind speed module
257	!
258	IF(ln_ctl) THEN ! print mean trends (used for debugging)
259	CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 )
260	CALL prt_ctl(tab2d_1=emp , clinfo1=' emp - : ', mask1=tmask, ovlap=1 )
261	CALL prt_ctl(tab2d_1=emps , clinfo1=' emps - : ', mask1=tmask, ovlap=1 )
262	CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 )
263	CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 )
264	CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask : ', mask1=tmask, ovlap=1, kdim=jpk )
265	CALL prt_ctl(tab3d_1=tn , clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 )
266	CALL prt_ctl(tab3d_1=sn , clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 )
267	CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, &
268	& tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 )
269	ENDIF
270	!
271	END SUBROUTINE sbc
272
273	!!======================================================================
274	END MODULE sbcmod

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/DEV_r1837_mass_heat_salt_fluxes/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 1859

Download in other formats: