New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traldf.F90 @ 2082

Last change on this file since 2082 was 2082, checked in by cetlod, 14 years ago

Improve the merge of TRA-TRC, see ticket #717
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 16.2 KB
Line 
1MODULE traldf
2   !!======================================================================
3   !!                       ***  MODULE  traldf  ***
4   !! Ocean Active tracers : lateral diffusive trends
5   !!=====================================================================
6   !! History :  9.0  ! 2005-11 (G. Madec)  Original code
7   !!       NEMO 3.0  ! 2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_ldf     : update the tracer trend with the lateral diffusion
12   !!       ldf_ctl : initialization, namelist read, and parameters control
13   !!       ldf_ano : compute lateral diffusion for constant T-S profiles
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE phycst          ! physical constants
18   USE ldftra_oce      ! ocean tracer   lateral physics
19   USE ldfslp          ! ???
20   USE traldf_bilapg   ! lateral mixing            (tra_ldf_bilapg routine)
21   USE traldf_bilap    ! lateral mixing             (tra_ldf_bilap routine)
22   USE traldf_iso      ! lateral mixing               (tra_ldf_iso routine)
23   USE traldf_lap      ! lateral mixing               (tra_ldf_lap routine)
24   USE trdmod_oce      ! ocean space and time domain
25   USE trdtra          ! ocean active tracers trends
26   USE prtctl          ! Print control
27   USE in_out_manager  ! I/O manager
28   USE lib_mpp         ! distribued memory computing library
29   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_ldf         ! called by step.F90
35   PUBLIC   tra_ldf_init    ! called by opa.F90
36   !
37   INTEGER ::   nldf = 0   ! type of lateral diffusion used defined from ln_traldf_... namlist logicals)
38#if defined key_traldf_ano
39   REAL, DIMENSION(jpi,jpj,jpk) ::   t0_ldf, s0_ldf   ! lateral diffusion trends of T & S
40      !                                               ! for a constant vertical profile
41#endif
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE tra_ldf( kt )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_ldf  ***
57      !!
58      !! ** Purpose :   compute the lateral ocean tracer physics.
59      !!
60      !!----------------------------------------------------------------------
61      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
62      !!
63      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::  ztrdt, ztrds
64      !!----------------------------------------------------------------------
65
66      IF( l_trdtra )   THEN                    !* Save ta and sa trends
67         ALLOCATE( ztrdt(jpi,jpj,jpk) )   ;    ztrdt(:,:,:) = tsa(:,:,:,jp_tem) 
68         ALLOCATE( ztrds(jpi,jpj,jpk) )   ;    ztrds(:,:,:) = tsa(:,:,:,jp_sal)
69      ENDIF
70
71      SELECT CASE ( nldf )                       ! compute lateral mixing trend and add it to the general trend
72      CASE ( 0 )   ;   CALL tra_ldf_lap   ( kt, 'TRA', gtsu, gtsv, tsb, tsa, jpts        )  ! iso-level laplacian
73      CASE ( 1 )   ;   CALL tra_ldf_iso   ( kt, 'TRA', gtsu, gtsv, tsb, tsa, jpts, ahtb0 )  ! rotated laplacian
74      CASE ( 2 )   ;   CALL tra_ldf_bilap ( kt, 'TRA', gtsu, gtsv, tsb, tsa, jpts        )  ! iso-level bilaplacian
75      CASE ( 3 )   ;   CALL tra_ldf_bilapg( kt, 'TRA',             tsb, tsa, jpts        )  ! s-coord. horizontal bilaplacian
76         !
77      CASE ( -1 )                                     ! esopa: test all possibility with control print
78         CALL tra_ldf_lap   ( kt, 'TRA', gtsu, gtsv, tsb, tsa, jpts        ) 
79         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' ldf0 - Ta: ', mask1=tmask,               &
80         &             tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
81         CALL tra_ldf_iso   ( kt, 'TRA', gtsu, gtsv, tsb, tsa, jpts, ahtb0 ) 
82         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' ldf1 - Ta: ', mask1=tmask,               &
83         &             tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
84         CALL tra_ldf_bilap ( kt, 'TRA', gtsu, gtsv, tsb, tsa, jpts        ) 
85         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' ldf2 - Ta: ', mask1=tmask,               &
86         &             tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
87         CALL tra_ldf_bilapg( kt, 'TRA',             tsb, tsa, jpts        ) 
88         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' ldf3 - Ta: ', mask1=tmask,               &
89         &             tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
90      END SELECT
91
92#if defined key_traldf_ano
93      tsa(:,:,:,jp_tem) = tsa(:,:,:,jp_tem) - t0_ldf(:,:,:)      ! anomaly: substract the reference diffusivity
94      tsa(:,:,:,jp_sal) = tsa(:,:,:,jp_sal) - s0_ldf(:,:,:)
95#endif
96
97      IF( l_trdtra )   THEN                      ! save the horizontal diffusive trends for further diagnostics
98         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
99         ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:)
100         CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_ldf, ztrdt )
101         CALL trd_tra( kt, 'TRA', jp_sal, jptra_trd_ldf, ztrds )
102         DEALLOCATE( ztrdt )      ;     DEALLOCATE( ztrds ) 
103      ENDIF
104      !                                          ! print mean trends (used for debugging)
105      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' ldf  - Ta: ', mask1=tmask,               &
106         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
107      !
108   END SUBROUTINE tra_ldf
109
110
111   SUBROUTINE tra_ldf_init
112      !!----------------------------------------------------------------------
113      !!                  ***  ROUTINE tra_ldf_init  ***
114      !!
115      !! ** Purpose :   Choice of the operator for the lateral tracer diffusion
116      !!
117      !! ** Method  :   set nldf from the namtra_ldf logicals
118      !!      nldf == -1   ESOPA test: ALL operators are used
119      !!      nldf ==  0   laplacian operator
120      !!      nldf ==  1   Rotated laplacian operator
121      !!      nldf ==  2   bilaplacian operator
122      !!      nldf ==  3   Rotated bilaplacian
123      !!----------------------------------------------------------------------
124      INTEGER ::   ioptio, ierr         ! temporary integers
125!     
126!     NAMELIST/namtra_ldf/ ln_traldf_lap  , ln_traldf_bilap,                  &
127!        &                 ln_traldf_level, ln_traldf_hor  , ln_traldf_iso,   &
128!        &                 rn_aht_0       , rn_ahtb_0      , rn_aeiv_0
129      !!----------------------------------------------------------------------
130
131      !  Define the lateral mixing oparator for tracers
132      ! ===============================================
133   
134!     REWIND( numnam )                ! Namelist namtra_ldf already read in ldftra module
135!     READ  ( numnam, namtra_ldf )   
136
137      IF(lwp) THEN                    ! Namelist print
138         WRITE(numout,*)
139         WRITE(numout,*) 'tra_ldf_init : lateral tracer diffusive operator'
140         WRITE(numout,*) '~~~~~~~~~~~'
141         WRITE(numout,*) '   Namelist namtra_ldf : set lateral mixing parameters (type, direction, coefficients)'
142         WRITE(numout,*) '      laplacian operator          ln_traldf_lap   = ', ln_traldf_lap
143         WRITE(numout,*) '      bilaplacian operator        ln_traldf_bilap = ', ln_traldf_bilap
144         WRITE(numout,*) '      iso-level                   ln_traldf_level = ', ln_traldf_level
145         WRITE(numout,*) '      horizontal (geopotential)   ln_traldf_hor   = ', ln_traldf_hor
146         WRITE(numout,*) '      iso-neutral                 ln_traldf_iso   = ', ln_traldf_iso
147      ENDIF
148
149      !                               ! control the input
150      ioptio = 0
151      IF( ln_traldf_lap   )   ioptio = ioptio + 1
152      IF( ln_traldf_bilap )   ioptio = ioptio + 1
153      IF( ioptio >  1 )   CALL ctl_stop( '          use ONE or NONE of the 2 lap/bilap operator type on tracer' )
154      IF( ioptio == 0 )   nldf = -2   ! No lateral diffusion
155      ioptio = 0
156      IF( ln_traldf_level )   ioptio = ioptio + 1
157      IF( ln_traldf_hor   )   ioptio = ioptio + 1
158      IF( ln_traldf_iso   )   ioptio = ioptio + 1
159      IF( ioptio /= 1 )   CALL ctl_stop( '          use only ONE direction (level/hor/iso)' )
160
161      ! defined the type of lateral diffusion from ln_traldf_... logicals
162      ! CAUTION : nldf = 1 is used in trazdf_imp, change it carefully
163      ierr = 0
164      IF( ln_traldf_lap ) THEN       ! laplacian operator
165         IF ( ln_zco ) THEN                ! z-coordinate
166            IF ( ln_traldf_level )   nldf = 0      ! iso-level  (no rotation)
167            IF ( ln_traldf_hor   )   nldf = 0      ! horizontal (no rotation)
168            IF ( ln_traldf_iso   )   nldf = 1      ! isoneutral (   rotation)
169         ENDIF
170         IF ( ln_zps ) THEN             ! z-coordinate
171            IF ( ln_traldf_level )   ierr = 1      ! iso-level not allowed
172            IF ( ln_traldf_hor   )   nldf = 0      ! horizontal (no rotation)
173            IF ( ln_traldf_iso   )   nldf = 1      ! isoneutral (   rotation)
174         ENDIF
175         IF ( ln_sco ) THEN             ! z-coordinate
176            IF ( ln_traldf_level )   nldf = 0      ! iso-level  (no rotation)
177            IF ( ln_traldf_hor   )   nldf = 1      ! horizontal (   rotation)
178            IF ( ln_traldf_iso   )   nldf = 1      ! isoneutral (   rotation)
179         ENDIF
180      ENDIF
181
182      IF( ln_traldf_bilap ) THEN      ! bilaplacian operator
183         IF ( ln_zco ) THEN                ! z-coordinate
184            IF ( ln_traldf_level )   nldf = 2      ! iso-level  (no rotation)
185            IF ( ln_traldf_hor   )   nldf = 2      ! horizontal (no rotation)
186            IF ( ln_traldf_iso   )   ierr = 2      ! isoneutral (   rotation)
187         ENDIF
188         IF ( ln_zps ) THEN             ! z-coordinate
189            IF ( ln_traldf_level )   ierr = 1      ! iso-level not allowed
190            IF ( ln_traldf_hor   )   nldf = 2      ! horizontal (no rotation)
191            IF ( ln_traldf_iso   )   ierr = 2      ! isoneutral (   rotation)
192         ENDIF
193         IF ( ln_sco ) THEN             ! z-coordinate
194            IF ( ln_traldf_level )   nldf = 2      ! iso-level  (no rotation)
195            IF ( ln_traldf_hor   )   nldf = 3      ! horizontal (   rotation)
196            IF ( ln_traldf_iso   )   ierr = 2      ! isoneutral (   rotation)
197         ENDIF
198      ENDIF
199
200      IF( ierr == 1 )   CALL ctl_stop( ' iso-level in z-coordinate - partial step, not allowed' )
201      IF( ierr == 2 )   CALL ctl_stop( ' isoneutral bilaplacian operator does not exist' )
202      IF( lk_traldf_eiv .AND. .NOT.ln_traldf_iso )   &
203           CALL ctl_stop( '          eddy induced velocity on tracers',   &
204           &              ' the eddy induced velocity on tracers requires isopycnal laplacian diffusion' )
205      IF( nldf == 1 .OR. nldf == 3 ) THEN      ! rotation
206         IF( .NOT.lk_ldfslp )   CALL ctl_stop( '          the rotation of the diffusive tensor require key_ldfslp' )
207         l_traldf_rot = .TRUE.                 ! needed for trazdf_imp
208      ENDIF
209
210      IF( lk_esopa ) THEN
211         IF(lwp) WRITE(numout,*) '          esopa control: use all lateral physics options'
212         nldf = -1
213      ENDIF
214
215      IF(lwp) THEN
216         WRITE(numout,*)
217         IF( nldf == -2 )   WRITE(numout,*) '          NO lateral diffusion'
218         IF( nldf == -1 )   WRITE(numout,*) '          ESOPA test All scheme used'
219         IF( nldf ==  0 )   WRITE(numout,*) '          laplacian operator'
220         IF( nldf ==  1 )   WRITE(numout,*) '          Rotated laplacian operator'
221         IF( nldf ==  2 )   WRITE(numout,*) '          bilaplacian operator'
222         IF( nldf ==  3 )   WRITE(numout,*) '          Rotated bilaplacian'
223      ENDIF
224
225      ! Reference T & S diffusivity (if necessary)
226      ! ===========================
227      CALL ldf_ano
228      !
229   END SUBROUTINE tra_ldf_init
230
231#if defined key_traldf_ano
232   !!----------------------------------------------------------------------
233   !!   'key_traldf_ano'               T & S lateral diffusion on anomalies
234   !!----------------------------------------------------------------------
235
236   SUBROUTINE ldf_ano
237      !!----------------------------------------------------------------------
238      !!                  ***  ROUTINE ldf_ano  ***
239      !!
240      !! ** Purpose :   initializations of
241      !!----------------------------------------------------------------------
242      USE zdf_oce         ! vertical mixing
243      USE trazdf          ! vertical mixing: double diffusion
244      USE zdfddm          ! vertical mixing: double diffusion
245      !!
246      INTEGER  ::   jk              ! Dummy loop indice
247      LOGICAL  ::   llsave          !
248      REAL(wp) ::   zt0, zs0, z12   ! temporary scalar
249      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zt_ref, ztb, zavt   ! 3D workspace
250      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zs_ref, zsb         ! 3D workspace
251      !!----------------------------------------------------------------------
252
253      IF(lwp) THEN
254         WRITE(numout,*)
255         WRITE(numout,*) 'tra:ldf_ano : lateral diffusion acting on anomalies'
256         WRITE(numout,*) '~~~~~~~~~~~'
257      ENDIF
258
259      ! defined the T & S reference profiles
260      ! ------------------------------------
261      zt0 =10.e0                               ! homogeneous ocean
262      zs0 =35.e0
263      zt_ref(:,:,:) = 10.0 * tmask(:,:,:)
264      zs_ref(:,:,:) = 35.0 * tmask(:,:,:)
265      IF(lwp) WRITE(numout,*) '              homogeneous ocean T = ', zt0, ' S = ',zs0
266
267      !                                        ! T & S profile (to be coded +namelist parameter
268
269      ! prepare the ldf computation
270      ! ---------------------------
271      llsave = l_trdtra
272      l_trdtra = .false.      ! desactivate trend computation
273      t0_ldf(:,:,:) = 0.e0
274      s0_ldf(:,:,:) = 0.e0
275      ztb   (:,:,:) = tsb (:,:,:,jp_tem)
276      zsb   (:,:,:) = tsb (:,:,:,jp_sal)
277      ua    (:,:,:) = tsa (:,:,:,jp_tem)
278      va    (:,:,:) = tsa (:,:,:,jp_sal)
279      zavt  (:,:,:) = avt(:,:,:)
280      IF( lk_zdfddm ) THEN CALL ctl_stop( ' key_traldf_ano with key_zdfddm not implemented' )
281      ! set tb, sb to reference values and avr to zero
282      tsb (:,:,:,jp_tem) = zt_ref(:,:,:)
283      tsb (:,:,:,jp_sal) = zs_ref(:,:,:)
284      tsa (:,:,:,jp_tem) = 0.e0
285      tsa (:,:,:,jp_sal) = 0.e0
286      avt(:,:,:)         = 0.e0
287
288      ! Compute the ldf trends
289      ! ----------------------
290      CALL tra_ldf( nit000+1 )      ! horizontal components (+1: no more init)
291      CALL tra_zdf( nit000   )      ! vertical component (if necessary nit000 to performed the init)
292
293      ! finalise the computation and recover all arrays
294      ! -----------------------------------------------
295      l_trdtra = llsave
296      z12 = 2.e0
297      IF( neuler == 1)   z12 = 1.e0
298      IF( ln_zdfexp ) THEN      ! ta,sa are the trends
299         t0_ldf(:,:,:) = tsa(:,:,:,jp_tem)
300         s0_ldf(:,:,:) = tsa(:,:,:,jp_sal)
301      ELSE
302         DO jk = 1, jpkm1
303            t0_ldf(:,:,jk) = ( tsa(:,:,jk,jp_tem) - tsb(:,:,jk,jp_tem) ) / ( z12 *rdttra(jk) )
304            s0_ldf(:,:,jk) = ( tsa(:,:,jk,jp_sal) - tsb(:,:,jk,jp_sal) ) / ( z12 *rdttra(jk) )
305         END DO
306      ENDIF
307      tsb(:,:,:,jp_tem) = ztb (:,:,:)
308      tsb(:,:,:,jp_sal) = zsb (:,:,:)
309      tsa(:,:,:,jp_tem) = ua  (:,:,:)
310      tsa(:,:,:,jp_sal) = va  (:,:,:)
311      avt(:,:,:)        = zavt(:,:,:)
312      !
313   END SUBROUTINE ldf_ano
314
315#else
316   !!----------------------------------------------------------------------
317   !!   default option :   Dummy code   NO T & S background profiles
318   !!----------------------------------------------------------------------
319   SUBROUTINE ldf_ano
320      IF(lwp) THEN
321         WRITE(numout,*)
322         WRITE(numout,*) 'tra:ldf_ano : lateral diffusion acting on the full fields'
323         WRITE(numout,*) '~~~~~~~~~~~'
324      ENDIF
325   END SUBROUTINE ldf_ano
326#endif
327
328   !!======================================================================
329END MODULE traldf
Note: See TracBrowser for help on using the repository browser.