New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_ioipsl.F90 in branches/DEV_r2106_LOCEAN2010/NEMO/OPA_SRC/IOM – NEMO

source: branches/DEV_r2106_LOCEAN2010/NEMO/OPA_SRC/IOM/iom_ioipsl.F90 @ 2200

Last change on this file since 2200 was 2200, checked in by smasson, 14 years ago

merge trunk rev 2198 into DEV_r2106_LOCEAN2010
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 24.1 KB
Line 
1MODULE iom_ioipsl
2   !!=====================================================================
3   !!                    ***  MODULE  iom_ioipsl ***
4   !! Input/Output manager :  Library to read input files with IOIPSL (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_ioipsl_gettime
9   !!--------------------------------------------------------------------
10   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis kvid in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE in_out_manager  ! I/O manager
21   USE dom_oce         ! ocean space and time domain
22   USE iom_def         ! iom variables definitions
23   USE ioipsl          ! IOIPSL library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC iom_ioipsl_open, iom_ioipsl_close, iom_ioipsl_varid, iom_ioipsl_get, iom_ioipsl_gettime, iom_ioipsl_rstput
29
30   INTERFACE iom_ioipsl_get
31      MODULE PROCEDURE iom_ioipsl_g0d, iom_ioipsl_g123d
32   END INTERFACE
33   INTERFACE iom_ioipsl_rstput
34      MODULE PROCEDURE iom_ioipsl_rp0123d
35   END INTERFACE
36   !!----------------------------------------------------------------------
37   !!  OPA 9.0 , LOCEAN-IPSL (2006)
38   !! $Id$
39   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41
42CONTAINS
43
44   SUBROUTINE iom_ioipsl_open( cdname, kiomid, ldwrt, ldok, kdompar )
45      !!---------------------------------------------------------------------
46      !!                   ***  SUBROUTINE  iom_open  ***
47      !!
48      !! ** Purpose :  open an input file with IOIPSL (only fliocom module)
49      !!---------------------------------------------------------------------
50      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
51      INTEGER                , INTENT(  out)           ::   kiomid      ! ioipsl identifier of the opened file
52      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
53      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
54      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
55
56      CHARACTER(LEN=100) ::   clinfo      ! info character
57      CHARACTER(LEN=10 ) ::   clstatus    ! status of opened file (REPLACE or NEW)
58      INTEGER            ::   iln         ! lengths of character
59      INTEGER            ::   istop       ! temporary storage of nstop
60      INTEGER            ::   ifliodom    ! model domain identifier (see flio_dom_set)
61      INTEGER            ::   ioipslid    ! ioipsl identifier of the opened file
62      INTEGER            ::   jl          ! loop variable
63      LOGICAL            ::   llclobber   ! local definition of ln_clobber
64      !---------------------------------------------------------------------
65
66      clinfo = '                    iom_ioipsl_open ~~~  '
67      istop = nstop
68      !
69      llclobber = ldwrt .AND. ln_clobber
70      IF( ldok .AND. .NOT. llclobber ) THEN      ! Open existing file...
71         !                 ! =============
72         IF( ldwrt ) THEN  ! ... in write mode
73            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
74            CALL flioopfd( TRIM(cdname), ioipslid, "WRITE" )
75         ELSE              ! ... in read mode
76            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
77            CALL flioopfd( TRIM(cdname), ioipslid )
78         ENDIF
79      ELSE                 ! the file does not exist
80         !                 ! =============
81         iln = INDEX( cdname, '.nc' )
82         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
83            IF( llclobber ) THEN   ;   clstatus = 'REPLACE 64' 
84            ELSE                   ;   clstatus = 'NEW 64'
85            ENDIF
86            IF( jpnij > 1 ) THEN
87               ! define the domain position regarding to the global domain (mainly useful in mpp)
88               CALL flio_dom_set( jpnij, narea-1, (/1, 2/), (/jpiglo, jpjglo/)   &
89                  &             , kdompar(:,1), kdompar(:,2), kdompar(:,3), kdompar(:,4), kdompar(:,5)   &
90                  &             , 'BOX', ifliodom )       
91               ! Note that fliocrfd may change the value of cdname (add the cpu number...)
92               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname(1:iln-1)//'... in WRITE mode'
93               CALL fliocrfd( cdname, (/'x'         , 'y'         , 'z', 't'/)   &
94                  &         , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid, ifliodom, mode = clstatus )
95            ELSE              ! the file should be open for read mode so it must exist...
96               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname//' in WRITE mode'
97               CALL fliocrfd( cdname, (/'x'         , 'y'         , 'z', 't'/)   &
98                  &         , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid,           mode = clstatus )
99            ENDIF
100         ELSE              ! the file should be open for read mode so it must exist...
101            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
102         ENDIF
103      ENDIF
104      ! start to fill file informations
105      ! =============
106      IF( istop == nstop ) THEN   ! no error within this routine
107!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
108         kiomid = 0
109         DO jl = jpmax_files, 1, -1
110            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
111         ENDDO
112         iom_file(kiomid)%name   = TRIM(cdname)
113         iom_file(kiomid)%nfid   = ioipslid
114         iom_file(kiomid)%iolib  = jpioipsl
115         iom_file(kiomid)%nvars  = 0
116         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files
117         CALL flioinqf( ioipslid, id_uld = iom_file(kiomid)%iduld )
118         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
119      ELSE
120         kiomid = 0               ! return error flag
121      ENDIF
122      !
123   END SUBROUTINE iom_ioipsl_open
124
125
126   SUBROUTINE iom_ioipsl_close( kiomid )
127      !!--------------------------------------------------------------------
128      !!                   ***  SUBROUTINE  iom_ioipsl_close  ***
129      !!
130      !! ** Purpose : close an input file with IOIPSL (only fliocom module)
131      !!--------------------------------------------------------------------
132      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
133      !---------------------------------------------------------------------
134      !
135      CALL flioclo( iom_file(kiomid)%nfid )
136      !   
137   END SUBROUTINE iom_ioipsl_close
138
139
140   FUNCTION iom_ioipsl_varid ( kiomid, cdvar, kiv, kdimsz ) 
141      !!-----------------------------------------------------------------------
142      !!                  ***  FUNCTION  iom_varid  ***
143      !!
144      !! ** Purpose : get the id of a variable in a file with IOIPSL (only fliocom module)
145      !!-----------------------------------------------------------------------
146      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
147      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
148      INTEGER              , INTENT(in   )           ::   kiv   !
149      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
150      !
151      INTEGER                        ::   iom_ioipsl_varid  ! iom variable Id
152      INTEGER                        ::   ioipslid          ! ioipsl file identifier
153      INTEGER                        ::   ji                ! dummy loop index
154      INTEGER                        ::   i_nvd             ! number of dimension of the variable
155      INTEGER, DIMENSION(jpmax_dims) ::   idimid            ! dimension ids of the variable
156      LOGICAL                        ::   ll_fnd            ! found test
157      CHARACTER(LEN=100)             ::   clinfo            ! info character
158      !!-----------------------------------------------------------------------
159      clinfo = 'iom_ioipsl_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar)
160      iom_ioipsl_varid = 0                  ! default definition
161      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
162      ioipslid = iom_file(kiomid)%nfid      ! get back ioipsl file identifier
163      CALL flioinqv( ioipslid, cdvar, ll_fnd, nb_dims = i_nvd )   ! does the variable exist in the file
164      IF( ll_fnd ) THEN
165         IF( i_nvd <= jpmax_dims ) THEN
166            iom_ioipsl_varid = kiv
167            iom_file(kiomid)%nvars       = kiv
168            iom_file(kiomid)%nvid(kiv)   = -1   ! variable id is not available in ioipsl
169            iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
170            iom_file(kiomid)%ndims(kiv)  = i_nvd
171            CALL flioinqv( ioipslid, cdvar, ll_fnd,   &
172                  &           len_dims = iom_file(kiomid)%dimsz(1:i_nvd,kiv), &   ! dimensions size
173                  &           id_dims  = idimid(1:i_nvd) )                        ! dimensions ids
174            iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
175            DO ji = 1, i_nvd                       ! find the unlimited dimension
176               IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.
177            END DO
178            !---------- Deal with scale_factor and add_offset
179            CALL flioinqa( ioipslid, cdvar, 'scale_factor', ll_fnd )
180            IF( ll_fnd) THEN
181               CALL fliogeta( ioipslid, cdvar, 'scale_factor', iom_file(kiomid)%scf(kiv) )
182            ELSE
183               iom_file(kiomid)%scf(kiv) = 1.
184            END IF
185            CALL flioinqa( ioipslid, cdvar, 'add_offset', ll_fnd )
186            IF( ll_fnd ) THEN
187               CALL fliogeta( ioipslid, cdvar, 'add_offset', iom_file(kiomid)%ofs(kiv) )
188            ELSE
189               iom_file(kiomid)%ofs(kiv) = 0.
190            END IF
191            ! return the simension size
192            IF( PRESENT(kdimsz) ) THEN
193               IF( i_nvd == SIZE(kdimsz) ) THEN
194                  kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
195               ELSE
196                  WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
197                  CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
198               ENDIF
199            ENDIF
200         ELSE
201            CALL ctl_stop( TRIM(clinfo), 'Too many dimensions in the file '//iom_file(kiomid)%name,   &
202                  &                       'increase the parameter jpmax_vars')
203         ENDIF
204      ELSE 
205         iom_ioipsl_varid = -1   !   variable not found, return error code: -1
206      ENDIF
207      !
208   END FUNCTION iom_ioipsl_varid
209
210
211   SUBROUTINE iom_ioipsl_g0d( kiomid, kvid, pvar )
212      !!-----------------------------------------------------------------------
213      !!                  ***  ROUTINE  iom_ioipsl_g0d  ***
214      !!
215      !! ** Purpose : read a scalar with IOIPSL (only fliocom module)
216      !!-----------------------------------------------------------------------
217      INTEGER , INTENT(in   ) ::   kiomid    ! Identifier of the file
218      INTEGER , INTENT(in   ) ::   kvid      ! variable id
219      REAL(wp), INTENT(  out) ::   pvar      ! read field
220      !
221      CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), pvar )
222      !
223   END SUBROUTINE iom_ioipsl_g0d
224
225
226   SUBROUTINE iom_ioipsl_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
227         &                      pv_r1d, pv_r2d, pv_r3d)
228      !!-----------------------------------------------------------------------
229      !!                  ***  ROUTINE  iom_ioipsl_g123d  ***
230      !!
231      !! ** Purpose : read a 1D/2D/3D variable with IOIPSL (only fliocom module)
232      !!
233      !! ** Method : read ONE record at each CALL
234      !!-----------------------------------------------------------------------
235      INTEGER                    , INTENT(in   )           ::   kiomid     ! iom identifier of the file
236      INTEGER                    , INTENT(in   )           ::   kvid       ! Name of the variable
237      INTEGER                    , INTENT(in   )           ::   knbdim     ! number of dimensions of the variable
238      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart     ! start position of the reading in each axis
239      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount     ! number of points to be read in each axis
240      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
241      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d     ! read field (1D case)
242      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d     ! read field (2D case)
243      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d     ! read field (3D case)
244      !
245      INTEGER               ::   ioipslid   ! ioipsl file identifier
246      CHARACTER(LEN=100)    ::   clvn       ! variable name
247      !---------------------------------------------------------------------
248      clvn = TRIM(iom_file(kiomid)%cn_var(kvid))   ! get back variable name
249      ioipslid = iom_file(kiomid)%nfid             ! get back IPIPSL file id
250      !
251      IF( PRESENT(pv_r1d) ) THEN
252         CALL fliogetv( ioipslid, clvn, pv_r1d(:                ), start = kstart(1:knbdim), count = kcount(1:knbdim) )
253      ELSEIF( PRESENT(pv_r2d) ) THEN
254         CALL fliogetv( ioipslid, clvn, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim), count = kcount(1:knbdim) )
255      ELSEIF( PRESENT(pv_r3d) ) THEN
256         CALL fliogetv( ioipslid, clvn, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim), count = kcount(1:knbdim) )
257      ENDIF
258      !
259      !
260   END SUBROUTINE iom_ioipsl_g123d
261
262
263   SUBROUTINE iom_ioipsl_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
264      !!--------------------------------------------------------------------
265      !!                   ***  SUBROUTINE iom_gettime  ***
266      !!
267      !! ** Purpose : read the time axis kvid in the file with IOIPSL (only fliocom module)
268      !!--------------------------------------------------------------------
269      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
270      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
271      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
272      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
273      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
274      !---------------------------------------------------------------------
275      !
276      CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), ptime(:),   &
277            &         start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /) )
278      IF ( PRESENT(cdunits) ) THEN
279         CALL fliogeta( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), "units", cdunits )
280      ENDIF
281      IF ( PRESENT(cdcalendar) ) THEN
282         CALL fliogeta( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), "calendar", cdcalendar )
283      ENDIF
284      !
285   END SUBROUTINE iom_ioipsl_gettime
286
287
288   SUBROUTINE iom_ioipsl_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
289         &                                 pv_r0d, pv_r1d, pv_r2d, pv_r3d )
290      !!--------------------------------------------------------------------
291      !!                   ***  SUBROUTINE  iom_ioipsl_rstput  ***
292      !!
293      !! ** Purpose : read the time axis cdvar in the file
294      !!--------------------------------------------------------------------
295      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
296      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
297      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
298      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
299      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
300      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
301      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
302      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
303      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
304      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
305      !
306      INTEGER               :: idims                ! number of dimension
307      INTEGER               :: idvar                ! variable id
308      INTEGER               :: itype                ! variable type
309      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes
310      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
311      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
312      CHARACTER(LEN=100)    :: clinfo               ! info character
313      INTEGER               :: ioipslid             ! ioipsl file identifier
314      !---------------------------------------------------------------------
315      !
316      clinfo = '          iom_ioipsl_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
317      ioipslid = iom_file(kiomid)%nfid
318      !
319      ! define dimension variables if it is not already done
320      ! ==========================
321      IF( iom_file(kiomid)%nvars == 0 ) THEN
322         ! define the dimension variables if it is not already done
323         CALL fliodefv( ioipslid,'nav_lon', (/1,2/), v_t=flio_r4   , axis='X',   &
324               &                  long_name="Longitude", units="degrees_east" )
325         CALL fliodefv( ioipslid,'nav_lat', (/1,2/), v_t=flio_r4   , axis='Y',   &
326               &                  long_name="Latitude", units="degrees_north" )
327         CALL fliodefv( ioipslid,'nav_lev', (/3/)  , v_t=flio_i4   , axis='Z',   &
328               &                  long_name="Model levels",units="model_levels")
329         CALL fliodefv( ioipslid,'time_counter', (/4/), v_t=flio_r4, axis='T',   &
330               &                  long_name="Time axis", units='seconds since 0001-01-01 00:00:00' )
331         ! update informations structure related the dimension variable we just added...
332         iom_file(kiomid)%nvars       = 4
333         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
334         iom_file(kiomid)%cn_var(1:3) = (/ 'nav_lon', 'nav_lat', 'nav_lev' /)
335         iom_file(kiomid)%cn_var(4)   = 'time_counter'
336         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
337         ! trick: defined to 0 to say that dimension variables are defined but not yet written
338         iom_file(kiomid)%dimsz(1, 1) = 0   
339         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
340      ENDIF
341
342      ! define the data if it is not already done
343      ! ===============
344      IF( kvid <= 0 ) THEN
345         ! variable definition
346         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
347         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
348         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
349         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
350         ENDIF
351         IF( PRESENT(ktype) ) THEN   ! variable external type
352            SELECT CASE (ktype)
353            CASE (jp_r8)  ;   itype = flio_r8
354            CASE (jp_r4)  ;   itype = flio_r4
355            CASE (jp_i4)  ;   itype = flio_i4
356            CASE (jp_i2)  ;   itype = flio_i2
357            CASE (jp_i1)  ;   itype = flio_i1   !   fliocom does not handle i1 type of variable
358            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
359            END SELECT
360         ELSE
361            itype = flio_r8
362         ENDIF
363         IF( PRESENT(pv_r0d) ) THEN   ;   CALL fliodefv (ioipslid, TRIM(cdvar)                 , v_t = itype)
364         ELSE                         ;   CALL fliodefv (ioipslid, TRIM(cdvar), idimid(1:idims), v_t = itype)
365         ENDIF
366         ! update informations structure related the new variable we want to add...
367         idvar                          = iom_file(kiomid)%nvars + 1
368         iom_file(kiomid)%nvars         = idvar
369         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
370         iom_file(kiomid)%nvid(idvar)   = -1   ! netcdf variable id is not available in ioipsl
371         iom_file(kiomid)%scf(idvar)    = 1.
372         iom_file(kiomid)%ofs(idvar)    = 0.
373         iom_file(kiomid)%ndims(idvar)  = idims
374         IF( .NOT. PRESENT(pv_r0d) ) THEN
375            iom_file(kiomid)%luld(idvar) = .TRUE.
376            CALL flioinqf( ioipslid, ln_dim = idimsz )
377            iom_file(kiomid)%dimsz(1:idims-1,idvar) = idimsz(idimid(1:idims-1))
378         ELSE                               
379            iom_file(kiomid)%luld(idvar) = .FALSE.
380         ENDIF
381         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
382      ELSE
383         idvar = kvid
384      ENDIF
385
386      ! time step kwrite : write the variable
387      IF( kt == kwrite ) THEN
388         ! on what kind of domain must the data be written?
389         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
390            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
391            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
392               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
393            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
394               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
395            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
396               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
397            ELSE
398               CALL ctl_stop( 'iom_ioipsl_rp0123d: should have been an impossible case...' )
399            ENDIF
400
401            ! write dimension variables if it is not already done
402            ! =============
403            ! trick: is defined to 0 => dimension variable are defined but not yet written
404            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
405               CALL flioputv( ioipslid, 'nav_lon'     , glamt(ix1:ix2, iy1:iy2) )
406               CALL flioputv( ioipslid, 'nav_lat'     , gphit(ix1:ix2, iy1:iy2) )
407               CALL flioputv( ioipslid, 'nav_lev'     , gdept_0 )
408               ! +++ WRONG VALUE: to be improved but not really useful...
409               CALL flioputv( ioipslid, 'time_counter', kt )
410               ! update the values of the variables dimensions size
411               CALL flioinqf( ioipslid, ln_dim = idimsz )
412               iom_file(kiomid)%dimsz(1:2, 1) = idimsz(1:2)
413               iom_file(kiomid)%dimsz(1:2, 2) = idimsz(1:2)
414               iom_file(kiomid)%dimsz(1, 3:4) = (/idimsz(3), 1/)
415               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
416            ENDIF
417         ENDIF
418
419         ! write the data
420         ! =============
421         IF(     PRESENT(pv_r0d) ) THEN   ;   CALL flioputv( ioipslid, cdvar, pv_r0d                      )
422         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   CALL flioputv( ioipslid, cdvar, pv_r1d(                  :) )
423         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   CALL flioputv( ioipslid, cdvar, pv_r2d(ix1:ix2, iy1:iy2   ) )
424         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   CALL flioputv( ioipslid, cdvar, pv_r3d(ix1:ix2, iy1:iy2, :) )
425         ENDIF
426         ! add 1 to the size of the temporal dimension (not really useful...)
427         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
428               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
429         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
430      ENDIF
431      !     
432   END SUBROUTINE iom_ioipsl_rp0123d
433
434
435   !!======================================================================
436END MODULE iom_ioipsl
Note: See TracBrowser for help on using the repository browser.