New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssr.F90 in branches/NERC/dev_r5518_GO6_under_ice_relax/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/NERC/dev_r5518_GO6_under_ice_relax/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssr.F90 @ 9634

Last change on this file since 9634 was 9634, checked in by jpalmier, 6 years ago

pass the SSS under ice relaxation term through the namelist
File size: 13.5 KB
Line 
1MODULE sbcssr
2   !!======================================================================
3   !!                       ***  MODULE  sbcssr  ***
4   !! Surface module :  heat and fresh water fluxes a restoring term toward observed SST/SSS
5   !!======================================================================
6   !! History :  3.0  !  2006-06  (G. Madec)  Original code
7   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssr       : add to sbc a restoring term toward SST/SSS climatology
12   !!   sbc_ssr_init  : initialisation of surface restoring
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE sbc_oce        ! surface boundary condition
17   USE phycst         ! physical constants
18   USE sbcrnf         ! surface boundary condition : runoffs
19   !
20   USE fldread        ! read input fields
21   USE iom            ! I/O manager
22   USE in_out_manager ! I/O manager
23   USE lib_mpp        ! distribued memory computing library
24   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
25   USE timing         ! Timing
26   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   sbc_ssr        ! routine called in sbcmod
32   PUBLIC   sbc_ssr_init   ! routine called in sbcmod
33
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   erp   !: evaporation damping   [kg/m2/s]
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   qrp   !: heat flux damping        [w/m2]
36
37   !                                   !!* Namelist namsbc_ssr *
38   INTEGER, PUBLIC ::   nn_sstr         ! SST/SSS restoring indicator
39   INTEGER, PUBLIC ::   nn_sssr         ! SST/SSS restoring indicator
40   REAL(wp)        ::   rn_dqdt         ! restoring factor on SST and SSS
41   REAL(wp)        ::   rn_deds         ! restoring factor on SST and SSS on Ice-free ocean
42   REAL(wp)        ::   rn_deds_ice     ! restoring factor on SST and SSS under sea-ice
43   LOGICAL         ::   ln_sssr_bnd     ! flag to bound erp term
44   REAL(wp)        ::   rn_sssr_bnd     ! ABS(Max./Min.) value of erp term [mm/day]
45
46   REAL(wp) , ALLOCATABLE, DIMENSION(:) ::   buffer   ! Temporary buffer for exchange
47   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sst   ! structure of input SST (file informations, fields read)
48   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sss   ! structure of input SSS (file informations, fields read)
49
50   !! * Substitutions
51#  include "domzgr_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
54   !! $Id$
55   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE sbc_ssr( kt )
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE sbc_ssr  ***
62      !!
63      !! ** Purpose :   Add to heat and/or freshwater fluxes a damping term
64      !!                toward observed SST and/or SSS.
65      !!
66      !! ** Method  : - Read namelist namsbc_ssr
67      !!              - Read observed SST and/or SSS
68      !!              - at each nscb time step
69      !!                   add a retroaction term on qns    (nn_sstr = 1)
70      !!                   add a damping term on sfx        (nn_sssr = 1)
71      !!                   add a damping term on emp        (nn_sssr = 2)
72      !!---------------------------------------------------------------------
73      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
74      !!
75      INTEGER  ::   ji, jj   ! dummy loop indices
76      REAL(wp) ::   zerp     ! local scalar for evaporation damping
77      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
78      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
79      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
80      !! AXY (16-04-2018) scaling under-sea-ice relaxation
81      REAL(wp) ::   zice     ! local scalar to permit differential under sea-ice relaxation
82      REAL(wp) ::   zsrp_ice     !  local scalar for unit conversion of rn_deds factor - under ice
83      INTEGER  ::   ierror   ! return error code
84      !!
85      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
86      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('sbc_ssr')
90      !
91      IF( nn_sstr + nn_sssr /= 0 ) THEN
92         !
93         IF( nn_sstr == 1)   CALL fld_read( kt, nn_fsbc, sf_sst )   ! Read SST data and provides it at kt
94         IF( nn_sssr >= 1)   CALL fld_read( kt, nn_fsbc, sf_sss )   ! Read SSS data and provides it at kt
95         !
96         !                                         ! ========================= !
97         IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN      !    Add restoring term     !
98            !                                      ! ========================= !
99            !
100            IF( nn_sstr == 1 ) THEN                                   !* Temperature restoring term
101               DO jj = 1, jpj
102                  DO ji = 1, jpi
103                     zqrp = rn_dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj,1) )
104                     qns(ji,jj) = qns(ji,jj) + zqrp
105                     qrp(ji,jj) = zqrp
106                  END DO
107               END DO
108               CALL iom_put( "qrp", qrp )                             ! heat flux damping
109            ENDIF
110            !
111            IF( nn_sssr == 1 ) THEN                                   !* Salinity damping term (salt flux only (sfx))
112               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
113               zsrp_ice = rn_deds_ice / rday                                  ! from [mm/day] to [kg/m2/s]
114!CDIR COLLAPSE
115               DO jj = 1, jpj
116                  DO ji = 1, jpi
117                     !! AXY (16-04-2018) Calculate ice-scaled zsrp term - from
118                     !!      rn_deds (ice-free) to rn_deds_ice (100% ice)
119                     zice = ((1. - fr_i(ji,jj)) * zsrp) +        &
120                        &   (fr_i(ji,jj) * zsrp_ice)
121                     zerp = zice * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
122                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) ) 
123                     sfx(ji,jj) = sfx(ji,jj) + zerp                 ! salt flux
124                     erp(ji,jj) = zerp / MAX( sss_m(ji,jj), 1.e-20 ) ! converted into an equivalent volume flux (diagnostic only)
125                  END DO
126               END DO
127               CALL iom_put( "erp", erp )                             ! freshwater flux damping
128               !
129            ELSEIF( nn_sssr == 2 ) THEN                               !* Salinity damping term (volume flux (emp) and associated heat flux (qns)
130               zsrp = rn_deds / rday                                  ! from [mm/day] to [kg/m2/s]
131               zsrp_ice = rn_deds_ice / rday                          ! from [mm/day] to [kg/m2/s]
132               zerp_bnd = rn_sssr_bnd / rday                          !       -              -   
133!CDIR COLLAPSE
134               DO jj = 1, jpj
135                  DO ji = 1, jpi                           
136                     !! AXY (16-04-2018) Calculate ice-scaled zsrp term - from
137                     !!      rn_deds (ice-free) to rn_deds_ice (100% ice)
138                     zice = ((1. - fr_i(ji,jj)) * zsrp) +        &
139                        &   (fr_i(ji,jj) * zsrp_ice)
140                     zerp = zice * ( 1. - 2.*rnfmsk(ji,jj) )   &      ! No damping in vicinity of river mouths
141                        &        * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj,1) )   &
142                        &        / MAX(  sss_m(ji,jj), 1.e-20   )
143                     IF( ln_sssr_bnd )   zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) )
144                     emp(ji,jj) = emp (ji,jj) + zerp
145                     qns(ji,jj) = qns(ji,jj) - zerp * rcp * sst_m(ji,jj)
146                     erp(ji,jj) = zerp
147                  END DO
148               END DO
149               CALL iom_put( "erp", erp )                             ! freshwater flux damping
150            ENDIF
151            !
152         ENDIF
153         !
154      ENDIF
155      !
156      IF( nn_timing == 1 )  CALL timing_stop('sbc_ssr')
157      !
158   END SUBROUTINE sbc_ssr
159
160 
161   SUBROUTINE sbc_ssr_init
162      !!---------------------------------------------------------------------
163      !!                  ***  ROUTINE sbc_ssr_init  ***
164      !!
165      !! ** Purpose :   initialisation of surface damping term
166      !!
167      !! ** Method  : - Read namelist namsbc_ssr
168      !!              - Read observed SST and/or SSS if required
169      !!---------------------------------------------------------------------
170      INTEGER  ::   ji, jj   ! dummy loop indices
171      REAL(wp) ::   zerp     ! local scalar for evaporation damping
172      REAL(wp) ::   zqrp     ! local scalar for heat flux damping
173      REAL(wp) ::   zsrp     ! local scalar for unit conversion of rn_deds factor
174      REAL(wp) ::   zerp_bnd ! local scalar for unit conversion of rn_epr_max factor
175      INTEGER  ::   ierror   ! return error code
176      !!
177      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
178      TYPE(FLD_N) ::   sn_sst, sn_sss        ! informations about the fields to be read
179      NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, rn_deds_ice, sn_sst, sn_sss, ln_sssr_bnd, rn_sssr_bnd
180      INTEGER     ::  ios
181      !!----------------------------------------------------------------------
182      !
183 
184      REWIND( numnam_ref )              ! Namelist namsbc_ssr in reference namelist :
185      READ  ( numnam_ref, namsbc_ssr, IOSTAT = ios, ERR = 901)
186901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in reference namelist', lwp )
187
188      REWIND( numnam_cfg )              ! Namelist namsbc_ssr in configuration namelist :
189      READ  ( numnam_cfg, namsbc_ssr, IOSTAT = ios, ERR = 902 )
190902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ssr in configuration namelist', lwp )
191      IF(lwm) WRITE ( numond, namsbc_ssr )
192
193      IF(lwp) THEN                 !* control print
194         WRITE(numout,*)
195         WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term '
196         WRITE(numout,*) '~~~~~~~ '
197         WRITE(numout,*) '   Namelist namsbc_ssr :'
198         WRITE(numout,*) '      SST restoring term (Yes=1)                    nn_sstr     = ', nn_sstr
199         WRITE(numout,*) '      SSS damping term (Yes=1, salt flux)           nn_sssr     = ', nn_sssr
200         WRITE(numout,*) '                       (Yes=2, volume flux) '
201         WRITE(numout,*) '      dQ/dT (restoring magnitude on SST)            rn_dqdt     = ', rn_dqdt, ' W/m2/K'
202         WRITE(numout,*) '      dE/dS (restoring magnitude on ice-free SSS)   rn_deds     = ', rn_deds, ' mm/day'
203         WRITE(numout,*) '      dE/dS (restoring magnitude under sea-ice SSS) rn_deds_ice = ', rn_deds_ice, ' mm/day'
204         WRITE(numout,*) '      flag to bound erp term                        ln_sssr_bnd = ', ln_sssr_bnd
205         WRITE(numout,*) '      ABS(Max./Min.) erp threshold                  rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day'
206      ENDIF
207      !
208      !                            !* Allocate erp and qrp array
209      ALLOCATE( qrp(jpi,jpj), erp(jpi,jpj), STAT=ierror )
210      IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate erp and qrp array' )
211      !
212      IF( nn_sstr == 1 ) THEN      !* set sf_sst structure & allocate arrays
213         !
214         ALLOCATE( sf_sst(1), STAT=ierror )
215         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst structure' )
216         ALLOCATE( sf_sst(1)%fnow(jpi,jpj,1), STAT=ierror )
217         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst now array' )
218         !
219         ! fill sf_sst with sn_sst and control print
220         CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr' )
221         IF( sf_sst(1)%ln_tint )   ALLOCATE( sf_sst(1)%fdta(jpi,jpj,1,2), STAT=ierror )
222         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sst data array' )
223         !
224      ENDIF
225      !
226      IF( nn_sssr >= 1 ) THEN      !* set sf_sss structure & allocate arrays
227         !
228         ALLOCATE( sf_sss(1), STAT=ierror )
229         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss structure' )
230         ALLOCATE( sf_sss(1)%fnow(jpi,jpj,1), STAT=ierror )
231         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss now array' )
232         !
233         ! fill sf_sss with sn_sss and control print
234         CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr' )
235         IF( sf_sss(1)%ln_tint )   ALLOCATE( sf_sss(1)%fdta(jpi,jpj,1,2), STAT=ierror )
236         IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_ssr: unable to allocate sf_sss data array' )
237         !
238      ENDIF
239      !
240      !                            !* Initialize qrp and erp if no restoring
241      IF( nn_sstr /= 1                   )   qrp(:,:) = 0._wp
242      IF( nn_sssr /= 1 .OR. nn_sssr /= 2 )   erp(:,:) = 0._wp
243      !
244   END SUBROUTINE sbc_ssr_init
245     
246   !!======================================================================
247END MODULE sbcssr
Note: See TracBrowser for help on using the repository browser.