New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limistate_2.F90 in branches/NERC/dev_r3874_FASTNEt/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: branches/NERC/dev_r3874_FASTNEt/NEMOGCM/NEMO/LIM_SRC_2/limistate_2.F90 @ 6736

Last change on this file since 6736 was 6736, checked in by jamesharle, 8 years ago

FASTNEt code modifications

  • Property svn:keywords set to Id
File size: 10.9 KB
Line 
1MODULE limistate_2
2   !!======================================================================
3   !!                     ***  MODULE  limistate_2  ***
4   !!              Initialisation of diagnostics ice variables
5   !!======================================================================
6   !! History :   1.0  !  01-04  (C. Ethe, G. Madec)  Original code
7   !!             2.0  !  03-08  (G. Madec)  add lim_istate_init
8   !!                  !  04-04  (S. Theetten) initialization from a file
9   !!                  !  06-07  (S. Masson)  IOM to read the restart
10   !!                  !  07-10  (G. Madec)  surface module
11   !!--------------------------------------------------------------------
12#if defined key_lim2
13   !!----------------------------------------------------------------------
14   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   lim_istate_2      :  Initialisation of diagnostics ice variables
18   !!   lim_istate_init_2 :  initialization of ice state and namelist read
19   !!----------------------------------------------------------------------
20   USE phycst
21   USE par_ice_2       ! ice parameters
22   USE dom_ice_2
23   USE eosbn2          ! equation of state
24   USE lbclnk
25   USE oce
26   USE ice_2
27   USE iom
28   USE in_out_manager
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC lim_istate_2      ! routine called by lim_init_2.F90
34
35   !!! ** init namelist (namiceini) **
36   LOGICAL  ::   ln_limini = .FALSE.  !: Ice initialization state
37   REAL(wp) ::   ttest     = 2.0      ! threshold water temperature for initial sea ice
38   REAL(wp) ::   hninn     = 0.5      ! initial snow thickness in the north
39   REAL(wp) ::   hginn     = 3.0      ! initial ice thickness in the north
40   REAL(wp) ::   alinn     = 0.05     ! initial leads area in the north
41   REAL(wp) ::   hnins     = 0.1      ! initial snow thickness in the south
42   REAL(wp) ::   hgins     = 1.0      ! initial ice thickness in the south
43   REAL(wp) ::   alins     = 0.1      ! initial leads area in the south
44   
45   REAL(wp) ::   zero      = 0.e0     ! constant value = 0
46   REAL(wp) ::   zone      = 1.e0     ! constant value = 1
47   !!----------------------------------------------------------------------
48   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52
53CONTAINS
54
55   SUBROUTINE lim_istate_2
56      !!-------------------------------------------------------------------
57      !!                    ***  ROUTINE lim_istate_2  ***
58      !!
59      !! ** Purpose :   defined the sea-ice initial state
60      !!
61      !! ** Method  :   restart from a state defined in a binary file
62      !!                or from arbitrary sea-ice conditions
63      !!--------------------------------------------------------------------
64      INTEGER  ::   ji, jj, jk                ! dummy loop indices
65      REAL(wp) ::   zidto                     ! temporary scalar
66      !--------------------------------------------------------------------
67 
68      CALL lim_istate_init_2     !  reading the initials parameters of the ice
69
70      IF( .NOT. ln_limini ) THEN 
71         
72         tfu(:,:) = tfreez( tsn(:,:,1,jp_sal) ) * tmask(:,:,1)       ! freezing/melting point of sea water [Celcius]
73
74         DO jj = 1, jpj
75            DO ji = 1, jpi
76               !                     ! ice if sst <= t-freez + ttest
77               IF( tsn(ji,jj,1,jp_tem)  - tfu(ji,jj) >= ttest ) THEN   ;   zidto = 0.e0      ! no ice
78               ELSE                                                    ;   zidto = 1.e0      !    ice
79               ENDIF
80               !
81               IF( fcor(ji,jj) >= 0.e0 ) THEN     !--  Northern hemisphere.
82                  hicif(ji,jj)   = zidto * hginn
83                  frld(ji,jj)    = zidto * alinn + ( 1.0 - zidto ) * 1.0
84                  hsnif(ji,jj)   = zidto * hninn
85               ELSE                               !---  Southern hemisphere.
86                  hicif(ji,jj)   = zidto * hgins
87                  frld(ji,jj)    = zidto * alins + ( 1.0 - zidto ) * 1.0
88                  hsnif(ji,jj)   = zidto * hnins
89               ENDIF
90            END DO
91         END DO
92
93         tfu(:,:) = tfu(:,:) + rt0       ! ftu converted from Celsius to Kelvin (rt0 over land)
94         
95         sist  (:,:)   = tfu(:,:)
96         tbif  (:,:,1) = tfu(:,:)
97         tbif  (:,:,2) = tfu(:,:)
98         tbif  (:,:,3) = tfu(:,:)
99
100      ENDIF
101     
102      fsbbq (:,:)   = 0.e0
103      qstoif(:,:)   = 0.e0
104      u_ice (:,:)   = 0.e0
105      v_ice (:,:)   = 0.e0
106
107      !---  Moments for advection.             
108
109      sxice (:,:)  = 0.e0   ;   sxsn (:,:)  = 0.e0   ;   sxa  (:,:)  = 0.e0
110      syice (:,:)  = 0.e0   ;   sysn (:,:)  = 0.e0   ;   sya  (:,:)  = 0.e0
111      sxxice(:,:)  = 0.e0   ;   sxxsn(:,:)  = 0.e0   ;   sxxa (:,:)  = 0.e0
112      syyice(:,:)  = 0.e0   ;   syysn(:,:)  = 0.e0   ;   syya (:,:)  = 0.e0
113      sxyice(:,:)  = 0.e0   ;   sxysn(:,:)  = 0.e0   ;   sxya (:,:)  = 0.e0
114
115      sxc0  (:,:)  = 0.e0   ;   sxc1 (:,:)  = 0.e0   ;   sxc2 (:,:)  = 0.e0
116      syc0  (:,:)  = 0.e0   ;   syc1 (:,:)  = 0.e0   ;   syc2 (:,:)  = 0.e0
117      sxxc0 (:,:)  = 0.e0   ;   sxxc1(:,:)  = 0.e0   ;   sxxc2(:,:)  = 0.e0
118      syyc0 (:,:)  = 0.e0   ;   syyc1(:,:)  = 0.e0   ;   syyc2(:,:)  = 0.e0
119      sxyc0 (:,:)  = 0.e0   ;   sxyc1(:,:)  = 0.e0   ;   sxyc2(:,:)  = 0.e0
120
121      sxst  (:,:)  = 0.e0
122      syst  (:,:)  = 0.e0
123      sxxst (:,:)  = 0.e0
124      syyst (:,:)  = 0.e0
125      sxyst (:,:)  = 0.e0
126#if ! defined key_lim2_vp
127      stress1_i (:,:) = 0._wp                          ! EVP rheology
128      stress2_i (:,:) = 0._wp
129      stress12_i(:,:) = 0._wp
130#endif
131
132      !-- lateral boundary conditions
133      CALL lbc_lnk( hicif, 'T', 1. )
134      CALL lbc_lnk( frld , 'T', 1. )
135
136      ! C A U T I O N  frld = 1 over land and lbc_lnk put zero along
137      ! *************  closed boundaries herefore we force to one over land
138      frld(:,:) = tms(:,:) * frld(:,:) + ( 1. - tms(:,:) )   
139
140      CALL lbc_lnk( hsnif, 'T', 1. )
141      CALL lbc_lnk( sist , 'T', 1. , pval = rt0 )      ! set rt0 on closed boundary (required by bulk formulation)
142      DO jk = 1, jplayersp1
143         CALL lbc_lnk(tbif(:,:,jk), 'T', 1. )
144      END DO
145      CALL lbc_lnk( fsbbq  , 'T', 1. )
146      CALL lbc_lnk( qstoif , 'T', 1. )
147
148   END SUBROUTINE lim_istate_2
149
150   
151   SUBROUTINE lim_istate_init_2
152      !!-------------------------------------------------------------------
153      !!                   ***  ROUTINE lim_istate_init_2  ***
154      !!       
155      !! ** Purpose :   Definition of initial state of the ice
156      !!
157      !! ** Method  :   Read the namiceini namelist and check the parameter
158      !!       values called at the first timestep (nit000)
159      !!
160      !! ** input   :   Namelist namiceini
161      !!-------------------------------------------------------------------
162      INTEGER :: inum_ice
163      INTEGER :: ji,jj
164
165      NAMELIST/namiceini/ ln_limini, ttest, hninn, hginn, alinn, &
166         &                hnins, hgins, alins
167      !!-------------------------------------------------------------------
168      !
169      REWIND ( numnam_ice )               ! Read Namelist namiceini
170      READ   ( numnam_ice , namiceini )
171      !
172      IF(lwp) THEN
173         WRITE(numout,*)
174         WRITE(numout,*) 'lim_istate_init_2 : ice parameters inititialisation '
175         WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
176         WRITE(numout,*) '         threshold water temp. for initial sea-ice    ttest      = ', ttest
177         WRITE(numout,*) '         initial snow thickness in the north          hninn      = ', hninn
178         WRITE(numout,*) '         initial ice thickness in the north           hginn      = ', hginn 
179         WRITE(numout,*) '         initial leads area in the north              alinn      = ', alinn           
180         WRITE(numout,*) '         initial snow thickness in the south          hnins      = ', hnins 
181         WRITE(numout,*) '         initial ice thickness in the south           hgins      = ', hgins
182         WRITE(numout,*) '         initial leads area in the south              alins      = ', alins
183         WRITE(numout,*) '         Ice state initialization using input file    ln_limini  = ', ln_limini
184      ENDIF
185
186      IF( ln_limini ) THEN                      ! Ice initialization using input file
187         !
188         CALL iom_open( 'Ice_initialization.nc', inum_ice )
189         !
190         IF( inum_ice > 0 ) THEN
191            IF(lwp) WRITE(numout,*)
192            IF(lwp) WRITE(numout,*) '                  ice state initialization with : Ice_initialization.nc'
193           
194#if defined key_lim2_initcd_alt1
195            CALL iom_get( inum_ice, jpdom_data, 'hicif', hicif )     
196            CALL iom_get( inum_ice, jpdom_data, 'hsnif', hsnif )     
197            CALL iom_get( inum_ice, jpdom_data, 'frld' , frld  )     
198            CALL iom_get( inum_ice, jpdom_data, 'tbif1'   , tbif(:,:,1)  )
199            CALL iom_get( inum_ice, jpdom_data, 'tbif2'   , tbif(:,:,2)  )
200            CALL iom_get( inum_ice, jpdom_data, 'tbif3'   , tbif(:,:,3)  )
201            CALL iom_get( inum_ice, jpdom_data, 'sist'   , sist  )
202#elif defined key_lim2_initcd_alt2
203            CALL iom_get( inum_ice, jpdom_data, 'iicethic', hicif )     
204            CALL iom_get( inum_ice, jpdom_data, 'isnowthi', hsnif )     
205            CALL iom_get( inum_ice, jpdom_data, 'ileadfra' , frld  )     
206            CALL iom_get( inum_ice, jpdom_data, 'isstempe'   , sist  )
207            CALL iom_get( inum_ice, jpdom_unknown, 'iicetemp', tbif(1:nlci,1:nlcj,:),   &
208                 &        kstart = (/ mig(1),mjg(1),1 /), kcount = (/ nlci,nlcj,jplayersp1 /) )
209#else
210            CALL iom_get( inum_ice, jpdom_data, 'hicif', hicif )     
211            CALL iom_get( inum_ice, jpdom_data, 'hsnif', hsnif )     
212            CALL iom_get( inum_ice, jpdom_data, 'frld' , frld  )     
213            CALL iom_get( inum_ice, jpdom_data, 'ts'   , sist  )
214            CALL iom_get( inum_ice, jpdom_unknown, 'tbif', tbif(1:nlci,1:nlcj,:),   &
215                 &        kstart = (/ mig(1),mjg(1),1 /), kcount = (/ nlci,nlcj,jplayersp1 /) )
216#endif         
217            ! put some values in the extra-halo...
218            DO jj = nlcj+1, jpj   ;   tbif(1:nlci,jj,:) = tbif(1:nlci,nlej,:)   ;   END DO
219            DO ji = nlci+1, jpi   ;   tbif(ji    ,: ,:) = tbif(nlei  ,:   ,:)   ;   END DO
220
221            CALL iom_close( inum_ice)
222            !
223         ENDIF
224      ENDIF
225      !     
226   END SUBROUTINE lim_istate_init_2
227
228#else
229   !!----------------------------------------------------------------------
230   !!   Default option :         Empty module      NO LIM 2.0 sea-ice model
231   !!----------------------------------------------------------------------
232CONTAINS
233   SUBROUTINE lim_istate_2        ! Empty routine
234   END SUBROUTINE lim_istate_2
235#endif
236
237   !!======================================================================
238END MODULE limistate_2
Note: See TracBrowser for help on using the repository browser.