New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in branches/NERC/dev_r3874_FASTNEt/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/NERC/dev_r3874_FASTNEt/NEMOGCM/NEMO/OPA_SRC/stpctl.F90 @ 6736

Last change on this file since 6736 was 6736, checked in by jamesharle, 8 years ago

FASTNEt code modifications
  • Property svn:keywords set to Id
File size: 8.2 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  (G. Madec) Original code
7   !!            6.0  ! 1992-06  (M. Imbard)
8   !!            8.0  ! 1997-06  (A.M. Treguier)
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   stp_ctl      : Control the run
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers variables
17   USE dom_oce         ! ocean space and time domain variables
18   USE sol_oce         ! ocean space and time domain variables
19   USE in_out_manager  ! I/O manager
20   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
21   USE lib_mpp         ! distributed memory computing
22   USE dynspg_oce      ! pressure gradient schemes
23   USE c1d             ! 1D vertical configuration
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC stp_ctl           ! routine called by step.F90
29   !!----------------------------------------------------------------------
30   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
31   !! $Id$
32   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
33   !!----------------------------------------------------------------------
34
35CONTAINS
36
37   SUBROUTINE stp_ctl( kt, kindic )
38      !!----------------------------------------------------------------------
39      !!                    ***  ROUTINE stp_ctl  ***
40      !!                     
41      !! ** Purpose :   Control the run
42      !!
43      !! ** Method  : - Save the time step in numstp
44      !!              - Print it each 50 time steps
45      !!              - Print solver statistics in numsol
46      !!              - Stop the run IF problem for the solver ( indec < 0 )
47      !!
48      !! ** Actions :   'time.step' file containing the last ocean time-step
49      !!               
50      !!----------------------------------------------------------------------
51      INTEGER, INTENT( in ) ::   kt         ! ocean time-step index
52      INTEGER, INTENT( inout ) ::   kindic  ! indicator of solver convergence
53      !!
54      INTEGER  ::   ji, jj, jk              ! dummy loop indices
55      INTEGER  ::   ii, ij, ik              ! temporary integers
56      REAL(wp) ::   zumax, zsmin, zssh2     ! temporary scalars
57      INTEGER, DIMENSION(3) ::   ilocu      !
58      INTEGER, DIMENSION(2) ::   ilocs      !
59      !!----------------------------------------------------------------------
60
61      IF( kt == nit000 .AND. lwp ) THEN
62         WRITE(numout,*)
63         WRITE(numout,*) 'stp_ctl : time-stepping control'
64         WRITE(numout,*) '~~~~~~~'
65         ! open time.step file
66         CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
67      ENDIF
68
69         IF(MOD(kt,10) == 0) THEN
70      IF(lwp) WRITE ( numstp, '(1x, i8)' )   kt      !* save the current time step in numstp
71      IF(lwp) REWIND( numstp )                       !  --------------------------
72         ENDIF
73
74      !                                              !* Test maximum of velocity (zonal only)
75      !                                              !  ------------------------
76      !! zumax = MAXVAL( ABS( un(:,:,:) ) )                ! slower than the following loop on NEC SX5
77      zumax = 0.e0
78         IF(MOD(kt,10) == 0 .OR. MOD( kt, nwrite ) == 1 ) THEN
79      DO jk = 1, jpk
80         DO jj = 1, jpj
81            DO ji = 1, jpi
82               zumax = MAX(zumax,ABS(un(ji,jj,jk)))
83          END DO
84        END DO
85      END DO       
86         ENDIF
87      IF( zumax > 20.e0 ) THEN
88            WRITE(numout,*) ' stpctl: the zonal velocity is larger than 20 m/s in dom ', narea
89      ENDIF
90         IF(MOD(kt,10) == 0 .OR. MOD( kt, nwrite ) == 1 ) THEN
91      IF( lk_mpp )   CALL mpp_max( zumax )                 ! max over the global domain
92         ENDIF
93      !
94      IF( MOD( kt, nwrite ) == 1 .AND. lwp )   WRITE(numout,*) ' ==>> time-step= ',kt,' abs(U) max: ', zumax
95      !
96      IF( zumax > 20.e0 ) THEN
97         IF( lk_mpp ) THEN
98            CALL mpp_maxloc(ABS(un),umask,zumax,ii,ij,ik)
99         ELSE
100            ilocu = MAXLOC( ABS( un(:,:,:) ) )
101            ii = ilocu(1) + nimpp - 1
102            ij = ilocu(2) + njmpp - 1
103            ik = ilocu(3)
104         ENDIF
105         IF(lwp) THEN
106            WRITE(numout,cform_err)
107            WRITE(numout,*) ' stpctl: the zonal velocity is larger than 20 m/s'
108            WRITE(numout,*) ' ====== '
109            WRITE(numout,9400) kt, zumax, ii, ij, ik
110            WRITE(numout,*)
111            WRITE(numout,*) '          output of last fields in numwso'
112         ENDIF
113#if defined key_umax
114         kindic = -3
115#endif
116      ENDIF
1179400  FORMAT (' kt=',i6,' max abs(U): ',1pg11.4,', i j k: ',3i5)
118
119      !                                              !* Test minimum of salinity
120      !                                              !  ------------------------
121      !! zsmin = MINVAL( tsn(:,:,1,jp_sal), mask = tmask(:,:,1) == 1.e0 )  slower than the following loop on NEC SX5
122         IF(MOD(kt,10) == 0 .OR. MOD( kt, nwrite ) == 1 ) THEN
123      zsmin = 100.e0
124      DO jj = 2, jpjm1
125         DO ji = 1, jpi
126            IF( tmask(ji,jj,1) == 1) zsmin = MIN(zsmin,tsn(ji,jj,1,jp_sal))
127         END DO
128      END DO
129      IF( lk_mpp )   CALL mpp_min( zsmin )                ! min over the global domain
130         ENDIF
131      !
132      IF( MOD( kt, nwrite ) == 1 .AND. lwp )   WRITE(numout,*) ' ==>> time-step= ',kt,' SSS min:', zsmin
133      !
134      IF( zsmin < 0.) THEN
135         IF (lk_mpp) THEN
136            CALL mpp_minloc ( tsn(:,:,1,jp_sal),tmask(:,:,1), zsmin, ii,ij )
137         ELSE
138            ilocs = MINLOC( tsn(:,:,1,jp_sal), mask = tmask(:,:,1) == 1.e0 )
139            ii = ilocs(1) + nimpp - 1
140            ij = ilocs(2) + njmpp - 1
141         ENDIF
142         !
143         IF(lwp) THEN
144            WRITE(numout,cform_err)
145            WRITE(numout,*) 'stp_ctl : NEGATIVE sea surface salinity'
146            WRITE(numout,*) '======= '
147            WRITE(numout,9500) kt, zsmin, ii, ij
148            WRITE(numout,*)
149            WRITE(numout,*) '          output of last fields in numwso'
150         ENDIF
151         kindic = -3
152      ENDIF
1539500  FORMAT (' kt=',i6,' min SSS: ',1pg11.4,', i j: ',2i5)
154
155     
156      IF( lk_c1d )  RETURN          ! No log file in case of 1D vertical configuration
157
158      ! log file (solver or ssh statistics)
159      ! --------
160      IF( lk_dynspg_flt ) THEN      ! elliptic solver statistics (if required)
161         !
162         IF(lwp) WRITE(numsol,9200) kt, niter, res, SQRT(epsr)/eps       ! Solver
163         !
164         IF( kindic < 0 .AND. zsmin > 0.e0 .AND. zumax <= 20.e0 ) THEN   ! create a abort file if problem found
165            IF(lwp) THEN
166               WRITE(numout,*) ' stpctl: the elliptic solver DO not converge or explode'
167               WRITE(numout,*) ' ====== '
168               WRITE(numout,9200) kt, niter, res, sqrt(epsr)/eps
169               WRITE(numout,*)
170               WRITE(numout,*) ' stpctl: output of last fields'
171               WRITE(numout,*) ' ======  '
172            ENDIF
173         ENDIF
174         !
175      ELSE                                   !* ssh statistics (and others...)
176         IF( kt == nit000 .AND. lwp ) THEN   ! open ssh statistics file (put in solver.stat file)
177            CALL ctl_opn( numsol, 'solver.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
178         ENDIF
179         !
180         IF(MOD(kt,10) == 0 .OR. MOD( kt, nwrite ) == 1 ) THEN
181         zssh2 = SUM( sshn(:,:) * sshn(:,:) * tmask_i(:,:) )
182         IF( lk_mpp )   CALL mpp_sum( zssh2 )      ! sum over the global domain
183         !
184         IF(lwp) WRITE(numsol,9300) kt, zssh2, zumax, zsmin      ! ssh statistics
185         ENDIF
186         !
187      ENDIF
188
1899200  FORMAT('it:', i8, ' iter:', i4, ' r: ',e16.10, ' b: ',e16.10 )
1909300  FORMAT(' it :', i8, ' ssh2: ', e16.10, ' Umax: ',e16.10,' Smin: ',e16.10)
191      !
192   END SUBROUTINE stp_ctl
193
194   !!======================================================================
195END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.