New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diahsb.F90 in branches/NERC/dev_r5589_is_oce_cpl/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/NERC/dev_r5589_is_oce_cpl/NEMOGCM/NEMO/OPA_SRC/DIA/diahsb.F90 @ 5964

Last change on this file since 5964 was 5964, checked in by mathiot, 8 years ago

ice sheet cpl: modifications to compile and run SETTE test

  • Property svn:keywords set to Id
File size: 20.7 KB
Line 
1MODULE diahsb
2   !!======================================================================
3   !!                       ***  MODULE  diahsb  ***
4   !! Ocean diagnostics: Heat, salt and volume budgets
5   !!======================================================================
6   !! History :  3.3  ! 2010-09  (M. Leclair)  Original code
7   !!                 ! 2012-10  (C. Rousset)  add iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dia_hsb       : Diagnose the conservation of ocean heat and salt contents, and volume
12   !!   dia_hsb_rst   : Read or write DIA file in restart file
13   !!   dia_hsb_init  : Initialization of the conservation diagnostic
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE phycst          ! physical constants
18   USE sbc_oce         ! surface thermohaline fluxes
19   USE sbcrnf          ! river runoff
20   USE sbcisf          ! ice shelves
21   USE domvvl          ! vertical scale factors
22   USE traqsr          ! penetrative solar radiation
23   USE trabbc          ! bottom boundary condition
24   USE trabbc          ! bottom boundary condition
25   USE bdy_par         ! (for lk_bdy)
26   USE restart         ! ocean restart
27   !
28   USE iom             ! I/O manager
29   USE in_out_manager  ! I/O manager
30   USE lib_fortran     ! glob_sum
31   USE lib_mpp         ! distributed memory computing library
32   USE timing          ! preformance summary
33   USE wrk_nemo        ! work arrays
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   dia_hsb        ! routine called by step.F90
39   PUBLIC   dia_hsb_init   ! routine called by nemogcm.F90
40   PUBLIC   dia_hsb_rst    ! routine called by step.F90
41
42   LOGICAL, PUBLIC ::   ln_diahsb   !: check the heat and salt budgets
43
44   REAL(wp) ::   surf_tot              ! ocean surface
45   REAL(wp) ::   frc_t, frc_s, frc_v   ! global forcing trends
46   REAL(wp) ::   frc_wn_t, frc_wn_s    ! global forcing trends
47   !
48   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   surf 
49   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   surf_ini      , ssh_ini          !
50   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   ssh_hc_loc_ini, ssh_sc_loc_ini   !
51   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   hc_loc_ini, sc_loc_ini, e3t_ini  !
52
53   !! * Substitutions
54#  include "domzgr_substitute.h90"
55#  include "vectopt_loop_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
58   !! $Id$
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE dia_hsb( kt )
64      !!---------------------------------------------------------------------------
65      !!                  ***  ROUTINE dia_hsb  ***
66      !!     
67      !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation
68      !!
69      !! ** Method : - Compute the deviation of heat content, salt content and volume
70      !!             at the current time step from their values at nit000
71      !!             - Compute the contribution of forcing and remove it from these deviations
72      !!
73      !!---------------------------------------------------------------------------
74      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
75      !
76      INTEGER    ::   ji, jj, jk                  ! dummy loop indice
77      REAL(wp)   ::   zdiff_hc    , zdiff_sc      ! heat and salt content variations
78      REAL(wp)   ::   zdiff_hc1   , zdiff_sc1     !  -         -     -        -
79      REAL(wp)   ::   zdiff_v1    , zdiff_v2      ! volume variation
80      REAL(wp)   ::   zerr_hc1    , zerr_sc1      ! heat and salt content misfit
81      REAL(wp)   ::   zvol_tot                    ! volume
82      REAL(wp)   ::   z_frc_trd_t , z_frc_trd_s   !    -     -
83      REAL(wp)   ::   z_frc_trd_v                 !    -     -
84      REAL(wp)   ::   z_wn_trd_t , z_wn_trd_s     !    -     -
85      REAL(wp)   ::   z_ssh_hc , z_ssh_sc         !    -     -
86      REAL(wp), DIMENSION(:,:), POINTER ::   z2d0, z2d1
87      !!---------------------------------------------------------------------------
88      IF( nn_timing == 1 )   CALL timing_start('dia_hsb')     
89      CALL wrk_alloc( jpi,jpj,   z2d0, z2d1 )
90      !
91      tsn(:,:,:,1) = tsn(:,:,:,1) * tmask(:,:,:) ; tsb(:,:,:,1) = tsb(:,:,:,1) * tmask(:,:,:) ;
92      tsn(:,:,:,2) = tsn(:,:,:,2) * tmask(:,:,:) ; tsb(:,:,:,2) = tsb(:,:,:,2) * tmask(:,:,:) ;
93      ! ------------------------- !
94      ! 1 - Trends due to forcing !
95      ! ------------------------- !
96      z_frc_trd_v = r1_rau0 * glob_sum( - ( emp(:,:) - rnf(:,:) + fwfisf(:,:) ) * surf(:,:) ) ! volume fluxes
97      z_frc_trd_t =           glob_sum( sbc_tsc(:,:,jp_tem) * surf(:,:) )                               ! heat fluxes
98      z_frc_trd_s =           glob_sum( sbc_tsc(:,:,jp_sal) * surf(:,:) )                               ! salt fluxes
99      ! Add runoff    heat & salt input
100      IF( ln_rnf    )   z_frc_trd_t = z_frc_trd_t + glob_sum( rnf_tsc(:,:,jp_tem) * surf(:,:) )
101      IF( ln_rnf_sal)   z_frc_trd_s = z_frc_trd_s + glob_sum( rnf_tsc(:,:,jp_sal) * surf(:,:) )
102      ! Add ice shelf heat & salt input
103      IF( nn_isf .GE. 1 )  THEN
104          z_frc_trd_t = z_frc_trd_t + glob_sum( risf_tsc(:,:,jp_tem) * surf(:,:) )
105          z_frc_trd_s = z_frc_trd_s + glob_sum( risf_tsc(:,:,jp_sal) * surf(:,:) )
106      ENDIF
107
108      ! Add penetrative solar radiation
109      IF( ln_traqsr )   z_frc_trd_t = z_frc_trd_t + r1_rau0_rcp * glob_sum( qsr     (:,:) * surf(:,:) )
110      ! Add geothermal heat flux
111      IF( ln_trabbc )   z_frc_trd_t = z_frc_trd_t +               glob_sum( qgh_trd0(:,:) * surf(:,:) )
112      !
113      IF( .NOT. lk_vvl ) THEN
114         IF ( ln_isfcav ) THEN
115            DO ji=1,jpi
116               DO jj=1,jpj
117                  z2d0(ji,jj) = surf(ji,jj) * wn(ji,jj,mikt(ji,jj)) * tsb(ji,jj,mikt(ji,jj),jp_tem)
118                  z2d1(ji,jj) = surf(ji,jj) * wn(ji,jj,mikt(ji,jj)) * tsb(ji,jj,mikt(ji,jj),jp_sal)
119               ENDDO
120            ENDDO
121         ELSE
122            z2d0(:,:) = surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_tem)
123            z2d1(:,:) = surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_sal)
124         END IF
125         z_wn_trd_t = - glob_sum( z2d0 ) 
126         z_wn_trd_s = - glob_sum( z2d1 )
127      ENDIF
128
129      frc_v = frc_v + z_frc_trd_v * rdt
130      frc_t = frc_t + z_frc_trd_t * rdt
131      frc_s = frc_s + z_frc_trd_s * rdt
132      !                                          ! Advection flux through fixed surface (z=0)
133      IF( .NOT. lk_vvl ) THEN
134         frc_wn_t = frc_wn_t + z_wn_trd_t * rdt
135         frc_wn_s = frc_wn_s + z_wn_trd_s * rdt
136      ENDIF
137
138      ! ------------------------ !
139      ! 2 -  Content variations !
140      ! ------------------------ !
141      ! glob_sum_full is needed because you keep the full interior domain to compute the sum (iscpl)
142      zdiff_v2 = 0._wp
143      zdiff_hc = 0._wp
144      zdiff_sc = 0._wp
145
146      ! volume variation (calculated with ssh)
147      zdiff_v1 = glob_sum_full( surf(:,:) * sshn(:,:) - surf_ini(:,:) * ssh_ini(:,:) )
148
149      ! heat & salt content variation (associated with ssh)
150      IF( .NOT. lk_vvl ) THEN
151         IF ( ln_isfcav ) THEN
152            DO ji = 1, jpi
153               DO jj = 1, jpj
154                  z2d0(ji,jj) = surf(ji,jj) * ( tsn(ji,jj,mikt(ji,jj),jp_tem) * sshn(ji,jj) - ssh_hc_loc_ini(ji,jj) ) 
155                  z2d1(ji,jj) = surf(ji,jj) * ( tsn(ji,jj,mikt(ji,jj),jp_sal) * sshn(ji,jj) - ssh_sc_loc_ini(ji,jj) ) 
156               END DO
157            END DO
158         ELSE
159            z2d0(:,:) = surf(:,:) * ( tsn(:,:,1,jp_tem) * sshn(:,:) - ssh_hc_loc_ini(:,:) ) 
160            z2d1(:,:) = surf(:,:) * ( tsn(:,:,1,jp_sal) * sshn(:,:) - ssh_sc_loc_ini(:,:) ) 
161         END IF
162         z_ssh_hc = glob_sum_full( z2d0 ) 
163         z_ssh_sc = glob_sum_full( z2d1 ) 
164      ENDIF
165
166      DO jk = 1, jpkm1
167         ! volume variation (calculated with scale factors)
168         zdiff_v2 = zdiff_v2 + glob_sum_full( surf    (:,:) * fse3t_n  (:,:,jk) * tmask(:,:,jk) &
169              &                             - surf_ini(:,:) *   e3t_ini(:,:,jk) )
170         ! heat content variation
171         zdiff_hc = zdiff_hc + glob_sum_full( surf    (:,:) * tmask(:,:,jk) * fse3t_n(:,:,jk) * tsn(:,:,jk,jp_tem) &
172              &                             - surf_ini(:,:) * hc_loc_ini(:,:,jk) )
173         ! salt content variation
174         zdiff_sc = zdiff_sc + glob_sum_full( surf    (:,:) * tmask(:,:,jk) * fse3t_n(:,:,jk) * tsn(:,:,jk,jp_sal) & 
175              &                             - surf_ini(:,:) * sc_loc_ini(:,:,jk) )
176      ENDDO
177
178      ! Substract forcing from heat content, salt content and volume variations
179      zdiff_v1 = zdiff_v1 - frc_v
180      IF( lk_vvl )   zdiff_v2 = zdiff_v2 - frc_v
181      zdiff_hc = zdiff_hc - frc_t
182      zdiff_sc = zdiff_sc - frc_s
183      IF( .NOT. lk_vvl ) THEN
184         zdiff_hc1 = zdiff_hc + z_ssh_hc 
185         zdiff_sc1 = zdiff_sc + z_ssh_sc
186         zerr_hc1  = z_ssh_hc - frc_wn_t
187         zerr_sc1  = z_ssh_sc - frc_wn_s
188      ENDIF
189
190      ! ----------------------- !
191      ! 3 - Diagnostics writing !
192      ! ----------------------- !
193      zvol_tot = 0._wp                    ! total ocean volume (calculated with scale factors)
194      DO jk = 1, jpkm1
195         zvol_tot  = zvol_tot + glob_sum_full( surf(:,:) * tmask(:,:,jk) * fse3t_n(:,:,jk) )
196      END DO
197
198!!gm to be added ?
199!      IF( .NOT. lk_vvl ) THEN            ! fixed volume, add the ssh contribution
200!        zvol_tot = zvol_tot + glob_sum( surf(:,:) * sshn(:,:) )
201!      ENDIF
202!!gm end
203
204      IF( lk_vvl ) THEN
205        CALL iom_put( 'bgtemper' , zdiff_hc / zvol_tot )              ! Temperature variation (C)
206        CALL iom_put( 'bgsaline' , zdiff_sc / zvol_tot )              ! Salinity    variation (psu)
207        CALL iom_put( 'bgheatco' , zdiff_hc * 1.e-20 * rau0 * rcp )   ! Heat content variation (1.e20 J)
208        CALL iom_put( 'bgsaltco' , zdiff_sc * 1.e-9    )              ! Salt content variation (psu*km3)
209        CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9    )              ! volume ssh variation (km3) 
210        CALL iom_put( 'bgvole3t' , zdiff_v2 * 1.e-9    )              ! volume e3t variation (km3) 
211        CALL iom_put( 'bgfrcvol' , frc_v    * 1.e-9    )              ! vol - surface forcing (km3)
212        CALL iom_put( 'bgfrctem' , frc_t / zvol_tot    )              ! hc  - surface forcing (C)
213        CALL iom_put( 'bgfrcsal' , frc_s / zvol_tot    )              ! sc  - surface forcing (psu)
214      ELSE
215        CALL iom_put( 'bgtemper' , zdiff_hc1 / zvol_tot)              ! Heat content variation (C)
216        CALL iom_put( 'bgsaline' , zdiff_sc1 / zvol_tot)              ! Salt content variation (psu)
217        CALL iom_put( 'bgheatco' , zdiff_hc1 * 1.e-20 * rau0 * rcp )  ! Heat content variation (1.e20 J)
218        CALL iom_put( 'bgsaltco' , zdiff_sc1 * 1.e-9   )              ! Salt content variation (psu*km3)
219        CALL iom_put( 'bgvolssh' , zdiff_v1  * 1.e-9   )              ! volume ssh variation (km3) 
220        CALL iom_put( 'bgfrcvol' , frc_v    * 1.e-9    )              ! vol - surface forcing (km3)
221        CALL iom_put( 'bgfrctem' , frc_t / zvol_tot    )              ! hc  - surface forcing (C)
222        CALL iom_put( 'bgfrcsal' , frc_s / zvol_tot    )              ! sc  - surface forcing (psu)
223        CALL iom_put( 'bgmistem' , zerr_hc1 / zvol_tot )              ! hc  - error due to free surface (C)
224        CALL iom_put( 'bgmissal' , zerr_sc1 / zvol_tot )              ! sc  - error due to free surface (psu)
225      ENDIF
226      !
227      IF( lrst_oce )   CALL dia_hsb_rst( kt, 'WRITE' )
228
229      CALL wrk_dealloc( jpi,jpj,   z2d0, z2d1 )
230
231      IF( nn_timing == 1 )   CALL timing_stop('dia_hsb')
232      !
233   END SUBROUTINE dia_hsb
234
235
236   SUBROUTINE dia_hsb_rst( kt, cdrw )
237     !!---------------------------------------------------------------------
238     !!                   ***  ROUTINE limdia_rst  ***
239     !!                     
240     !! ** Purpose :   Read or write DIA file in restart file
241     !!
242     !! ** Method  :   use of IOM library
243     !!----------------------------------------------------------------------
244     INTEGER         , INTENT(in) ::   kt     ! ocean time-step
245     CHARACTER(len=*), INTENT(in) ::   cdrw   ! "READ"/"WRITE" flag
246     !
247     INTEGER ::   ji, jj, jk   ! dummy loop indices
248     INTEGER ::   id1          ! local integers
249     !!----------------------------------------------------------------------
250     !
251     IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
252        IF( ln_rstart ) THEN                   !* Read the restart file
253           !id1 = iom_varid( numror, 'frc_vol'  , ldstop = .FALSE. )
254           !
255           IF(lwp) WRITE(numout,*) '~~~~~~~'
256           IF(lwp) WRITE(numout,*) ' dia_hsb_rst at it= ', kt,' date= ', ndastp
257           IF(lwp) WRITE(numout,*) '~~~~~~~'
258           CALL iom_get( numror, 'frc_v', frc_v )
259           CALL iom_get( numror, 'frc_t', frc_t )
260           CALL iom_get( numror, 'frc_s', frc_s )
261           IF( .NOT. lk_vvl ) THEN
262              CALL iom_get( numror, 'frc_wn_t', frc_wn_t )
263              CALL iom_get( numror, 'frc_wn_s', frc_wn_s )
264           ENDIF
265           CALL iom_get( numror, jpdom_autoglo, 'surf_ini', surf_ini ) ! ice sheet coupling
266           CALL iom_get( numror, jpdom_autoglo, 'ssh_ini', ssh_ini )
267           CALL iom_get( numror, jpdom_autoglo, 'e3t_ini', e3t_ini )
268           CALL iom_get( numror, jpdom_autoglo, 'hc_loc_ini', hc_loc_ini )
269           CALL iom_get( numror, jpdom_autoglo, 'sc_loc_ini', sc_loc_ini )
270           IF( .NOT. lk_vvl ) THEN
271              CALL iom_get( numror, jpdom_autoglo, 'ssh_hc_loc_ini', ssh_hc_loc_ini )
272              CALL iom_get( numror, jpdom_autoglo, 'ssh_sc_loc_ini', ssh_sc_loc_ini )
273           ENDIF
274       ELSE
275          IF(lwp) WRITE(numout,*) '~~~~~~~'
276          IF(lwp) WRITE(numout,*) ' dia_hsb at initial state '
277          IF(lwp) WRITE(numout,*) '~~~~~~~'
278          surf_ini(:,:) = e1e2t(:,:) * tmask_i(:,:)         ! initial ocean surface
279          ssh_ini(:,:) = sshn(:,:)                          ! initial ssh
280          DO jk = 1, jpk
281             ! if ice sheet/oceqn coupling, need to mask ini variables here (mask could change at the next NEMO instance).
282             e3t_ini   (:,:,jk) = fse3t_n(:,:,jk)    * tmask(:,:,jk)                    ! initial vertical scale factors
283             hc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_tem) * fse3t_n(:,:,jk) * tmask(:,:,jk)  ! initial heat content
284             sc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_sal) * fse3t_n(:,:,jk) * tmask(:,:,jk)  ! initial salt content
285          END DO
286          frc_v = 0._wp                                           ! volume       trend due to forcing
287          frc_t = 0._wp                                           ! heat content   -    -   -    -   
288          frc_s = 0._wp                                           ! salt content   -    -   -    -       
289          IF( .NOT. lk_vvl ) THEN
290             IF ( ln_isfcav ) THEN
291                DO ji=1,jpi
292                   DO jj=1,jpj
293                      ssh_hc_loc_ini(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_tem) * sshn(ji,jj)   ! initial heat content in ssh
294                      ssh_sc_loc_ini(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_sal) * sshn(ji,jj)   ! initial salt content in ssh
295                   ENDDO
296                ENDDO
297             ELSE
298                ssh_hc_loc_ini(:,:) = tsn(:,:,1,jp_tem) * sshn(:,:)   ! initial heat content in ssh
299                ssh_sc_loc_ini(:,:) = tsn(:,:,1,jp_sal) * sshn(:,:)   ! initial salt content in ssh
300             END IF
301             frc_wn_t = 0._wp                                       ! initial heat content misfit due to free surface
302             frc_wn_s = 0._wp                                       ! initial salt content misfit due to free surface
303          ENDIF
304       ENDIF
305
306     ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
307        !                                   ! -------------------
308        IF(lwp) WRITE(numout,*) '~~~~~~~'
309        IF(lwp) WRITE(numout,*) ' dia_hsb_rst at it= ', kt,' date= ', ndastp
310        IF(lwp) WRITE(numout,*) '~~~~~~~'
311
312        CALL iom_rstput( kt, nitrst, numrow, 'frc_v'   , frc_v     )
313        CALL iom_rstput( kt, nitrst, numrow, 'frc_t'   , frc_t     )
314        CALL iom_rstput( kt, nitrst, numrow, 'frc_s'   , frc_s     )
315        IF( .NOT. lk_vvl ) THEN
316           CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_t', frc_wn_t )
317           CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_s', frc_wn_s )
318        ENDIF
319        CALL iom_rstput( kt, nitrst, numrow, 'surf_ini', surf_ini )      ! ice sheet coupling
320        CALL iom_rstput( kt, nitrst, numrow, 'ssh_ini', ssh_ini )
321        CALL iom_rstput( kt, nitrst, numrow, 'e3t_ini', e3t_ini )
322        CALL iom_rstput( kt, nitrst, numrow, 'hc_loc_ini', hc_loc_ini )
323        CALL iom_rstput( kt, nitrst, numrow, 'sc_loc_ini', sc_loc_ini )
324        IF( .NOT. lk_vvl ) THEN
325           CALL iom_rstput( kt, nitrst, numrow, 'ssh_hc_loc_ini', ssh_hc_loc_ini )
326           CALL iom_rstput( kt, nitrst, numrow, 'ssh_sc_loc_ini', ssh_sc_loc_ini )
327        ENDIF
328        !
329     ENDIF
330     !
331   END SUBROUTINE dia_hsb_rst
332
333
334   SUBROUTINE dia_hsb_init
335      !!---------------------------------------------------------------------------
336      !!                  ***  ROUTINE dia_hsb  ***
337      !!     
338      !! ** Purpose: Initialization for the heat salt volume budgets
339      !!
340      !! ** Method : Compute initial heat content, salt content and volume
341      !!
342      !! ** Action : - Compute initial heat content, salt content and volume
343      !!             - Initialize forcing trends
344      !!             - Compute coefficients for conversion
345      !!---------------------------------------------------------------------------
346      INTEGER ::   jk       ! dummy loop indice
347      INTEGER ::   ierror   ! local integer
348      INTEGER ::   ios
349      !
350      NAMELIST/namhsb/ ln_diahsb
351      !!----------------------------------------------------------------------
352
353      IF(lwp) THEN
354         WRITE(numout,*)
355         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
356         WRITE(numout,*) '~~~~~~~~ '
357      ENDIF
358
359      REWIND( numnam_ref )              ! Namelist namhsb in reference namelist
360      READ  ( numnam_ref, namhsb, IOSTAT = ios, ERR = 901)
361901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in reference namelist', lwp )
362
363      REWIND( numnam_cfg )              ! Namelist namhsb in configuration namelist
364      READ  ( numnam_cfg, namhsb, IOSTAT = ios, ERR = 902 )
365902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in configuration namelist', lwp )
366      IF(lwm) WRITE ( numond, namhsb )
367
368      !
369      IF(lwp) THEN                   ! Control print
370         WRITE(numout,*)
371         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
372         WRITE(numout,*) '~~~~~~~~~~~~'
373         WRITE(numout,*) '   Namelist namhsb : set hsb parameters'
374         WRITE(numout,*) '      Switch for hsb diagnostic (T) or not (F)  ln_diahsb  = ', ln_diahsb
375         WRITE(numout,*)
376      ENDIF
377
378      IF( .NOT. ln_diahsb )   RETURN
379         !      IF( .NOT. lk_mpp_rep ) &
380         !        CALL ctl_stop (' Your global mpp_sum if performed in single precision - 64 bits -', &
381         !             &         ' whereas the global sum to be precise must be done in double precision ',&
382         !             &         ' please add key_mpp_rep')
383
384      ! ------------------- !
385      ! 1 - Allocate memory !
386      ! ------------------- !
387      ALLOCATE( hc_loc_ini(jpi,jpj,jpk), sc_loc_ini(jpi,jpj,jpk), surf_ini(jpi,jpj), &
388         &      e3t_ini(jpi,jpj,jpk), surf(jpi,jpj),  ssh_ini(jpi,jpj), STAT=ierror  )
389      IF( ierror > 0 ) THEN
390         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
391      ENDIF
392
393      IF(.NOT. lk_vvl ) ALLOCATE( ssh_hc_loc_ini(jpi,jpj), ssh_sc_loc_ini(jpi,jpj),STAT=ierror )
394      IF( ierror > 0 ) THEN
395         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
396      ENDIF
397
398      ! ----------------------------------------------- !
399      ! 2 - Time independant variables and file opening !
400      ! ----------------------------------------------- !
401      IF(lwp) WRITE(numout,*) "dia_hsb: heat salt volume budgets activated"
402      IF(lwp) WRITE(numout,*) '~~~~~~~'
403      surf(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)      ! masked surface grid cell area
404      surf_tot  = glob_sum( surf(:,:) )                                       ! total ocean surface area
405
406      IF( lk_bdy ) CALL ctl_warn( 'dia_hsb does not take open boundary fluxes into account' )         
407      !
408      ! ---------------------------------- !
409      ! 4 - initial conservation variables !
410      ! ---------------------------------- !
411      CALL dia_hsb_rst( nit000, 'READ' )  !* read or initialize all required files
412      !
413   END SUBROUTINE dia_hsb_init
414
415   !!======================================================================
416END MODULE diahsb
Note: See TracBrowser for help on using the repository browser.