source: branches/NERC/dev_r5107_NOC_MEDUSA/NEMOGCM/NEMO/TOP_SRC/PISCES/trcini_pisces.F90 @ 5712

Last change on this file since 5712 was 4996, checked in by cetlod, 6 years ago

trunk : New diagnostics in PISCES model, see ticket #1424

  • Property svn:keywords set to Id
File size: 10.1 KB
Line 
1MODULE trcini_pisces
2   !!======================================================================
3   !!                         ***  MODULE trcini_pisces  ***
4   !! TOP :   initialisation of the PISCES biochemical model
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. Maier-Reiner) Original code
7   !!              -   !  1999-10  (O. Aumont, C. Le Quere)
8   !!              -   !  2002     (O. Aumont)  PISCES
9   !!             1.0  !  2005-03  (O. Aumont, A. El Moussaoui) F90
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec) from trcini.pisces.h90
11   !!             3.5  !  2012-05  (C. Ethe) Merge PISCES-LOBSTER
12   !!----------------------------------------------------------------------
13#if defined key_pisces || defined key_pisces_reduced
14   !!----------------------------------------------------------------------
15   !!   'key_pisces'                                       PISCES bio-model
16   !!----------------------------------------------------------------------
17   !! trc_ini_pisces   : PISCES biochemical model initialisation
18   !!----------------------------------------------------------------------
19   USE par_trc         ! TOP parameters
20   USE oce_trc         !  shared variables between ocean and passive tracers
21   USE trc             !  passive tracers common variables
22   USE sms_pisces      !  PISCES Source Minus Sink variables
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_ini_pisces   ! called by trcini.F90 module
28
29
30#  include "top_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE trc_ini_pisces
39      !!----------------------------------------------------------------------
40      !!                   ***  ROUTINE trc_ini_pisces ***
41      !!
42      !! ** Purpose :   Initialisation of the PISCES biochemical model
43      !!----------------------------------------------------------------------
44
45      IF( lk_p4z ) THEN  ;   CALL p4z_ini   !  PISCES
46      ELSE               ;   CALL p2z_ini   !  LOBSTER
47      ENDIF
48
49   END SUBROUTINE trc_ini_pisces
50
51   SUBROUTINE p4z_ini
52      !!----------------------------------------------------------------------
53      !!                   ***  ROUTINE p4z_ini ***
54      !!
55      !! ** Purpose :   Initialisation of the PISCES biochemical model
56      !!----------------------------------------------------------------------
57#if defined key_pisces 
58      !
59      USE p4zsms          ! Main P4Z routine
60      USE p4zche          !  Chemical model
61      USE p4zsink         !  vertical flux of particulate matter due to sinking
62      USE p4zopt          !  optical model
63      USE p4zsbc          !  Boundary conditions
64      USE p4zfechem       !  Iron chemistry
65      USE p4zrem          !  Remineralisation of organic matter
66      USE p4zflx          !  Gas exchange
67      USE p4zlim          !  Co-limitations of differents nutrients
68      USE p4zprod         !  Growth rate of the 2 phyto groups
69      USE p4zmicro        !  Sources and sinks of microzooplankton
70      USE p4zmeso         !  Sources and sinks of mesozooplankton
71      USE p4zmort         !  Mortality terms for phytoplankton
72      USE p4zlys          !  Calcite saturation
73      !
74      REAL(wp), SAVE :: sco2   =  2.312e-3_wp
75      REAL(wp), SAVE :: alka0  =  2.423e-3_wp
76      REAL(wp), SAVE :: oxyg0  =  177.6e-6_wp 
77      REAL(wp), SAVE :: po4    =  2.174e-6_wp 
78      REAL(wp), SAVE :: bioma0 =  1.000e-8_wp 
79      REAL(wp), SAVE :: silic1 =  91.65e-6_wp 
80      REAL(wp), SAVE :: no3    =  31.04e-6_wp * 7.625_wp
81      !
82      INTEGER  ::  ji, jj, jk, ierr
83      REAL(wp) ::  zcaralk, zbicarb, zco3
84      REAL(wp) ::  ztmas, ztmas1
85      !!----------------------------------------------------------------------
86
87      IF(lwp) WRITE(numout,*)
88      IF(lwp) WRITE(numout,*) ' p4z_ini :   PISCES biochemical model initialisation'
89      IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
90
91                                                 ! Allocate PISCES arrays
92      ierr =         sms_pisces_alloc()         
93      ierr = ierr +  p4z_che_alloc()
94      ierr = ierr +  p4z_sink_alloc()
95      ierr = ierr +  p4z_opt_alloc()
96      ierr = ierr +  p4z_prod_alloc()
97      ierr = ierr +  p4z_rem_alloc()
98      ierr = ierr +  p4z_flx_alloc()
99      !
100      IF( lk_mpp    )   CALL mpp_sum( ierr )
101      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'pisces_alloc: unable to allocate PISCES arrays' )
102      !
103      ryyss    = nyear_len(1) * rday    ! number of seconds per year
104      r1_ryyss = 1. / ryyss
105      !
106
107      CALL p4z_sms_init       !  Maint routine
108      !                                            ! Time-step
109      rfact   = rdttrc(1)                          ! ---------
110      rfactr  = 1. / rfact
111      rfact2  = rfact / FLOAT( nrdttrc )
112      rfact2r = 1. / rfact2
113
114      IF(lwp) WRITE(numout,*) '    Passive Tracer  time step    rfact  = ', rfact, ' rdt = ', rdttra(1)
115      IF(lwp) write(numout,*) '    PISCES  Biology time step    rfact2 = ', rfact2
116
117
118
119      ! Set biological ratios
120      ! ---------------------
121      rno3    =  16._wp / 122._wp
122      po4r    =   1._wp / 122._wp
123      o2nit   =  32._wp / 122._wp
124      rdenit  = 105._wp /  16._wp
125      rdenita =   3._wp /  5._wp
126      o2ut    = 133._wp / 122._wp
127
128      ! Initialization of tracer concentration in case of  no restart
129      !--------------------------------------------------------------
130      IF( .NOT. ln_rsttr ) THEN 
131         
132         trn(:,:,:,jpdic) = sco2
133         trn(:,:,:,jpdoc) = bioma0
134         trn(:,:,:,jptal) = alka0
135         trn(:,:,:,jpoxy) = oxyg0
136         trn(:,:,:,jpcal) = bioma0
137         trn(:,:,:,jppo4) = po4 / po4r
138         trn(:,:,:,jppoc) = bioma0
139#  if ! defined key_kriest
140         trn(:,:,:,jpgoc) = bioma0
141         trn(:,:,:,jpbfe) = bioma0 * 5.e-6
142#  else
143         trn(:,:,:,jpnum) = bioma0 / ( 6. * xkr_massp )
144#  endif
145         trn(:,:,:,jpsil) = silic1
146         trn(:,:,:,jpdsi) = bioma0 * 0.15
147         trn(:,:,:,jpgsi) = bioma0 * 5.e-6
148         trn(:,:,:,jpphy) = bioma0
149         trn(:,:,:,jpdia) = bioma0
150         trn(:,:,:,jpzoo) = bioma0
151         trn(:,:,:,jpmes) = bioma0
152         trn(:,:,:,jpfer) = 0.6E-9
153         trn(:,:,:,jpsfe) = bioma0 * 5.e-6
154         trn(:,:,:,jpdfe) = bioma0 * 5.e-6
155         trn(:,:,:,jpnfe) = bioma0 * 5.e-6
156         trn(:,:,:,jpnch) = bioma0 * 12. / 55.
157         trn(:,:,:,jpdch) = bioma0 * 12. / 55.
158         trn(:,:,:,jpno3) = no3
159         trn(:,:,:,jpnh4) = bioma0
160
161         ! initialize the half saturation constant for silicate
162         ! ----------------------------------------------------
163         xksi(:,:)    = 2.e-6
164         xksimax(:,:) = xksi(:,:)
165      END IF
166
167      ! Time step duration for biology
168      xstep = rfact2 / rday
169
170      CALL p4z_sink_init      !  vertical flux of particulate organic matter
171      CALL p4z_opt_init       !  Optic: PAR in the water column
172      CALL p4z_lim_init       !  co-limitations by the various nutrients
173      CALL p4z_prod_init      !  phytoplankton growth rate over the global ocean.
174      CALL p4z_sbc_init       !  boundary conditions
175      CALL p4z_fechem_init    !  Iron chemistry
176      CALL p4z_rem_init       !  remineralisation
177      CALL p4z_mort_init      !  phytoplankton mortality
178      CALL p4z_micro_init     !  microzooplankton
179      CALL p4z_meso_init      !  mesozooplankton
180      CALL p4z_lys_init       !  calcite saturation
181      CALL p4z_flx_init       !  gas exchange
182
183      ndayflxtr = 0
184
185      IF(lwp) WRITE(numout,*) 
186      IF(lwp) WRITE(numout,*) 'Initialization of PISCES tracers done'
187      IF(lwp) WRITE(numout,*) 
188#endif
189      !
190   END SUBROUTINE p4z_ini
191
192   SUBROUTINE p2z_ini
193      !!----------------------------------------------------------------------
194      !!                   ***  ROUTINE p2z_ini ***
195      !!
196      !! ** Purpose :   Initialisation of the LOBSTER biochemical model
197      !!----------------------------------------------------------------------
198#if defined key_pisces_reduced 
199      !
200      USE p2zopt
201      USE p2zexp
202      USE p2zbio
203      USE p2zsed
204      !
205      INTEGER  ::  ji, jj, jk, ierr
206      !!----------------------------------------------------------------------
207
208      IF(lwp) WRITE(numout,*)
209      IF(lwp) WRITE(numout,*) ' p2z_ini :   LOBSTER biochemical model initialisation'
210      IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
211
212      ierr =        sms_pisces_alloc()         
213      ierr = ierr + p2z_exp_alloc()
214      !
215      IF( lk_mpp    )   CALL mpp_sum( ierr )
216      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'p2z_ini: unable to allocate LOBSTER arrays' )
217
218      ! LOBSTER initialisation for GYRE : init NO3=f(density) by asklod AS Kremeur 2005-07
219      ! ----------------------
220      IF( .NOT. ln_rsttr ) THEN             ! in case of  no restart
221         trn(:,:,:,jpdet) = 0.1 * tmask(:,:,:)
222         trn(:,:,:,jpzoo) = 0.1 * tmask(:,:,:)
223         trn(:,:,:,jpnh4) = 0.1 * tmask(:,:,:)
224         trn(:,:,:,jpphy) = 0.1 * tmask(:,:,:)
225         trn(:,:,:,jpdom) = 1.0 * tmask(:,:,:)
226         WHERE( rhd(:,:,:) <= 24.5e-3 )  ;  trn(:,:,:,jpno3 ) = 2._wp * tmask(:,:,:)
227         ELSE WHERE                      ;  trn(:,:,:,jpno3) = ( 15.55 * ( rhd(:,:,:) * 1000. ) - 380.11 ) * tmask(:,:,:)
228         END WHERE                       
229      ENDIF
230      !                       !  Namelist read
231      CALL p2z_opt_init       !  Optics parameters
232      CALL p2z_sed_init       !  sedimentation
233      CALL p2z_bio_init       !  biology
234      CALL p2z_exp_init       !  export
235      !
236      IF(lwp) WRITE(numout,*) 
237      IF(lwp) WRITE(numout,*) 'Initialization of LOBSTER tracers done'
238      IF(lwp) WRITE(numout,*) 
239#endif
240      !
241   END SUBROUTINE p2z_ini
242#else
243   !!----------------------------------------------------------------------
244   !!   Dummy module                            No PISCES biochemical model
245   !!----------------------------------------------------------------------
246CONTAINS
247   SUBROUTINE trc_ini_pisces             ! Empty routine
248   END SUBROUTINE trc_ini_pisces
249#endif
250
251   !!======================================================================
252END MODULE trcini_pisces
Note: See TracBrowser for help on using the repository browser.