New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_bilap.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traldf_bilap.F90 @ 2034

Last change on this file since 2034 was 2034, checked in by cetlod, 14 years ago

cosmetic changes
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 9.0 KB
Line 
1MODULE traldf_bilap
2   !!==============================================================================
3   !!                   ***  MODULE  traldf_bilap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :     !  91-11  (G. Madec)  Original code
7   !!               !  93-03  (M. Guyon)  symetrical conditions
8   !!               !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!               !  96-01  (G. Madec)  statement function for e3
10   !!               !  96-01  (M. Imbard)  mpp exchange
11   !!               !  97-07  (G. Madec)  optimization, and ahtt
12   !!          8.5  !  02-08  (G. Madec)  F90: Free form and module
13   !!          9.0  !  04-08  (C. Talandier) New trends organization
14   !!               !  05-11  (G. Madec)  zps or sco as default option
15   !!          3.3  !  10-05  (C. Ethe, G. Madec)  merge TRC-TRA
16   !!==============================================================================
17
18   !!----------------------------------------------------------------------
19   !!   tra_ldf_bilap : update the tracer trend with the horizontal diffusion
20   !!                   using a iso-level biharmonic operator
21   !!----------------------------------------------------------------------
22   !! * Modules used
23   USE oce             ! ocean dynamics and active tracers
24   USE dom_oce         ! ocean space and time domain
25   USE ldftra_oce      ! ocean tracer   lateral physics
26   USE in_out_manager  ! I/O manager
27   USE ldfslp          ! iso-neutral slopes
28   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
29   USE diaptr          ! poleward transport diagnostics
30
31   IMPLICIT NONE
32   PRIVATE
33
34   !! * Routine accessibility
35   PUBLIC tra_ldf_bilap   ! routine called by step.F90
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "ldftra_substitute.h90"
40#  include "ldfeiv_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
44   !! $Id$
45   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
46   !!----------------------------------------------------------------------
47
48CONTAINS
49 
50   SUBROUTINE tra_ldf_bilap( kt, cdtype, pgu, pgv,  &
51      &                                  ptb, pta, kjpt ) 
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_ldf_bilap  ***
54      !!
55      !! ** Purpose :   Compute the before horizontal tracer diffusive
56      !!      trend and add it to the general trend of tracer equation.
57      !!
58      !! ** Method  :   4th order diffusive operator along model level surfaces
59      !!      evaluated using before fields (forward time scheme). The hor.
60      !!      diffusive trends  is given by:
61      !!      Laplacian of tb:
62      !!         zlt   = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(tb) ]
63      !!                                  + dj-1[ e1v*e3v/e2v dj(tb) ]  }
64      !!      Multiply by the eddy diffusivity coef. and insure lateral bc:
65      !!        zlt   = ahtt * zlt
66      !!        call to lbc_lnk
67      !!      Bilaplacian (laplacian of zlt):
68      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(zlt) ]
69      !!                                  + dj-1[ e1v*e3v/e2v dj(zlt) ]  }
70      !!
71      !!      Add this trend to the general trend
72      !!         (pta) = (pta) + ( difft )
73      !!
74      !! ** Action : - Update pta arrays with the before iso-level
75      !!               biharmonic mixing trend.
76      !!----------------------------------------------------------------------
77      !!
78      USE oce         , ztu => ua   ! use ua as workspace
79      USE oce         , ztv => va   ! use va as workspace
80      !!
81      INTEGER         , INTENT(in   )                                ::   kt             ! ocean time-step index
82      CHARACTER(len=3), INTENT(in   )                                ::   cdtype         ! =TRA or TRC (tracer indicator)
83      INTEGER         , INTENT(in   )                                ::   kjpt            ! number of tracers
84      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,kjpt  )     ::   pgu, pgv     ! tracer gradient at pstep levels
85      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)   ::   ptb          ! before and now tracer fields
86      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)   ::   pta          ! tracer trend
87      !!
88      INTEGER  ::  ji, jj, jk, jn         ! dummy loop indices
89      INTEGER  ::  iku, ikv               ! temporary integers
90      REAL(wp) ::  zbtr, ztra             ! temporary scalars
91      REAL(wp), DIMENSION(jpi,jpj) ::   & 
92         zeeu, zeev, zlt               ! 2D workspace
93      !!----------------------------------------------------------------------
94
95      IF( kt == nit000 ) THEN
96         IF(lwp) WRITE(numout,*)
97         IF(lwp) WRITE(numout,*) 'tra_ldf_bilap : iso-level biharmonic operator'
98         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
99      ENDIF
100      !                                                          ! ===========
101      DO jn = 1, kjpt                                            ! tracer loop
102         !                                                       ! ===========
103         !                                               
104         DO jk = 1, jpkm1                                 
105            !                                             
106           
107            ! 0. Initialization of metric arrays (for z- or s-coordinates)
108            ! ----------------------------------
109            DO jj = 1, jpjm1
110               DO ji = 1, fs_jpim1   ! vector opt.
111                  zeeu(ji,jj) = e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj) * umask(ji,jj,jk)
112                  zeev(ji,jj) = e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj) * vmask(ji,jj,jk)
113               END DO
114            END DO
115
116
117            ! 1. Laplacian
118            ! ------------
119           
120            ! First derivative (gradient)
121            DO jj = 1, jpjm1
122               DO ji = 1, fs_jpim1   ! vector opt.
123                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
124                  ztv(ji,jj,jk) = zeev(ji,jj) * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
125               END DO
126            END DO
127            IF( ln_zps ) THEN      ! set gradient at partial step level
128               DO jj = 1, jpjm1
129                  DO ji = 1, jpim1
130                     ! last level
131                     iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
132                     ikv = MIN ( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
133                     IF( iku == jk )  ztu(ji,jj,jk) = zeeu(ji,jj) * pgu(ji,jj,jn)
134                     IF( ikv == jk )  ztv(ji,jj,jk) = zeev(ji,jj) * pgv(ji,jj,jn)
135                  END DO
136               END DO
137            ENDIF
138
139            ! Second derivative (divergence) multiply by the eddy diffusivity coefficient
140            DO jj = 2, jpjm1
141               DO ji = fs_2, fs_jpim1   ! vector opt.
142                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
143                  zlt(ji,jj) = fsahtt(ji,jj,jk) &
144                     &                * zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
145               END DO
146            END DO
147
148            ! Lateral boundary conditions on the laplacian (zlt)   (unchanged sgn)
149            CALL lbc_lnk( zlt, 'T', 1. )
150
151            ! 2. Bilaplacian
152            ! --------------
153           
154            ! third derivative (gradient)
155            DO jj = 1, jpjm1
156               DO ji = 1, fs_jpim1   ! vector opt.
157                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( zlt(ji+1,jj  ) - zlt(ji,jj) )
158                  ztv(ji,jj,jk) = zeev(ji,jj) * ( zlt(ji  ,jj+1) - zlt(ji,jj) )
159               END DO
160            END DO
161
162            ! fourth derivative (divergence) and add to the general tracer trend
163            DO jj = 2, jpjm1
164               DO ji = fs_2, fs_jpim1   ! vector opt.
165                  ! horizontal diffusive trends
166                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
167                  ztra = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
168                  ! add it to the general tracer trends
169                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
170               END DO
171            END DO
172            !                                             ! ===============
173         END DO                                           ! Horizontal slab
174         !                                                ! ===============
175         ! "zonal" mean lateral diffusive heat and salt transport
176         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
177           IF( jn == jp_tem )  pht_ldf(:) = ptr_vj( ztv(:,:,:) )
178           IF( jn == jp_sal )  pst_ldf(:) = ptr_vj( ztv(:,:,:) )
179         ENDIF
180         !
181      END DO
182
183   END SUBROUTINE tra_ldf_bilap
184
185   !!==============================================================================
186END MODULE traldf_bilap
Note: See TracBrowser for help on using the repository browser.