New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/zpshde.F90 @ 2024

Last change on this file since 2024 was 2024, checked in by cetlod, 14 years ago

Merge of active and passive tracer advection/diffusion modules, see ticket:693
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 15.9 KB
Line 
1MODULE zpshde
2   !!==============================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate - partial step : Horizontal Derivative
5   !!==============================================================================
6   !! History :
7   !!       OPA   8.5  !  2002-04  (A. Bozec)  Original code
8   !!             8.5  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
9   !!             9.0  !  2004-03  (C. Ethe)  adapted for passive tracers
10   !!      NEMO   3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
11   !!==============================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!   zps_hde_trc  :  Horizontal DErivative of passive tracers at the last
17   !!                   ocean level (Z-coord. with Partial Steps)
18   !!----------------------------------------------------------------------
19   !! * Modules used
20   USE dom_oce         ! ocean space domain variables
21   USE oce             ! ocean dynamics and tracers variables
22   USE phycst          ! physical constants
23   USE in_out_manager  ! I/O manager
24   USE eosbn2          ! ocean equation of state
25   USE lbclnk          ! lateral boundary conditions (or mpp link)
26
27   IMPLICIT NONE
28   PRIVATE
29
30   !! * Routine accessibility
31   PUBLIC zps_hde          ! routine called by step.F90
32   PUBLIC zps_hde_init     ! routine called by opa.F90
33#if defined key_top
34   PUBLIC zps_hde_trc 
35#endif
36
37   !! * module variables
38   INTEGER, DIMENSION(jpi,jpj) ::   &
39      mbatu, mbatv      ! bottom ocean level index at U- and V-points
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !!----------------------------------------------------------------------
46   !!  OPA 9.0 , LOCEAN-IPSL (2005)
47   !! $Id$
48   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
49   !!----------------------------------------------------------------------
50CONTAINS
51   SUBROUTINE zps_hde ( kt, ptem, psal, prd ,   &
52                            pgtu, pgsu, pgru,   &
53                            pgtv, pgsv, pgrv  )
54      !!----------------------------------------------------------------------
55      !!                     ***  ROUTINE zps_hde  ***
56      !!                   
57      !! ** Purpose :   Compute the horizontal derivative of T, S and rd
58      !!      at u- and v-points with a linear interpolation for z-coordinate
59      !!      with partial steps.
60      !!
61      !! ** Method  :   In z-coord with partial steps, scale factors on last
62      !!      levels are different for each grid point, so that T, S and rd
63      !!      points are not at the same depth as in z-coord. To have horizontal
64      !!      gradients again, we interpolate T and S at the good depth :
65      !!      Linear interpolation of T, S   
66      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
67      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
68      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
69      !!         This formulation computes the two cases:
70      !!                 CASE 1                   CASE 2 
71      !!         k-1  ___ ___________   k-1   ___ ___________
72      !!                    Ti  T~                  T~  Ti+1
73      !!                  _____                        _____
74      !!         k        |   |Ti+1     k           Ti |   |
75      !!                  |   |____                ____|   |
76      !!              ___ |   |   |           ___  |   |   |
77      !!                 
78      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
79      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
80      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
81      !!          or
82      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
83      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
84      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
85      !!          Idem for di(s) and dj(s)         
86      !!
87      !!      For rho, we call eos_insitu_2d which will compute rd~(t~,s~) at
88      !!      the good depth zh from interpolated T and S for the different
89      !!      formulation of the equation of state (eos).
90      !!      Gradient formulation for rho :
91      !!          di(rho) = rd~ - rd(i,j,k) or rd (i+1,j,k) - rd~
92      !!
93      !! ** Action  : - pgtu, pgsu, pgru: horizontal gradient of T, S
94      !!                and rd at U-points
95      !!              - pgtv, pgsv, pgrv: horizontal gradient of T, S
96      !!                and rd at V-points
97      !!----------------------------------------------------------------------
98      !! * Arguments
99      INTEGER, INTENT( in ) ::   kt ! ocean time-step index
100      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT( in )  :: ptem, psal, prd  ! 3D T, S and rd fields
101      REAL(wp), DIMENSION(jpi,jpj)    , INTENT( out ) :: pgtu, pgsu, pgru !  horizontal grad. of T, S and rd at u-point
102      REAL(wp), DIMENSION(jpi,jpj)    , INTENT( out ) :: pgtv, pgsv, pgrv !  horizontal grad. of T, S and rd at v-point
103      !! * Local declarations
104      INTEGER ::   ji , jj          ! Dummy loop indices
105      INTEGER ::   iku, ikv         ! partial step level at u- and v-points
106      REAL(wp), DIMENSION(jpi,jpj) ::   zti, ztj, zsi, zsj   ! interpolated value of T, S
107      REAL(wp), DIMENSION(jpi,jpj) ::   zri, zrj             ! interpolated value of rd
108      REAL(wp), DIMENSION(jpi,jpj) ::   zhgi, zhgj           ! depth of interpolation for eos2d
109      REAL(wp) :: ze3wu, ze3wv, zmaxu, zmaxv                 ! temporary scalars
110
111
112      ! Interpolation of T and S at the last ocean level
113# if defined key_vectopt_loop
114         jj = 1
115         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
116# else
117      DO jj = 1, jpjm1
118         DO ji = 1, jpim1
119# endif
120            ! last level
121            iku = mbatu(ji,jj)
122            ikv = mbatv(ji,jj)
123            ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
124            ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
125
126            ! i- direction
127            IF( ze3wu >= 0. ) THEN      ! case 1
128               ! interpolated values of T and S
129               zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
130               zti(ji,jj) = ptem(ji+1,jj,iku) + zmaxu * ( ptem(ji+1,jj,iku-1) - ptem(ji+1,jj,iku) )
131               zsi(ji,jj) = psal(ji+1,jj,iku) + zmaxu * ( psal(ji+1,jj,iku-1) - psal(ji+1,jj,iku) )
132               ! depth of the partial step level
133               zhgi(ji,jj) = fsdept(ji,jj,iku)
134               ! gradient of T and S
135               pgtu(ji,jj) = umask(ji,jj,1) * ( zti(ji,jj) - ptem(ji,jj,iku) )
136               pgsu(ji,jj) = umask(ji,jj,1) * ( zsi(ji,jj) - psal(ji,jj,iku) )
137
138            ELSE                        ! case 2
139               ! interpolated values of T and S
140               zmaxu =  -ze3wu / fse3w(ji,jj,iku)
141               zti(ji,jj) = ptem(ji,jj,iku) + zmaxu * ( ptem(ji,jj,iku-1) - ptem(ji,jj,iku) )
142               zsi(ji,jj) = psal(ji,jj,iku) + zmaxu * ( psal(ji,jj,iku-1) - psal(ji,jj,iku) )
143               ! depth of the partial step level
144               zhgi(ji,jj) = fsdept(ji+1,jj,iku)
145               ! gradient of T and S
146               pgtu(ji,jj) = umask(ji,jj,1) * ( ptem(ji+1,jj,iku) - zti (ji,jj) )
147               pgsu(ji,jj) = umask(ji,jj,1) * ( psal(ji+1,jj,iku) - zsi (ji,jj) )
148            ENDIF
149
150            ! j- direction
151            IF( ze3wv >= 0. ) THEN      ! case 1
152               ! interpolated values of T and S
153               zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
154               ztj(ji,jj) = ptem(ji,jj+1,ikv) + zmaxv * ( ptem(ji,jj+1,ikv-1) - ptem(ji,jj+1,ikv) )
155               zsj(ji,jj) = psal(ji,jj+1,ikv) + zmaxv * ( psal(ji,jj+1,ikv-1) - psal(ji,jj+1,ikv) )
156               ! depth of the partial step level
157               zhgj(ji,jj) = fsdept(ji,jj,ikv) 
158               ! gradient of T and S
159               pgtv(ji,jj) = vmask(ji,jj,1) * ( ztj(ji,jj) - ptem(ji,jj,ikv) )
160               pgsv(ji,jj) = vmask(ji,jj,1) * ( zsj(ji,jj) - psal(ji,jj,ikv) )
161
162            ELSE                        ! case 2
163               ! interpolated values of T and S
164               zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
165               ztj(ji,jj) = ptem(ji,jj,ikv) + zmaxv * ( ptem(ji,jj,ikv-1) - ptem(ji,jj,ikv) )
166               zsj(ji,jj) = psal(ji,jj,ikv) + zmaxv * ( psal(ji,jj,ikv-1) - psal(ji,jj,ikv) ) 
167               ! depth of the partial step level
168               zhgj(ji,jj) = fsdept(ji,jj+1,ikv) 
169               ! gradient of T and S
170               pgtv(ji,jj) = vmask(ji,jj,1) * ( ptem(ji,jj+1,ikv) - ztj(ji,jj) )
171               pgsv(ji,jj) = vmask(ji,jj,1) * ( psal(ji,jj+1,ikv) - zsj(ji,jj) )
172            ENDIF
173# if ! defined key_vectopt_loop
174         END DO
175# endif
176      END DO
177
178      ! Compute interpolated rd from zti, zsi, ztj, zsj for the 2 cases at the depth of the partial
179      ! step and store it in  zri, zrj for each  case
180      CALL eos( zti, zsi, zhgi, zri )
181      CALL eos( ztj, zsj, zhgj, zrj )
182
183
184      ! Gradient of density at the last level
185# if defined key_vectopt_loop
186         jj = 1
187         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
188# else
189      DO jj = 1, jpjm1
190         DO ji = 1, jpim1
191# endif
192            iku = mbatu(ji,jj)
193            ikv = mbatv(ji,jj)
194            ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
195            ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
196            IF( ze3wu >= 0. ) THEN    ! i-direction: case 1
197               pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji,jj) - prd(ji,jj,iku) )
198            ELSE                      ! i-direction: case 2
199               pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj) )
200            ENDIF
201            IF( ze3wv >= 0. ) THEN    ! j-direction: case 1
202               pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj) - prd(ji,jj,ikv) ) 
203            ELSE                      ! j-direction: case 2
204               pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )
205            ENDIF
206# if ! defined key_vectopt_loop
207         END DO
208# endif
209      END DO
210
211      ! Lateral boundary conditions on each gradient
212      CALL lbc_lnk( pgtu , 'U', -1. )   ;   CALL lbc_lnk( pgtv , 'V', -1. )
213      CALL lbc_lnk( pgsu , 'U', -1. )   ;   CALL lbc_lnk( pgsv , 'V', -1. )
214      CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )
215
216   END SUBROUTINE zps_hde
217
218#if defined key_top
219   !!----------------------------------------------------------------------
220   !!   'key_top'                                                TOP models
221   !!----------------------------------------------------------------------
222   SUBROUTINE zps_hde_trc ( kt, kjpt, ptra, pgtru, pgtrv )
223      !!----------------------------------------------------------------------
224      !!                     ***  ROUTINE zps_hde_trc  ***
225      !!                   
226      !! ** Purpose :   Compute the horizontal derivative of passive tracers
227      !!      TRA at u- and v-points with a linear interpolation for z-coordinate
228      !!      with partial steps.
229      !!
230      !! ** Method  :   the same for T & S
231      !!
232      !! ** Action  : - pgtru : horizontal gradient of TRA at U-points
233      !!              - pgtrv : horizontal gradient of TRA at V-points
234      !!----------------------------------------------------------------------
235      !! * Arguments
236      INTEGER                              , INTENT( in )  ::  kt    ! ocean time-step index
237      INTEGER                              , INTENT( in )  ::  kjpt  ! number of tracers
238      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT( in )  ::  ptra  ! 4D tracers fields
239      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT( out ) ::  pgtru, pgtrv  ! horizontal grad. of TRA u- and v-points
240      !! * Local declarations
241      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
242      INTEGER  ::   iku, ikv        ! partial step level at u- and v-points
243      REAL(wp) ::   ztrai, ztraj, ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
244      !!----------------------------------------------------------------------
245
246      DO jn = 1, kjpt
247         ! Interpolation of passive tracers at the last ocean level
248# if defined key_vectopt_loop
249         jj = 1
250         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
251# else
252         DO jj = 1, jpjm1
253            DO ji = 1, jpim1
254# endif
255               ! last level
256               iku = mbatu(ji,jj)
257               ikv = mbatv(ji,jj)
258               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
259               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
260
261               ! i- direction
262               IF( ze3wu >= 0. ) THEN      ! case 1
263                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
264                  ! interpolated values of passive tracers
265                  ztrai = ptra(ji+1,jj,iku,jn) + zmaxu * ( ptra(ji+1,jj,iku-1,jn) - ptra(ji+1,jj,iku,jn) )
266                  ! gradient of passive tracers
267                  pgtru(ji,jj,jn) = umask(ji,jj,1) * ( ztrai - ptra(ji,jj,iku,jn) )
268               ELSE                        ! case 2
269                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
270                  ! interpolated values of passive tracers
271                  ztrai = ptra(ji,jj,iku,jn) + zmaxu * ( ptra(ji,jj,iku-1,jn) - ptra(ji,jj,iku,jn) )
272                  ! gradient of passive tracers
273                  pgtru(ji,jj,jn) = umask(ji,jj,1) * ( ptra(ji+1,jj,iku,jn) - ztrai )
274               ENDIF
275
276               ! j- direction
277               IF( ze3wv >= 0. ) THEN      ! case 1
278                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
279                  ! interpolated values of passive tracers
280                  ztraj = ptra(ji,jj+1,ikv,jn) + zmaxv * ( ptra(ji,jj+1,ikv-1,jn) - ptra(ji,jj+1,ikv,jn) )
281                  ! gradient of passive tracers
282                  pgtrv(ji,jj,jn) = vmask(ji,jj,1) * ( ztraj - ptra(ji,jj,ikv,jn) )
283               ELSE                        ! case 2
284                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
285                  ! interpolated values of passive tracers
286                  ztraj = ptra(ji,jj,ikv,jn) + zmaxv * ( ptra(ji,jj,ikv-1,jn) - ptra(ji,jj,ikv,jn) )
287                  ! gradient of passive tracers
288                  pgtrv(ji,jj,jn) = vmask(ji,jj,1) * ( ptra(ji,jj+1,ikv,jn) - ztraj )
289               ENDIF
290# if ! defined key_vectopt_loop
291            END DO
292# endif
293         END DO
294
295         ! Lateral boundary conditions on each gradient
296         CALL lbc_lnk( pgtru(:,:,jn) , 'U', -1. )
297         CALL lbc_lnk( pgtrv(:,:,jn) , 'V', -1. )
298
299      END DO
300
301   END SUBROUTINE zps_hde_trc
302#endif
303
304   SUBROUTINE zps_hde_init
305      !!----------------------------------------------------------------------
306      !!                     ***  ROUTINE zps_hde_init  ***
307      !!
308      !! ** Purpose : Computation of bottom ocean level index at U- and V-points
309      !!                   
310      !!----------------------------------------------------------------------
311      !! * Local declarations
312      INTEGER ::   ji, jj           ! Dummy loop indices
313      REAL(wp), DIMENSION(jpi,jpj) :: zti, ztj     !  temporary arrays
314      !!----------------------------------------------------------------------
315
316      mbatu(:,:) = 0
317      mbatv(:,:) = 0
318      DO jj = 1, jpjm1
319         DO ji = 1, fs_jpim1   ! vector opt.
320            mbatu(ji,jj) = MAX( MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1, 2 )
321            mbatv(ji,jj) = MAX( MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1, 2 )
322         END DO
323      END DO
324      zti(:,:) = FLOAT( mbatu(:,:) )
325      ztj(:,:) = FLOAT( mbatv(:,:) )
326      ! lateral boundary conditions: T-point, sign unchanged
327      CALL lbc_lnk( zti , 'U', 1. )
328      CALL lbc_lnk( ztj , 'V', 1. )
329      mbatu(:,:) = MAX( INT( zti(:,:) ), 2 )
330      mbatv(:,:) = MAX( INT( ztj(:,:) ), 2 )
331
332   END SUBROUTINE zps_hde_init
333   !!======================================================================
334END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.