New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 2082

Last change on this file since 2082 was 2082, checked in by cetlod, 14 years ago

Improve the merge of TRA-TRC, see ticket #717
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 15.8 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :   OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!                  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!             NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!             1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!             3.0  !  2008-01  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_iso  : update the tracer trend with the horizontal
18   !!                  component of a iso-neutral laplacian operator
19   !!                  and with the vertical part of
20   !!                  the isopycnal or geopotential s-coord. operator
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and active tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ldftra_oce      ! ocean active tracers: lateral physics
25   USE zdf_oce         ! ocean vertical physics
26   USE in_out_manager  ! I/O manager
27   USE iom             !
28   USE ldfslp          ! iso-neutral slopes
29   USE diaptr          ! poleward transport diagnostics
30   USE trc_oce         ! share passive tracers/Ocean variables
31#if defined key_diaar5
32   USE phycst          ! physical constants
33   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
34#endif
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_ldf_iso   ! routine called by step.F90
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "ldftra_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50
51CONTAINS
52
53   SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv,  &
54      &                                ptb, pta, kjpt, pahtb0 )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_ldf_iso  ***
57      !!
58      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
59      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
60      !!      add it to the general trend of tracer equation.
61      !!
62      !! ** Method  :   The horizontal component of the lateral diffusive trends
63      !!      is provided by a 2nd order operator rotated along neural or geopo-
64      !!      tential surfaces to which an eddy induced advection can be added
65      !!      It is computed using before fields (forward in time) and isopyc-
66      !!      nal or geopotential slopes computed in routine ldfslp.
67      !!
68      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
69      !!      ========    with partial cell update if ln_zps=T.
70      !!
71      !!      2nd part :  horizontal fluxes of the lateral mixing operator
72      !!      ========   
73      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
74      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
75      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
76      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
77      !!      take the horizontal divergence of the fluxes:
78      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
79      !!      Add this trend to the general trend (ta,sa):
80      !!         ta = ta + difft
81      !!
82      !!      3rd part: vertical trends of the lateral mixing operator
83      !!      ========  (excluding the vertical flux proportional to dk[t] )
84      !!      vertical fluxes associated with the rotated lateral mixing:
85      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
86      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
87      !!      take the horizontal divergence of the fluxes:
88      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
89      !!      Add this trend to the general trend (ta,sa):
90      !!         pta = pta + difft
91      !!
92      !! ** Action :   Update pta arrays with the before rotated diffusion
93      !!----------------------------------------------------------------------
94      !!* Module used
95      USE oce         , zftu => ua   ! use ua as workspace
96      USE oce         , zftv => va   ! use va as workspace
97      !!* Arguments
98      INTEGER         , INTENT(in   )                                ::   kt             ! ocean time-step index
99      CHARACTER(len=3), INTENT(in   )                                ::   cdtype         ! =TRA or TRC (tracer indicator)
100      INTEGER         , INTENT(in   )                                ::   kjpt            ! number of tracers
101      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,kjpt  )     ::   pgu, pgv     ! tracer gradient at pstep levels
102      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)   ::   ptb          ! before and now tracer fields
103      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)   ::   pta          ! tracer trend
104      REAL(wp)        , INTENT(in   )                                ::   pahtb0         ! background diffusion coef
105      !!* Local declarations
106      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
107      INTEGER  ::  iku, ikv     ! temporary integer
108      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! temporary scalars
109      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !    "         "
110      REAL(wp) ::  zcoef0, zbtr, ztra                           !    "         "
111      REAL(wp), DIMENSION(jpi,jpj)     ::   zdkt, zdk1t         ! 2D workspace
112      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, ztfw     ! 3D workspace
113#if defined key_diaar5
114      REAL(wp), DIMENSION(jpi,jpj)     ::   z2d                  !  "         "
115      REAL(wp)                         ::   zztmp                !  "         "
116#endif
117      !!----------------------------------------------------------------------
118
119      IF( ( cdtype == 'TRA' .AND. kt == nit000 ) .OR. ( cdtype == 'TRC' .AND. kt == nittrc000 ) )  THEN
120         IF(lwp) WRITE(numout,*)
121         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
122         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
123      ENDIF
124      !
125      !                                                          ! ===========
126      DO jn = 1, kjpt                                            ! tracer loop
127         !                                                       ! ===========
128         !                                               
129         !!----------------------------------------------------------------------
130         !!   I - masked horizontal derivative
131         !!----------------------------------------------------------------------
132         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
133         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
134         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
135         !!end
136
137         ! Horizontal tracer gradient
138         DO jk = 1, jpkm1
139            DO jj = 1, jpjm1
140               DO ji = 1, fs_jpim1   ! vector opt.
141                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
142                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
143               END DO
144            END DO
145         END DO
146         IF( ln_zps ) THEN      ! partial steps correction at the last level
147            DO jj = 1, jpjm1
148               DO ji = 1, fs_jpim1   ! vector opt.
149                  ! last level
150                  iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
151                  ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
152                  zdit(ji,jj,iku) = pgu(ji,jj,jn)         
153                  zdjt(ji,jj,ikv) = pgv(ji,jj,jn)     
154               END DO
155            END DO
156         ENDIF
157
158         !!----------------------------------------------------------------------
159         !!   II - horizontal trend  (full)
160         !!----------------------------------------------------------------------
161         
162!CDIR PARALLEL DO PRIVATE( zdk1t )
163         !                                                ! ===============
164         DO jk = 1, jpkm1                                 ! Horizontal slab
165            !                                             ! ===============
166            ! 1. Vertical tracer gradient at level jk and jk+1
167            ! ------------------------------------------------
168            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
169           
170            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
171           
172            IF( jk == 1 ) THEN
173               zdkt(:,:) = zdk1t(:,:)
174            ELSE
175               zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
176            ENDIF
177
178
179            ! 2. Horizontal fluxes
180            ! --------------------
181           
182            DO jj = 1 , jpjm1
183               DO ji = 1, fs_jpim1   ! vector opt.
184                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
185                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
186                 
187                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
188                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
189                 
190                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
191                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
192                 
193                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
194                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
195                  !
196                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
197                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
198                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
199                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
200                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
201                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
202               END DO
203            END DO
204
205
206            ! II.4 Second derivative (divergence) and add to the general trend
207            ! ----------------------------------------------------------------
208            DO jj = 2 , jpjm1
209               DO ji = fs_2, fs_jpim1   ! vector opt.
210                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
211                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
212                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
213               END DO
214            END DO
215            !                                          ! ===============
216         END DO                                        !   End of slab 
217         !                                             ! ===============
218         ! "Poleward" diffusive heat or salt transports
219         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
220            IF( jn == jp_tem)   pht_ldf(:) = ptr_vj( zftv(:,:,:) )
221            IF( jn == jp_sal)   pst_ldf(:) = ptr_vj( zftv(:,:,:) )
222         ENDIF
223 
224#if defined key_diaar5
225         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
226            zztmp = 0.5 * rau0 * rcp 
227            z2d(:,:) = 0.e0 
228            DO jk = 1, jpkm1
229               DO jj = 2, jpjm1
230                  DO ji = fs_2, fs_jpim1   ! vector opt.
231                     z2d(ji,jj) = z2d(ji,jj) + zztmp * zftu(ji,jj,jk)   &
232            &                    * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) * e1u(ji,jj) * fse3u(ji,jj,jk) 
233                  END DO
234               END DO
235            END DO
236            CALL lbc_lnk( z2d, 'U', -1. )
237            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
238            z2d(:,:) = 0.e0 
239            DO jk = 1, jpkm1
240               DO jj = 2, jpjm1
241                  DO ji = fs_2, fs_jpim1   ! vector opt.
242                     z2d(ji,jj) = z2d(ji,jj) + zztmp * zftv(ji,jj,jk)   &
243           &                   * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) * e2v(ji,jj) * fse3v(ji,jj,jk) 
244                  END DO
245               END DO
246            END DO
247            CALL lbc_lnk( z2d, 'V', -1. )
248            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
249         END IF
250#endif
251
252         !!----------------------------------------------------------------------
253         !!   III - vertical trend of T & S (extra diagonal terms only)
254         !!----------------------------------------------------------------------
255         
256         ! Local constant initialization
257         ! -----------------------------
258         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
259         
260         ! Vertical fluxes
261         ! ---------------
262         
263         ! Surface and bottom vertical fluxes set to zero
264         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
265         
266         ! interior (2=<jk=<jpk-1)
267         DO jk = 2, jpkm1
268            DO jj = 2, jpjm1
269               DO ji = fs_2, fs_jpim1   ! vector opt.
270                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
271                 
272                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
273                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
274                 
275                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
276                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
277                 
278                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
279                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
280                 
281                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
282                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
283                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
284                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
285               END DO
286            END DO
287         END DO
288         
289         
290         ! I.5 Divergence of vertical fluxes added to the general tracer trend
291         ! -------------------------------------------------------------------
292         
293         DO jk = 1, jpkm1
294            DO jj = 2, jpjm1
295               DO ji = fs_2, fs_jpim1   ! vector opt.
296                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
297                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
298                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
299               END DO
300            END DO
301         END DO
302         !
303      END DO
304      !
305   END SUBROUTINE tra_ldf_iso
306
307#else
308   !!----------------------------------------------------------------------
309   !!   default option :   Dummy code   NO rotation of the diffusive tensor
310   !!----------------------------------------------------------------------
311CONTAINS
312   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
313      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
314   END SUBROUTINE tra_ldf_iso
315#endif
316
317   !!==============================================================================
318END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.