New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traadv_muscl.F90 @ 2034

Last change on this file since 2034 was 2034, checked in by cetlod, 14 years ago

cosmetic changes
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 13.6 KB
Line 
1MODULE traadv_muscl
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   tra_adv_muscl : update the tracer trend with the horizontal
14   !!                   and vertical advection trends using MUSCL scheme
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE trdmod_oce      ! tracers trends
19   USE trdtra      ! tracers trends
20   USE in_out_manager  ! I/O manager
21   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
22   USE trabbl          ! tracers: bottom boundary layer
23   USE lib_mpp         ! distribued memory computing
24   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
25   USE diaptr          ! poleward transport diagnostics
26
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   tra_adv_muscl  ! routine called by step.F90
32
33   LOGICAL  :: l_trd       ! flag to compute trends
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43
44CONTAINS
45
46   SUBROUTINE tra_adv_muscl( kt, cdtype, pun, pvn, pwn, &
47      &                                       ptb, pta, kjpt   )
48      !!----------------------------------------------------------------------
49      !!                    ***  ROUTINE tra_adv_muscl  ***
50      !!
51      !! ** Purpose :   Compute the now trend due to total advection of T and
52      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
53      !!      Conservation Laws) and add it to the general tracer trend.
54      !!
55      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
56      !!
57      !! ** Action  : - update (ta,sa) with the now advective tracer trends
58      !!              - save trends
59      !!
60      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
61      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
62      !!----------------------------------------------------------------------
63      USE oce         , zwx => ua   ! use ua as workspace
64      USE oce         , zwy => va   ! use va as workspace
65      !!
66      INTEGER         , INTENT(in   )                               ::   kt              ! ocean time-step index
67      CHARACTER(len=3), INTENT(in   )                               ::   cdtype          ! =TRA or TRC (tracer indicator)
68      INTEGER         , INTENT(in   )                               ::   kjpt            ! number of tracers
69      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk)       ::   pun, pvn, pwn   ! 3 ocean velocity components
70      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)  ::   ptb           ! before and now tracer fields
71      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::   pta           ! tracer trend
72      !!
73      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
74      REAL(wp) ::   zu, z0u, zzwx
75      REAL(wp) ::   zv, z0v, zzwy
76      REAL(wp) ::   zw, z0w
77      REAL(wp) ::   ztra, zbtr, z2, zdt, zalpha
78      REAL(wp), DIMENSION (jpi,jpj,jpk) :: zslpx, zslpy   ! 3D workspace
79      !!----------------------------------------------------------------------
80
81      IF( kt == nit000 .AND. lwp ) THEN
82         WRITE(numout,*)
83         WRITE(numout,*) 'tra_adv : MUSCL advection scheme'
84         WRITE(numout,*) '~~~~~~~'
85         !
86         l_trd = .FALSE.
87         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
88      ENDIF
89
90      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;    z2 = 1.
91      ELSE                                        ;    z2 = 2.
92      ENDIF
93      !
94      !                                                     ! ===========
95      DO jn = 1, kjpt                                       ! tracer loop
96         !                                                  ! ===========
97         ! I. Horizontal advective fluxes
98         ! ------------------------------
99         ! first guess of the slopes
100         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
101         ! interior values
102         DO jk = 1, jpkm1
103            DO jj = 1, jpjm1     
104               DO ji = 1, fs_jpim1   ! vector opt.
105                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
106                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
107               END DO
108           END DO
109         END DO
110         !
111         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
112         CALL lbc_lnk( zwy, 'V', -1. )
113         !                                             !-- Slopes of tracer
114         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
115         DO jk = 1, jpkm1                                     ! interior values
116            DO jj = 2, jpj
117               DO ji = fs_2, jpi   ! vector opt.
118                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
119                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
120                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
121                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
122               END DO
123            END DO
124         END DO
125         !
126         DO jk = 1, jpkm1                                     ! Slopes limitation
127            DO jj = 2, jpj
128               DO ji = fs_2, jpi   ! vector opt.
129                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
130                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
131                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
132                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
133                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
134                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
135               END DO
136           END DO
137         END DO             ! interior values
138
139         !                                             !-- MUSCL horizontal advective fluxes
140         DO jk = 1, jpkm1                                     ! interior values
141            zdt  = z2 * rdttra(jk)
142            DO jj = 2, jpjm1
143               DO ji = fs_2, fs_jpim1   ! vector opt.
144                  ! MUSCL fluxes
145                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
146                  zalpha = 0.5 - z0u
147                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
148                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
149                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
150                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
151                  !
152                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
153                  zalpha = 0.5 - z0v
154                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
155                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
156                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk) 
157                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
158               END DO
159            END DO
160         END DO
161         !                                                    ! lateral boundary conditions on zwx, zwy   (changed sign)
162         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )
163         !
164         ! Tracer flux divergence at t-point added to the general trend
165         DO jk = 1, jpkm1
166            DO jj = 2, jpjm1     
167               DO ji = fs_2, fs_jpim1   ! vector opt.
168                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
169                  ! horizontal advective trends
170                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
171                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
172                  ! add it to the general tracer trends
173                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
174               END DO
175           END DO
176         END DO       
177         !                                 ! trend diagnostics (contribution of upstream fluxes)
178         IF( l_trd )  THEN
179            CALL trd_tra( kt, cdtype, jn, jpt_trd_xad, zwx, pun, ptb(:,:,:,jn) )
180            CALL trd_tra( kt, cdtype, jn, jpt_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
181         END IF
182         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
183         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
184            IF( lk_zco ) THEN
185               DO jk = 1, jpkm1
186                  DO jj = 2, jpjm1
187                     DO ji = fs_2, fs_jpim1   ! vector opt.
188                       zwy(ji,jj,jk) = zwy(ji,jj,jk) * fse3v(ji,jj,jk)                 
189                     END DO
190                  END DO
191               END DO
192            ENDIF
193            IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) )
194            IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) )
195         ENDIF
196
197         ! II. Vertical advective fluxes
198         ! -----------------------------
199         !                                             !-- first guess of the slopes
200         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
201         DO jk = 2, jpkm1                                     ! interior values
202            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
203         END DO
204
205         !                                             !-- Slopes of tracer
206         zslpx(:,:,1) = 0.e0                                  ! surface values
207         DO jk = 2, jpkm1                                     ! interior value
208            DO jj = 1, jpj
209               DO ji = 1, jpi
210                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
211                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
212               END DO
213            END DO
214         END DO
215         !                                             !-- Slopes limitation
216         DO jk = 2, jpkm1                                     ! interior values
217            DO jj = 1, jpj
218               DO ji = 1, jpi
219                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
220                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
221                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
222               END DO
223            END DO
224         END DO
225         !                                             !-- vertical advective flux
226         !                                                    ! surface values  (bottom already set to zero)
227         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
228         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
229         ENDIF 
230         !
231         DO jk = 1, jpkm1                                     ! interior values
232            zdt  = z2 * rdttra(jk)
233            DO jj = 2, jpjm1     
234               DO ji = fs_2, fs_jpim1   ! vector opt.
235                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
236                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
237                  zalpha = 0.5 + z0w
238                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr 
239                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
240                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
241                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
242               END DO
243            END DO
244         END DO
245
246         ! Compute & add the vertical advective trend
247         DO jk = 1, jpkm1
248            DO jj = 2, jpjm1     
249               DO ji = fs_2, fs_jpim1   ! vector opt.
250                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
251                  ! vertical advective trends
252                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
253                  ! add it to the general tracer trends
254                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
255               END DO
256            END DO
257         END DO
258         !                                 ! Save the vertical advective trends for diagnostic
259         IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jpt_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
260         !
261      ENDDO
262      !
263   END SUBROUTINE tra_adv_muscl
264
265   !!======================================================================
266END MODULE traadv_muscl
Note: See TracBrowser for help on using the repository browser.