| 1 | MODULE limsbc_2 |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc_2 *** |
|---|
| 4 | !! LIM-2 : updates the fluxes at the ocean surface with ice-ocean fluxes |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : LIM ! 2000-01 (H. Goosse) Original code |
|---|
| 7 | !! 1.0 ! 2002-07 (C. Ethe, G. Madec) re-writing F90 |
|---|
| 8 | !! 3.0 ! 2006-07 (G. Madec) surface module |
|---|
| 9 | !! 3.3 ! 2009-05 (G. Garric, C. Bricaud) addition of the lim2_evp case |
|---|
| 10 | !! - ! 2010-11 (G. Madec) ice-ocean stress computed at each ocean time-step |
|---|
| 11 | !! 4.0 ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | #if defined key_lim2 |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! 'key_lim2' LIM 2.0 sea-ice model |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! lim_sbc_alloc_2 : allocate the limsbc arrays |
|---|
| 18 | !! lim_sbc_init : initialisation |
|---|
| 19 | !! lim_sbc_flx_2 : update mass, heat and salt fluxes at the ocean surface |
|---|
| 20 | !! lim_sbc_tau_2 : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE par_oce ! ocean parameters |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE dom_oce ! ocean domain |
|---|
| 25 | USE dom_ice_2 ! LIM-2: ice domain |
|---|
| 26 | USE ice_2 ! LIM-2: ice variables |
|---|
| 27 | USE sbc_ice ! surface boundary condition: ice |
|---|
| 28 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 29 | USE sbccpl |
|---|
| 30 | |
|---|
| 31 | USE albedo ! albedo parameters |
|---|
| 32 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 33 | USE lib_mpp ! MPP library |
|---|
| 34 | USE wrk_nemo ! work arrays |
|---|
| 35 | USE in_out_manager ! I/O manager |
|---|
| 36 | USE diaar5, ONLY : lk_diaar5 |
|---|
| 37 | USE iom ! I/O library |
|---|
| 38 | USE prtctl ! Print control |
|---|
| 39 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 40 | USE cpl_oasis3, ONLY : lk_cpl |
|---|
| 41 | |
|---|
| 42 | IMPLICIT NONE |
|---|
| 43 | PRIVATE |
|---|
| 44 | |
|---|
| 45 | PUBLIC lim_sbc_init_2 ! called by ice_init_2 |
|---|
| 46 | PUBLIC lim_sbc_flx_2 ! called by sbc_ice_lim_2 |
|---|
| 47 | PUBLIC lim_sbc_tau_2 ! called by sbc_ice_lim_2 |
|---|
| 48 | |
|---|
| 49 | REAL(wp) :: r1_rdtice ! = 1. / rdt_ice |
|---|
| 50 | REAL(wp) :: epsi16 = 1.e-16_wp ! constant values |
|---|
| 51 | REAL(wp) :: rzero = 0._wp ! - - |
|---|
| 52 | REAL(wp) :: rone = 1._wp ! - - |
|---|
| 53 | ! |
|---|
| 54 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0, sice_0 ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean relative velocity [m/s] |
|---|
| 57 | |
|---|
| 58 | !! * Substitutions |
|---|
| 59 | # include "vectopt_loop_substitute.h90" |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 62 | !! $Id$ |
|---|
| 63 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | INTEGER FUNCTION lim_sbc_alloc_2() |
|---|
| 68 | !!------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE lim_sbc_alloc_2 *** |
|---|
| 70 | !!------------------------------------------------------------------- |
|---|
| 71 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 72 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc_2) |
|---|
| 73 | ! |
|---|
| 74 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc_2 ) |
|---|
| 75 | IF( lim_sbc_alloc_2 /= 0 ) CALL ctl_warn('lim_sbc_alloc_2: failed to allocate arrays.') |
|---|
| 76 | ! |
|---|
| 77 | END FUNCTION lim_sbc_alloc_2 |
|---|
| 78 | |
|---|
| 79 | |
|---|
| 80 | SUBROUTINE lim_sbc_flx_2( kt ) |
|---|
| 81 | !!------------------------------------------------------------------- |
|---|
| 82 | !! *** ROUTINE lim_sbc_2 *** |
|---|
| 83 | !! |
|---|
| 84 | !! ** Purpose : Update surface ocean boundary condition over areas |
|---|
| 85 | !! that are at least partially covered by sea-ice |
|---|
| 86 | !! |
|---|
| 87 | !! ** Action : - comput. of the momentum, heat and freshwater/salt |
|---|
| 88 | !! fluxes at the ice-ocean interface. |
|---|
| 89 | !! - Update the fluxes provided to the ocean |
|---|
| 90 | !! |
|---|
| 91 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 92 | !! - qns : sea heat flux: non solar |
|---|
| 93 | !! - emp : freshwater budget: volume flux |
|---|
| 94 | !! - emps : freshwater budget: concentration/dillution |
|---|
| 95 | !! - utau : sea surface i-stress (ocean referential) |
|---|
| 96 | !! - vtau : sea surface j-stress (ocean referential) |
|---|
| 97 | !! - fr_i : ice fraction |
|---|
| 98 | !! - tn_ice : sea-ice surface temperature |
|---|
| 99 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
|---|
| 100 | !! |
|---|
| 101 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 102 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 103 | !!--------------------------------------------------------------------- |
|---|
| 104 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 105 | !! |
|---|
| 106 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 107 | INTEGER :: ii0, ii1, ij0, ij1 ! local integers |
|---|
| 108 | INTEGER :: ifvt, i1mfr, idfr, iflt ! - - |
|---|
| 109 | INTEGER :: ial, iadv, ifral, ifrdv ! - - |
|---|
| 110 | REAL(wp) :: zqsr, zqns, zfm ! local scalars |
|---|
| 111 | REAL(wp) :: zinda, zfons, zemp ! - - |
|---|
| 112 | REAL(wp), POINTER, DIMENSION(:,:) :: zqnsoce ! 2D workspace |
|---|
| 113 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb, zalbp ! 2D/3D workspace |
|---|
| 114 | !!--------------------------------------------------------------------- |
|---|
| 115 | |
|---|
| 116 | CALL wrk_alloc( jpi, jpj, zqnsoce ) |
|---|
| 117 | CALL wrk_alloc( jpi, jpj, 1, zalb, zalbp ) |
|---|
| 118 | |
|---|
| 119 | !------------------------------------------! |
|---|
| 120 | ! heat flux at the ocean surface ! |
|---|
| 121 | !------------------------------------------! |
|---|
| 122 | |
|---|
| 123 | zqnsoce(:,:) = qns(:,:) |
|---|
| 124 | DO jj = 1, jpj |
|---|
| 125 | DO ji = 1, jpi |
|---|
| 126 | zinda = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 127 | ifvt = zinda * MAX( rzero , SIGN( rone, - phicif(ji,jj) ) ) |
|---|
| 128 | i1mfr = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - frld(ji,jj) ) ) ) |
|---|
| 129 | idfr = 1.0 - MAX( rzero , SIGN( rone, frld(ji,jj) - pfrld(ji,jj) ) ) |
|---|
| 130 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
|---|
| 131 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 132 | iadv = ( 1 - i1mfr ) * zinda |
|---|
| 133 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 134 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 135 | |
|---|
| 136 | !!$ zinda = 1.0 - AINT( pfrld(ji,jj) ) ! = 0. if pure ocean else 1. (at previous time) |
|---|
| 137 | !!$ |
|---|
| 138 | !!$ i1mfr = 1.0 - AINT( frld(ji,jj) ) ! = 0. if pure ocean else 1. (at current time) |
|---|
| 139 | !!$ |
|---|
| 140 | !!$ IF( phicif(ji,jj) <= 0. ) THEN ; ifvt = zinda ! = 1. if (snow and no ice at previous time) else 0. ??? |
|---|
| 141 | !!$ ELSE ; ifvt = 0. |
|---|
| 142 | !!$ ENDIF |
|---|
| 143 | !!$ |
|---|
| 144 | !!$ IF( frld(ji,jj) >= pfrld(ji,jj) ) THEN ; idfr = 0. ! = 0. if lead fraction increases from previous to current |
|---|
| 145 | !!$ ELSE ; idfr = 1. |
|---|
| 146 | !!$ ENDIF |
|---|
| 147 | !!$ |
|---|
| 148 | !!$ iflt = zinda * (1 - i1mfr) * (1 - ifvt ) ! = 1. if ice (not only snow) at previous and pure ocean at current |
|---|
| 149 | !!$ |
|---|
| 150 | !!$ ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 151 | !!$! snow no ice ice ice or nothing lead fraction increases |
|---|
| 152 | !!$! at previous now at previous |
|---|
| 153 | !!$! -> ice aera increases ??? -> ice aera decreases ??? |
|---|
| 154 | !!$ |
|---|
| 155 | !!$ iadv = ( 1 - i1mfr ) * zinda |
|---|
| 156 | !!$! pure ocean ice at |
|---|
| 157 | !!$! at current previous |
|---|
| 158 | !!$! -> = 1. if ice disapear between previous and current |
|---|
| 159 | !!$ |
|---|
| 160 | !!$ ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 161 | !!$! ice at ??? |
|---|
| 162 | !!$! current |
|---|
| 163 | !!$! -> ??? |
|---|
| 164 | !!$ |
|---|
| 165 | !!$ ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 166 | !!$! ice disapear |
|---|
| 167 | !!$ |
|---|
| 168 | !!$ |
|---|
| 169 | |
|---|
| 170 | ! computation the solar flux at ocean surface |
|---|
| 171 | #if defined key_coupled |
|---|
| 172 | zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) ) |
|---|
| 173 | #else |
|---|
| 174 | zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 175 | #endif |
|---|
| 176 | ! computation the non solar heat flux at ocean surface |
|---|
| 177 | zqns = - ( 1. - thcm(ji,jj) ) * zqsr & ! part of the solar energy used in leads |
|---|
| 178 | & + iflt * ( fscmbq(ji,jj) + ffltbif(ji,jj) ) & |
|---|
| 179 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice & |
|---|
| 180 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) * r1_rdtice |
|---|
| 181 | |
|---|
| 182 | fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj) ! ??? |
|---|
| 183 | ! |
|---|
| 184 | qsr (ji,jj) = zqsr ! solar heat flux |
|---|
| 185 | qns (ji,jj) = zqns - fdtcn(ji,jj) ! non solar heat flux |
|---|
| 186 | END DO |
|---|
| 187 | END DO |
|---|
| 188 | |
|---|
| 189 | CALL iom_put( 'hflx_ice_cea', - fdtcn(:,:) ) |
|---|
| 190 | CALL iom_put( 'qns_io_cea', qns(:,:) - zqnsoce(:,:) * pfrld(:,:) ) |
|---|
| 191 | CALL iom_put( 'qsr_io_cea', fstric(:,:) * (1.e0 - pfrld(:,:)) ) |
|---|
| 192 | |
|---|
| 193 | !------------------------------------------! |
|---|
| 194 | ! mass flux at the ocean surface ! |
|---|
| 195 | !------------------------------------------! |
|---|
| 196 | DO jj = 1, jpj |
|---|
| 197 | DO ji = 1, jpi |
|---|
| 198 | ! |
|---|
| 199 | #if defined key_coupled |
|---|
| 200 | ! freshwater exchanges at the ice-atmosphere / ocean interface (coupled mode) |
|---|
| 201 | zemp = emp_tot(ji,jj) - emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! |
|---|
| 202 | & + rdmsnif(ji,jj) * r1_rdtice ! freshwaterflux due to snow melting |
|---|
| 203 | #else |
|---|
| 204 | ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 205 | zemp = + emp(ji,jj) * frld(ji,jj) & ! e-p budget over open ocean fraction |
|---|
| 206 | & - tprecip(ji,jj) * ( 1. - frld(ji,jj) ) & ! liquid precipitation reaches directly the ocean |
|---|
| 207 | & + sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) & ! change in ice cover within the time step |
|---|
| 208 | & + rdmsnif(ji,jj) * r1_rdtice ! freshwater flux due to snow melting |
|---|
| 209 | #endif |
|---|
| 210 | ! |
|---|
| 211 | ! computing salt exchanges at the ice/ocean interface |
|---|
| 212 | zfons = ( soce_0(ji,jj) - sice_0(ji,jj) ) * ( rdmicif(ji,jj) * r1_rdtice ) |
|---|
| 213 | ! |
|---|
| 214 | ! converting the salt flux from ice to a freshwater flux from ocean |
|---|
| 215 | zfm = zfons / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 216 | ! |
|---|
| 217 | emps(ji,jj) = zemp + zfm ! surface ocean concentration/dilution effect (use on SSS evolution) |
|---|
| 218 | emp (ji,jj) = zemp ! surface ocean volume flux (use on sea-surface height evolution) |
|---|
| 219 | ! |
|---|
| 220 | END DO |
|---|
| 221 | END DO |
|---|
| 222 | |
|---|
| 223 | IF( lk_diaar5 ) THEN ! AR5 diagnostics |
|---|
| 224 | CALL iom_put( 'isnwmlt_cea' , rdmsnif(:,:) * r1_rdtice ) |
|---|
| 225 | CALL iom_put( 'fsal_virt_cea', soce_0(:,:) * rdmicif(:,:) * r1_rdtice ) |
|---|
| 226 | CALL iom_put( 'fsal_real_cea', - sice_0(:,:) * rdmicif(:,:) * r1_rdtice ) |
|---|
| 227 | ENDIF |
|---|
| 228 | |
|---|
| 229 | !-----------------------------------------------! |
|---|
| 230 | ! Coupling variables ! |
|---|
| 231 | !-----------------------------------------------! |
|---|
| 232 | |
|---|
| 233 | #if defined key_coupled |
|---|
| 234 | tn_ice(:,:,1) = sist(:,:) ! sea-ice surface temperature |
|---|
| 235 | ht_i(:,:,1) = hicif(:,:) |
|---|
| 236 | ht_s(:,:,1) = hsnif(:,:) |
|---|
| 237 | a_i(:,:,1) = fr_i(:,:) |
|---|
| 238 | ! ! Computation of snow/ice and ocean albedo |
|---|
| 239 | CALL albedo_ice( tn_ice, ht_i, ht_s, zalbp, zalb ) |
|---|
| 240 | alb_ice(:,:,1) = 0.5 * ( zalbp(:,:,1) + zalb (:,:,1) ) ! Ice albedo (mean clear and overcast skys) |
|---|
| 241 | CALL iom_put( "icealb_cea", alb_ice(:,:,1) * fr_i(:,:) ) ! ice albedo |
|---|
| 242 | #endif |
|---|
| 243 | |
|---|
| 244 | IF(ln_ctl) THEN ! control print |
|---|
| 245 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ') |
|---|
| 246 | CALL prt_ctl(tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=emps , clinfo2=' emps : ') |
|---|
| 247 | CALL prt_ctl(tab2d_1=utau , clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 248 | & tab2d_2=vtau , clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 249 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ', tab2d_2=tn_ice(:,:,1), clinfo2=' tn_ice : ') |
|---|
| 250 | ENDIF |
|---|
| 251 | ! |
|---|
| 252 | CALL wrk_dealloc( jpi, jpj, zqnsoce ) |
|---|
| 253 | CALL wrk_dealloc( jpi, jpj, 1, zalb, zalbp ) |
|---|
| 254 | ! |
|---|
| 255 | END SUBROUTINE lim_sbc_flx_2 |
|---|
| 256 | |
|---|
| 257 | |
|---|
| 258 | SUBROUTINE lim_sbc_tau_2( kt , pu_oce, pv_oce ) |
|---|
| 259 | !!------------------------------------------------------------------- |
|---|
| 260 | !! *** ROUTINE lim_sbc_tau_2 *** |
|---|
| 261 | !! |
|---|
| 262 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 263 | !! |
|---|
| 264 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 265 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 266 | !! at T-point (C-grid) or I-point (B-grid) |
|---|
| 267 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 268 | !! - update the modulus of stress at ocean surface |
|---|
| 269 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 270 | !! * at each ocean time step (each kt): |
|---|
| 271 | !! compute linearized ice-ocean stresses as |
|---|
| 272 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 273 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 274 | !! |
|---|
| 275 | !! NB: - the averaging operator used depends on the ice dynamics grid (cp_ice_msh='I' or 'C') |
|---|
| 276 | !! - ice-ocean rotation angle only allowed in cp_ice_msh='I' case |
|---|
| 277 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 278 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 279 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximation... |
|---|
| 280 | !! |
|---|
| 281 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 282 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 283 | !!--------------------------------------------------------------------- |
|---|
| 284 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 285 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 286 | !! |
|---|
| 287 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 288 | REAL(wp) :: zfrldu, zat_u, zu_i, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 289 | REAL(wp) :: zfrldv, zat_v, zv_i, zvtau_ice, zv_t, zmodi ! - - |
|---|
| 290 | REAL(wp) :: zsang, zumt ! - - |
|---|
| 291 | REAL(wp), POINTER, DIMENSION(:,:) :: ztio_u, ztio_v ! ocean stress below sea-ice |
|---|
| 292 | !!--------------------------------------------------------------------- |
|---|
| 293 | ! |
|---|
| 294 | CALL wrk_alloc( jpi, jpj, ztio_u, ztio_v ) |
|---|
| 295 | ! |
|---|
| 296 | SELECT CASE( cp_ice_msh ) |
|---|
| 297 | ! !-----------------------! |
|---|
| 298 | CASE( 'I' ) ! B-grid ice dynamics ! I-point (i.e. F-point with sea-ice indexation) |
|---|
| 299 | ! !--=--------------------! |
|---|
| 300 | ! |
|---|
| 301 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 302 | !CDIR NOVERRCHK |
|---|
| 303 | DO jj = 1, jpj !* modulus of ice-ocean relative velocity at I-point |
|---|
| 304 | !CDIR NOVERRCHK |
|---|
| 305 | DO ji = 1, jpi |
|---|
| 306 | zu_i = u_ice(ji,jj) - u_oce(ji,jj) ! ice-ocean relative velocity at I-point |
|---|
| 307 | zv_i = v_ice(ji,jj) - v_oce(ji,jj) |
|---|
| 308 | tmod_io(ji,jj) = SQRT( zu_i * zu_i + zv_i * zv_i ) ! modulus of this velocity (at I-point) |
|---|
| 309 | END DO |
|---|
| 310 | END DO |
|---|
| 311 | !CDIR NOVERRCHK |
|---|
| 312 | DO jj = 1, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 313 | !CDIR NOVERRCHK |
|---|
| 314 | DO ji = 1, jpim1 ! NO vector opt. |
|---|
| 315 | ! ! modulus of U_ice-U_oce at T-point |
|---|
| 316 | zumt = 0.25_wp * ( tmod_io(ji+1,jj) + tmod_io(ji ,jj ) & |
|---|
| 317 | & + tmod_io(ji,jj+1) + tmod_io(ji+1,jj+1) ) |
|---|
| 318 | ! ! update the modulus of stress at ocean surface |
|---|
| 319 | taum(ji,jj) = frld(ji,jj) * taum(ji,jj) + ( 1._wp - frld(ji,jj) ) * rhoco * zumt * zumt |
|---|
| 320 | END DO |
|---|
| 321 | END DO |
|---|
| 322 | CALL lbc_lnk( taum, 'T', 1. ) |
|---|
| 323 | ! |
|---|
| 324 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 325 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 326 | ! |
|---|
| 327 | ENDIF |
|---|
| 328 | ! |
|---|
| 329 | ! !== at each ocean time-step ==! |
|---|
| 330 | ! |
|---|
| 331 | ! !* ice/ocean stress WITH a ice-ocean rotation angle at I-point |
|---|
| 332 | DO jj = 2, jpj |
|---|
| 333 | zsang = SIGN( 1._wp, gphif(1,jj) ) * sangvg ! change the cosine angle sign in the SH |
|---|
| 334 | DO ji = 2, jpi ! NO vect. opt. possible |
|---|
| 335 | ! ... ice-ocean relative velocity at I-point using instantaneous surface ocean current at u- & v-pts |
|---|
| 336 | zu_i = u_ice(ji,jj) - 0.5_wp * ( pu_oce(ji-1,jj ) + pu_oce(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 337 | zv_i = v_ice(ji,jj) - 0.5_wp * ( pv_oce(ji ,jj-1) + pv_oce(ji-1,jj-1) ) * tmu(ji,jj) |
|---|
| 338 | ! ... components of stress with a ice-ocean rotation angle |
|---|
| 339 | zmodi = rhoco * tmod_io(ji,jj) |
|---|
| 340 | ztio_u(ji,jj) = zmodi * ( cangvg * zu_i - zsang * zv_i ) |
|---|
| 341 | ztio_v(ji,jj) = zmodi * ( cangvg * zv_i + zsang * zu_i ) |
|---|
| 342 | END DO |
|---|
| 343 | END DO |
|---|
| 344 | ! !* surface ocean stresses at u- and v-points |
|---|
| 345 | DO jj = 2, jpjm1 |
|---|
| 346 | DO ji = 2, jpim1 ! NO vector opt. |
|---|
| 347 | ! ! ice-ocean stress at U and V-points (from I-point values) |
|---|
| 348 | zutau_ice = 0.5_wp * ( ztio_u(ji+1,jj) + ztio_u(ji+1,jj+1) ) |
|---|
| 349 | zvtau_ice = 0.5_wp * ( ztio_v(ji,jj+1) + ztio_v(ji+1,jj+1) ) |
|---|
| 350 | ! ! open-ocean (lead) fraction at U- & V-points (from T-point values) |
|---|
| 351 | zfrldu = 0.5_wp * ( frld(ji,jj) + frld(ji+1,jj) ) |
|---|
| 352 | zfrldv = 0.5_wp * ( frld(ji,jj) + frld(ji,jj+1) ) |
|---|
| 353 | ! ! update the surface ocean stress (ice-cover wheighted) |
|---|
| 354 | utau(ji,jj) = zfrldu * utau_oce(ji,jj) + ( 1._wp - zfrldu ) * zutau_ice |
|---|
| 355 | vtau(ji,jj) = zfrldv * vtau_oce(ji,jj) + ( 1._wp - zfrldv ) * zvtau_ice |
|---|
| 356 | END DO |
|---|
| 357 | END DO |
|---|
| 358 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 359 | ! |
|---|
| 360 | ! |
|---|
| 361 | ! !-----------------------! |
|---|
| 362 | CASE( 'C' ) ! C-grid ice dynamics ! U & V-points (same as in the ocean) |
|---|
| 363 | ! !--=--------------------! |
|---|
| 364 | ! |
|---|
| 365 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 366 | !CDIR NOVERRCHK |
|---|
| 367 | DO jj = 2, jpjm1 !* modulus of the ice-ocean velocity at T-point |
|---|
| 368 | !CDIR NOVERRCHK |
|---|
| 369 | DO ji = fs_2, fs_jpim1 |
|---|
| 370 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) ! 2*(U_ice-U_oce) at T-point |
|---|
| 371 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 372 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) ! |U_ice-U_oce|^2 |
|---|
| 373 | ! ! update the modulus of stress at ocean surface |
|---|
| 374 | taum (ji,jj) = frld(ji,jj) * taum(ji,jj) + ( 1._wp - frld(ji,jj) ) * rhoco * zmodt |
|---|
| 375 | tmod_io(ji,jj) = SQRT( zmodt ) * rhoco ! rhoco*|Uice-Uoce| |
|---|
| 376 | END DO |
|---|
| 377 | END DO |
|---|
| 378 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 379 | ! |
|---|
| 380 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 381 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 382 | ! |
|---|
| 383 | ENDIF |
|---|
| 384 | ! |
|---|
| 385 | ! !== at each ocean time-step ==! |
|---|
| 386 | ! |
|---|
| 387 | DO jj = 2, jpjm1 !* ice stress over ocean WITHOUT a ice-ocean rotation angle |
|---|
| 388 | DO ji = fs_2, fs_jpim1 |
|---|
| 389 | ! ! ocean area at u- & v-points |
|---|
| 390 | zfrldu = 0.5_wp * ( frld(ji,jj) + frld(ji+1,jj) ) |
|---|
| 391 | zfrldv = 0.5_wp * ( frld(ji,jj) + frld(ji,jj+1) ) |
|---|
| 392 | ! ! quadratic drag formulation without rotation |
|---|
| 393 | ! ! using instantaneous surface ocean current |
|---|
| 394 | zutau_ice = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 395 | zvtau_ice = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 396 | ! ! update the surface ocean stress (ice-cover wheighted) |
|---|
| 397 | utau(ji,jj) = zfrldu * utau_oce(ji,jj) + ( 1._wp - zfrldu ) * zutau_ice |
|---|
| 398 | vtau(ji,jj) = zfrldv * vtau_oce(ji,jj) + ( 1._wp - zfrldv ) * zvtau_ice |
|---|
| 399 | END DO |
|---|
| 400 | END DO |
|---|
| 401 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 402 | ! |
|---|
| 403 | END SELECT |
|---|
| 404 | |
|---|
| 405 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 406 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 407 | ! |
|---|
| 408 | CALL wrk_dealloc( jpi, jpj, ztio_u, ztio_v ) |
|---|
| 409 | ! |
|---|
| 410 | END SUBROUTINE lim_sbc_tau_2 |
|---|
| 411 | |
|---|
| 412 | |
|---|
| 413 | SUBROUTINE lim_sbc_init_2 |
|---|
| 414 | !!------------------------------------------------------------------- |
|---|
| 415 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 416 | !! |
|---|
| 417 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 418 | !! the temporal evolution of key variables |
|---|
| 419 | !! |
|---|
| 420 | !! ** input : Namelist namicedia |
|---|
| 421 | !!------------------------------------------------------------------- |
|---|
| 422 | ! |
|---|
| 423 | IF(lwp) WRITE(numout,*) |
|---|
| 424 | IF(lwp) WRITE(numout,*) 'lim_sbc_init_2 : LIM-2 sea-ice - surface boundary condition' |
|---|
| 425 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~ ' |
|---|
| 426 | |
|---|
| 427 | ! ! allocate lim_sbc arrays |
|---|
| 428 | IF( lim_sbc_alloc_2() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_flx_2 : unable to allocate arrays' ) |
|---|
| 429 | ! |
|---|
| 430 | r1_rdtice = 1._wp / rdt_ice |
|---|
| 431 | ! |
|---|
| 432 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 433 | sice_0(:,:) = sice |
|---|
| 434 | ! |
|---|
| 435 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 436 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 437 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 438 | soce_0(:,:) = 4._wp |
|---|
| 439 | sice_0(:,:) = 2._wp |
|---|
| 440 | END WHERE |
|---|
| 441 | ENDIF |
|---|
| 442 | ! |
|---|
| 443 | END SUBROUTINE lim_sbc_init_2 |
|---|
| 444 | |
|---|
| 445 | #else |
|---|
| 446 | !!---------------------------------------------------------------------- |
|---|
| 447 | !! Default option Empty module NO LIM 2.0 sea-ice model |
|---|
| 448 | !!---------------------------------------------------------------------- |
|---|
| 449 | #endif |
|---|
| 450 | |
|---|
| 451 | !!====================================================================== |
|---|
| 452 | END MODULE limsbc_2 |
|---|
