New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtasal.F90 in branches/DEV_r2106_LOCEAN2010/NEMO/OPA_SRC/DTA – NEMO

source: branches/DEV_r2106_LOCEAN2010/NEMO/OPA_SRC/DTA/dtasal.F90 @ 2236

Last change on this file since 2236 was 2236, checked in by cetlod, 14 years ago

First guess of NEMO_v3.3
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 11.1 KB
Line 
1MODULE dtasal
2   !!======================================================================
3   !!                     ***  MODULE  dtasal  ***
4   !! Ocean data  :  read ocean salinity data from monthly atlas data
5   !!=====================================================================
6#if defined key_dtasal   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_dtasal'                                          salinity data
9   !!----------------------------------------------------------------------
10   !!   dta_sal      : read ocean salinity data
11   !!----------------------------------------------------------------------
12   !! * Modules used
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE fldread         ! read input fields
16   USE in_out_manager  ! I/O manager
17   USE phycst          ! physical constants
18#if defined key_orca_lev10
19   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
20#endif
21
22   IMPLICIT NONE
23   PRIVATE
24
25   !! * Routine accessibility
26   PUBLIC dta_sal   ! called by step.F90 and inidta.F90
27   
28   !! * Shared module variables
29   LOGICAL , PUBLIC, PARAMETER ::   lk_dtasal = .TRUE.    !: salinity data flag
30   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   s_dta    !: salinity data at given time-step
31
32   !! * Module variables
33   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sal       ! structure of input SST (file informations, fields read)
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !!   OPA 9.0 , LOCEAN-IPSL (2005)
39   !! $Id$
40   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   !!----------------------------------------------------------------------
46   !!   Default option:                                         NetCDF file
47   !!----------------------------------------------------------------------
48
49   SUBROUTINE dta_sal( kt )
50      !!----------------------------------------------------------------------
51      !!                   ***  ROUTINE dta_sal  ***
52      !!       
53      !! ** Purpose :   Reads monthly salinity data
54      !!             
55      !! ** Method  : - Read on unit numsdt the monthly salinity data interpo-
56      !!     lated onto the model grid.
57      !!              - At each time step, a linear interpolation is applied
58      !!     between two monthly values.
59      !!
60      !! History :
61      !!        !  91-03  ()  Original code
62      !!        !  92-07  (M. Imbard)
63      !!   9.0  !  02-06  (G. Madec)  F90: Free form and module
64      !!----------------------------------------------------------------------
65      INTEGER, INTENT(in) ::   kt             ! ocean time step
66     
67      INTEGER ::   ji, jj, jk, jl, jkk            ! dummy loop indicies
68      INTEGER ::   ik, ierror                     ! temporary integers
69#if defined key_tradmp
70      INTEGER ::   il0, il1, ii0, ii1, ij0, ij1   ! temporary integers
71#endif
72      REAL(wp)::   zl
73     
74#if defined key_orca_lev10
75      INTEGER ::   ikr, ikw, ikt, jjk 
76      REAL(wp)::   zfac
77#endif
78      REAL(wp), DIMENSION(jpk) :: zsaldta         ! auxiliary array for interpolation
79      CHARACTER(len=100)       :: cn_dir          ! Root directory for location of ssr files
80      TYPE(FLD_N)              :: sn_sal
81      LOGICAL , SAVE           :: linit_sal = .FALSE.
82      !!----------------------------------------------------------------------
83      NAMELIST/namdta_sal/cn_dir,sn_sal
84     
85      ! 1. Initialization
86      ! -----------------------
87     
88      IF( kt == nit000 .AND. ( .NOT. linit_sal ) ) THEN
89       
90         !                         ! set file information
91         cn_dir = './'             ! directory in which the model is executed
92         ! ... default values (NB: frequency positive => hours, negative => months)
93         !            !   file    ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
94         !            !   name    !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
95         sn_sal = FLD_N( 'salinity',  -1.  ,  'vosaline',  .false.   , .true.  ,  'monthly'  , ''       , ''         )
96
97         REWIND ( numnam )         ! ... read in namlist namdta_sal
98         READ( numnam, namdta_sal ) 
99
100         IF(lwp) THEN              ! control print
101            WRITE(numout,*)
102            WRITE(numout,*) 'dta_sal : Salinity Climatology '
103            WRITE(numout,*) '~~~~~~~ '
104         ENDIF
105         ALLOCATE( sf_sal(1), STAT=ierror )
106         IF( ierror > 0 ) THEN
107             CALL ctl_stop( 'dta_sal: unable to allocate sf_sal structure' )   ;   RETURN
108         ENDIF
109
110#if defined key_orca_lev10
111                                ALLOCATE( sf_sal(1)%fnow(jpi,jpj,jpkdta)   )
112         IF( sn_sal%ln_tint )   ALLOCATE( sf_sal(1)%fdta(jpi,jpj,jpkdta,2) )
113#else
114                                ALLOCATE( sf_sal(1)%fnow(jpi,jpj,jpk)   )
115         IF( sn_sal%ln_tint )   ALLOCATE( sf_sal(1)%fdta(jpi,jpj,jpk,2) )
116#endif
117         ! fill sf_sal with sn_sal and control print
118         CALL fld_fill( sf_sal, (/ sn_sal /), cn_dir, 'dta_sal', 'Salinity data', 'namdta_sal' )
119         linit_sal = .TRUE.       
120      ENDIF
121     
122      ! 2. Read monthly file
123      ! -------------------
124     
125      CALL fld_read( kt, 1, sf_sal )
126
127      IF( lwp .AND. kt == nit000 ) THEN
128         WRITE(numout,*)
129         WRITE(numout,*) ' read Levitus salinity ok'
130         WRITE(numout,*)
131      ENDIF
132
133#if defined key_tradmp
134      IF( cp_cfg == "orca"  .AND. jp_cfg == 2 ) THEN
135   
136         !                                        ! =======================
137         !                                        !  ORCA_R2 configuration
138         !                                        ! =======================
139         ij0 = 101   ;   ij1 = 109
140         ii0 = 141   ;   ii1 = 155   
141         DO jj = mj0(ij0), mj1(ij1)                  ! Reduced salinity in the Alboran Sea
142            DO ji = mi0(ii0), mi1(ii1)
143               sf_sal(1)%fnow(ji,jj,13:13) = sf_sal(1)%fnow(ji,jj,13:13) - 0.15
144               sf_sal(1)%fnow(ji,jj,14:15) = sf_sal(1)%fnow(ji,jj,14:15) - 0.25
145               sf_sal(1)%fnow(ji,jj,16:17) = sf_sal(1)%fnow(ji,jj,16:17) - 0.30
146               sf_sal(1)%fnow(ji,jj,18:25) = sf_sal(1)%fnow(ji,jj,18:25) - 0.35
147            END DO
148         END DO
149
150         IF( n_cla == 1 ) THEN 
151            !                                         ! New salinity profile at Gibraltar
152            il0 = 138   ;   il1 = 138   
153            ij0 = 101   ;   ij1 = 102
154            ii0 = 139   ;   ii1 = 139   
155            DO jl = mi0(il0), mi1(il1)
156               DO jj = mj0(ij0), mj1(ij1)
157                  DO ji = mi0(ii0), mi1(ii1)
158                        sf_sal(1)%fnow(ji,jj,:) = sf_sal(1)%fnow(jl,jj,:)
159                  END DO
160               END DO
161            END DO
162            !                                         ! New salinity profile at Bab el Mandeb
163            il0 = 164   ;   il1 = 164   
164            ij0 =  87   ;   ij1 =  88
165            ii0 = 161   ;   ii1 = 163   
166            DO jl = mi0(il0), mi1(il1)
167               DO jj = mj0(ij0), mj1(ij1)
168                  DO ji = mi0(ii0), mi1(ii1)
169                     sf_sal(1)%fnow(ji,jj,:) = sf_sal(1)%fnow(jl,jj,:)
170                  END DO
171               END DO
172            END DO
173            !
174         ENDIF
175            !
176      ENDIF
177#endif   
178       
179#if defined key_orca_lev10
180      DO jjk = 1, 5
181         s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,1)
182      ENDDO
183      DO jk = 1, jpk-20,10
184         ikr =  INT(jk/10) + 1
185         ikw =  (ikr-1) *10 + 1
186         ikt =  ikw + 5
187         DO jjk=ikt,ikt+9
188            zfac = ( gdept_0(jjk   ) - gdepw_0(ikt) ) / ( gdepw_0(ikt+10) - gdepw_0(ikt) )
189            s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,ikr) + ( sf_sal(1)%fnow(:,:,ikr+1) - sf_sal(1)%fnow(:,:,ikr) ) * zfac
190         END DO
191      END DO
192      DO jjk = jpk-5, jpk
193         s_dta(:,:,jjk) = sf_sal(1)%fnow(:,:,jpkdta-1)
194      END DO
195      ! fill the overlap areas
196      CALL lbc_lnk (s_dta(:,:,:),'Z',-999.,'no0')       
197#else
198      s_dta(:,:,:)=sf_sal(1)%fnow(:,:,:)
199#endif
200       
201      IF( ln_sco ) THEN
202         DO jj = 1, jpj                  ! interpolation of salinites
203            DO ji = 1, jpi
204               DO jk = 1, jpk
205                  zl=fsdept_0(ji,jj,jk)
206                  IF(zl < gdept_0(1)  ) zsaldta(jk) =  s_dta(ji,jj,1    ) 
207                  IF(zl > gdept_0(jpk)) zsaldta(jk) =  s_dta(ji,jj,jpkm1) 
208                  DO jkk = 1, jpkm1
209                     IF((zl-gdept_0(jkk))*(zl-gdept_0(jkk+1)).le.0.0) THEN
210                          zsaldta(jk) = s_dta(ji,jj,jkk)                                 &
211                                     &           + (zl-gdept_0(jkk))/(gdept_0(jkk+1)-gdept_0(jkk))      &
212                                     &                              *(s_dta(ji,jj,jkk+1) - s_dta(ji,jj,jkk))
213                     ENDIF
214                  END DO
215               END DO
216               DO jk = 1, jpkm1
217                  s_dta(ji,jj,jk) = zsaldta(jk) 
218               END DO
219               s_dta(ji,jj,jpk) = 0.0 
220            END DO
221         END DO
222           
223         IF( lwp .AND. kt==nn_it000 ) THEN
224            WRITE(numout,*)
225            WRITE(numout,*) ' Levitus salinity data interpolated to s-coordinate'
226            WRITE(numout,*)
227         ENDIF
228
229      ELSE
230         !                                  ! Mask
231         s_dta(:,:,:) = s_dta(:,:,:) * tmask(:,:,:)
232         s_dta(:,:,jpk) = 0. 
233         IF( ln_zps ) THEN               ! z-coord. partial steps
234            DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
235               DO ji = 1, jpi
236                  ik = mbathy(ji,jj) - 1
237                  IF( ik > 2 ) THEN
238                     zl = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
239                     s_dta(ji,jj,ik) = (1.-zl) * s_dta(ji,jj,ik) + zl * s_dta(ji,jj,ik-1)
240                  ENDIF
241               END DO
242            END DO
243         ENDIF
244      ENDIF
245       
246      IF( lwp .AND. kt == nit000 ) THEN
247         WRITE(numout,*)' salinity Levitus '
248         WRITE(numout,*)
249         WRITE(numout,*)'  level = 1'
250         CALL prihre(s_dta(:,:,1),    jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)
251         WRITE(numout,*)'  level = ',jpk/2
252         CALL prihre(s_dta(:,:,jpk/2),jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)           
253         WRITE(numout,*) '  level = ',jpkm1
254         CALL prihre(s_dta(:,:,jpkm1),jpi,jpj,1,jpi,20,1,jpj,20,1.,numout)
255      ENDIF
256
257   END SUBROUTINE dta_sal
258
259#else
260   !!----------------------------------------------------------------------
261   !!   Default option:                                    NO salinity data
262   !!----------------------------------------------------------------------
263   LOGICAL , PUBLIC, PARAMETER ::   lk_dtasal = .FALSE.   !: salinity data flag
264CONTAINS
265   SUBROUTINE dta_sal( kt )        ! Empty routine
266      WRITE(*,*) 'dta_sal: You should not have seen this print! error?', kt
267   END SUBROUTINE dta_sal
268#endif
269   !!======================================================================
270END MODULE dtasal
Note: See TracBrowser for help on using the repository browser.