New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssr.F90 in branches/NERC/dev_r3874_FASTNEt/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/NERC/dev_r3874_FASTNEt/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssr.F90 @ 6736

Last change on this file since 6736 was 6736, checked in by jamesharle, 8 years ago

FASTNEt code modifications
  • Property svn:keywords set to Id
File size: 12.5 KB
Line 
1MODULE sbcssr
2   !!======================================================================
3   !!                       ***  MODULE  sbcssr  ***
4   !! Surface module :  heat and fresh water fluxes a restoring term toward observed SST/SSS
5   !!======================================================================
6   !! History :  3.0  !  2006-06  (G. Madec)  Original code
7   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssr        : add to sbc a restoring term toward SST/SSS climatology
12   !!----------------------------------------------------------------------
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE sbc_oce         ! surface boundary condition
16   USE phycst          ! physical constants
17   USE sbcrnf          ! surface boundary condition : runoffs
18   USE fldread         ! read input fields
19   USE iom             ! I/O manager
20   USE in_out_manager  ! I/O manager
21   USE lib_mpp         ! distribued memory computing library
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE timing          ! Timing
24   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssr        ! routine called in sbcmod
30   PUBLIC   sbc_ssr_init   ! routine called in sbcmod
31
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   erp   !: evaporation damping   [kg/m2/s]
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   qrp   !: heat flux damping        [w/m2]
34
35   !                                           !!* Namelist namsbc_ssr *
36   INTEGER, PUBLIC ::   nn_sstr     =   0       ! SST/SSS restoring indicator
37   INTEGER, PUBLIC ::   nn_sssr     =   0       ! SST/SSS restoring indicator
38   REAL(wp)        ::   rn_dqdt     = -40.e0    ! restoring factor on SST and SSS
39   REAL(wp)        ::   rn_deds     = -27.70    ! restoring factor on SST and SSS
40   LOGICAL         ::   ln_sssr_bnd = .false.   ! flag to bound erp term
41   REAL(wp)        ::   rn_sssr_bnd =   0.e0    ! ABS(Max./Min.) value of erp term [mm/day]
42
43   REAL(wp) , ALLOCATABLE, DIMENSION(:) ::   buffer   ! Temporary buffer for exchange
44   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sst   ! structure of input SST (file informations, fields read)
45   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sss   ! structure of input SSS (file informations, fields read)
46
47   !! * Substitutions
48#  include "domzgr_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE sbc_ssr( kt )
57      !!---------------------------------------------------------------------
58      !!                     ***  ROUTINE sbc_ssr  ***
59      !!
60      !! ** Purpose :   Add to heat and/or freshwater fluxes a damping term
61      !!                toward observed SST and/or SSS.
62      !!
63      !! ** Method  : - Read namelist namsbc_ssr
64      !!              - Read observed SST and/or SSS
65      !!              - at each nscb time step
66      !!                   add a retroaction term on qns    (nn_sstr = 1)
67      !!                   add a damping term on emps       (nn_sssr = 1)
68      !!                   add a damping term on emp & emps (nn_sssr = 2)
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
71      !!
72      INTEGER  ::   ji, jj   ! dummy loop indices
73      REAL(wp) ::   zerp     ! local scalar for evaporation damping
74      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
75      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
76      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
77      INTEGER  ::   ierror   ! return error code
78      !!
79      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
80      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
81      NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, sn_sst, sn_sss, ln_sssr_bnd, rn_sssr_bnd
82      !!----------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('sbc_ssr')
85      !
86      IF( nn_sstr + nn_sssr /= 0 ) THEN
87         !
88         IF( nn_sstr == 1)   CALL fld_read( kt, nn_fsbc, sf_sst )   ! Read SST data and provides it at kt
89         IF( nn_sssr >= 1)   CALL fld_read( kt, nn_fsbc, sf_sss )   ! Read SSS data and provides it at kt
90         !
91         !                                         ! ========================= !
92         IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    Add restoring term     !
93            !                                      ! ========================= !
94            !
95            IF( nn_sstr == 1 ) THEN                   !* Temperature restoring term
96!CDIR COLLAPSE
97               DO jj = 1, jpj
98                  DO ji = 1, jpi
99                     zqrp = rn_dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj,1) )
100                     qns(ji,jj) = qns(ji,jj) + zqrp
101                     qrp(ji,jj) = zqrp
102                  END DO
103               END DO
104               CALL iom_put( "qrp", qrp )                             ! heat flux damping
105            ENDIF
106            !
107            IF( nn_sssr == 1 ) THEN                   !* Salinity damping term (salt flux, emps only)
108               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
109!CDIR COLLAPSE
110               DO jj = 1, jpj
111                  DO ji = 1, jpi
112                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
113                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) )   &
114                        &        / ( sss_m(ji,jj) + 1.e-20   )
115                     emps(ji,jj) = emps(ji,jj) + zerp
116                     erp( ji,jj) = zerp
117                  END DO
118               END DO
119               CALL iom_put( "erp", erp )                             ! freshwater flux damping
120               !
121            ELSEIF( nn_sssr == 2 ) THEN               !* Salinity damping term (volume flux, emp and emps)
122               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
123               zerp_bnd = rn_sssr_bnd / rday                          !       -              -   
124!CDIR COLLAPSE
125               DO jj = 1, jpj
126                  DO ji = 1, jpi                           
127                     zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
128                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) )   &
129                        &        / ( sss_m(ji,jj) + 1.e-20   )
130                     IF( ln_sssr_bnd )   zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) )
131                     emp (ji,jj) = emp (ji,jj) + zerp
132                     emps(ji,jj) = emps(ji,jj) + zerp
133                     erp (ji,jj) = zerp
134                  END DO
135               END DO
136               CALL iom_put( "erp", erp )                             ! freshwater flux damping
137            ENDIF
138            !
139         ENDIF
140         !
141      ENDIF
142      !
143      IF( nn_timing == 1 )  CALL timing_stop('sbc_ssr')
144      !
145   END SUBROUTINE sbc_ssr
146
147 
148   SUBROUTINE sbc_ssr_init
149      !!---------------------------------------------------------------------
150      !!                  ***  ROUTINE sbc_ssr_init  ***
151      !!
152      !! ** Purpose :   initialisation of surface damping term
153      !!
154      !! ** Method  : - Read namelist namsbc_ssr
155      !!              - Read observed SST and/or SSS if required
156      !!---------------------------------------------------------------------
157      INTEGER  ::   ji, jj   ! dummy loop indices
158      REAL(wp) ::   zerp     ! local scalar for evaporation damping
159      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
160      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
161      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
162      INTEGER  ::   ierror   ! return error code
163      !!
164      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
165      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
166      NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, sn_sst, sn_sss, ln_sssr_bnd, rn_sssr_bnd
167      !!----------------------------------------------------------------------
168      !
169      !                            !* set file information
170      cn_dir  = './'            ! directory in which the model is executed
171      ! ... default values (NB: frequency positive => hours, negative => months)
172      !            !   file    ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
173      !            !   name    !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
174      sn_sst = FLD_N( 'sst'    ,    24     ,  'sst'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
175      sn_sss = FLD_N( 'sss'    ,    -1     ,  'sss'     ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
176
177      REWIND( numnam )             !* read in namlist namflx
178      READ  ( numnam, namsbc_ssr ) 
179
180      IF(lwp) THEN                 !* control print
181         WRITE(numout,*)
182         WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term '
183         WRITE(numout,*) '~~~~~~~ '
184         WRITE(numout,*) '   Namelist namsbc_ssr :'
185         WRITE(numout,*) '      SST restoring term (Yes=1)             nn_sstr     = ', nn_sstr
186         WRITE(numout,*) '      SSS damping term (Yes=1, salt flux)    nn_sssr     = ', nn_sssr
187         WRITE(numout,*) '                       (Yes=2, volume flux) '
188         WRITE(numout,*) '      dQ/dT (restoring magnitude on SST)     rn_dqdt     = ', rn_dqdt, ' W/m2/K'
189         WRITE(numout,*) '      dE/dS (restoring magnitude on SST)     rn_deds     = ', rn_deds, ' mm/day'
190         WRITE(numout,*) '      flag to bound erp term                 ln_sssr_bnd = ', ln_sssr_bnd
191         WRITE(numout,*) '      ABS(Max./Min.) erp threshold           rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day'
192      ENDIF
193      !
194      !                            !* Allocate erp and qrp array
195      ALLOCATE( qrp(jpi,jpj), erp(jpi,jpj), STAT=ierror )
196      IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate erp and qrp array' )
197      !
198      IF( nn_sstr == 1 ) THEN      !* set sf_sst structure & allocate arrays
199         !
200         ALLOCATE( sf_sst(1), STAT=ierror )
201         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst structure' )
202         ALLOCATE( sf_sst(1)%fnow(jpi,jpj,1), STAT=ierror )
203         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst now array' )
204         !
205         ! fill sf_sst with sn_sst and control print
206         CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr' )
207         IF( sf_sst(1)%ln_tint )   ALLOCATE( sf_sst(1)%fdta(jpi,jpj,1,2), STAT=ierror )
208         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst data array' )
209         !
210      ENDIF
211      !
212      IF( nn_sssr >= 1 ) THEN      !* set sf_sss structure & allocate arrays
213         !
214         ALLOCATE( sf_sss(1), STAT=ierror )
215         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss structure' )
216         ALLOCATE( sf_sss(1)%fnow(jpi,jpj,1), STAT=ierror )
217         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss now array' )
218         !
219         ! fill sf_sss with sn_sss and control print
220         CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr' )
221         IF( sf_sss(1)%ln_tint )   ALLOCATE( sf_sss(1)%fdta(jpi,jpj,1,2), STAT=ierror )
222         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss data array' )
223         !
224      ENDIF
225      !
226      !                            !* Initialize qrp and erp if no restoring
227      IF( nn_sstr /= 1                   )   qrp(:,:) = 0._wp
228      IF( nn_sssr /= 1 .OR. nn_sssr /= 2 )   erp(:,:) = 0._wp
229      !
230   END SUBROUTINE sbc_ssr_init
231     
232   !!======================================================================
233END MODULE sbcssr
Note: See TracBrowser for help on using the repository browser.