New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcopt.F90 in branches/DEV_r1879_FCM/NEMOGCM/NEMO/TOP_SRC/LOBSTER – NEMO

source: branches/DEV_r1879_FCM/NEMOGCM/NEMO/TOP_SRC/LOBSTER/trcopt.F90 @ 2007

Last change on this file since 2007 was 2007, checked in by smasson, 14 years ago

update branches/DEV_r1879_FCM/NEMOGCM/NEMO with tags/nemo_v3_2_1/NEMO
  • Property svn:keywords set to Id
File size: 7.1 KB
Line 
1MODULE trcopt
2   !!======================================================================
3   !!                         ***  MODULE trcopt  ***
4   !! TOP :   LOBSTER Compute the light availability in the water column
5   !!======================================================================
6   !! History :    -   !  1995-05  (M. Levy) Original code
7   !!              -   !  1999-09  (J.-M. Andre, M. Levy)
8   !!              -   !  1999-11  (C. Menkes, M.-A. Foujols) itabe initial
9   !!              -   !  2000-02  (M.A. Foujols) change x**y par exp(y*log(x))
10   !!   NEMO      2.0  !  2007-12  (C. Deltel, G. Madec)  F90
11   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  minor optimisation + style
12   !!----------------------------------------------------------------------
13#if defined key_lobster
14   !!----------------------------------------------------------------------
15   !!   'key_lobster'                                     LOBSTER bio-model
16   !!----------------------------------------------------------------------
17   !!   trc_opt        :   Compute the light availability in the water column
18   !!----------------------------------------------------------------------
19   USE oce_trc         !
20   USE trc
21   USE sms_lobster
22   USE prtctl_trc      ! Print control for debbuging
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_opt   ! called in trcprg.F90
28
29   !!* Substitution
30#  include "top_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
33   !! $Id$
34   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE trc_opt( kt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE trc_opt  ***
42      !!
43      !! ** Purpose :   computes the light propagation in the water column
44      !!              and the euphotic layer depth
45      !!
46      !! ** Method  :   local par is computed in w layers using light propagation
47      !!              mean par in t layers are computed by integration
48      !!
49!!gm please remplace the '???' by true comments
50      !! ** Action  :   xpar   ???
51      !!                neln   ???
52      !!                xze    ???
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT( in ) ::   kt   ! index of the time stepping
55      !!
56      INTEGER  ::   ji, jj, jk          ! dummy loop indices
57      CHARACTER (len=25) ::   charout   ! temporary character
58      REAL(wp) ::   zpig                ! log of the total pigment
59      REAL(wp) ::   zkr, zkg            ! total absorption coefficient in red and green
60      REAL(wp) ::   zcoef               ! temporary scalar
61      REAL(wp), DIMENSION(jpi,jpj)     ::   zpar100         ! irradiance at euphotic layer depth
62      REAL(wp), DIMENSION(jpi,jpj)     ::   zpar0m          ! irradiance just below the surface
63      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zparr, zparg    ! red and green compound of par
64
65      !!---------------------------------------------------------------------
66
67      IF( kt == nit000 ) THEN
68         IF(lwp) WRITE(numout,*)
69         IF(lwp) WRITE(numout,*) ' trc_opt : LOBSTER optic-model'
70         IF(lwp) WRITE(numout,*) ' ~~~~~~~ '
71      ENDIF
72
73      !                                          ! surface irradiance
74      zpar0m (:,:)   = qsr   (:,:) * 0.43        ! ------------------
75      zpar100(:,:)   = zpar0m(:,:) * 0.01
76      xpar   (:,:,1) = zpar0m(:,:)
77      zparr  (:,:,1) = zpar0m(:,:) * 0.5
78      zparg  (:,:,1) = zpar0m(:,:) * 0.5
79
80!!gm optimisation : introduce zcoef and LOG computed once for all
81
82      !                                          ! Photosynthetically Available Radiation (PAR)
83      zcoef = 12 * redf / rcchl / rpig           ! --------------------------------------
84      DO jk = 2, jpk                                  ! local par at w-levels
85         DO jj = 1, jpj
86            DO ji = 1, jpi
87!!gm           zpig = MAX( TINY(0.), trn(ji,jj,jk-1,jpphy) ) * zcoef
88!!gm           zkr  = xkr0 + xkrp * EXP( xlr * LOG(zpig) )
89!!gm           zkg  = xkg0 + xkgp * EXP( xlg * LOG(zpig) )
90               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk-1,jpphy) ) * zcoef  )
91               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
92               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
93               zparr(ji,jj,jk) = zparr(ji,jj,jk-1) * EXP( -zkr * fse3t(ji,jj,jk-1) )
94               zparg(ji,jj,jk) = zparg(ji,jj,jk-1) * EXP( -zkg * fse3t(ji,jj,jk-1) )
95            END DO
96        END DO
97      END DO
98!!gm optimisation : suppress one division
99      DO jk = 1, jpkm1                                ! mean par at t-levels
100         DO jj = 1, jpj
101            DO ji = 1, jpi
102               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk,jpphy) ) * zcoef  )
103               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
104               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
105!!gm           zparr(ji,jj,jk) = zparr(ji,jj,jk) / zkr / fse3t(ji,jj,jk) * ( 1 - EXP( -zkr * fse3t(ji,jj,jk) ) )
106!!gm           zparg(ji,jj,jk) = zparg(ji,jj,jk) / zkg / fse3t(ji,jj,jk) * ( 1 - EXP( -zkg * fse3t(ji,jj,jk) ) )
107               zparr(ji,jj,jk) = zparr(ji,jj,jk) / ( zkr * fse3t(ji,jj,jk) ) * ( 1 - EXP( -zkr * fse3t(ji,jj,jk) ) )
108               zparg(ji,jj,jk) = zparg(ji,jj,jk) / ( zkg * fse3t(ji,jj,jk) ) * ( 1 - EXP( -zkg * fse3t(ji,jj,jk) ) )
109               xpar (ji,jj,jk) = MAX( zparr(ji,jj,jk) + zparg(ji,jj,jk), 1.e-15 )
110            END DO
111         END DO
112      END DO
113
114      !                                          ! Euphotic layer
115      !                                          ! --------------
116      neln(:,:) = 1                                   ! euphotic layer level
117      DO jk = 1, jpk                                  ! (i.e. 1rst T-level strictly below EL bottom)
118         DO jj = 1, jpj
119           DO ji = 1, jpi
120              IF( xpar(ji,jj,jk) >= zpar100(ji,jj) )   neln(ji,jj) = jk + 1 
121              !                                       ! nb. this is to ensure compatibility with
122              !                                       ! nmld_trc definition in trd_mld_trc_zint
123           END DO
124         END DO
125      END DO
126      !                                               ! Euphotic layer depth
127      DO jj = 1, jpj
128         DO ji = 1, jpi
129            xze(ji,jj) = fsdepw(ji,jj,neln(ji,jj))
130         END DO
131      END DO
132
133
134      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
135         WRITE(charout, FMT="('opt')")
136         CALL prt_ctl_trc_info( charout )
137         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
138      ENDIF
139      !
140   END SUBROUTINE trc_opt
141
142#else
143   !!======================================================================
144   !!  Dummy module :                                   No PISCES bio-model
145   !!======================================================================
146CONTAINS
147   SUBROUTINE trc_opt( kt )                   ! Empty routine
148      INTEGER, INTENT( in ) ::   kt
149      WRITE(*,*) 'trc_opt: You should not have seen this print! error?', kt
150   END SUBROUTINE trc_opt
151#endif 
152
153   !!======================================================================
154END MODULE  trcopt
Note: See TracBrowser for help on using the repository browser.