New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2082

Last change on this file since 2082 was 2082, checked in by cetlod, 14 years ago

Improve the merge of TRA-TRC, see ticket #717
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 8.0 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
17   !!                 using a iso-level harmonic (laplacien) operator.
18   !!----------------------------------------------------------------------
19   !! * Modules used
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26
27
28   IMPLICIT NONE
29   PRIVATE
30
31   !! * Routine accessibility
32   PUBLIC tra_ldf_lap  ! routine called by step.F90
33
34   REAL(wp), DIMENSION(jpi,jpj) ::   e1ur, e2vr   ! scale factor coefficients
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "ldftra_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
42   !! $Id$
43   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
44   !!----------------------------------------------------------------------
45   
46CONTAINS
47
48   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,  &
49      &                                ptb, pta, kjpt ) 
50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE tra_ldf_lap  ***
52      !!                   
53      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
54      !!      trend and add it to the general trend of tracer equation.
55      !!
56      !! ** Method  :   Second order diffusive operator evaluated using before
57      !!      fields (forward time scheme). The horizontal diffusive trends of
58      !!      the tracer is given by:
59      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
60      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
61      !!     Note: key_zco defined, the e3t=e3u=e3v, the trend becomes: 
62      !!          difft = 1/(e1t*e2t) {  di-1[ aht e2u/e1u di(tb) ]
63      !!                               + dj-1[ aht e1v/e2v dj(tb) ] }
64      !!      Add this trend to the general tracer trend pta :
65      !!          pta = pta + difft
66      !!
67      !! ** Action  : - Update pta arrays with the before iso-level
68      !!                harmonic mixing trend.
69      !!----------------------------------------------------------------------
70      !!
71      USE oce         , ztu => ua   ! use ua as workspace
72      USE oce         , ztv => va   ! use va as workspace
73      !!
74      INTEGER         , INTENT(in   )                                ::   kt             ! ocean time-step index
75      CHARACTER(len=3), INTENT(in   )                                ::   cdtype         ! =TRA or TRC (tracer indicator)
76      INTEGER         , INTENT(in   )                                ::   kjpt            ! number of tracers
77      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,kjpt  )     ::   pgu, pgv     ! tracer gradient at pstep levels
78      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)   ::   ptb          ! before and now tracer fields
79      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)   ::   pta          ! tracer trend
80      !!
81      INTEGER ::   ji, jj, jk, jn          ! dummy loop indices
82      INTEGER ::   iku, ikv                ! temporary integers
83      REAL(wp) ::   &
84         zabe1, zabe2, ztra, zbtr           ! temporary scalars
85      !!----------------------------------------------------------------------
86     
87      IF( ( cdtype == 'TRA' .AND. kt == nit000 ) .OR. ( cdtype == 'TRC' .AND. kt == nittrc000 ) )  THEN
88         IF(lwp) WRITE(numout,*)
89         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
90         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
91         e1ur(:,:) = e2u(:,:) / e1u(:,:)
92         e2vr(:,:) = e1v(:,:) / e2v(:,:)
93      ENDIF
94
95      !
96      DO jn = 1, kjpt                                            ! tracer loop
97         !                                                       ! ===========     
98         !                                                 
99         DO jk = 1, jpkm1                               
100            !                                           
101            ! 1. First derivative (gradient)
102            ! -------------------
103            DO jj = 1, jpjm1
104               DO ji = 1, fs_jpim1   ! vector opt.
105                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
106                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
107                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
108                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
109               END DO
110            END DO
111            IF( ln_zps ) THEN      ! set gradient at partial step level
112               DO jj = 1, jpjm1
113                  DO ji = 1, fs_jpim1   ! vector opt.
114                     ! last level
115                     iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
116                     ikv = MIN ( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
117                     IF( iku == jk ) THEN
118                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
119                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
120                     ENDIF
121                     IF( ikv == jk ) THEN
122                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
123                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
124                     ENDIF
125                  END DO
126               END DO
127            ENDIF
128         
129         
130            ! 2. Second derivative (divergence) added to the general tracer trends
131            ! ---------------------------------------------------------------------
132            DO jj = 2, jpjm1
133               DO ji = fs_2, fs_jpim1   ! vector opt.
134                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
135                  ! horizontal diffusive trends
136                  ztra = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
137                     &           + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
138                  ! add it to the general tracer trends
139                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
140               END DO
141            END DO
142            !                                               ! =============
143         END DO                                             !  End of slab 
144         !                                                  ! =============
145         ! "Poleward" diffusive heat or salt transports
146         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
147            IF( jn  == jp_tem)   pht_ldf(:) = ptr_vj( ztv(:,:,:) )
148            IF( jn  == jp_sal)   pst_ldf(:) = ptr_vj( ztv(:,:,:) )
149         ENDIF
150         !
151      END DO
152      !
153   END SUBROUTINE tra_ldf_lap
154
155   !!==============================================================================
156END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.