| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !!---------------------------------------------------------------------- |
|---|
| 24 | |
|---|
| 25 | !!---------------------------------------------------------------------- |
|---|
| 26 | !! stp : OPA system time-stepping |
|---|
| 27 | !!---------------------------------------------------------------------- |
|---|
| 28 | USE oce ! ocean dynamics and tracers variables |
|---|
| 29 | USE dom_oce ! ocean space and time domain variables |
|---|
| 30 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 31 | USE ldftra_oce ! ocean tracer - trends |
|---|
| 32 | USE ldfdyn_oce ! ocean dynamics - trends |
|---|
| 33 | USE in_out_manager ! I/O manager |
|---|
| 34 | USE iom ! |
|---|
| 35 | USE lbclnk |
|---|
| 36 | |
|---|
| 37 | USE daymod ! calendar (day routine) |
|---|
| 38 | |
|---|
| 39 | USE dtatem ! ocean temperature data (dta_tem routine) |
|---|
| 40 | USE dtasal ! ocean salinity data (dta_sal routine) |
|---|
| 41 | USE sbcmod ! surface boundary condition (sbc routine) |
|---|
| 42 | USE sbcrnf ! surface boundary condition: runoff variables |
|---|
| 43 | USE sbccpl ! surface boundary condition: coupled formulation (call send at end of step) |
|---|
| 44 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 45 | |
|---|
| 46 | #if defined key_top |
|---|
| 47 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
|---|
| 48 | #endif |
|---|
| 49 | |
|---|
| 50 | USE traqsr ! solar radiation penetration (tra_qsr routine) |
|---|
| 51 | USE trasbc ! surface boundary condition (tra_sbc routine) |
|---|
| 52 | USE trabbc ! bottom boundary condition (tra_bbc routine) |
|---|
| 53 | USE trabbl ! bottom boundary layer (tra_bbl routine) |
|---|
| 54 | USE tradmp ! internal damping (tra_dmp routine) |
|---|
| 55 | USE traadv ! advection scheme control (tra_adv_ctl routine) |
|---|
| 56 | USE traldf ! lateral mixing (tra_ldf routine) |
|---|
| 57 | USE cla ! cross land advection (tra_cla routine) |
|---|
| 58 | ! zdfkpp ! KPP non-local tracer fluxes (tra_kpp routine) |
|---|
| 59 | USE trazdf ! vertical mixing (tra_zdf routine) |
|---|
| 60 | USE tranxt ! time-stepping (tra_nxt routine) |
|---|
| 61 | USE tranpc ! non-penetrative convection (tra_npc routine) |
|---|
| 62 | |
|---|
| 63 | USE eosbn2 ! equation of state (eos_bn2 routine) |
|---|
| 64 | |
|---|
| 65 | USE dynadv ! advection (dyn_adv routine) |
|---|
| 66 | USE dynbfr ! Bottom friction terms (dyn_bfr routine) |
|---|
| 67 | USE dynvor ! vorticity term (dyn_vor routine) |
|---|
| 68 | USE dynhpg ! hydrostatic pressure grad. (dyn_hpg routine) |
|---|
| 69 | USE dynldf ! lateral momentum diffusion (dyn_ldf routine) |
|---|
| 70 | USE dynzdf ! vertical diffusion (dyn_zdf routine) |
|---|
| 71 | USE dynspg_oce ! surface pressure gradient (dyn_spg routine) |
|---|
| 72 | USE dynspg ! surface pressure gradient (dyn_spg routine) |
|---|
| 73 | USE dynnxt ! time-stepping (dyn_nxt routine) |
|---|
| 74 | |
|---|
| 75 | USE obc_par ! open boundary condition variables |
|---|
| 76 | USE obcdta ! open boundary condition data (obc_dta routine) |
|---|
| 77 | USE obcrst ! open boundary cond. restart (obc_rst routine) |
|---|
| 78 | USE obcrad ! open boundary cond. radiation (obc_rad routine) |
|---|
| 79 | |
|---|
| 80 | USE bdy_par ! unstructured open boundary data variables |
|---|
| 81 | USE bdydta ! unstructured open boundary data (bdy_dta routine) |
|---|
| 82 | |
|---|
| 83 | USE sshwzv ! vertical velocity and ssh (ssh_wzv routine) |
|---|
| 84 | |
|---|
| 85 | USE ldfslp ! iso-neutral slopes (ldf_slp routine) |
|---|
| 86 | USE ldfeiv ! eddy induced velocity coef. (ldf_eiv routine) |
|---|
| 87 | USE ldfeiv_vis ! eddy induced velocity coef. (ldf_eiv_vis routine) |
|---|
| 88 | |
|---|
| 89 | USE zdftmx ! tide-induced vertical mixing (zdf_tmx routine) |
|---|
| 90 | USE zdfbfr ! bottom friction (zdf_bfr routine) |
|---|
| 91 | USE zdftke_old ! old TKE vertical mixing (zdf_tke_old routine) |
|---|
| 92 | USE zdftke ! TKE vertical mixing (zdf_tke routine) |
|---|
| 93 | USE zdfkpp ! KPP vertical mixing (zdf_kpp routine) |
|---|
| 94 | USE zdfddm ! double diffusion mixing (zdf_ddm routine) |
|---|
| 95 | USE zdfevd ! enhanced vertical diffusion (zdf_evd routine) |
|---|
| 96 | USE zdfric ! Richardson vertical mixing (zdf_ric routine) |
|---|
| 97 | USE zdfmxl ! Mixed-layer depth (zdf_mxl routine) |
|---|
| 98 | |
|---|
| 99 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
|---|
| 100 | |
|---|
| 101 | USE diawri ! Standard run outputs (dia_wri routine) |
|---|
| 102 | USE trdicp ! Ocean momentum/tracers trends (trd_wri routine) |
|---|
| 103 | USE trdmld ! mixed-layer trends (trd_mld routine) |
|---|
| 104 | USE trdmld_rst ! restart for mixed-layer trends |
|---|
| 105 | USE trdmod_oce ! ocean momentum/tracers trends |
|---|
| 106 | USE trdvor ! vorticity budget (trd_vor routine) |
|---|
| 107 | USE diagap ! hor. mean model-data gap (dia_gap routine) |
|---|
| 108 | USE diahdy ! dynamic height (dia_hdy routine) |
|---|
| 109 | USE diaptr ! poleward transports (dia_ptr routine) |
|---|
| 110 | USE diaar5 ! AR5 diagnosics (dia_ar5 routine) |
|---|
| 111 | USE diahth ! thermocline depth (dia_hth routine) |
|---|
| 112 | USE diafwb ! freshwater budget (dia_fwb routine) |
|---|
| 113 | USE flo_oce ! floats variables |
|---|
| 114 | USE floats ! floats computation (flo_stp routine) |
|---|
| 115 | |
|---|
| 116 | USE stpctl ! time stepping control (stp_ctl routine) |
|---|
| 117 | USE restart ! ocean restart (rst_wri routine) |
|---|
| 118 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 119 | |
|---|
| 120 | #if defined key_agrif |
|---|
| 121 | USE agrif_opa_sponge ! Momemtum and tracers sponges |
|---|
| 122 | #endif |
|---|
| 123 | |
|---|
| 124 | IMPLICIT NONE |
|---|
| 125 | PRIVATE |
|---|
| 126 | |
|---|
| 127 | PUBLIC stp ! called by opa.F90 |
|---|
| 128 | |
|---|
| 129 | !! * Substitutions |
|---|
| 130 | # include "domzgr_substitute.h90" |
|---|
| 131 | # include "zdfddm_substitute.h90" |
|---|
| 132 | !!---------------------------------------------------------------------- |
|---|
| 133 | !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009) |
|---|
| 134 | !! $Id$ |
|---|
| 135 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 136 | !!---------------------------------------------------------------------- |
|---|
| 137 | |
|---|
| 138 | CONTAINS |
|---|
| 139 | |
|---|
| 140 | #if defined key_agrif |
|---|
| 141 | SUBROUTINE stp( ) |
|---|
| 142 | INTEGER :: kstp ! ocean time-step index |
|---|
| 143 | #else |
|---|
| 144 | SUBROUTINE stp( kstp ) |
|---|
| 145 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 146 | #endif |
|---|
| 147 | !!---------------------------------------------------------------------- |
|---|
| 148 | !! *** ROUTINE stp *** |
|---|
| 149 | !! |
|---|
| 150 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 151 | !! - Time stepping of LIM (dynamic and thermodynamic eqs.) |
|---|
| 152 | !! - Tme stepping of TRC (passive tracer eqs.) |
|---|
| 153 | !! |
|---|
| 154 | !! ** Method : -1- Update forcings and data |
|---|
| 155 | !! -2- Update ocean physics |
|---|
| 156 | !! -3- Compute the t and s trends |
|---|
| 157 | !! -4- Update t and s |
|---|
| 158 | !! -5- Compute the momentum trends |
|---|
| 159 | !! -6- Update the horizontal velocity |
|---|
| 160 | !! -7- Compute the diagnostics variables (rd,N2, div,cur,w) |
|---|
| 161 | !! -8- Outputs and diagnostics |
|---|
| 162 | !!---------------------------------------------------------------------- |
|---|
| 163 | INTEGER :: jk ! dummy loop indice |
|---|
| 164 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 165 | !! --------------------------------------------------------------------- |
|---|
| 166 | |
|---|
| 167 | #if defined key_agrif |
|---|
| 168 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 169 | ! IF( Agrif_Root() .and. lwp) Write(*,*) '---' |
|---|
| 170 | ! IF(lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp |
|---|
| 171 | # if defined key_iomput |
|---|
| 172 | IF( Agrif_Nbstepint() == 0) CALL iom_swap |
|---|
| 173 | # endif |
|---|
| 174 | #endif |
|---|
| 175 | indic = 1 ! reset to no error condition |
|---|
| 176 | |
|---|
| 177 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 178 | |
|---|
| 179 | CALL iom_setkt( kstp ) ! say to iom that we are at time step kstp |
|---|
| 180 | |
|---|
| 181 | CALL rst_opn( kstp ) ! Open the restart file |
|---|
| 182 | |
|---|
| 183 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 184 | ! Update data, open boundaries, surface boundary condition (including sea-ice) |
|---|
| 185 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 186 | IF( lk_dtatem ) CALL dta_tem( kstp ) ! update 3D temperature data |
|---|
| 187 | IF( lk_dtasal ) CALL dta_sal( kstp ) ! update 3D salinity data |
|---|
| 188 | CALL sbc ( kstp ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 189 | IF( lk_obc ) CALL obc_dta( kstp ) ! update dynamic and tracer data at open boundaries |
|---|
| 190 | IF( lk_obc ) CALL obc_rad( kstp ) ! compute phase velocities at open boundaries |
|---|
| 191 | IF( lk_bdy ) CALL bdy_dta( kstp ) ! update dynamic and tracer data at unstructured open boundary |
|---|
| 192 | |
|---|
| 193 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 194 | ! Ocean dynamics : ssh, wn, hdiv, rot ! |
|---|
| 195 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 196 | CALL ssh_wzv( kstp ) ! after ssh & vertical velocity |
|---|
| 197 | |
|---|
| 198 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 199 | ! Ocean physics update (ua, va, ta, sa used as workspace) |
|---|
| 200 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 201 | CALL bn2( tb, sb, rn2b ) ! before Brunt-Vaisala frequency |
|---|
| 202 | CALL bn2( tn, sn, rn2 ) ! now Brunt-Vaisala frequency |
|---|
| 203 | ! |
|---|
| 204 | ! VERTICAL PHYSICS |
|---|
| 205 | CALL zdf_bfr( kstp ) ! bottom friction |
|---|
| 206 | ! ! Vertical eddy viscosity and diffusivity coefficients |
|---|
| 207 | IF( lk_zdfric ) CALL zdf_ric ( kstp ) ! Richardson number dependent Kz |
|---|
| 208 | IF( lk_zdftke_old ) CALL zdf_tke_old( kstp ) ! TKE closure scheme for Kz (old scheme) |
|---|
| 209 | IF( lk_zdftke ) CALL zdf_tke ( kstp ) ! TKE closure scheme for Kz |
|---|
| 210 | IF( lk_zdfkpp ) CALL zdf_kpp ( kstp ) ! KPP closure scheme for Kz |
|---|
| 211 | IF( lk_zdfcst ) THEN ! Constant Kz (reset avt, avm[uv] to the background value) |
|---|
| 212 | avt (:,:,:) = rn_avt0 * tmask(:,:,:) |
|---|
| 213 | avmu(:,:,:) = rn_avm0 * umask(:,:,:) |
|---|
| 214 | avmv(:,:,:) = rn_avm0 * vmask(:,:,:) |
|---|
| 215 | ENDIF |
|---|
| 216 | IF( ln_rnf_mouth ) THEN ! increase diffusivity at rivers mouths |
|---|
| 217 | DO jk = 2, nkrnf ; avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk) ; END DO |
|---|
| 218 | ENDIF |
|---|
| 219 | IF( ln_zdfevd ) CALL zdf_evd( kstp ) ! enhanced vertical eddy diffusivity |
|---|
| 220 | |
|---|
| 221 | IF( lk_zdftmx ) CALL zdf_tmx( kstp ) ! tidal vertical mixing |
|---|
| 222 | |
|---|
| 223 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
|---|
| 224 | & CALL zdf_ddm( kstp ) ! double diffusive mixing |
|---|
| 225 | CALL zdf_mxl( kstp ) ! mixed layer depth |
|---|
| 226 | |
|---|
| 227 | ! write tke information in the restart file |
|---|
| 228 | IF( lrst_oce .AND. lk_zdftke ) CALL tke_rst( kstp, 'WRITE' ) |
|---|
| 229 | ! |
|---|
| 230 | ! LATERAL PHYSICS |
|---|
| 231 | ! |
|---|
| 232 | IF( lk_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 233 | CALL eos( tb, sb, rhd ) ! before in situ density |
|---|
| 234 | IF( ln_zps ) CALL zps_hde( kstp, tb, sb, rhd, & ! Partial steps: before horizontal gradient |
|---|
| 235 | & gtu, gsu, gru, & ! of t, s, rd at the last ocean level |
|---|
| 236 | & gtv, gsv, grv ) |
|---|
| 237 | CALL ldf_slp( kstp, rhd, rn2b ) ! before slope of the lateral mixing |
|---|
| 238 | ENDIF |
|---|
| 239 | #if defined key_traldf_c2d |
|---|
| 240 | IF( lk_traldf_eiv ) THEN ! eddy induced velocity coefficient |
|---|
| 241 | IF ( ln_traldf_vis ) THEN |
|---|
| 242 | CALL ldf_eiv_vis( kstp ) |
|---|
| 243 | ELSE |
|---|
| 244 | CALL ldf_eiv( kstp ) |
|---|
| 245 | ENDIF |
|---|
| 246 | ENDIF |
|---|
| 247 | # endif |
|---|
| 248 | |
|---|
| 249 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 250 | ! diagnostics and outputs (ua, va, ta, sa used as workspace) |
|---|
| 251 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 252 | IF( lk_floats ) CALL flo_stp( kstp ) ! drifting Floats |
|---|
| 253 | IF( lk_diahth ) CALL dia_hth( kstp ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 254 | IF( lk_diagap ) CALL dia_gap( kstp ) ! basin averaged diagnostics |
|---|
| 255 | IF( lk_diahdy ) CALL dia_hdy( kstp ) ! dynamical heigh diagnostics |
|---|
| 256 | IF( lk_diafwb ) CALL dia_fwb( kstp ) ! Fresh water budget diagnostics |
|---|
| 257 | IF( ln_diaptr ) CALL dia_ptr( kstp ) ! Poleward TRansports diagnostics |
|---|
| 258 | IF( lk_diaar5 ) CALL dia_ar5( kstp ) ! ar5 diag |
|---|
| 259 | CALL dia_wri( kstp ) ! ocean model: outputs |
|---|
| 260 | |
|---|
| 261 | #if defined key_top |
|---|
| 262 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 263 | ! Passive Tracer Model |
|---|
| 264 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 265 | CALL trc_stp( kstp ) ! time-stepping |
|---|
| 266 | #endif |
|---|
| 267 | |
|---|
| 268 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 269 | ! Active tracers (ua, va used as workspace) |
|---|
| 270 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 271 | ta(:,:,:) = 0.e0 ! set tracer trends to zero |
|---|
| 272 | sa(:,:,:) = 0.e0 |
|---|
| 273 | |
|---|
| 274 | CALL tra_sbc ( kstp ) ! surface boundary condition |
|---|
| 275 | IF( ln_traqsr ) CALL tra_qsr ( kstp ) ! penetrative solar radiation qsr |
|---|
| 276 | IF( lk_trabbc ) CALL tra_bbc ( kstp ) ! bottom heat flux |
|---|
| 277 | IF( lk_trabbl_dif ) CALL tra_bbl_dif( kstp ) ! diffusive bottom boundary layer scheme |
|---|
| 278 | IF( lk_trabbl_adv ) CALL tra_bbl_adv( kstp ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 279 | IF( lk_tradmp ) CALL tra_dmp ( kstp ) ! internal damping trends |
|---|
| 280 | CALL tra_adv ( kstp ) ! horizontal & vertical advection |
|---|
| 281 | IF( n_cla == 1 ) CALL tra_cla ( kstp ) ! Cross Land Advection (Update Hor. advection) |
|---|
| 282 | IF( lk_zdfkpp ) CALL tra_kpp ( kstp ) ! KPP non-local tracer fluxes |
|---|
| 283 | CALL tra_ldf ( kstp ) ! lateral mixing |
|---|
| 284 | #if defined key_agrif |
|---|
| 285 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 286 | #endif |
|---|
| 287 | CALL tra_zdf ( kstp ) ! vertical mixing and after tracer fields |
|---|
| 288 | |
|---|
| 289 | IF( ln_dynhpg_imp ) THEN ! semi-implicit hpg (time stepping then eos) |
|---|
| 290 | IF( ln_zdfnpc ) CALL tra_npc ( kstp ) ! update after fields by non-penetrative convection |
|---|
| 291 | CALL tra_nxt ( kstp ) ! tracer fields at next time step |
|---|
| 292 | CALL eos( ta, sa, rhd, rhop ) ! Time-filtered in situ density for hpg computation |
|---|
| 293 | IF( ln_zps ) CALL zps_hde( kstp, ta, sa, rhd, & ! Partial steps: time filtered hor. derivative |
|---|
| 294 | & gtu, gsu, gru, & ! of t, s, rd at the bottom ocean level |
|---|
| 295 | & gtv, gsv, grv ) |
|---|
| 296 | |
|---|
| 297 | ELSE ! centered hpg (eos then time stepping) |
|---|
| 298 | CALL eos( tn, sn, rhd, rhop ) ! now in situ density for hpg computation |
|---|
| 299 | IF( ln_zps ) CALL zps_hde( kstp, tn, sn, rhd, & ! Partial steps: now horizontal derivative |
|---|
| 300 | & gtu, gsu, gru, & ! of t, s, rd at the bottom ocean level |
|---|
| 301 | & gtv, gsv, grv ) |
|---|
| 302 | IF( ln_zdfnpc ) CALL tra_npc ( kstp ) ! update after fields by non-penetrative convection |
|---|
| 303 | CALL tra_nxt ( kstp ) ! tracer fields at next time step |
|---|
| 304 | ENDIF |
|---|
| 305 | |
|---|
| 306 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 307 | ! Dynamics (ta, sa used as workspace) |
|---|
| 308 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 309 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 310 | va(:,:,:) = 0.e0 |
|---|
| 311 | |
|---|
| 312 | CALL dyn_adv( kstp ) ! advection (vector or flux form) |
|---|
| 313 | CALL dyn_vor( kstp ) ! vorticity term including Coriolis |
|---|
| 314 | CALL dyn_ldf( kstp ) ! lateral mixing |
|---|
| 315 | #if defined key_agrif |
|---|
| 316 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momemtum sponge |
|---|
| 317 | #endif |
|---|
| 318 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 319 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 320 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 321 | indic=0 |
|---|
| 322 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 323 | CALL dyn_nxt( kstp ) ! lateral velocity at next time step |
|---|
| 324 | |
|---|
| 325 | CALL ssh_nxt( kstp ) ! sea surface height at next time step |
|---|
| 326 | |
|---|
| 327 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 328 | ! Control and restarts |
|---|
| 329 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 330 | CALL stp_ctl( kstp, indic ) |
|---|
| 331 | IF( indic < 0 ) THEN |
|---|
| 332 | CALL ctl_stop( 'step: indic < 0' ) |
|---|
| 333 | CALL dia_wri_state( 'output.abort', kstp ) |
|---|
| 334 | ENDIF |
|---|
| 335 | IF( kstp == nit000 ) CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 336 | IF( lrst_oce ) CALL rst_write ( kstp ) ! write output ocean restart file |
|---|
| 337 | IF( lk_obc ) CALL obc_rst_write( kstp ) ! write open boundary restart file |
|---|
| 338 | |
|---|
| 339 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 340 | ! Trends (ua, va, ta, sa used as workspace) |
|---|
| 341 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 342 | IF( nstop == 0 ) THEN |
|---|
| 343 | IF( lk_trddyn ) CALL trd_dwr( kstp ) ! trends: dynamics |
|---|
| 344 | IF( lk_trdtra ) CALL trd_twr( kstp ) ! trends: active tracers |
|---|
| 345 | IF( lk_trdmld ) CALL trd_mld( kstp ) ! trends: Mixed-layer |
|---|
| 346 | IF( lk_trdvor ) CALL trd_vor( kstp ) ! trends: vorticity budget |
|---|
| 347 | ENDIF |
|---|
| 348 | |
|---|
| 349 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 350 | ! Coupled mode |
|---|
| 351 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 352 | IF( lk_cpl ) CALL sbc_cpl_snd( kstp ) ! coupled mode : field exchanges |
|---|
| 353 | ! |
|---|
| 354 | ! |
|---|
| 355 | END SUBROUTINE stp |
|---|
| 356 | |
|---|
| 357 | !!====================================================================== |
|---|
| 358 | END MODULE step |
|---|
