MODULE dynbfr
   !!==============================================================================
   !!                 ***  MODULE  dynbfr  ***
   !! Ocean dynamics :  bottom friction component of the momentum mixing trend
   !!==============================================================================
   !! History :  9.0  !  2008-11  (A. C. Coward)  Original code
   !!----------------------------------------------------------------------

   !!----------------------------------------------------------------------
   !!   dyn_bfr      : Update the momentum trend with the bottom friction contribution
   !!----------------------------------------------------------------------
   USE oce             ! ocean dynamics and tracers variables
   USE dom_oce         ! ocean space and time domain variables 
   USE zdf_oce         ! ocean vertical physics variables
   USE zdfbfr          ! bottom friction

   USE trdmod          ! ocean active dynamics and tracers trends 
   USE trdmod_oce      ! ocean variables trends
   USE in_out_manager  ! I/O manager
   USE prtctl          ! Print control

   IMPLICIT NONE
   PRIVATE

   PUBLIC   dyn_bfr    !  routine called by step.F90

   !! * Substitutions
#  include "domzgr_substitute.h90"
#  include "zdfddm_substitute.h90"
#  include "vectopt_loop_substitute.h90"
   !!----------------------------------------------------------------------
   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009) 
   !! $Id: dynzdf.F90 1152 2008-06-26 14:11:13Z rblod $
   !! Software governed by the CeCILL licence  (NEMOGCM/License_CeCILL.txt)
   !!----------------------------------------------------------------------

CONTAINS
   
   SUBROUTINE dyn_bfr( kt )
      !!----------------------------------------------------------------------
      !!                  ***  ROUTINE dyn_bfr  ***
      !!
      !! ** Purpose :   compute the bottom friction ocean dynamics physics.
      !!
      !! ** Action  :   (ua,va)   momentum trend increased by bottom friction trend
      !!---------------------------------------------------------------------
      USE oce, ONLY :   ztrdu => ta   ! use ta as 3D workspace
      USE oce, ONLY :   ztrdv => sa   ! use sa as 3D workspace
      !!
      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
      !! 
      INTEGER  ::   ji, jj          ! dummy loop indexes
      INTEGER  ::   ikbu  , ikbv    ! temporary integers
      INTEGER  ::   ikbum1, ikbvm1  !    -          -
      REAL(wp) ::   zinv, zbfru, zbfrv   ! temporary scalar
      !!---------------------------------------------------------------------
      !
      zinv = -1. / ( 2.*rdt )

      IF( l_trddyn )   THEN                      ! temporary save of ua and va trends
         ztrdu(:,:,:) = ua(:,:,:)
         ztrdv(:,:,:) = va(:,:,:)
      ENDIF

# if defined key_vectopt_loop
      DO jj = 1, 1
         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
# else
      DO jj = 2, jpjm1
         DO ji = 2, jpim1
# endif
            ikbu = MIN( mbathy(ji+1,jj), mbathy(ji,jj) )
            ikbv = MIN( mbathy(ji,jj+1), mbathy(ji,jj) )
            ikbum1 = MAX( ikbu-1, 1 )
            ikbvm1 = MAX( ikbv-1, 1 )
            !
            ! Apply stability criteria on absolute value  : Min abs(bfr) => Max (bfr)
            zbfru = MAX( bfrua(ji,jj), fse3u(ji,jj,ikbu)*zinv )
            zbfrv = MAX( bfrva(ji,jj), fse3v(ji,jj,ikbv)*zinv )
            !
            ua(ji,jj,ikbum1) = ua(ji,jj,ikbum1) + zbfru * ub(ji,jj,ikbum1) / fse3u(ji,jj,ikbu)
            va(ji,jj,ikbvm1) = va(ji,jj,ikbvm1) + zbfrv * vb(ji,jj,ikbvm1) / fse3v(ji,jj,ikbv)
            !
         END DO
      END DO

      !
      IF( l_trddyn )   THEN                      ! save the vertical diffusive trends for further diagnostics
         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_bfr, 'DYN', kt )
      ENDIF
      !                                          ! print mean trends (used for debugging)
      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' bfr  - Ua: ', mask1=umask,               &
         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
      !
   END SUBROUTINE dyn_bfr

   !!==============================================================================
END MODULE dynbfr