New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/NERC/dev_r5518_GO6_CFC_CDIAC/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/NERC/dev_r5518_GO6_CFC_CDIAC/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 9419

Last change on this file since 9419 was 9419, checked in by jpalmier, 6 years ago

JPALM -- TOP last minute bug correction
File size: 15.1 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!             -   ! 2014-06 (A. Yool, J. Palmieri) adding MEDUSA-2
11   !!----------------------------------------------------------------------
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_init  :   Initialization for passive tracer
17   !!   top_alloc :   allocate the TOP arrays
18   !!----------------------------------------------------------------------
19   USE oce_trc         ! shared variables between ocean and passive tracers
20   USE trc             ! passive tracers common variables
21   USE trcrst          ! passive tracers restart
22   USE trcnam          ! Namelist read
23   USE trcini_cfc      ! CFC      initialisation
24   USE trcini_pisces   ! PISCES   initialisation
25   USE trcini_c14b     ! C14 bomb initialisation
26   USE trcini_age      ! AGE      initialisation
27   USE trcini_my_trc   ! MY_TRC   initialisation
28   USE trcini_idtra    ! idealize tracer initialisation
29   USE trcini_medusa   ! MEDUSA   initialisation
30   USE par_medusa      ! MEDUSA   parameters (needed for elemental cycles)
31   USE trcdta          ! initialisation from files
32   USE daymod          ! calendar manager
33   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
34   USE trcsub          ! variables to substep passive tracers
35   USE lib_mpp         ! distribued memory computing library
36   USE sbc_oce
37   USE trcice          ! tracers in sea ice
38# if defined key_medusa 
39   USE sms_medusa      ! MEDUSA   initialisation
40# endif
41   IMPLICIT NONE
42   PRIVATE
43   
44   PUBLIC   trc_init   ! called by opa
45
46    !! * Substitutions
47#  include "domzgr_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54   
55   SUBROUTINE trc_init
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE trc_init  ***
58      !!
59      !! ** Purpose :   Initialization of the passive tracer fields
60      !!
61      !! ** Method  : - read namelist
62      !!              - control the consistancy
63      !!              - compute specific initialisations
64      !!              - set initial tracer fields (either read restart
65      !!                or read data or analytical formulation
66      !!---------------------------------------------------------------------
67      INTEGER ::   ji, jj, jk, jn, jl    ! dummy loop indices
68# if defined key_medusa && defined key_roam
69      !! AXY (23/11/2017)
70      REAL(wp)                         :: zsum3d, zsum2d
71      REAL(wp)                         :: zq1, zq2, loc_vol, loc_area
72      REAL(wp), DIMENSION(6)           :: loc_cycletot3, loc_cycletot2
73      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztot3d
74      REAL(wp), DIMENSION(jpi,jpj)     :: ztot2d
75# endif
76      REAL(wp), DIMENSION(jpi,jpj)     :: carea
77      CHARACTER (len=25) :: charout
78      !!---------------------------------------------------------------------
79      !
80      IF( nn_timing == 1 )   CALL timing_start('trc_init')
81      !
82      IF(lwp) WRITE(numout,*)
83      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
84      IF(lwp) WRITE(numout,*) '~~~~~~~'
85
86      CALL top_alloc()              ! allocate TOP arrays
87
88      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
89      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
90      IF( l_trcdm2dc .AND. lwp ) &
91         &   CALL ctl_warn(' Coupling with passive tracers and used of diurnal cycle. &
92         & Computation of a daily mean shortwave for some biogeochemical models) ')
93
94      IF( nn_cla == 1 )   &
95         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
96
97      CALL trc_nam      ! read passive tracers namelists
98      !
99      IF(lwp) WRITE(numout,*)
100      !
101      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
102      !
103      IF(lwp) WRITE(numout,*)
104                                                              ! masked grid volume
105      !                                                              ! masked grid volume
106      DO jk = 1, jpk
107         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
108      END DO
109      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
110      !                                                              ! total volume of the ocean
111      areatot = glob_sum( cvol(:,:,:) )
112      carea(:,:) = e1e2t(:,:) * tmask(:,:,1) 
113
114      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
115      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
116      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
117      IF( lk_age     )       CALL trc_ini_age          ! AGE       tracer
118      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
119      IF( lk_idtra   )       CALL trc_ini_idtra        ! Idealize tracers
120      IF( lk_medusa  )       CALL trc_ini_medusa       ! MEDUSA  tracers
121
122      CALL trc_ice_ini                                 ! Tracers in sea ice
123
124      IF( ln_ctl ) THEN
125         !
126         IF (narea == 1) THEN 
127            ! The tracer.stat file only contains global tracer sum values, if
128            ! it contains anything at all. Hence it only needs to be opened
129            ! and written to on the master PE, not on all PEs. 
130            CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE','FORMATTED',  & 
131                          'SEQUENTIAL', -1, numout, lwp , narea ) 
132         ENDIF 
133         !
134      ENDIF
135
136      IF( ln_trcdta ) THEN
137         CALL trc_dta_init(jptra)
138      ENDIF
139
140      IF( ln_rsttr ) THEN
141        !
142        CALL trc_rst_read              ! restart from a file
143        !
144      ELSE
145        !
146        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
147            !
148            DO jn = 1, jptra
149               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
150                  jl = n_trc_index(jn) 
151                  CALL trc_dta( nit000, sf_trcdta(jl), rf_trfac(jl) )   ! read tracer data at nit000
152                  trn(:,:,:,jn) = sf_trcdta(jl)%fnow(:,:,:) 
153                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
154                     !                                                    (data used only for initialisation)
155                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
156                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
157                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
158                     !
159                  ENDIF
160               ENDIF
161            ENDDO
162            !
163        ENDIF
164        !
165        trb(:,:,:,:) = trn(:,:,:,:)
166        !
167      ENDIF
168 
169      tra(:,:,:,:) = 0._wp
170      !
171      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
172      !
173
174      trai(:) = 0._wp                                                   ! initial content of all tracers
175      DO jn = 1, jptra
176         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
177      END DO
178
179      IF(lwp) THEN               ! control print
180         WRITE(numout,*)
181         WRITE(numout,*)
182         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
183         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
184         WRITE(numout,*) '          *** Total inital content of all tracers '
185         WRITE(numout,*)
186# if defined key_debug_medusa
187         CALL flush(numout)
188# endif
189         !
190# if defined key_debug_medusa
191         WRITE(numout,*) ' litle check :  ', ctrcnm(1)
192         CALL flush(numout)
193# endif
194         DO jn = 1, jptra
195            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
196         ENDDO
197         WRITE(numout,*)
198      ENDIF
199      IF(lwp) WRITE(numout,*)
200      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
201         CALL prt_ctl_trc_init
202         WRITE(charout, FMT="('ini ')")
203         CALL prt_ctl_trc_info( charout )
204         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
205      ENDIF
206
207# if defined key_medusa && defined key_roam
208      ! AXY (17/11/2017): calculate initial totals of elemental cycles
209      !
210      ! This is done in a very hard-wired way here; in future, this could be
211      ! replaced with loops and using a 2D array; one dimension would cover
212      ! the tracers, the other would be for the elements; each tracer would
213      ! have a factor for each element to say how much of that element was
214      ! in that tracer; for example, PHN would be 1.0 for N, xrfn for Fe and
215      ! xthetapn for C, with the other elements 0.0; the array entry for PHN
216      ! would then be (1. 0. xrfn xthetapn 0. 0.) for (N, Si, Fe, C, A, O2);
217      ! saving this for the next iteration
218      !
219      cycletot(:) = 0._wp
220      ! report elemental totals at initialisation as we go along
221      IF ( lwp ) WRITE(numout,*)
222      IF ( lwp ) WRITE(numout,*)    ' Elemental cycle totals: '
223      ! nitrogen
224      ztot3d(:,:,:) = trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
225                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet) + trn(:,:,:,jpdin)
226      ztot2d(:,:)   = zn_sed_n(:,:)
227      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
228      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
229      cycletot(1)   = zsum3d + zsum2d
230      IF ( lwp ) WRITE(numout,9010) 'nitrogen', zsum3d, zsum2d, cycletot(1)
231      ! silicon
232      ztot3d(:,:,:) = trn(:,:,:,jppds) + trn(:,:,:,jpsil)
233      ztot2d(:,:)   = zn_sed_si(:,:)
234      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
235      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
236      cycletot(2)   = zsum3d + zsum2d
237      IF ( lwp ) WRITE(numout,9010) 'silicon', zsum3d, zsum2d, cycletot(2)
238      ! iron
239      ztot3d(:,:,:) = ((trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
240                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet)) * xrfn) + trn(:,:,:,jpfer)
241      ztot2d(:,:)   = zn_sed_fe(:,:)
242      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
243      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
244      cycletot(3)   = zsum3d + zsum2d
245      IF ( lwp ) WRITE(numout,9010) 'iron', zsum3d, zsum2d, cycletot(3)
246      ! carbon (uses fixed C:N ratios on plankton tracers)
247      ztot3d(:,:,:) = (trn(:,:,:,jpphn) * xthetapn)  + (trn(:,:,:,jpphd) * xthetapd)  +  &
248                      (trn(:,:,:,jpzmi) * xthetazmi) + (trn(:,:,:,jpzme) * xthetazme) +  &
249                      trn(:,:,:,jpdtc) + trn(:,:,:,jpdic)
250      ztot2d(:,:)   = zn_sed_c(:,:) + zn_sed_ca(:,:)
251      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
252      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
253      cycletot(4)   = zsum3d + zsum2d
254      IF ( lwp ) WRITE(numout,9010) 'carbon', zsum3d, zsum2d, cycletot(4)
255      ! alkalinity (note benthic correction)
256      ztot3d(:,:,:) = trn(:,:,:,jpalk)
257      ztot2d(:,:)   = zn_sed_ca(:,:) * 2._wp
258      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
259      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
260      cycletot(5)   = zsum3d + zsum2d
261      IF ( lwp ) WRITE(numout,9010) 'alkalinity', zsum3d, zsum2d, cycletot(5)
262      ! oxygen (note no benthic)
263      ztot3d(:,:,:) = trn(:,:,:,jpoxy)
264      ztot2d(:,:)   = 0._wp
265      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
266      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
267      cycletot(6)   = zsum3d + zsum2d
268      IF ( lwp ) WRITE(numout,9010) 'oxygen', zsum3d, zsum2d, cycletot(6)
269      ! Check
270      zsum3d        = glob_sum( cvol(:,:,:) )
271      zsum2d        = glob_sum( carea(:,:) )     
272      IF ( lwp ) THEN
273         WRITE(numout,*)
274         WRITE(numout,*) ' check : cvol    : ', zsum3d
275         WRITE(numout,*) ' check : carea   : ', zsum2d
276         WRITE(numout,*)
277      ENDIF
278      !
279# endif
280
281      IF(lwp) THEN
282          WRITE(numout,*)
283          WRITE(numout,*) 'trc_init : passive tracer set up completed'
284          WRITE(numout,*) '~~~~~~~'
285      ENDIF 
286# if defined key_debug_medusa
287         CALL trc_rst_stat
288         CALL flush(numout)
289# endif
290
2919000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
2929010  FORMAT(' element:',a10,                     &
293             ' 3d sum:',e18.10,' 2d sum:',e18.10, &
294             ' total:',e18.10)
295      !
296      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
297      !
298   END SUBROUTINE trc_init
299
300
301   SUBROUTINE top_alloc
302      !!----------------------------------------------------------------------
303      !!                     ***  ROUTINE top_alloc  ***
304      !!
305      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
306      !!----------------------------------------------------------------------
307      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
308      USE trc           , ONLY:   trc_alloc
309      USE trcnxt        , ONLY:   trc_nxt_alloc
310      USE trczdf        , ONLY:   trc_zdf_alloc
311      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
312#if defined key_trdmxl_trc 
313      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
314#endif
315# if defined key_medusa
316      USE bio_medusa_mod, ONLY:   bio_medusa_alloc
317# endif
318
319      !
320      INTEGER :: ierr
321      !!----------------------------------------------------------------------
322      !
323      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
324      ierr = ierr + trc_alloc    ()
325      ierr = ierr + trc_nxt_alloc()
326      ierr = ierr + trc_zdf_alloc()
327      ierr = ierr + trd_trc_oce_alloc()
328#if defined key_trdmxl_trc 
329      ierr = ierr + trd_mxl_trc_alloc()
330#endif
331#if defined key_medusa
332      ierr = ierr + bio_medusa_alloc()
333#endif
334      !
335      IF( lk_mpp    )   CALL mpp_sum( ierr )
336      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
337      !
338   END SUBROUTINE top_alloc
339
340#else
341   !!----------------------------------------------------------------------
342   !!  Empty module :                                     No passive tracer
343   !!----------------------------------------------------------------------
344CONTAINS
345   SUBROUTINE trc_init                      ! Dummy routine   
346   END SUBROUTINE trc_init
347#endif
348
349   !!======================================================================
350END MODULE trcini
Note: See TracBrowser for help on using the repository browser.