New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 5066

Last change on this file since 5066 was 5066, checked in by rfurner, 9 years ago

added current state of wetting and drying code to test...note it does not work
  • Property svn:keywords set to Id
File size: 61.5 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6? !  2014-09  (H. Liu) add Wetting/Drying pressure filter
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
29   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
30   !!----------------------------------------------------------------------
31   USE oce             ! ocean dynamics and tracers
32   USE dom_oce         ! ocean space and time domain
33   USE phycst          ! physical constants
34   USE trdmod          ! ocean dynamics trends
35   USE trdmod_oce      ! ocean variables trends
36   USE in_out_manager  ! I/O manager
37   USE prtctl          ! Print control
38   USE lbclnk          ! lateral boundary condition
39   USE lib_mpp         ! MPP library
40   USE wrk_nemo        ! Memory Allocation
41   USE timing          ! Timing
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   dyn_hpg        ! routine called by step module
47   PUBLIC   dyn_hpg_init   ! routine called by opa module
48
49   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
50   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
51   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
52   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
53   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
54   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
55   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
56
57   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
58
59   !! * Substitutions
60#  include "domzgr_substitute.h90"
61#  include "vectopt_loop_substitute.h90"
62   !!----------------------------------------------------------------------
63   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
64   !! $Id$
65   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE dyn_hpg( kt )
70      !!---------------------------------------------------------------------
71      !!                  ***  ROUTINE dyn_hpg  ***
72      !!
73      !! ** Method  :   Call the hydrostatic pressure gradient routine
74      !!              using the scheme defined in the namelist
75      !!
76      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
77      !!             - Save the trend (l_trddyn=T)
78      !!----------------------------------------------------------------------
79      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
80      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
84      !
85      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
86         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
87         ztrdu(:,:,:) = ua(:,:,:)
88         ztrdv(:,:,:) = va(:,:,:)
89      ENDIF
90      !
91      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
92      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
93      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
94      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
95      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
96      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
97      END SELECT
98      !
99      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
100         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
101         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
102         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
103         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
104      ENDIF
105      !
106      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
107         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
108      !
109      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
110      !
111   END SUBROUTINE dyn_hpg
112
113
114   SUBROUTINE dyn_hpg_init
115      !!----------------------------------------------------------------------
116      !!                 ***  ROUTINE dyn_hpg_init  ***
117      !!
118      !! ** Purpose :   initializations for the hydrostatic pressure gradient
119      !!              computation and consistency control
120      !!
121      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
122      !!      with the type of vertical coordinate used (zco, zps, sco)
123      !!----------------------------------------------------------------------
124      INTEGER ::   ioptio = 0      ! temporary integer
125      INTEGER ::   ios             ! Local integer output status for namelist read
126      !!
127      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
128         &                 ln_hpg_djc, ln_hpg_prj, ln_dynhpg_imp
129      !!----------------------------------------------------------------------
130      !
131      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
132      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
133901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
134
135      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
136      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
137902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
138      IF(lwm) WRITE ( numond, namdyn_hpg )
139      !
140      IF(lwp) THEN                   ! Control print
141         WRITE(numout,*)
142         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
143         WRITE(numout,*) '~~~~~~~~~~~~'
144         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
145         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
146         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
147         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
148         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
149         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
150         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
151      ENDIF
152      !
153      IF( ln_hpg_djc )   &
154         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
155                           & currently disabled (bugs under investigation). Please select &
156                           & either  ln_hpg_sco or  ln_hpg_prj instead')
157      !
158      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj) )   &
159         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
160                           & the standard jacobian formulation hpg_sco or &
161                           & the pressure jacobian formulation hpg_prj')
162      !
163      !                               ! Set nhpg from ln_hpg_... flags
164      IF( ln_hpg_zco )   nhpg = 0
165      IF( ln_hpg_zps )   nhpg = 1
166      IF( ln_hpg_sco )   nhpg = 2
167      IF( ln_hpg_djc )   nhpg = 3
168      IF( ln_hpg_prj )   nhpg = 4
169      !
170      !                               ! Consistency check
171      ioptio = 0
172      IF( ln_hpg_zco )   ioptio = ioptio + 1
173      IF( ln_hpg_zps )   ioptio = ioptio + 1
174      IF( ln_hpg_sco )   ioptio = ioptio + 1
175      IF( ln_hpg_djc )   ioptio = ioptio + 1
176      IF( ln_hpg_prj )   ioptio = ioptio + 1
177      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
178      !
179   END SUBROUTINE dyn_hpg_init
180
181
182   SUBROUTINE hpg_zco( kt )
183      !!---------------------------------------------------------------------
184      !!                  ***  ROUTINE hpg_zco  ***
185      !!
186      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
187      !!      The now hydrostatic pressure gradient at a given level, jk,
188      !!      is computed by taking the vertical integral of the in-situ
189      !!      density gradient along the model level from the suface to that
190      !!      level:    zhpi = grav .....
191      !!                zhpj = grav .....
192      !!      add it to the general momentum trend (ua,va).
193      !!            ua = ua - 1/e1u * zhpi
194      !!            va = va - 1/e2v * zhpj
195      !!
196      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
197      !!----------------------------------------------------------------------
198      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
199      !!
200      INTEGER  ::   ji, jj, jk       ! dummy loop indices
201      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
202      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
203      !!----------------------------------------------------------------------
204      !
205      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
206      !
207      IF( kt == nit000 ) THEN
208         IF(lwp) WRITE(numout,*)
209         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
210         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
211      ENDIF
212
213      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
214
215      ! Surface value
216      DO jj = 2, jpjm1
217         DO ji = fs_2, fs_jpim1   ! vector opt.
218            zcoef1 = zcoef0 * fse3w(ji,jj,1)
219            ! hydrostatic pressure gradient
220            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
221            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
222            ! add to the general momentum trend
223            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
224            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
225         END DO
226      END DO
227
228      !
229      ! interior value (2=<jk=<jpkm1)
230      DO jk = 2, jpkm1
231         DO jj = 2, jpjm1
232            DO ji = fs_2, fs_jpim1   ! vector opt.
233               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
234               ! hydrostatic pressure gradient
235               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
236                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
237                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
238
239               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
240                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
241                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
242               ! add to the general momentum trend
243               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
244               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
245            END DO
246         END DO
247      END DO
248      !
249      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
250      !
251   END SUBROUTINE hpg_zco
252
253
254   SUBROUTINE hpg_zps( kt )
255      !!---------------------------------------------------------------------
256      !!                 ***  ROUTINE hpg_zps  ***
257      !!
258      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
259      !!
260      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
261      !!----------------------------------------------------------------------
262      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
263      !!
264      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
265      INTEGER  ::   iku, ikv                         ! temporary integers
266      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
267      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
268      !!----------------------------------------------------------------------
269      !
270      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
271      !
272      IF( kt == nit000 ) THEN
273         IF(lwp) WRITE(numout,*)
274         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
275         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
276      ENDIF
277
278
279      ! Local constant initialization
280      zcoef0 = - grav * 0.5_wp
281
282      !  Surface value (also valid in partial step case)
283      DO jj = 2, jpjm1
284         DO ji = fs_2, fs_jpim1   ! vector opt.
285            zcoef1 = zcoef0 * fse3w(ji,jj,1)
286            ! hydrostatic pressure gradient
287            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
288            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
289            ! add to the general momentum trend
290            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
291            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
292         END DO
293      END DO
294
295
296      ! interior value (2=<jk=<jpkm1)
297      DO jk = 2, jpkm1
298         DO jj = 2, jpjm1
299            DO ji = fs_2, fs_jpim1   ! vector opt.
300               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
301               ! hydrostatic pressure gradient
302               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
303                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
304                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
305
306               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
307                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
308                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
309               ! add to the general momentum trend
310               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
311               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
312            END DO
313         END DO
314      END DO
315
316
317      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
318# if defined key_vectopt_loop
319         jj = 1
320         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
321# else
322      DO jj = 2, jpjm1
323         DO ji = 2, jpim1
324# endif
325            iku = mbku(ji,jj)
326            ikv = mbkv(ji,jj)
327            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
328            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
329            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
330               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
331               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
332                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
333               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
334            ENDIF
335            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
336               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
337               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
338                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
339               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
340            ENDIF
341# if ! defined key_vectopt_loop
342         END DO
343# endif
344      END DO
345      !
346      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
347      !
348   END SUBROUTINE hpg_zps
349
350
351   SUBROUTINE hpg_sco( kt )
352      !!---------------------------------------------------------------------
353      !!                  ***  ROUTINE hpg_sco  ***
354      !!
355      !! ** Method  :   s-coordinate case. Jacobian scheme.
356      !!      The now hydrostatic pressure gradient at a given level, jk,
357      !!      is computed by taking the vertical integral of the in-situ
358      !!      density gradient along the model level from the suface to that
359      !!      level. s-coordinates (ln_sco): a corrective term is added
360      !!      to the horizontal pressure gradient :
361      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
362      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
363      !!      add it to the general momentum trend (ua,va).
364      !!         ua = ua - 1/e1u * zhpi
365      !!         va = va - 1/e2v * zhpj
366      !!
367      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
368      !!----------------------------------------------------------------------
369      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
370      !!
371      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
372      REAL(wp) ::   zcoef0, zuap, zvap, znad, ztmp   ! temporary scalars
373      LOGICAL  ::   ll_tmp1, ll_tmp2           ! local logical variables
374      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
375      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy    !W/D pressure filter
376      !!----------------------------------------------------------------------
377      !
378      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
379      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
380      !
381      IF( kt == nit000 ) THEN
382         IF(lwp) WRITE(numout,*)
383         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
384         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
385      ENDIF
386
387      ! Local constant initialization
388      zcoef0 = - grav * 0.5_wp
389      ! To use density and not density anomaly
390      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
391      ELSE                 ;     znad = 0._wp         ! Fixed volume
392      ENDIF
393
394      IF(ln_wd) THEN
395        DO jj = 2, jpjm1
396           DO ji = 2, jpim1
397             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj))
398             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
399                                                       & rn_wdmin1 + rn_wdmin2
400
401             IF(ll_tmp1) THEN
402               zcpx(ji,jj) = 1.0_wp
403             ELSE IF(ll_tmp2) THEN
404               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
405               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
406                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
407             ELSE
408               zcpx(ji,jj) = 0._wp
409             END IF
410     
411             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1))
412             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
413                                                       & rn_wdmin1 + rn_wdmin2
414
415             IF(ll_tmp1) THEN
416               zcpy(ji,jj) = 1.0_wp
417             ELSE IF(ll_tmp2) THEN
418               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
419               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
420                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
421             ELSE
422               zcpy(ji,jj) = 0._wp
423             END IF
424           END DO
425        END DO
426        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
427      ENDIF
428
429#if defined key_surge
430      ! Surface value
431      DO jj = 2, jpjm1
432         DO ji = fs_2, fs_jpim1   ! vector opt.
433            ! hydrostatic pressure gradient along s-surfaces
434            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad )   &
435               &                                  - fse3w(ji  ,jj  ,1) * ( znad ) )
436            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad )   &
437               &                                  - fse3w(ji  ,jj  ,1) * ( znad ) )
438            ! s-coordinate pressure gradient correction
439            zuap = -zcoef0 * ( 2._wp * znad )   &
440               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
441            zvap = -zcoef0 * ( 2._wp * znad )   &
442               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
443
444            IF(ln_wd) THEN
445              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
446              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
447              zuap = zuap * zcpx(ji,jj)
448              zvap = zvap * zcpy(ji,jj)
449            ENDIF
450
451            ! add to the general momentum trend
452            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
453            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
454         END DO
455      END DO
456
457      ! interior value (2=<jk=<jpkm1)
458      DO jk = 2, jpkm1
459         DO jj = 2, jpjm1
460            DO ji = fs_2, fs_jpim1   ! vector opt.
461               ! hydrostatic pressure gradient along s-surfaces
462               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
463                  &           * (  fse3w(ji+1,jj,jk) * ( 2*znad )   &
464                  &              - fse3w(ji  ,jj,jk) * ( 2*znad )  )
465               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
466                  &           * (  fse3w(ji,jj+1,jk) * ( 2*znad )   &
467                  &              - fse3w(ji,jj  ,jk) * ( 2*znad )  )
468               ! s-coordinate pressure gradient correction
469               zuap = -zcoef0 * ( 2._wp * znad )   &
470                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
471               zvap = -zcoef0 * ( 2._wp * znad )   &
472                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
473
474               IF(ln_wd) THEN
475                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
476                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
477                 zuap = zuap * zcpx(ji,jj)
478                 zvap = zvap * zcpy(ji,jj)
479               ENDIF
480
481               ! add to the general momentum trend
482               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
483               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
484            END DO
485         END DO
486      END DO
487      !
488#else
489      ! Surface value
490      DO jj = 2, jpjm1
491         DO ji = fs_2, fs_jpim1   ! vector opt.
492            ! hydrostatic pressure gradient along s-surfaces
493            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
494               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
495            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
496               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
497            ! s-coordinate pressure gradient correction
498            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
499               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
500            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
501               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
502
503            IF(ln_wd) THEN
504              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
505              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
506              zuap = zuap * zcpx(ji,jj)
507              zvap = zvap * zcpy(ji,jj)
508            ENDIF
509
510            ! add to the general momentum trend
511            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
512            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
513         END DO
514      END DO
515
516      ! interior value (2=<jk=<jpkm1)
517      DO jk = 2, jpkm1
518         DO jj = 2, jpjm1
519            DO ji = fs_2, fs_jpim1   ! vector opt.
520               ! hydrostatic pressure gradient along s-surfaces
521               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
522                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
523                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
524               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
525                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
526                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
527               ! s-coordinate pressure gradient correction
528               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
529                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
530               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
531                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
532
533               IF(ln_wd) THEN
534                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
535                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
536                 zuap = zuap * zcpx(ji,jj)
537                 zvap = zvap * zcpy(ji,jj)
538               ENDIF
539
540               ! add to the general momentum trend
541               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
542               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
543            END DO
544         END DO
545      END DO
546#endif
547      !
548      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
549      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
550      !
551   END SUBROUTINE hpg_sco
552
553   SUBROUTINE hpg_djc( kt )
554      !!---------------------------------------------------------------------
555      !!                  ***  ROUTINE hpg_djc  ***
556      !!
557      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
558      !!
559      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
560      !!----------------------------------------------------------------------
561      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
562      !!
563      INTEGER  ::   ji, jj, jk          ! dummy loop indices
564      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
565      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
566      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
567      LOGICAL  ::   ll_tmp1, ll_tmp2    ! local logical variables
568      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
569      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
570      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
571      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
572      REAL(wp), POINTER, DIMENSION(:,:)   ::  zcpx, zcpy    !W/D pressure filter
573      !!----------------------------------------------------------------------
574      !
575      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
576      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
577      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
578      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
579      !
580
581      IF( kt == nit000 ) THEN
582         IF(lwp) WRITE(numout,*)
583         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
584         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
585      ENDIF
586
587      IF(ln_wd) THEN
588        DO jj = 2, jpjm1
589           DO ji = 2, jpim1
590             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj))
591             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
592                                                       & rn_wdmin1 + rn_wdmin2
593
594             IF(ll_tmp1) THEN
595               zcpx(ji,jj) = 1.0_wp
596             ELSE IF(ll_tmp2) THEN
597               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
598               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
599                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
600             ELSE
601               zcpx(ji,jj) = 0._wp
602             END IF
603     
604             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1))
605             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
606                                                       & rn_wdmin1 + rn_wdmin2
607
608             IF(ll_tmp1) THEN
609               zcpy(ji,jj) = 1.0_wp
610             ELSE IF(ll_tmp2) THEN
611               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
612               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
613                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
614             ELSE
615               zcpy(ji,jj) = 0._wp
616             END IF
617           END DO
618        END DO
619        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
620      ENDIF
621
622      ! Local constant initialization
623      zcoef0 = - grav * 0.5_wp
624      z1_10  = 1._wp / 10._wp
625      z1_12  = 1._wp / 12._wp
626
627      !----------------------------------------------------------------------------------------
628      !  compute and store in provisional arrays elementary vertical and horizontal differences
629      !----------------------------------------------------------------------------------------
630
631!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
632
633      DO jk = 2, jpkm1
634         DO jj = 2, jpjm1
635            DO ji = fs_2, fs_jpim1   ! vector opt.
636               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
637               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
638               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
639               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
640               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
641               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
642            END DO
643         END DO
644      END DO
645
646      !-------------------------------------------------------------------------
647      ! compute harmonic averages using eq. 5.18
648      !-------------------------------------------------------------------------
649      zep = 1.e-15
650
651!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
652!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
653
654      DO jk = 2, jpkm1
655         DO jj = 2, jpjm1
656            DO ji = fs_2, fs_jpim1   ! vector opt.
657               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
658
659               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
660               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
661
662               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
663               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
664
665               IF( cffw > zep) THEN
666                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
667                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
668               ELSE
669                  drhow(ji,jj,jk) = 0._wp
670               ENDIF
671
672               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
673                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
674
675               IF( cffu > zep ) THEN
676                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
677                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
678               ELSE
679                  drhou(ji,jj,jk ) = 0._wp
680               ENDIF
681
682               IF( cffx > zep ) THEN
683                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
684                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
685               ELSE
686                  dzu(ji,jj,jk) = 0._wp
687               ENDIF
688
689               IF( cffv > zep ) THEN
690                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
691                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
692               ELSE
693                  drhov(ji,jj,jk) = 0._wp
694               ENDIF
695
696               IF( cffy > zep ) THEN
697                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
698                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
699               ELSE
700                  dzv(ji,jj,jk) = 0._wp
701               ENDIF
702
703            END DO
704         END DO
705      END DO
706
707      !----------------------------------------------------------------------------------
708      ! apply boundary conditions at top and bottom using 5.36-5.37
709      !----------------------------------------------------------------------------------
710      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
711      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
712      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
713
714      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
715      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
716      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
717
718
719      !--------------------------------------------------------------
720      ! Upper half of top-most grid box, compute and store
721      !-------------------------------------------------------------
722
723!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
724!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
725
726      DO jj = 2, jpjm1
727         DO ji = fs_2, fs_jpim1   ! vector opt.
728            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
729               &                   * (  rhd(ji,jj,1)                                    &
730               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
731               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
732               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
733         END DO
734      END DO
735
736!!bug gm    : here also, simplification is possible
737!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
738
739      DO jk = 2, jpkm1
740         DO jj = 2, jpjm1
741            DO ji = fs_2, fs_jpim1   ! vector opt.
742
743               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
744                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
745                  &            - grav * z1_10 * (                                                                     &
746                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
747                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
748                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
749                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
750                  &                             )
751
752               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
753                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
754                  &            - grav* z1_10 * (                                                                      &
755                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
756                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
757                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
758                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
759                  &                            )
760
761               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
762                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
763                  &            - grav* z1_10 * (                                                                      &
764                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
765                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
766                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
767                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
768                  &                            )
769
770            END DO
771         END DO
772      END DO
773      CALL lbc_lnk(rho_k,'W',1.)
774      CALL lbc_lnk(rho_i,'U',1.)
775      CALL lbc_lnk(rho_j,'V',1.)
776
777
778      ! ---------------
779      !  Surface value
780      ! ---------------
781      DO jj = 2, jpjm1
782         DO ji = fs_2, fs_jpim1   ! vector opt.
783            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
784            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
785            IF(ln_wd) THEN
786              zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
787              zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
788            ENDIF
789            ! add to the general momentum trend
790            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
791            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
792         END DO
793      END DO
794
795      ! ----------------
796      !  interior value   (2=<jk=<jpkm1)
797      ! ----------------
798      DO jk = 2, jpkm1
799         DO jj = 2, jpjm1
800            DO ji = fs_2, fs_jpim1   ! vector opt.
801               ! hydrostatic pressure gradient along s-surfaces
802               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
803                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
804                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
805               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
806                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
807                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
808               IF(ln_wd) THEN
809                 zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
810                 zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
811               ENDIF
812               ! add to the general momentum trend
813               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
814               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
815            END DO
816         END DO
817      END DO
818      !
819      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
820      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
821      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
822      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
823      !
824   END SUBROUTINE hpg_djc
825
826
827   SUBROUTINE hpg_prj( kt )
828      !!---------------------------------------------------------------------
829      !!                  ***  ROUTINE hpg_prj  ***
830      !!
831      !! ** Method  :   s-coordinate case.
832      !!      A Pressure-Jacobian horizontal pressure gradient method
833      !!      based on the constrained cubic-spline interpolation for
834      !!      all vertical coordinate systems
835      !!
836      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
837      !!             - Save the trend (l_trddyn=T)
838      !!
839      !!----------------------------------------------------------------------
840      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
841      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
842      !!
843      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
844      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
845      !!
846      !! The local variables for the correction term
847      INTEGER  :: jk1, jis, jid, jjs, jjd
848      LOGICAL  :: ll_tmp1, ll_tmp2                  ! local logical variables
849      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
850      REAL(wp) :: zrhdt1
851      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
852      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
853      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
854      REAL(wp), POINTER, DIMENSION(:,:)   ::   zcpx, zcpy    !W/D pressure filter
855      !!----------------------------------------------------------------------
856      !
857      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
858      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
859      IF(ln_wd) CALL wrk_alloc( jpi,jpj, zcpx, zcpy )
860      !
861      IF( kt == nit000 ) THEN
862         IF(lwp) WRITE(numout,*)
863         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
864         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
865      ENDIF
866
867      !!----------------------------------------------------------------------
868      ! Local constant initialization
869      zcoef0 = - grav
870      znad = 0.0_wp
871      IF( lk_vvl ) znad = 1._wp
872
873      IF(ln_wd) THEN
874        DO jj = 2, jpjm1
875           DO ji = 2, jpim1
876             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj))
877             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji+1,jj)) > MAX(-bathy(ji,jj), -bathy(ji+1,jj)) +&
878                                                       & rn_wdmin1 + rn_wdmin2
879
880             IF(ll_tmp1) THEN
881               zcpx(ji,jj) = 1.0_wp
882             ELSE IF(ll_tmp2) THEN
883               ! no worries about sshn(ji+1,jj)-sshn(ji,jj) = 0, it won't happen ! here
884               zcpx(ji,jj) = ABS((sshn(ji+1,jj) + bathy(ji+1,jj) - sshn(ji,jj) - bathy(ji,jj)) /&
885                           &     (sshn(ji+1,jj) - sshn(ji,jj)))
886             ELSE
887               zcpx(ji,jj) = 0._wp
888             END IF
889     
890             ll_tmp1 = MIN(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1))
891             ll_tmp2 = MAX(sshn(ji,jj), sshn(ji,jj+1)) > MAX(-bathy(ji,jj), -bathy(ji,jj+1)) +&
892                                                       & rn_wdmin1 + rn_wdmin2
893
894             IF(ll_tmp1.OR.ll_tmp2) THEN
895               zcpy(ji,jj) = 1.0_wp
896             ELSE IF(ll_tmp2) THEN
897               ! no worries about sshn(ji,jj+1)-sshn(ji,jj) = 0, it won't happen ! here
898               zcpy(ji,jj) = ABS((sshn(ji,jj+1) + bathy(ji,jj+1) - sshn(ji,jj) - bathy(ji,jj)) /&
899                           &     (sshn(ji,jj+1) - sshn(ji,jj)))
900             ELSE
901               zcpy(ji,jj) = 0._wp
902             END IF
903           END DO
904        END DO
905        CALL lbc_lnk( zcpx, 'U', 1._wp )    ;   CALL lbc_lnk( zcpy, 'V', 1._wp )
906      ENDIF
907
908      ! Clean 3-D work arrays
909      zhpi(:,:,:) = 0._wp
910      zrhh(:,:,:) = rhd(:,:,:)
911
912      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
913      DO jj = 1, jpj
914        DO ji = 1, jpi
915          jk = mbathy(ji,jj)
916          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
917          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
918          ELSE IF(jk < jpkm1) THEN
919             DO jkk = jk+1, jpk
920                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
921                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
922             END DO
923          ENDIF
924        END DO
925      END DO
926
927      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
928      DO jj = 1, jpj;   DO ji = 1, jpi
929          zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
930      END DO        ;   END DO
931
932      DO jk = 2, jpk;   DO jj = 1, jpj;   DO ji = 1, jpi
933          zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
934      END DO        ;   END DO        ;   END DO
935
936      fsp(:,:,:) = zrhh(:,:,:)
937      xsp(:,:,:) = zdept(:,:,:)
938
939      ! Construct the vertical density profile with the
940      ! constrained cubic spline interpolation
941      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
942      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
943
944      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
945      DO jj = 2, jpj
946        DO ji = 2, jpi
947          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
948                                         bsp(ji,jj,1),   csp(ji,jj,1), &
949                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
950
951          ! assuming linear profile across the top half surface layer
952          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
953        END DO
954      END DO
955
956      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
957      DO jk = 2, jpkm1
958        DO jj = 2, jpj
959          DO ji = 2, jpi
960            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
961                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
962                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
963                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
964          END DO
965        END DO
966      END DO
967
968      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
969      DO jj = 2, jpjm1
970        DO ji = 2, jpim1
971          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshu_n for ztilde compilation
972          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshv_n for ztilde compilation
973        END DO
974      END DO
975
976      DO jk = 2, jpkm1
977        DO jj = 2, jpjm1
978          DO ji = 2, jpim1
979            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
980            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
981          END DO
982        END DO
983      END DO
984
985      DO jk = 1, jpkm1
986        DO jj = 2, jpjm1
987          DO ji = 2, jpim1
988            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
989            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
990          END DO
991        END DO
992      END DO
993
994      DO jk = 1, jpkm1
995        DO jj = 2, jpjm1
996          DO ji = 2, jpim1
997            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
998            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
999            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1000            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1001          END DO
1002        END DO
1003      END DO
1004
1005
1006      DO jk = 1, jpkm1
1007        DO jj = 2, jpjm1
1008          DO ji = 2, jpim1
1009            zpwes = 0._wp; zpwed = 0._wp
1010            zpnss = 0._wp; zpnsd = 0._wp
1011            zuijk = zu(ji,jj,jk)
1012            zvijk = zv(ji,jj,jk)
1013
1014            !!!!!     for u equation
1015            IF( jk <= mbku(ji,jj) ) THEN
1016               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1017                 jis = ji + 1; jid = ji
1018               ELSE
1019                 jis = ji;     jid = ji +1
1020               ENDIF
1021
1022               ! integrate the pressure on the shallow side
1023               jk1 = jk
1024               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1025                 IF( jk1 == mbku(ji,jj) ) THEN
1026                   zuijk = -zdept(jis,jj,jk1)
1027                   EXIT
1028                 ENDIF
1029                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1030                 zpwes = zpwes +                                    &
1031                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1032                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1033                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1034                 jk1 = jk1 + 1
1035               END DO
1036
1037               ! integrate the pressure on the deep side
1038               jk1 = jk
1039               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1040                 IF( jk1 == 1 ) THEN
1041                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1042                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1043                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1044                                                     dsp(jid,jj,1)) * zdeps
1045                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1046                   EXIT
1047                 ENDIF
1048                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1049                 zpwed = zpwed +                                        &
1050                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1051                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1052                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1053                 jk1 = jk1 - 1
1054               END DO
1055
1056               ! update the momentum trends in u direction
1057
1058               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1059               IF( lk_vvl ) THEN
1060                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1061                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1062                ELSE
1063                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1064               ENDIF
1065
1066               IF(ln_wd) THEN
1067                  zdpdx1 = zdpdx1 * zcpx(ji,jj)
1068                  zdpdx2 = zdpdx2 * zcpx(ji,jj)
1069                ENDIF
1070                ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) 
1071            ENDIF
1072
1073            !!!!!     for v equation
1074            IF( jk <= mbkv(ji,jj) ) THEN
1075               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1076                 jjs = jj + 1; jjd = jj
1077               ELSE
1078                 jjs = jj    ; jjd = jj + 1
1079               ENDIF
1080
1081               ! integrate the pressure on the shallow side
1082               jk1 = jk
1083               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1084                 IF( jk1 == mbkv(ji,jj) ) THEN
1085                   zvijk = -zdept(ji,jjs,jk1)
1086                   EXIT
1087                 ENDIF
1088                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1089                 zpnss = zpnss +                                      &
1090                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1091                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1092                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1093                 jk1 = jk1 + 1
1094               END DO
1095
1096               ! integrate the pressure on the deep side
1097               jk1 = jk
1098               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1099                 IF( jk1 == 1 ) THEN
1100                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1101                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1102                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1103                                                     dsp(ji,jjd,1) ) * zdeps
1104                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1105                   EXIT
1106                 ENDIF
1107                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1108                 zpnsd = zpnsd +                                        &
1109                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1110                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1111                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1112                 jk1 = jk1 - 1
1113               END DO
1114
1115
1116               ! update the momentum trends in v direction
1117
1118               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1119               IF( lk_vvl ) THEN
1120                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1121                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1122               ELSE
1123                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1124               ENDIF
1125
1126               IF(ln_wd) THEN
1127                  zdpdy1 = zdpdy1 * zcpy(ji,jj)
1128                  zdpdy2 = zdpdy2 * zcpy(ji,jj)
1129               ENDIF
1130
1131               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1132            ENDIF
1133
1134
1135           END DO
1136        END DO
1137      END DO
1138      !
1139      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1140      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1141      IF(ln_wd) CALL wrk_dealloc( jpi,jpj, zcpx, zcpy )
1142      !
1143   END SUBROUTINE hpg_prj
1144
1145   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1146      !!----------------------------------------------------------------------
1147      !!                 ***  ROUTINE cspline  ***
1148      !!
1149      !! ** Purpose :   constrained cubic spline interpolation
1150      !!
1151      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1152      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1153      !!
1154      !!----------------------------------------------------------------------
1155      IMPLICIT NONE
1156      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1157      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1158                                                                    ! the interpoated function
1159      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1160                                                                    ! 2: Linear
1161
1162      ! Local Variables
1163      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1164      INTEGER  ::   jpi, jpj, jpkm1
1165      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1166      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1167      REAL(wp) ::   zdf(size(fsp,3))
1168      !!----------------------------------------------------------------------
1169
1170      jpi   = size(fsp,1)
1171      jpj   = size(fsp,2)
1172      jpkm1 = size(fsp,3) - 1
1173
1174
1175      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1176         DO ji = 1, jpi
1177            DO jj = 1, jpj
1178           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1179           !    DO jk = 2, jpkm1-1
1180           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1181           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1182           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1183           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1184           !
1185           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1186           !
1187           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1188           !           zdf(jk) = 0._wp
1189           !       ELSE
1190           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1191           !       ENDIF
1192           !    END DO
1193
1194           !!Simply geometric average
1195               DO jk = 2, jpkm1-1
1196                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1197                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1198
1199                  IF(zdf1 * zdf2 <= 0._wp) THEN
1200                     zdf(jk) = 0._wp
1201                  ELSE
1202                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1203                  ENDIF
1204               END DO
1205
1206               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1207                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1208               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1209                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1210                          & 0.5_wp * zdf(jpkm1 - 1)
1211
1212               DO jk = 1, jpkm1 - 1
1213                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1214                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1215                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1216                 zddf1  = -2._wp * ztmp1 + ztmp2
1217                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1218                 zddf2  =  2._wp * ztmp1 - ztmp2
1219
1220                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1221                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1222                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1223                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1224                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1225                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1226                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1227                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1228                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1229               END DO
1230            END DO
1231         END DO
1232
1233      ELSE IF (polynomial_type == 2) THEN     ! Linear
1234         DO ji = 1, jpi
1235            DO jj = 1, jpj
1236               DO jk = 1, jpkm1-1
1237                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1238                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1239
1240                  dsp(ji,jj,jk) = 0._wp
1241                  csp(ji,jj,jk) = 0._wp
1242                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1243                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1244               END DO
1245            END DO
1246         END DO
1247
1248      ELSE
1249           CALL ctl_stop( 'invalid polynomial type in cspline' )
1250      ENDIF
1251
1252
1253   END SUBROUTINE cspline
1254
1255
1256   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1257      !!----------------------------------------------------------------------
1258      !!                 ***  ROUTINE interp1  ***
1259      !!
1260      !! ** Purpose :   1-d linear interpolation
1261      !!
1262      !! ** Method  :
1263      !!                interpolation is straight forward
1264      !!                extrapolation is also permitted (no value limit)
1265      !!
1266      !!----------------------------------------------------------------------
1267      IMPLICIT NONE
1268      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1269      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1270      REAL(wp)             ::  zdeltx
1271      !!----------------------------------------------------------------------
1272
1273      zdeltx = xr - xl
1274      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1275        f = 0.5_wp * (fl + fr)
1276      ELSE
1277        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1278      ENDIF
1279
1280   END FUNCTION interp1
1281
1282   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1283      !!----------------------------------------------------------------------
1284      !!                 ***  ROUTINE interp1  ***
1285      !!
1286      !! ** Purpose :   1-d constrained cubic spline interpolation
1287      !!
1288      !! ** Method  :  cubic spline interpolation
1289      !!
1290      !!----------------------------------------------------------------------
1291      IMPLICIT NONE
1292      REAL(wp), INTENT(in) ::  x, a, b, c, d
1293      REAL(wp)             ::  f ! value from the interpolation
1294      !!----------------------------------------------------------------------
1295
1296      f = a + x* ( b + x * ( c + d * x ) )
1297
1298   END FUNCTION interp2
1299
1300
1301   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1302      !!----------------------------------------------------------------------
1303      !!                 ***  ROUTINE interp1  ***
1304      !!
1305      !! ** Purpose :   Calculate the first order of deriavtive of
1306      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1307      !!
1308      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1309      !!
1310      !!----------------------------------------------------------------------
1311      IMPLICIT NONE
1312      REAL(wp), INTENT(in) ::  x, a, b, c, d
1313      REAL(wp)             ::  f ! value from the interpolation
1314      !!----------------------------------------------------------------------
1315
1316      f = b + x * ( 2._wp * c + 3._wp * d * x)
1317
1318   END FUNCTION interp3
1319
1320
1321   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1322      !!----------------------------------------------------------------------
1323      !!                 ***  ROUTINE interp1  ***
1324      !!
1325      !! ** Purpose :   1-d constrained cubic spline integration
1326      !!
1327      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1328      !!
1329      !!----------------------------------------------------------------------
1330      IMPLICIT NONE
1331      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1332      REAL(wp)             ::  za1, za2, za3
1333      REAL(wp)             ::  f                   ! integration result
1334      !!----------------------------------------------------------------------
1335
1336      za1 = 0.5_wp * b
1337      za2 = c / 3.0_wp
1338      za3 = 0.25_wp * d
1339
1340      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1341         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1342
1343   END FUNCTION integ_spline
1344
1345
1346   !!======================================================================
1347END MODULE dynhpg
1348
Note: See TracBrowser for help on using the repository browser.