New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 2104

Last change on this file since 2104 was 2104, checked in by cetlod, 14 years ago

update DEV_r2006_merge_TRA_TRC according to review
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 7.8 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6   !! History :  OPA  !  87-06  (P. Andrich, D. L Hostis)  Original code
7   !!                 !  91-11  (G. Madec)
8   !!                 !  95-11  (G. Madec)  suppress volumetric scale factors
9   !!                 !  96-01  (G. Madec)  statement function for e3
10   !!            NEMO !  02-06  (G. Madec)  F90: Free form and module
11   !!            1.0  !  04-08  (C. Talandier) New trends organization
12   !!                 !  05-11  (G. Madec)  add zps case
13   !!            3.0  !  10-06  (C. Ethe, G. Madec) Merge TRA-TRC
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
18   !!                 using a iso-level harmonic (laplacien) operator.
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE ldftra_oce      ! ocean active tracers: lateral physics
23   USE in_out_manager  ! I/O manager
24   USE diaptr          ! poleward transport diagnostics
25   USE trc_oce         ! share passive tracers/Ocean variables
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   tra_ldf_lap   ! routine called by step.F90
31
32   REAL(wp), DIMENSION(jpi,jpj) ::   e1ur, e2vr   ! scale factor coefficients
33
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "ldftra_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , LOCEAN-IPSL (2010)
40   !! $Id$
41   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
42   !!----------------------------------------------------------------------
43   
44CONTAINS
45
46   SUBROUTINE tra_ldf_lap( kt, cdtype, pgu, pgv,   &
47      &                                ptb, pta, kjpt ) 
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE tra_ldf_lap  ***
50      !!                   
51      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
52      !!      trend and add it to the general trend of tracer equation.
53      !!
54      !! ** Method  :   Second order diffusive operator evaluated using before
55      !!      fields (forward time scheme). The horizontal diffusive trends of
56      !!      the tracer is given by:
57      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
58      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
59      !!     Note: key_zco defined, the e3t=e3u=e3v, the trend becomes: 
60      !!          difft = 1/(e1t*e2t) {  di-1[ aht e2u/e1u di(tb) ]
61      !!                               + dj-1[ aht e1v/e2v dj(tb) ] }
62      !!      Add this trend to the general tracer trend pta :
63      !!          pta = pta + difft
64      !!
65      !! ** Action  : - Update pta arrays with the before iso-level
66      !!                harmonic mixing trend.
67      !!----------------------------------------------------------------------
68      USE oce         , ztu => ua   ! use ua as workspace
69      USE oce         , ztv => va   ! use va as workspace
70      !!
71      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
72      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
73      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
74      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
76      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
77      !!
78      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
79      INTEGER  ::   iku, ikv             ! local integers
80      REAL(wp) ::   zabe1, zabe2, zbtr   ! local scalars
81      !!----------------------------------------------------------------------
82     
83      IF( kt == nit000 )  THEN
84         IF(lwp) WRITE(numout,*)
85         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype
86         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
87         e1ur(:,:) = e2u(:,:) / e1u(:,:)
88         e2vr(:,:) = e1v(:,:) / e2v(:,:)
89      ENDIF
90
91      !                                                          ! =========== !
92      DO jn = 1, kjpt                                            ! tracer loop !
93         !                                                       ! =========== !   
94         DO jk = 1, jpkm1                                            ! slab loop
95            !                                           
96            ! 1. First derivative (gradient)
97            ! -------------------
98            DO jj = 1, jpjm1
99               DO ji = 1, fs_jpim1   ! vector opt.
100                  zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * e1ur(ji,jj) * fse3u(ji,jj,jk)
101                  zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * e2vr(ji,jj) * fse3v(ji,jj,jk)
102                  ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) )
103                  ztv(ji,jj,jk) = zabe2 * ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
104               END DO
105            END DO
106            IF( ln_zps ) THEN      ! set gradient at partial step level
107               DO jj = 1, jpjm1
108                  DO ji = 1, fs_jpim1   ! vector opt.
109                     ! last level
110                     iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
111                     ikv = MIN ( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
112                     IF( iku == jk ) THEN
113                        zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * e1ur(ji,jj) * fse3u(ji,jj,iku)
114                        ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn)
115                     ENDIF
116                     IF( ikv == jk ) THEN
117                        zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * e2vr(ji,jj) * fse3v(ji,jj,ikv)
118                        ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn)
119                     ENDIF
120                  END DO
121               END DO
122            ENDIF
123         
124         
125            ! 2. Second derivative (divergence) added to the general tracer trends
126            ! ---------------------------------------------------------------------
127            DO jj = 2, jpjm1
128               DO ji = fs_2, fs_jpim1   ! vector opt.
129                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
130                  ! horizontal diffusive trends added to the general tracer trends
131                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
132                     &                                          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
133               END DO
134            END DO
135            !
136         END DO                                             !  End of slab 
137         !
138         ! "Poleward" diffusive heat or salt transports
139         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
140            IF( jn  == jp_tem)   pht_ldf(:) = ptr_vj( ztv(:,:,:) )
141            IF( jn  == jp_sal)   pst_ldf(:) = ptr_vj( ztv(:,:,:) )
142         ENDIF
143         !                                                  ! ==================
144      END DO                                                ! end of tracer loop
145      !                                                     ! ==================
146   END SUBROUTINE tra_ldf_lap
147
148   !!==============================================================================
149END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.