New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_core.F90 in branches/NERC/dev_r3874_FASTNEt/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/NERC/dev_r3874_FASTNEt/NEMOGCM/NEMO/OPA_SRC/SBC/sbcblk_core.F90 @ 6736

Last change on this file since 6736 was 6736, checked in by jamesharle, 8 years ago

FASTNEt code modifications

  • Property svn:keywords set to Id
File size: 53.0 KB
Line 
1MODULE sbcblk_core
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_core  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2004-08  (U. Schweckendiek)  Original code
7   !!            2.0  !  2005-04  (L. Brodeau, A.M. Treguier) additions:
8   !!                           -  new bulk routine for efficiency
9   !!                           -  WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!!
10   !!                           -  file names and file characteristics in namelist
11   !!                           -  Implement reading of 6-hourly fields   
12   !!            3.0  !  2006-06  (G. Madec) sbc rewritting   
13   !!             -   !  2006-12  (L. Brodeau) Original code for TURB_CORE_2Z
14   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
15   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
16   !!            3.4  !  2011-11  (C. Harris) Fill arrays required by CICE
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_blk_core  : bulk formulation as ocean surface boundary condition
21   !!                   (forced mode, CORE bulk formulea)
22   !!   blk_oce_core  : ocean: computes momentum, heat and freshwater fluxes
23   !!   blk_ice_core  : ice  : computes momentum, heat and freshwater fluxes
24   !!   turb_core     : computes the CORE turbulent transfer coefficients
25   !!----------------------------------------------------------------------
26   USE oce             ! ocean dynamics and tracers
27   USE dom_oce         ! ocean space and time domain
28   USE phycst          ! physical constants
29   USE fldread         ! read input fields
30   USE sbc_oce         ! Surface boundary condition: ocean fields
31   USE sbcdcy          ! surface boundary condition: diurnal cycle
32   USE iom             ! I/O manager library
33   USE in_out_manager  ! I/O manager
34   USE lib_mpp         ! distribued memory computing library
35   USE wrk_nemo        ! work arrays
36   USE timing          ! Timing
37   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
38   USE prtctl          ! Print control
39   USE sbcwave,ONLY :  cdn_wave !wave module
40#if defined key_lim3 || defined key_cice
41   USE sbc_ice         ! Surface boundary condition: ice fields
42#endif
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   sbc_blk_core         ! routine called in sbcmod module
48   PUBLIC   blk_ice_core         ! routine called in sbc_ice_lim module
49   PUBLIC   turb_core_2z         ! routine calles in sbcblk_mfs module
50
51   INTEGER , PARAMETER ::   jpfld   = 9           ! maximum number of files to read
52   INTEGER , PARAMETER ::   jp_wndi = 1           ! index of 10m wind velocity (i-component) (m/s)    at T-point
53   INTEGER , PARAMETER ::   jp_wndj = 2           ! index of 10m wind velocity (j-component) (m/s)    at T-point
54   INTEGER , PARAMETER ::   jp_humi = 3           ! index of specific humidity               ( - )
55   INTEGER , PARAMETER ::   jp_qsr  = 4           ! index of solar heat                      (W/m2)
56   INTEGER , PARAMETER ::   jp_qlw  = 5           ! index of Long wave                       (W/m2)
57   INTEGER , PARAMETER ::   jp_tair = 6           ! index of 10m air temperature             (Kelvin)
58   INTEGER , PARAMETER ::   jp_prec = 7           ! index of total precipitation (rain+snow) (Kg/m2/s)
59   INTEGER , PARAMETER ::   jp_snow = 8           ! index of snow (solid prcipitation)       (kg/m2/s)
60   INTEGER , PARAMETER ::   jp_tdif = 9           ! index of tau diff associated to HF tau   (N/m2)   at T-point
61   
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf   ! structure of input fields (file informations, fields read)
63         
64   !                                             !!! CORE bulk parameters
65   REAL(wp), PARAMETER ::   rhoa =    1.22        ! air density
66   REAL(wp), PARAMETER ::   cpa  = 1000.5         ! specific heat of air
67   REAL(wp), PARAMETER ::   Lv   =    2.5e6       ! latent heat of vaporization
68   REAL(wp), PARAMETER ::   Ls   =    2.839e6     ! latent heat of sublimation
69   REAL(wp), PARAMETER ::   Stef =    5.67e-8     ! Stefan Boltzmann constant
70   REAL(wp), PARAMETER ::   Cice =    1.63e-3     ! transfer coefficient over ice
71   REAL(wp), PARAMETER ::   albo =    0.066       ! ocean albedo assumed to be contant
72
73   !                                  !!* Namelist namsbc_core : CORE bulk parameters
74   LOGICAL  ::   ln_2m     = .FALSE.   ! logical flag for height of air temp. and hum
75   LOGICAL  ::   ln_taudif = .FALSE.   ! logical flag to use the "mean of stress module - module of mean stress" data
76   REAL(wp) ::   rn_pfac   = 1.        ! multiplication factor for precipitation
77
78   !! * Substitutions
79#  include "domzgr_substitute.h90"
80#  include "vectopt_loop_substitute.h90"
81   !!----------------------------------------------------------------------
82   !! NEMO/OPA 3.3 , NEMO-consortium (2010)
83   !! $Id$
84   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
85   !!----------------------------------------------------------------------
86CONTAINS
87
88   SUBROUTINE sbc_blk_core( kt )
89      !!---------------------------------------------------------------------
90      !!                    ***  ROUTINE sbc_blk_core  ***
91      !!                   
92      !! ** Purpose :   provide at each time step the surface ocean fluxes
93      !!      (momentum, heat, freshwater and runoff)
94      !!
95      !! ** Method  : (1) READ each fluxes in NetCDF files:
96      !!      the 10m wind velocity (i-component) (m/s)    at T-point
97      !!      the 10m wind velocity (j-component) (m/s)    at T-point
98      !!      the specific humidity               ( - )
99      !!      the solar heat                      (W/m2)
100      !!      the Long wave                       (W/m2)
101      !!      the 10m air temperature             (Kelvin)
102      !!      the total precipitation (rain+snow) (Kg/m2/s)
103      !!      the snow (solid prcipitation)       (kg/m2/s)
104      !!   OPTIONAL parameter (see ln_taudif namelist flag):
105      !!      the tau diff associated to HF tau   (N/m2)   at T-point
106      !!              (2) CALL blk_oce_core
107      !!
108      !!      C A U T I O N : never mask the surface stress fields
109      !!                      the stress is assumed to be in the mesh referential
110      !!                      i.e. the (i,j) referential
111      !!
112      !! ** Action  :   defined at each time-step at the air-sea interface
113      !!              - utau, vtau  i- and j-component of the wind stress
114      !!              - taum        wind stress module at T-point
115      !!              - wndm        10m wind module at T-point
116      !!              - qns, qsr    non-slor and solar heat flux
117      !!              - emp, emps   evaporation minus precipitation
118      !!----------------------------------------------------------------------
119      INTEGER, INTENT(in) ::   kt   ! ocean time step
120      !!
121      INTEGER  ::   ierror   ! return error code
122      INTEGER  ::   ifpr     ! dummy loop indice
123      INTEGER  ::   jfld     ! dummy loop arguments
124      !!
125      CHARACTER(len=100) ::  cn_dir   !   Root directory for location of core files
126      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
127      TYPE(FLD_N) ::   sn_wndi, sn_wndj, sn_humi, sn_qsr       ! informations about the fields to be read
128      TYPE(FLD_N) ::   sn_qlw , sn_tair, sn_prec, sn_snow      !   "                                 "
129      TYPE(FLD_N) ::   sn_tdif                                 !   "                                 "
130      NAMELIST/namsbc_core/ cn_dir , ln_2m  , ln_taudif, rn_pfac,           &
131         &                  sn_wndi, sn_wndj, sn_humi  , sn_qsr ,           &
132         &                  sn_qlw , sn_tair, sn_prec  , sn_snow, sn_tdif
133      !!---------------------------------------------------------------------
134
135      !                                         ! ====================== !
136      IF( kt == nit000 ) THEN                   !  First call kt=nit000  !
137         !                                      ! ====================== !
138         ! set file information (default values)
139         cn_dir = './'       ! directory in which the model is executed
140         !
141         ! (NB: frequency positive => hours, negative => months)
142         !            !    file    ! frequency ! variable ! time intep !  clim   ! 'yearly' or ! weights  ! rotation !
143         !            !    name    !  (hours)  !  name    !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs    !
144         sn_wndi = FLD_N( 'uwnd10m',    24     , 'u_10'   ,  .false.   , .false. ,   'yearly'  , ''       , ''       )
145         sn_wndj = FLD_N( 'vwnd10m',    24     , 'v_10'   ,  .false.   , .false. ,   'yearly'  , ''       , ''       )
146         sn_qsr  = FLD_N( 'qsw'    ,    24     , 'qsw'    ,  .false.   , .false. ,   'yearly'  , ''       , ''       )
147         sn_qlw  = FLD_N( 'qlw'    ,    24     , 'qlw'    ,  .false.   , .false. ,   'yearly'  , ''       , ''       )
148         sn_tair = FLD_N( 'tair10m',    24     , 't_10'   ,  .false.   , .false. ,   'yearly'  , ''       , ''       )
149         sn_humi = FLD_N( 'humi10m',    24     , 'q_10'   ,  .false.   , .false. ,   'yearly'  , ''       , ''       )
150         sn_prec = FLD_N( 'precip' ,    -1     , 'precip' ,  .true.    , .false. ,   'yearly'  , ''       , ''       )
151         sn_snow = FLD_N( 'snow'   ,    -1     , 'snow'   ,  .true.    , .false. ,   'yearly'  , ''       , ''       )
152         sn_tdif = FLD_N( 'taudif' ,    24     , 'taudif' ,  .true.    , .false. ,   'yearly'  , ''       , ''       )
153         !
154         REWIND( numnam )                          ! read in namlist namsbc_core
155         READ  ( numnam, namsbc_core )
156         !                                         ! check: do we plan to use ln_dm2dc with non-daily forcing?
157         IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 )   & 
158            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' ) 
159         IF( ln_dm2dc .AND. sn_qsr%ln_tint ) THEN
160            CALL ctl_warn( 'sbc_blk_core: ln_dm2dc is taking care of the temporal interpolation of daily qsr',   &
161                 &         '              ==> We force time interpolation = .false. for qsr' )
162            sn_qsr%ln_tint = .false.
163         ENDIF
164         !                                         ! store namelist information in an array
165         slf_i(jp_wndi) = sn_wndi   ;   slf_i(jp_wndj) = sn_wndj
166         slf_i(jp_qsr ) = sn_qsr    ;   slf_i(jp_qlw ) = sn_qlw
167         slf_i(jp_tair) = sn_tair   ;   slf_i(jp_humi) = sn_humi
168         slf_i(jp_prec) = sn_prec   ;   slf_i(jp_snow) = sn_snow
169         slf_i(jp_tdif) = sn_tdif
170         !                 
171         lhftau = ln_taudif                        ! do we use HF tau information?
172         jfld = jpfld - COUNT( (/.NOT. lhftau/) )
173         !
174         ALLOCATE( sf(jfld), STAT=ierror )         ! set sf structure
175         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_blk_core: unable to allocate sf structure' )
176         DO ifpr= 1, jfld
177            ALLOCATE( sf(ifpr)%fnow(jpi,jpj,1) )
178            IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf(ifpr)%fdta(jpi,jpj,1,2) )
179         END DO
180         !                                         ! fill sf with slf_i and control print
181         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulation for ocean surface boundary condition', 'namsbc_core' )
182         !
183      ENDIF
184
185      CALL fld_read( kt, nn_fsbc, sf )        ! input fields provided at the current time-step
186
187      !                                                        ! surface ocean fluxes computed with CLIO bulk formulea
188      IF( MOD( kt - 1, nn_fsbc ) == 0 )   CALL blk_oce_core( sf, sst_m, ssu_m, ssv_m )
189
190#if defined key_cice
191      IF( MOD( kt - 1, nn_fsbc ) == 0 )   THEN
192         qlw_ice(:,:,1)   = sf(jp_qlw)%fnow(:,:,1) 
193         qsr_ice(:,:,1)   = sf(jp_qsr)%fnow(:,:,1)
194         tatm_ice(:,:)    = sf(jp_tair)%fnow(:,:,1)         
195         qatm_ice(:,:)    = sf(jp_humi)%fnow(:,:,1)
196         tprecip(:,:)     = sf(jp_prec)%fnow(:,:,1) * rn_pfac
197         sprecip(:,:)     = sf(jp_snow)%fnow(:,:,1) * rn_pfac
198         wndi_ice(:,:)    = sf(jp_wndi)%fnow(:,:,1)
199         wndj_ice(:,:)    = sf(jp_wndj)%fnow(:,:,1)
200      ENDIF
201#endif
202      !
203   END SUBROUTINE sbc_blk_core
204   
205   
206   SUBROUTINE blk_oce_core( sf, pst, pu, pv )
207      !!---------------------------------------------------------------------
208      !!                     ***  ROUTINE blk_core  ***
209      !!
210      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
211      !!      the ocean surface at each time step
212      !!
213      !! ** Method  :   CORE bulk formulea for the ocean using atmospheric
214      !!      fields read in sbc_read
215      !!
216      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
217      !!              - vtau    : j-component of the stress at V-point  (N/m2)
218      !!              - taum    : Wind stress module at T-point         (N/m2)
219      !!              - wndm    : Wind speed module at T-point          (m/s)
220      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
221      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
222      !!              - evap    : Evaporation over the ocean            (kg/m2/s)
223      !!              - emp(s)  : evaporation minus precipitation       (kg/m2/s)
224      !!
225      !!  ** Nota  :   sf has to be a dummy argument for AGRIF on NEC
226      !!---------------------------------------------------------------------
227      TYPE(fld), INTENT(in), DIMENSION(:)   ::   sf    ! input data
228      REAL(wp) , INTENT(in), DIMENSION(:,:) ::   pst   ! surface temperature                      [Celcius]
229      REAL(wp) , INTENT(in), DIMENSION(:,:) ::   pu    ! surface current at U-point (i-component) [m/s]
230      REAL(wp) , INTENT(in), DIMENSION(:,:) ::   pv    ! surface current at V-point (j-component) [m/s]
231      !
232      INTEGER  ::   ji, jj               ! dummy loop indices
233      REAL(wp) ::   zcoef_qsatw, zztmp   ! local variable
234      REAL(wp), DIMENSION(:,:), POINTER ::   zwnd_i, zwnd_j    ! wind speed components at T-point
235      REAL(wp), DIMENSION(:,:), POINTER ::   zqsatw            ! specific humidity at pst
236      REAL(wp), DIMENSION(:,:), POINTER ::   zqlw, zqsb        ! long wave and sensible heat fluxes
237      REAL(wp), DIMENSION(:,:), POINTER ::   zqla, zevap       ! latent heat fluxes and evaporation
238      REAL(wp), DIMENSION(:,:), POINTER ::   Cd                ! transfer coefficient for momentum      (tau)
239      REAL(wp), DIMENSION(:,:), POINTER ::   Ch                ! transfer coefficient for sensible heat (Q_sens)
240      REAL(wp), DIMENSION(:,:), POINTER ::   Ce                ! tansfert coefficient for evaporation   (Q_lat)
241      REAL(wp), DIMENSION(:,:), POINTER ::   zst               ! surface temperature in Kelvin
242      REAL(wp), DIMENSION(:,:), POINTER ::   zt_zu             ! air temperature at wind speed height
243      REAL(wp), DIMENSION(:,:), POINTER ::   zq_zu             ! air spec. hum.  at wind speed height
244      !!---------------------------------------------------------------------
245      !
246      IF( nn_timing == 1 )  CALL timing_start('blk_oce_core')
247      !
248      CALL wrk_alloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zqlw, zqsb, zqla, zevap )
249      CALL wrk_alloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu )
250      !
251      ! local scalars ( place there for vector optimisation purposes)
252      zcoef_qsatw = 0.98 * 640380. / rhoa
253     
254      zst(:,:) = pst(:,:) + rt0      ! converte Celcius to Kelvin (and set minimum value far above 0 K)
255
256      ! ----------------------------------------------------------------------------- !
257      !      0   Wind components and module at T-point relative to the moving ocean   !
258      ! ----------------------------------------------------------------------------- !
259
260      ! ... components ( U10m - U_oce ) at T-point (unmasked)
261      zwnd_i(:,:) = 0.e0 
262      zwnd_j(:,:) = 0.e0
263#if defined key_vectopt_loop
264!CDIR COLLAPSE
265#endif
266      DO jj = 2, jpjm1
267         DO ji = fs_2, fs_jpim1   ! vect. opt.
268            zwnd_i(ji,jj) = (  sf(jp_wndi)%fnow(ji,jj,1) - 0.5 * ( pu(ji-1,jj  ) + pu(ji,jj) )  )
269            zwnd_j(ji,jj) = (  sf(jp_wndj)%fnow(ji,jj,1) - 0.5 * ( pv(ji  ,jj-1) + pv(ji,jj) )  )
270         END DO
271      END DO
272      CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. )
273      CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. )
274      ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked)
275!CDIR NOVERRCHK
276!CDIR COLLAPSE
277      wndm(:,:) = SQRT(  zwnd_i(:,:) * zwnd_i(:,:)   &
278         &             + zwnd_j(:,:) * zwnd_j(:,:)  ) * tmask(:,:,1)
279
280      ! ----------------------------------------------------------------------------- !
281      !      I   Radiative FLUXES                                                     !
282      ! ----------------------------------------------------------------------------- !
283   
284      ! ocean albedo assumed to be constant + modify now Qsr to include the diurnal cycle                    ! Short Wave
285      zztmp = 1. - albo
286      IF( ln_dm2dc ) THEN   ;   qsr(:,:) = zztmp * sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) * tmask(:,:,1)
287      ELSE                  ;   qsr(:,:) = zztmp *          sf(jp_qsr)%fnow(:,:,1)   * tmask(:,:,1)
288      ENDIF
289!CDIR COLLAPSE
290      zqlw(:,:) = (  sf(jp_qlw)%fnow(:,:,1) - Stef * zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:)  ) * tmask(:,:,1)   ! Long  Wave
291      ! ----------------------------------------------------------------------------- !
292      !     II    Turbulent FLUXES                                                    !
293      ! ----------------------------------------------------------------------------- !
294
295      ! ... specific humidity at SST and IST
296!CDIR NOVERRCHK
297!CDIR COLLAPSE
298      zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) ) 
299
300      ! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point :
301      IF( ln_2m ) THEN
302         !! If air temp. and spec. hum. are given at different height (2m) than wind (10m) :
303         CALL TURB_CORE_2Z(2.,10., zst   , sf(jp_tair)%fnow,         &
304            &                      zqsatw, sf(jp_humi)%fnow, wndm,   &
305            &                      Cd    , Ch              , Ce  ,   &
306            &                      zt_zu , zq_zu                   )
307      ELSE
308         !! If air temp. and spec. hum. are given at same height than wind (10m) :
309!gm bug?  at the compiling phase, add a copy in temporary arrays...  ==> check perf
310!         CALL TURB_CORE_1Z( 10., zst   (:,:), sf(jp_tair)%fnow(:,:),              &
311!            &                    zqsatw(:,:), sf(jp_humi)%fnow(:,:), wndm(:,:),   &
312!            &                    Cd    (:,:),             Ch  (:,:), Ce  (:,:)  )
313!gm bug
314! ARPDBG - this won't compile with gfortran. Fix but check performance
315! as per comment above.
316         CALL TURB_CORE_1Z( 10., zst   , sf(jp_tair)%fnow(:,:,1),       &
317            &                    zqsatw, sf(jp_humi)%fnow(:,:,1), wndm, &
318            &                    Cd    , Ch              , Ce    )
319      ENDIF
320
321      ! ... tau module, i and j component
322      DO jj = 1, jpj
323         DO ji = 1, jpi
324            zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj)
325            taum  (ji,jj) = zztmp * wndm  (ji,jj)
326            zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj)
327            zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj)
328         END DO
329      END DO
330
331      ! ... add the HF tau contribution to the wind stress module?
332      IF( lhftau ) THEN 
333!CDIR COLLAPSE
334         taum(:,:) = taum(:,:) + sf(jp_tdif)%fnow(:,:,1)
335      ENDIF
336      CALL iom_put( "taum_oce", taum )   ! output wind stress module
337
338      ! ... utau, vtau at U- and V_points, resp.
339      !     Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
340      DO jj = 1, jpjm1
341         DO ji = 1, fs_jpim1
342            utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj  ) )
343            vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji  ,jj+1) )
344         END DO
345      END DO
346      CALL lbc_lnk( utau(:,:), 'U', -1. )
347      CALL lbc_lnk( vtau(:,:), 'V', -1. )
348
349      !  Turbulent fluxes over ocean
350      ! -----------------------------
351      IF( ln_2m ) THEN
352         ! Values of temp. and hum. adjusted to 10m must be used instead of 2m values
353         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - zq_zu(:,:) ) * wndm(:,:) )   ! Evaporation
354         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - zt_zu(:,:) ) * wndm(:,:)     ! Sensible Heat
355      ELSE
356!CDIR COLLAPSE
357         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - sf(jp_humi)%fnow(:,:,1) ) * wndm(:,:) )   ! Evaporation
358!CDIR COLLAPSE
359         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - sf(jp_tair)%fnow(:,:,1) ) * wndm(:,:)     ! Sensible Heat
360      ENDIF
361!CDIR COLLAPSE
362      zqla (:,:) = Lv * zevap(:,:)                                                              ! Latent Heat
363
364      IF(ln_ctl) THEN
365         CALL prt_ctl( tab2d_1=zqla  , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=Ce , clinfo2=' Ce  : ' )
366         CALL prt_ctl( tab2d_1=zqsb  , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=Ch , clinfo2=' Ch  : ' )
367         CALL prt_ctl( tab2d_1=zqlw  , clinfo1=' blk_oce_core: zqlw   : ', tab2d_2=qsr, clinfo2=' qsr : ' )
368         CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' )
369         CALL prt_ctl( tab2d_1=utau  , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
370            &          tab2d_2=vtau  , clinfo2=              ' vtau : '  , mask2=vmask )
371         CALL prt_ctl( tab2d_1=wndm  , clinfo1=' blk_oce_core: wndm   : ')
372         CALL prt_ctl( tab2d_1=zst   , clinfo1=' blk_oce_core: zst    : ')
373      ENDIF
374       
375      ! ----------------------------------------------------------------------------- !
376      !     III    Total FLUXES                                                       !
377      ! ----------------------------------------------------------------------------- !
378     
379!CDIR COLLAPSE
380      qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)      ! Downward Non Solar flux
381!CDIR COLLAPSE
382      emp(:,:) = zevap(:,:) - sf(jp_prec)%fnow(:,:,1) * rn_pfac * tmask(:,:,1)
383!CDIR COLLAPSE
384      emps(:,:) = emp(:,:)
385      !
386      CALL iom_put( "qlw_oce",   zqlw )                 ! output downward longwave heat over the ocean
387      CALL iom_put( "qsb_oce", - zqsb )                 ! output downward sensible heat over the ocean
388      CALL iom_put( "qla_oce", - zqla )                 ! output downward latent   heat over the ocean
389      CALL iom_put( "qns_oce",   qns  )                 ! output downward non solar heat over the ocean
390      !
391      IF(ln_ctl) THEN
392         CALL prt_ctl(tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=zqlw , clinfo2=' zqlw  : ')
393         CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=qsr  , clinfo2=' qsr   : ')
394         CALL prt_ctl(tab2d_1=pst  , clinfo1=' blk_oce_core: pst    : ', tab2d_2=emp  , clinfo2=' emp   : ')
395         CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
396            &         tab2d_2=vtau , clinfo2=              ' vtau  : ' , mask2=vmask )
397      ENDIF
398      !
399      CALL wrk_dealloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zqlw, zqsb, zqla, zevap )
400      CALL wrk_dealloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu )
401      !
402      IF( nn_timing == 1 )  CALL timing_stop('blk_oce_core')
403      !
404   END SUBROUTINE blk_oce_core
405   
406   
407   SUBROUTINE blk_ice_core(  pst   , pui   , pvi   , palb ,   &
408      &                      p_taui, p_tauj, p_qns , p_qsr,   &
409      &                      p_qla , p_dqns, p_dqla,          &
410      &                      p_tpr , p_spr ,                  &
411      &                      p_fr1 , p_fr2 , cd_grid, pdim  ) 
412      !!---------------------------------------------------------------------
413      !!                     ***  ROUTINE blk_ice_core  ***
414      !!
415      !! ** Purpose :   provide the surface boundary condition over sea-ice
416      !!
417      !! ** Method  :   compute momentum, heat and freshwater exchanged
418      !!                between atmosphere and sea-ice using CORE bulk
419      !!                formulea, ice variables and read atmmospheric fields.
420      !!                NB: ice drag coefficient is assumed to be a constant
421      !!
422      !! caution : the net upward water flux has with mm/day unit
423      !!---------------------------------------------------------------------
424      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pst      ! ice surface temperature (>0, =rt0 over land) [Kelvin]
425      REAL(wp), DIMENSION(:,:)  , INTENT(in   ) ::   pui      ! ice surface velocity (i- and i- components      [m/s]
426      REAL(wp), DIMENSION(:,:)  , INTENT(in   ) ::   pvi      !    at I-point (B-grid) or U & V-point (C-grid)
427      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb     ! ice albedo (clear sky) (alb_ice_cs)               [%]
428      REAL(wp), DIMENSION(:,:)  , INTENT(  out) ::   p_taui   ! i- & j-components of surface ice stress        [N/m2]
429      REAL(wp), DIMENSION(:,:)  , INTENT(  out) ::   p_tauj   !   at I-point (B-grid) or U & V-point (C-grid)
430      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   p_qns    ! non solar heat flux over ice (T-point)         [W/m2]
431      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   p_qsr    !     solar heat flux over ice (T-point)         [W/m2]
432      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   p_qla    ! latent    heat flux over ice (T-point)         [W/m2]
433      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   p_dqns   ! non solar heat sensistivity  (T-point)         [W/m2]
434      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   p_dqla   ! latent    heat sensistivity  (T-point)         [W/m2]
435      REAL(wp), DIMENSION(:,:)  , INTENT(  out) ::   p_tpr    ! total precipitation          (T-point)      [Kg/m2/s]
436      REAL(wp), DIMENSION(:,:)  , INTENT(  out) ::   p_spr    ! solid precipitation          (T-point)      [Kg/m2/s]
437      REAL(wp), DIMENSION(:,:)  , INTENT(  out) ::   p_fr1    ! 1sr fraction of qsr penetration in ice (T-point)  [%]
438      REAL(wp), DIMENSION(:,:)  , INTENT(  out) ::   p_fr2    ! 2nd fraction of qsr penetration in ice (T-point)  [%]
439      CHARACTER(len=1)          , INTENT(in   ) ::   cd_grid  ! ice grid ( C or B-grid)
440      INTEGER                   , INTENT(in   ) ::   pdim     ! number of ice categories
441      !!
442      INTEGER  ::   ji, jj, jl    ! dummy loop indices
443      INTEGER  ::   ijpl          ! number of ice categories (size of 3rd dim of input arrays)
444      REAL(wp) ::   zst2, zst3
445      REAL(wp) ::   zcoef_wnorm, zcoef_wnorm2, zcoef_dqlw, zcoef_dqla, zcoef_dqsb
446      REAL(wp) ::   zztmp                                        ! temporary variable
447      REAL(wp) ::   zcoef_frca                                   ! fractional cloud amount
448      REAL(wp) ::   zwnorm_f, zwndi_f , zwndj_f                  ! relative wind module and components at F-point
449      REAL(wp) ::             zwndi_t , zwndj_t                  ! relative wind components at T-point
450      !!
451      REAL(wp), DIMENSION(:,:)  , POINTER ::   z_wnds_t          ! wind speed ( = | U10m - U_ice | ) at T-point
452      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_qlw             ! long wave heat flux over ice
453      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_qsb             ! sensible  heat flux over ice
454      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_dqlw            ! long wave heat sensitivity over ice
455      REAL(wp), DIMENSION(:,:,:), POINTER ::   z_dqsb            ! sensible  heat sensitivity over ice
456      !!---------------------------------------------------------------------
457      !
458      IF( nn_timing == 1 )  CALL timing_start('blk_ice_core')
459      !
460      CALL wrk_alloc( jpi,jpj, z_wnds_t )
461      CALL wrk_alloc( jpi,jpj,pdim, z_qlw, z_qsb, z_dqlw, z_dqsb ) 
462
463      ijpl  = pdim                            ! number of ice categories
464
465      ! local scalars ( place there for vector optimisation purposes)
466      zcoef_wnorm  = rhoa * Cice
467      zcoef_wnorm2 = rhoa * Cice * 0.5
468      zcoef_dqlw   = 4.0 * 0.95 * Stef
469      zcoef_dqla   = -Ls * Cice * 11637800. * (-5897.8)
470      zcoef_dqsb   = rhoa * cpa * Cice
471      zcoef_frca   = 1.0  - 0.3
472
473!!gm brutal....
474      z_wnds_t(:,:) = 0.e0
475      p_taui  (:,:) = 0.e0
476      p_tauj  (:,:) = 0.e0
477!!gm end
478
479#if defined key_lim3
480      tatm_ice(:,:) = sf(jp_tair)%fnow(:,:,1)   ! LIM3: make Tair available in sea-ice. WARNING allocated after call to ice_init
481#endif
482      ! ----------------------------------------------------------------------------- !
483      !    Wind components and module relative to the moving ocean ( U10m - U_ice )   !
484      ! ----------------------------------------------------------------------------- !
485      SELECT CASE( cd_grid )
486      CASE( 'I' )                  ! B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
487         !                           and scalar wind at T-point ( = | U10m - U_ice | ) (masked)
488!CDIR NOVERRCHK
489         DO jj = 2, jpjm1
490            DO ji = 2, jpim1   ! B grid : NO vector opt
491               ! ... scalar wind at I-point (fld being at T-point)
492               zwndi_f = 0.25 * (  sf(jp_wndi)%fnow(ji-1,jj  ,1) + sf(jp_wndi)%fnow(ji  ,jj  ,1)   &
493                  &              + sf(jp_wndi)%fnow(ji-1,jj-1,1) + sf(jp_wndi)%fnow(ji  ,jj-1,1)  ) - pui(ji,jj)
494               zwndj_f = 0.25 * (  sf(jp_wndj)%fnow(ji-1,jj  ,1) + sf(jp_wndj)%fnow(ji  ,jj  ,1)   &
495                  &              + sf(jp_wndj)%fnow(ji-1,jj-1,1) + sf(jp_wndj)%fnow(ji  ,jj-1,1)  ) - pvi(ji,jj)
496               zwnorm_f = zcoef_wnorm * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f )
497               ! ... ice stress at I-point
498               p_taui(ji,jj) = zwnorm_f * zwndi_f
499               p_tauj(ji,jj) = zwnorm_f * zwndj_f
500               ! ... scalar wind at T-point (fld being at T-point)
501               zwndi_t = sf(jp_wndi)%fnow(ji,jj,1) - 0.25 * (  pui(ji,jj+1) + pui(ji+1,jj+1)   &
502                  &                                          + pui(ji,jj  ) + pui(ji+1,jj  )  )
503               zwndj_t = sf(jp_wndj)%fnow(ji,jj,1) - 0.25 * (  pvi(ji,jj+1) + pvi(ji+1,jj+1)   &
504                  &                                          + pvi(ji,jj  ) + pvi(ji+1,jj  )  )
505               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
506            END DO
507         END DO
508         CALL lbc_lnk( p_taui  , 'I', -1. )
509         CALL lbc_lnk( p_tauj  , 'I', -1. )
510         CALL lbc_lnk( z_wnds_t, 'T',  1. )
511         !
512      CASE( 'C' )                  ! C-grid ice dynamics :   U & V-points (same as ocean)
513#if defined key_vectopt_loop
514!CDIR COLLAPSE
515#endif
516         DO jj = 2, jpj
517            DO ji = fs_2, jpi   ! vect. opt.
518               zwndi_t = (  sf(jp_wndi)%fnow(ji,jj,1) - 0.5 * ( pui(ji-1,jj  ) + pui(ji,jj) )  )
519               zwndj_t = (  sf(jp_wndj)%fnow(ji,jj,1) - 0.5 * ( pvi(ji  ,jj-1) + pvi(ji,jj) )  )
520               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
521            END DO
522         END DO
523#if defined key_vectopt_loop
524!CDIR COLLAPSE
525#endif
526         DO jj = 2, jpjm1
527            DO ji = fs_2, fs_jpim1   ! vect. opt.
528               p_taui(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji+1,jj  ) + z_wnds_t(ji,jj) )                          &
529                  &          * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj,1) + sf(jp_wndi)%fnow(ji,jj,1) ) - pui(ji,jj) )
530               p_tauj(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji,jj+1  ) + z_wnds_t(ji,jj) )                          &
531                  &          * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1,1) + sf(jp_wndj)%fnow(ji,jj,1) ) - pvi(ji,jj) )
532            END DO
533         END DO
534         CALL lbc_lnk( p_taui  , 'U', -1. )
535         CALL lbc_lnk( p_tauj  , 'V', -1. )
536         CALL lbc_lnk( z_wnds_t, 'T',  1. )
537         !
538      END SELECT
539
540      zztmp = 1. / ( 1. - albo )
541      !                                     ! ========================== !
542      DO jl = 1, ijpl                       !  Loop over ice categories  !
543         !                                  ! ========================== !
544!CDIR NOVERRCHK
545!CDIR COLLAPSE
546         DO jj = 1 , jpj
547!CDIR NOVERRCHK
548            DO ji = 1, jpi
549               ! ----------------------------!
550               !      I   Radiative FLUXES   !
551               ! ----------------------------!
552               zst2 = pst(ji,jj,jl) * pst(ji,jj,jl)
553               zst3 = pst(ji,jj,jl) * zst2
554               ! Short Wave (sw)
555               p_qsr(ji,jj,jl) = zztmp * ( 1. - palb(ji,jj,jl) ) * qsr(ji,jj)
556               ! Long  Wave (lw)
557               z_qlw(ji,jj,jl) = 0.95 * (  sf(jp_qlw)%fnow(ji,jj,1) - Stef * pst(ji,jj,jl) * zst3  ) * tmask(ji,jj,1)
558               ! lw sensitivity
559               z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3                                               
560
561               ! ----------------------------!
562               !     II    Turbulent FLUXES  !
563               ! ----------------------------!
564
565               ! ... turbulent heat fluxes
566               ! Sensible Heat
567               z_qsb(ji,jj,jl) = rhoa * cpa * Cice * z_wnds_t(ji,jj) * ( pst(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj,1) )
568               ! Latent Heat
569               p_qla(ji,jj,jl) = MAX( 0.e0, rhoa * Ls  * Cice * z_wnds_t(ji,jj)   &                           
570                  &                    * (  11637800. * EXP( -5897.8 / pst(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj,1)  ) )
571               ! Latent heat sensitivity for ice (Dqla/Dt)
572               p_dqla(ji,jj,jl) = zcoef_dqla * z_wnds_t(ji,jj) / ( zst2 ) * EXP( -5897.8 / pst(ji,jj,jl) )
573               ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice)
574               z_dqsb(ji,jj,jl) = zcoef_dqsb * z_wnds_t(ji,jj)
575
576               ! ----------------------------!
577               !     III    Total FLUXES     !
578               ! ----------------------------!
579               ! Downward Non Solar flux
580               p_qns (ji,jj,jl) =     z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - p_qla (ji,jj,jl)     
581               ! Total non solar heat flux sensitivity for ice
582               p_dqns(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + p_dqla(ji,jj,jl) )   
583            END DO
584            !
585         END DO
586         !
587      END DO
588      !
589      !--------------------------------------------------------------------
590      ! FRACTIONs of net shortwave radiation which is not absorbed in the
591      ! thin surface layer and penetrates inside the ice cover
592      ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
593   
594!CDIR COLLAPSE
595      p_fr1(:,:) = ( 0.18 * ( 1.0 - zcoef_frca ) + 0.35 * zcoef_frca )
596!CDIR COLLAPSE
597      p_fr2(:,:) = ( 0.82 * ( 1.0 - zcoef_frca ) + 0.65 * zcoef_frca )
598       
599!CDIR COLLAPSE
600      p_tpr(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac      ! total precipitation [kg/m2/s]
601!CDIR COLLAPSE
602      p_spr(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac      ! solid precipitation [kg/m2/s]
603      CALL iom_put( 'snowpre', p_spr )                  ! Snow precipitation
604      !
605      IF(ln_ctl) THEN
606         CALL prt_ctl(tab3d_1=p_qla   , clinfo1=' blk_ice_core: p_qla  : ', tab3d_2=z_qsb   , clinfo2=' z_qsb  : ', kdim=ijpl)
607         CALL prt_ctl(tab3d_1=z_qlw   , clinfo1=' blk_ice_core: z_qlw  : ', tab3d_2=p_dqla  , clinfo2=' p_dqla : ', kdim=ijpl)
608         CALL prt_ctl(tab3d_1=z_dqsb  , clinfo1=' blk_ice_core: z_dqsb : ', tab3d_2=z_dqlw  , clinfo2=' z_dqlw : ', kdim=ijpl)
609         CALL prt_ctl(tab3d_1=p_dqns  , clinfo1=' blk_ice_core: p_dqns : ', tab3d_2=p_qsr   , clinfo2=' p_qsr  : ', kdim=ijpl)
610         CALL prt_ctl(tab3d_1=pst     , clinfo1=' blk_ice_core: pst    : ', tab3d_2=p_qns   , clinfo2=' p_qns  : ', kdim=ijpl)
611         CALL prt_ctl(tab2d_1=p_tpr   , clinfo1=' blk_ice_core: p_tpr  : ', tab2d_2=p_spr   , clinfo2=' p_spr  : ')
612         CALL prt_ctl(tab2d_1=p_taui  , clinfo1=' blk_ice_core: p_taui : ', tab2d_2=p_tauj  , clinfo2=' p_tauj : ')
613         CALL prt_ctl(tab2d_1=z_wnds_t, clinfo1=' blk_ice_core: z_wnds_t : ')
614      ENDIF
615
616      CALL wrk_dealloc( jpi,jpj, z_wnds_t )
617      CALL wrk_dealloc( jpi,jpj,pdim, z_qlw, z_qsb, z_dqlw, z_dqsb ) 
618      !
619      IF( nn_timing == 1 )  CALL timing_stop('blk_ice_core')
620      !
621   END SUBROUTINE blk_ice_core
622 
623
624   SUBROUTINE TURB_CORE_1Z(zu, sst, T_a, q_sat, q_a,   &
625      &                        dU , Cd , Ch   , Ce   )
626      !!----------------------------------------------------------------------
627      !!                      ***  ROUTINE  turb_core  ***
628      !!
629      !! ** Purpose :   Computes turbulent transfert coefficients of surface
630      !!                fluxes according to Large & Yeager (2004)
631      !!
632      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
633      !!      Momentum, Latent and sensible heat exchange coefficients
634      !!      Caution: this procedure should only be used in cases when air
635      !!      temperature (T_air), air specific humidity (q_air) and wind (dU)
636      !!      are provided at the same height 'zzu'!
637      !!
638      !! References :   Large & Yeager, 2004 : ???
639      !!----------------------------------------------------------------------
640      REAL(wp)                , INTENT(in   ) ::   zu      ! altitude of wind measurement       [m]
641      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   sst     ! sea surface temperature         [Kelvin]
642      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   T_a     ! potential air temperature       [Kelvin]
643      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   q_sat   ! sea surface specific humidity   [kg/kg]
644      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   q_a     ! specific air humidity           [kg/kg]
645      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::   dU      ! wind module |U(zu)-U(0)|        [m/s]
646      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   Cd      ! transfert coefficient for momentum       (tau)
647      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   Ch      ! transfert coefficient for temperature (Q_sens)
648      REAL(wp), DIMENSION(:,:), INTENT(  out) ::   Ce      ! transfert coefficient for evaporation  (Q_lat)
649      !!
650      INTEGER :: j_itt
651      INTEGER , PARAMETER ::   nb_itt = 3
652      REAL(wp), PARAMETER ::   grav   = 9.8   ! gravity                       
653      REAL(wp), PARAMETER ::   kappa  = 0.4   ! von Karman s constant
654
655      REAL(wp), DIMENSION(:,:), POINTER  ::   dU10          ! dU                                   [m/s]
656      REAL(wp), DIMENSION(:,:), POINTER  ::   dT            ! air/sea temperature differeence      [K]
657      REAL(wp), DIMENSION(:,:), POINTER  ::   dq            ! air/sea humidity difference          [K]
658      REAL(wp), DIMENSION(:,:), POINTER  ::   Cd_n10        ! 10m neutral drag coefficient
659      REAL(wp), DIMENSION(:,:), POINTER  ::   Ce_n10        ! 10m neutral latent coefficient
660      REAL(wp), DIMENSION(:,:), POINTER  ::   Ch_n10        ! 10m neutral sensible coefficient
661      REAL(wp), DIMENSION(:,:), POINTER  ::   sqrt_Cd_n10   ! root square of Cd_n10
662      REAL(wp), DIMENSION(:,:), POINTER  ::   sqrt_Cd       ! root square of Cd
663      REAL(wp), DIMENSION(:,:), POINTER  ::   T_vpot        ! virtual potential temperature        [K]
664      REAL(wp), DIMENSION(:,:), POINTER  ::   T_star        ! turbulent scale of tem. fluct.
665      REAL(wp), DIMENSION(:,:), POINTER  ::   q_star        ! turbulent humidity of temp. fluct.
666      REAL(wp), DIMENSION(:,:), POINTER  ::   U_star        ! turb. scale of velocity fluct.
667      REAL(wp), DIMENSION(:,:), POINTER  ::   L             ! Monin-Obukov length                  [m]
668      REAL(wp), DIMENSION(:,:), POINTER  ::   zeta          ! stability parameter at height zu
669      REAL(wp), DIMENSION(:,:), POINTER  ::   U_n10         ! neutral wind velocity at 10m         [m]   
670      REAL(wp), DIMENSION(:,:), POINTER  ::   xlogt, xct, zpsi_h, zpsi_m
671     
672      INTEGER , DIMENSION(:,:), POINTER  ::   stab          ! 1st guess stability test integer
673      !!----------------------------------------------------------------------
674      !
675      IF( nn_timing == 1 )  CALL timing_start('TURB_CORE_1Z')
676      !
677      CALL wrk_alloc( jpi,jpj, stab )   ! integer
678      CALL wrk_alloc( jpi,jpj, dU10, dT, dq, Cd_n10, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd, L )
679      CALL wrk_alloc( jpi,jpj, T_vpot, T_star, q_star, U_star, zeta, U_n10, xlogt, xct, zpsi_h, zpsi_m )
680
681      !! * Start
682      !! Air/sea differences
683      dU10 = max(0.5, dU)     ! we don't want to fall under 0.5 m/s
684      dT = T_a - sst          ! assuming that T_a is allready the potential temp. at zzu
685      dq = q_a - q_sat
686      !!   
687      !! Virtual potential temperature
688      T_vpot = T_a*(1. + 0.608*q_a)
689      !!
690      !! Neutral Drag Coefficient
691      stab    = 0.5 + sign(0.5,dT)    ! stable : stab = 1 ; unstable : stab = 0
692      IF  ( ln_cdgw ) THEN
693        cdn_wave = cdn_wave - rsmall*(tmask(:,:,1)-1)
694        Cd_n10(:,:) =   cdn_wave
695      ELSE
696        Cd_n10  = 1E-3 * ( 2.7/dU10 + 0.142 + dU10/13.09 )    !   L & Y eq. (6a)
697      ENDIF
698      sqrt_Cd_n10 = sqrt(Cd_n10)
699      Ce_n10  = 1E-3 * ( 34.6 * sqrt_Cd_n10 )               !   L & Y eq. (6b)
700      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1-stab)) !   L & Y eq. (6c), (6d)
701      !!
702      !! Initializing transfert coefficients with their first guess neutral equivalents :
703      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
704
705      !! * Now starting iteration loop
706      DO j_itt=1, nb_itt
707         !! Turbulent scales :
708         U_star  = sqrt_Cd*dU10                !   L & Y eq. (7a)
709         T_star  = Ch/sqrt_Cd*dT               !   L & Y eq. (7b)
710         q_star  = Ce/sqrt_Cd*dq               !   L & Y eq. (7c)
711
712         !! Estimate the Monin-Obukov length :
713         L  = (U_star**2)/( kappa*grav*(T_star/T_vpot + q_star/(q_a + 1./0.608)) )
714
715         !! Stability parameters :
716         zeta  = zu/L ;  zeta   = sign( min(abs(zeta),10.0), zeta )
717         zpsi_h  = psi_h(zeta)
718         zpsi_m  = psi_m(zeta)
719
720         IF  ( ln_cdgw ) THEN
721           sqrt_Cd=kappa/((kappa/sqrt_Cd_n10) - zpsi_m) ; Cd=sqrt_Cd*sqrt_Cd;
722         ELSE
723           !! Shifting the wind speed to 10m and neutral stability :
724           U_n10 = dU10*1./(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)) !  L & Y eq. (9a)
725
726           !! Updating the neutral 10m transfer coefficients :
727           Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)              !  L & Y eq. (6a)
728           sqrt_Cd_n10 = sqrt(Cd_n10)
729           Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                           !  L & Y eq. (6b)
730           stab    = 0.5 + sign(0.5,zeta)
731           Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab))           !  L & Y eq. (6c), (6d)
732
733           !! Shifting the neutral  10m transfer coefficients to ( zu , zeta ) :
734           !!
735           xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10) - zpsi_m)
736           Cd  = Cd_n10/(xct*xct) ;  sqrt_Cd = sqrt(Cd)
737         ENDIF
738         !!
739         xlogt = log(zu/10.) - zpsi_h
740         !!
741         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
742         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
743         !!
744         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
745         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
746         !!
747      END DO
748      !!
749      CALL wrk_dealloc( jpi,jpj, stab )   ! integer
750      CALL wrk_dealloc( jpi,jpj, dU10, dT, dq, Cd_n10, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd, L )
751      CALL wrk_dealloc( jpi,jpj, T_vpot, T_star, q_star, U_star, zeta, U_n10, xlogt, xct, zpsi_h, zpsi_m )
752      !
753      IF( nn_timing == 1 )  CALL timing_stop('TURB_CORE_1Z')
754      !
755    END SUBROUTINE TURB_CORE_1Z
756
757
758    SUBROUTINE TURB_CORE_2Z(zt, zu, sst, T_zt, q_sat, q_zt, dU, Cd, Ch, Ce, T_zu, q_zu)
759      !!----------------------------------------------------------------------
760      !!                      ***  ROUTINE  turb_core  ***
761      !!
762      !! ** Purpose :   Computes turbulent transfert coefficients of surface
763      !!                fluxes according to Large & Yeager (2004).
764      !!
765      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
766      !!      Momentum, Latent and sensible heat exchange coefficients
767      !!      Caution: this procedure should only be used in cases when air
768      !!      temperature (T_air) and air specific humidity (q_air) are at 2m
769      !!      whereas wind (dU) is at 10m.
770      !!
771      !! References :   Large & Yeager, 2004 : ???
772      !!----------------------------------------------------------------------
773      REAL(wp), INTENT(in   )                     ::   zt       ! height for T_zt and q_zt                   [m]
774      REAL(wp), INTENT(in   )                     ::   zu       ! height for dU                              [m]
775      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   sst      ! sea surface temperature              [Kelvin]
776      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   T_zt     ! potential air temperature            [Kelvin]
777      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_sat    ! sea surface specific humidity         [kg/kg]
778      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_zt     ! specific air humidity                 [kg/kg]
779      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   dU       ! relative wind module |U(zu)-U(0)|       [m/s]
780      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cd       ! transfer coefficient for momentum         (tau)
781      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ch       ! transfer coefficient for sensible heat (Q_sens)
782      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ce       ! transfert coefficient for evaporation   (Q_lat)
783      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   T_zu     ! air temp. shifted at zu                     [K]
784      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   q_zu     ! spec. hum.  shifted at zu               [kg/kg]
785
786      INTEGER :: j_itt
787      INTEGER , PARAMETER :: nb_itt = 3              ! number of itterations
788      REAL(wp), PARAMETER ::   grav   = 9.8          ! gravity                       
789      REAL(wp), PARAMETER ::   kappa  = 0.4          ! von Karman's constant
790     
791      REAL(wp), DIMENSION(:,:), POINTER ::   dU10          ! dU                                [m/s]
792      REAL(wp), DIMENSION(:,:), POINTER ::   dT            ! air/sea temperature differeence   [K]
793      REAL(wp), DIMENSION(:,:), POINTER ::   dq            ! air/sea humidity difference       [K]
794      REAL(wp), DIMENSION(:,:), POINTER ::   Cd_n10        ! 10m neutral drag coefficient
795      REAL(wp), DIMENSION(:,:), POINTER ::   Ce_n10        ! 10m neutral latent coefficient
796      REAL(wp), DIMENSION(:,:), POINTER ::   Ch_n10        ! 10m neutral sensible coefficient
797      REAL(wp), DIMENSION(:,:), POINTER ::   sqrt_Cd_n10   ! root square of Cd_n10
798      REAL(wp), DIMENSION(:,:), POINTER ::   sqrt_Cd       ! root square of Cd
799      REAL(wp), DIMENSION(:,:), POINTER ::   T_vpot        ! virtual potential temperature        [K]
800      REAL(wp), DIMENSION(:,:), POINTER ::   T_star        ! turbulent scale of tem. fluct.
801      REAL(wp), DIMENSION(:,:), POINTER ::   q_star        ! turbulent humidity of temp. fluct.
802      REAL(wp), DIMENSION(:,:), POINTER ::   U_star        ! turb. scale of velocity fluct.
803      REAL(wp), DIMENSION(:,:), POINTER ::   L             ! Monin-Obukov length                  [m]
804      REAL(wp), DIMENSION(:,:), POINTER ::   zeta_u        ! stability parameter at height zu
805      REAL(wp), DIMENSION(:,:), POINTER ::   zeta_t        ! stability parameter at height zt
806      REAL(wp), DIMENSION(:,:), POINTER ::   U_n10         ! neutral wind velocity at 10m        [m]
807      REAL(wp), DIMENSION(:,:), POINTER ::   xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m
808
809      INTEGER , DIMENSION(:,:), POINTER ::   stab          ! 1st stability test integer
810      !!----------------------------------------------------------------------
811      !
812      IF( nn_timing == 1 )  CALL timing_start('TURB_CORE_2Z')
813      !
814      CALL wrk_alloc( jpi,jpj, dU10, dT, dq, Cd_n10, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd, L )
815      CALL wrk_alloc( jpi,jpj, T_vpot, T_star, q_star, U_star, zeta_u, zeta_t, U_n10 )
816      CALL wrk_alloc( jpi,jpj, xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m )
817      CALL wrk_alloc( jpi,jpj, stab )   ! interger
818
819      !! Initial air/sea differences
820      dU10 = max(0.5, dU)      !  we don't want to fall under 0.5 m/s
821      dT = T_zt - sst 
822      dq = q_zt - q_sat
823
824      !! Neutral Drag Coefficient :
825      stab = 0.5 + sign(0.5,dT)                 ! stab = 1  if dT > 0  -> STABLE
826      IF( ln_cdgw ) THEN
827        cdn_wave = cdn_wave - rsmall*(tmask(:,:,1)-1)
828        Cd_n10(:,:) =   cdn_wave
829      ELSE
830        Cd_n10  = 1E-3*( 2.7/dU10 + 0.142 + dU10/13.09 ) 
831      ENDIF
832      sqrt_Cd_n10 = sqrt(Cd_n10)
833      Ce_n10  = 1E-3*( 34.6 * sqrt_Cd_n10 )
834      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1 - stab))
835
836      !! Initializing transf. coeff. with their first guess neutral equivalents :
837      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
838
839      !! Initializing z_u values with z_t values :
840      T_zu = T_zt ;  q_zu = q_zt
841
842      !!  * Now starting iteration loop
843      DO j_itt=1, nb_itt
844         dT = T_zu - sst ;  dq = q_zu - q_sat ! Updating air/sea differences
845         T_vpot = T_zu*(1. + 0.608*q_zu)    ! Updating virtual potential temperature at zu
846         U_star = sqrt_Cd*dU10                ! Updating turbulent scales :   (L & Y eq. (7))
847         T_star  = Ch/sqrt_Cd*dT              !
848         q_star  = Ce/sqrt_Cd*dq              !
849         !!
850         L = (U_star*U_star) &                ! Estimate the Monin-Obukov length at height zu
851              & / (kappa*grav/T_vpot*(T_star*(1.+0.608*q_zu) + 0.608*T_zu*q_star))
852         !! Stability parameters :
853         zeta_u  = zu/L  ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
854         zeta_t  = zt/L  ;  zeta_t = sign( min(abs(zeta_t),10.0), zeta_t )
855         zpsi_hu = psi_h(zeta_u)
856         zpsi_ht = psi_h(zeta_t)
857         zpsi_m  = psi_m(zeta_u)
858         !!
859         !! Shifting the wind speed to 10m and neutral stability : (L & Y eq.(9a))
860!        U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u)))
861         U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m))
862         !!
863         !! Shifting temperature and humidity at zu :          (L & Y eq. (9b-9c))
864!        T_zu = T_zt - T_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
865         T_zu = T_zt - T_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
866!        q_zu = q_zt - q_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
867         q_zu = q_zt - q_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
868         !!
869         !! q_zu cannot have a negative value : forcing 0
870         stab = 0.5 + sign(0.5,q_zu) ;  q_zu = stab*q_zu
871         !!
872         IF( ln_cdgw ) THEN
873            sqrt_Cd=kappa/((kappa/sqrt_Cd_n10) - zpsi_m) ; Cd=sqrt_Cd*sqrt_Cd;
874         ELSE
875           !! Updating the neutral 10m transfer coefficients :
876           Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)    ! L & Y eq. (6a)
877           sqrt_Cd_n10 = sqrt(Cd_n10)
878           Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                 ! L & Y eq. (6b)
879           stab    = 0.5 + sign(0.5,zeta_u)
880           Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab)) ! L & Y eq. (6c-6d)
881           !!
882           !!
883           !! Shifting the neutral 10m transfer coefficients to (zu,zeta_u) :
884           xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)
885           Cd = Cd_n10/(xct*xct) ; sqrt_Cd = sqrt(Cd)
886         ENDIF
887         !!
888         xlogt = log(zu/10.) - zpsi_hu
889         !!
890         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
891         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
892         !!
893         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
894         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
895         !!
896         !!
897      END DO
898      !!
899      CALL wrk_dealloc( jpi,jpj, dU10, dT, dq, Cd_n10, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd, L )
900      CALL wrk_dealloc( jpi,jpj, T_vpot, T_star, q_star, U_star, zeta_u, zeta_t, U_n10 )
901      CALL wrk_dealloc( jpi,jpj, xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m )
902      CALL wrk_dealloc( jpi,jpj, stab )   ! interger
903      !
904      IF( nn_timing == 1 )  CALL timing_stop('TURB_CORE_2Z')
905      !
906    END SUBROUTINE TURB_CORE_2Z
907
908
909    FUNCTION psi_m(zta)   !! Psis, L & Y eq. (8c), (8d), (8e)
910      !-------------------------------------------------------------------------------
911      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
912
913      REAL(wp), PARAMETER :: pi = 3.141592653589793_wp
914      REAL(wp), DIMENSION(jpi,jpj)             :: psi_m
915      REAL(wp), DIMENSION(:,:), POINTER        :: X2, X, stabit
916      !-------------------------------------------------------------------------------
917
918      CALL wrk_alloc( jpi,jpj, X2, X, stabit )
919
920      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.0) ;  X  = sqrt(X2)
921      stabit    = 0.5 + sign(0.5,zta)
922      psi_m = -5.*zta*stabit  &                                                          ! Stable
923         &    + (1. - stabit)*(2*log((1. + X)/2) + log((1. + X2)/2) - 2*atan(X) + pi/2)  ! Unstable
924
925      CALL wrk_dealloc( jpi,jpj, X2, X, stabit )
926      !
927    END FUNCTION psi_m
928
929
930    FUNCTION psi_h( zta )    !! Psis, L & Y eq. (8c), (8d), (8e)
931      !-------------------------------------------------------------------------------
932      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   zta
933      !
934      REAL(wp), DIMENSION(jpi,jpj)             ::   psi_h
935      REAL(wp), DIMENSION(:,:), POINTER        :: X2, X, stabit
936      !-------------------------------------------------------------------------------
937
938      CALL wrk_alloc( jpi,jpj, X2, X, stabit )
939
940      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.) ;  X  = sqrt(X2)
941      stabit    = 0.5 + sign(0.5,zta)
942      psi_h = -5.*zta*stabit  &                                       ! Stable
943         &    + (1. - stabit)*(2.*log( (1. + X2)/2. ))                 ! Unstable
944
945      CALL wrk_dealloc( jpi,jpj, X2, X, stabit )
946      !
947    END FUNCTION psi_h
948 
949   !!======================================================================
950END MODULE sbcblk_core
Note: See TracBrowser for help on using the repository browser.