New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.F90 in branches/NERC/dev_r5589_is_oce_cpl/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/NERC/dev_r5589_is_oce_cpl/NEMOGCM/NEMO/OPA_SRC/DOM/dtatsd.F90 @ 5619

Last change on this file since 5619 was 5619, checked in by mathiot, 9 years ago

ocean/ice sheet coupling: initial commit
  • Property svn:keywords set to Id
File size: 18.2 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dta_tsd_init   ! called by opa.F90
30   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
31
32   LOGICAL , PUBLIC ::   ln_tsd_init      !: T & S data flag
33   LOGICAL , PUBLIC ::   ln_tsd_tradmp    !: internal damping toward input data flag
34
35   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
36   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsddmp   ! structure of input SST (file informations, fields read)
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE dta_tsd_init( ld_tradmp )
48      !!----------------------------------------------------------------------
49      !!                   ***  ROUTINE dta_tsd_init  ***
50      !!                   
51      !! ** Purpose :   initialisation of T & S input data
52      !!
53      !! ** Method  : - Read namtsd namelist
54      !!              - allocates T & S data structure
55      !!----------------------------------------------------------------------
56      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
57      !
58      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
59      !
60      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
61      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
62      TYPE(FLD_N)                   ::   sn_tem, sn_sal
63      TYPE(FLD_N)                   ::   sn_dmpt, sn_dmps
64      !!
65      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
66      NAMELIST/namtra_dmpfile/ sn_dmpt, sn_dmps
67      INTEGER  ::   ios
68      !!----------------------------------------------------------------------
69      !
70      IF( nn_timing == 1 )  CALL timing_start('dta_tsd_init')
71      !
72      !  Initialisation
73      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
74      !
75      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
76      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
77901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in reference namelist', lwp )
78
79      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
80      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
81902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in configuration namelist', lwp )
82      IF(lwm) WRITE ( numond, namtsd )
83
84      REWIND( numnam_ref )              ! Namelist namtra_dmp in reference namelist : Temperature and salinity damping term
85      READ  ( numnam_ref, namtra_dmpfile, IOSTAT = ios, ERR = 903)
86903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_dmp in reference namelist', lwp )
87
88      REWIND( numnam_cfg )              ! Namelist namtra_dmp in configuration namelist : Temperature and salinity damping term
89      READ  ( numnam_cfg, namtra_dmpfile, IOSTAT = ios, ERR = 904 )
90904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_dmp in configuration namelist', lwp )
91
92      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
93     
94      IF(lwp) THEN                  ! control print
95         WRITE(numout,*)
96         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
97         WRITE(numout,*) '~~~~~~~~~~~~ '
98         WRITE(numout,*) '   Namelist namtsd'
99         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
100         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
101         WRITE(numout,*)
102         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
103            WRITE(numout,*)
104            WRITE(numout,*) '   T & S data not used'
105         ENDIF
106      ENDIF
107      !
108      IF( ln_rstart .AND. ln_tsd_init ) THEN
109         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
110            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
111         ln_tsd_init = .FALSE.
112      ENDIF
113      !
114      !                             ! allocate the arrays (if necessary)
115      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
116         !
117         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
118         ALLOCATE( sf_tsddmp(jpts), STAT=ierr0 )
119         IF( ierr0 > 0 ) THEN
120            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
121         ENDIF
122         !
123                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
124         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
125                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
126         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
127         ! dmp file
128                                 ALLOCATE( sf_tsddmp(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
129         IF( sn_dmpt%ln_tint )   ALLOCATE( sf_tsddmp(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
130                                 ALLOCATE( sf_tsddmp(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
131         IF( sn_dmps%ln_tint )   ALLOCATE( sf_tsddmp(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
132         !
133         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
134            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
135         ENDIF
136         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
137         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
138         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
139         slf_i(jp_tem) = sn_dmpt   ;   slf_i(jp_sal) = sn_dmps
140         CALL fld_fill( sf_tsddmp, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
141         !
142      ENDIF
143      !
144      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd_init')
145      !
146   END SUBROUTINE dta_tsd_init
147
148
149   SUBROUTINE dta_tsd( kt, ptsd, ptsddmp )
150      !!----------------------------------------------------------------------
151      !!                   ***  ROUTINE dta_tsd  ***
152      !!                   
153      !! ** Purpose :   provides T and S data at kt
154      !!
155      !! ** Method  : - call fldread routine
156      !!              - ORCA_R2: add some hand made alteration to read data 
157      !!              - 'key_orca_lev10' interpolates on 10 times more levels
158      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
159      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
160      !!                as T-S data are no are used
161      !!
162      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
163      !!----------------------------------------------------------------------
164      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
165      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
166      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), OPTIONAL, INTENT(  out) ::   ptsddmp   ! T & S data
167      !
168      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
169      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
170      REAL(wp)::   zl, zi
171      REAL(wp), POINTER, DIMENSION(:) ::  ztp, zsp   ! 1D workspace
172      !!----------------------------------------------------------------------
173      !
174      IF( nn_timing == 1 )  CALL timing_start('dta_tsd')
175      !
176      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
177      IF ( PRESENT(ptsddmp) ) THEN
178         CALL fld_read( kt, 1, sf_tsddmp )      !==   read T & S data at kt time step   ==!
179         ptsddmp(:,:,:,jp_tem) = sf_tsddmp(jp_tem)%fnow(:,:,:)    ! NO mask
180         ptsddmp(:,:,:,jp_sal) = sf_tsddmp(jp_sal)%fnow(:,:,:) 
181      END IF
182      !
183      !
184      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
185      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
186         !
187         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
188         ii0 = 141   ;   ii1 = 155
189         DO jj = mj0(ij0), mj1(ij1)
190            DO ji = mi0(ii0), mi1(ii1)
191               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
192               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
193               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
194               !
195               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
196               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
197               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
198               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
199            END DO
200         END DO
201         IF( nn_cla == 1 ) THEN                          ! Cross Land advection
202            il0 = 138   ;   il1 = 138                          ! set T & S profile at Gibraltar Strait
203            ij0 = 101   ;   ij1 = 102
204            ii0 = 139   ;   ii1 = 139
205            DO jl = mi0(il0), mi1(il1)
206               DO jj = mj0(ij0), mj1(ij1)
207                  DO ji = mi0(ii0), mi1(ii1)
208                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
209                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
210                  END DO
211               END DO
212            END DO
213            il0 = 164   ;   il1 = 164                          ! set T & S profile at Bab el Mandeb Strait
214            ij0 =  87   ;   ij1 =  88
215            ii0 = 161   ;   ii1 = 163
216            DO jl = mi0(il0), mi1(il1)
217               DO jj = mj0(ij0), mj1(ij1)
218                  DO ji = mi0(ii0), mi1(ii1)
219                     sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:)
220                     sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:)
221                  END DO
222               END DO
223            END DO
224         ELSE                                            ! No Cross Land advection
225            ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
226            ii0 = 148   ;   ii1 = 160
227            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
228            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
229            sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
230         ENDIF
231      ENDIF
232      !
233      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
234      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
235      !
236      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
237         !
238         CALL wrk_alloc( jpk, ztp, zsp )
239         !
240         IF( kt == nit000 .AND. lwp )THEN
241            WRITE(numout,*)
242            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
243         ENDIF
244         !
245         DO jj = 1, jpj                         ! vertical interpolation of T & S
246            DO ji = 1, jpi
247               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
248                  zl = gdept_0(ji,jj,jk)
249                  IF(     zl < gdept_1d(1  ) ) THEN          ! above the first level of data
250                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
251                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
252                  ELSEIF( zl > gdept_1d(jpk) ) THEN          ! below the last level of data
253                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
254                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
255                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
256                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
257                        IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
258                           zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
259                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
260                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
261                        ENDIF
262                     END DO
263                  ENDIF
264               END DO
265               DO jk = 1, jpkm1
266                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
267                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
268               END DO
269               ptsd(ji,jj,jpk,jp_tem) = 0._wp
270               ptsd(ji,jj,jpk,jp_sal) = 0._wp
271            END DO
272         END DO
273         !
274         CALL wrk_dealloc( jpk, ztp, zsp )
275         !
276      ELSE                                !==   z- or zps- coordinate   ==!
277         !                             
278         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
279         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
280         !
281         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
282            DO jj = 1, jpj
283               DO ji = 1, jpi
284                  ik = mbkt(ji,jj) 
285                  IF( ik > 1 ) THEN
286                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
287                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
288                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
289                  ENDIF
290                  ik = mikt(ji,jj)
291                  IF( ik > 1 ) THEN
292                     zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
293                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
294                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
295                  END IF
296               END DO
297            END DO
298         ENDIF
299         !
300      ENDIF
301      !
302      IF( lwp .AND. kt == nit000 ) THEN
303         WRITE(numout,*) ' temperature Levitus '
304         WRITE(numout,*)
305         WRITE(numout,*)'  level = 1'
306         CALL prihre( ptsd(:,:,1    ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
307         WRITE(numout,*)'  level = ', jpk/2
308         CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
309         WRITE(numout,*)'  level = ', jpkm1
310         CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
311         WRITE(numout,*)
312         WRITE(numout,*) ' salinity Levitus '
313         WRITE(numout,*)
314         WRITE(numout,*)'  level = 1'
315         CALL prihre( ptsd(:,:,1    ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
316         WRITE(numout,*)'  level = ', jpk/2
317         CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
318         WRITE(numout,*)'  level = ', jpkm1
319         CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout )
320         WRITE(numout,*)
321      ENDIF
322      !
323      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
324         !                                              (data used only for initialisation)
325         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
326                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
327         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
328                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
329         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
330                                        DEALLOCATE( sf_tsd              )     ! the structure itself
331         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
332                                        DEALLOCATE( sf_tsddmp(jp_tem)%fnow )     ! T arrays in the structure
333         IF( sf_tsddmp(jp_tem)%ln_tint )   DEALLOCATE( sf_tsddmp(jp_tem)%fdta )
334                                        DEALLOCATE( sf_tsddmp(jp_sal)%fnow )     ! S arrays in the structure
335         IF( sf_tsddmp(jp_sal)%ln_tint )   DEALLOCATE( sf_tsddmp(jp_sal)%fdta )
336                                        DEALLOCATE( sf_tsddmp              )     ! the structure itself
337      ENDIF
338      !
339      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd')
340      !
341   END SUBROUTINE dta_tsd
342
343   !!======================================================================
344END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.