New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_bilap.F90 in branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf_bilap.F90 @ 5727

Last change on this file since 5727 was 5727, checked in by rfurner, 9 years ago

some bug fixes for wetting and drying elements...still not working though
  • Property svn:keywords set to Id
File size: 9.7 KB
Line 
1MODULE dynldf_bilap
2   !!======================================================================
3   !!                     ***  MODULE  dynldf_bilap  ***
4   !! Ocean dynamics:  lateral viscosity trend
5   !!======================================================================
6   !! History :  OPA  ! 1990-09  (G. Madec)  Original code
7   !!            4.0  ! 1993-03  (M. Guyon)  symetrical conditions (M. Guyon)
8   !!            6.0  ! 1996-01  (G. Madec)  statement function for e3
9   !!            8.0  ! 1997-07  (G. Madec)  lbc calls
10   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and module
11   !!            2.0  ! 2004-08  (C. Talandier) New trends organization
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dyn_ldf_bilap : update the momentum trend with the lateral diffusion
16   !!                   using an iso-level bilaplacian operator
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE ldfdyn_oce      ! ocean dynamics: lateral physics
21   USE in_out_manager  ! I/O manager
22   USE trdmod          ! ocean dynamics trends
23   USE trdmod_oce      ! ocean variables trends
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE wrk_nemo        ! Memory Allocation
26   USE timing          ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   dyn_ldf_bilap   ! called by step.F90
32
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "ldfdyn_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE dyn_ldf_bilap( kt )
45      !!----------------------------------------------------------------------
46      !!                     ***  ROUTINE dyn_ldf_bilap  ***
47      !!
48      !! ** Purpose :   Compute the before trend of the lateral momentum
49      !!      diffusion and add it to the general trend of momentum equation.
50      !!
51      !! ** Method  :   The before horizontal momentum diffusion trend is a
52      !!      bi-harmonic operator (bilaplacian type) which separates the
53      !!      divergent and rotational parts of the flow.
54      !!      Its horizontal components are computed as follow:
55      !!      laplacian:
56      !!          zlu = 1/e1u di[ hdivb ] - 1/(e2u*e3u) dj-1[ e3f rotb ]
57      !!          zlv = 1/e2v dj[ hdivb ] + 1/(e1v*e3v) di-1[ e3f rotb ]
58      !!      third derivative:
59      !!       * multiply by the eddy viscosity coef. at u-, v-point, resp.
60      !!          zlu = ahmu * zlu
61      !!          zlv = ahmv * zlv
62      !!       * curl and divergence of the laplacian
63      !!          zuf = 1/(e1f*e2f) ( di[e2v zlv] - dj[e1u zlu] )
64      !!          zut = 1/(e1t*e2t*e3t) ( di[e2u*e3u zlu] + dj[e1v*e3v zlv] )
65      !!      bilaplacian:
66      !!              diffu = 1/e1u di[ zut ] - 1/(e2u*e3u) dj-1[ e3f zuf ]
67      !!              diffv = 1/e2v dj[ zut ] + 1/(e1v*e3v) di-1[ e3f zuf ]
68      !!      If ln_sco=F and ln_zps=F, the vertical scale factors in the
69      !!      rotational part of the diffusion are simplified
70      !!      Add this before trend to the general trend (ua,va):
71      !!            (ua,va) = (ua,va) + (diffu,diffv)
72      !!      'key_trddyn' defined: the two components of the horizontal
73      !!                               diffusion trend are saved.
74      !!
75      !! ** Action : - Update (ua,va) with the before iso-level biharmonic
76      !!               mixing trend.
77      !!----------------------------------------------------------------------
78      !
79      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
80      !
81      INTEGER  ::   ji, jj, jk                  ! dummy loop indices
82      REAL(wp) ::   zua, zva, zbt, ze2u, ze2v   ! temporary scalar
83      REAL(wp), POINTER, DIMENSION(:,:  ) :: zcu, zcv
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zuf, zut, zlu, zlv
85      !!----------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )  CALL timing_start('dyn_ldf_bilap')
88      !
89      CALL wrk_alloc( jpi, jpj,      zcu, zcv           )
90      CALL wrk_alloc( jpi, jpj, jpk, zuf, zut, zlu, zlv ) 
91      !
92      IF( kt == nit000 .AND. lwp ) THEN
93         WRITE(numout,*)
94         WRITE(numout,*) 'dyn_ldf_bilap : iso-level bilaplacian operator'
95         WRITE(numout,*) '~~~~~~~~~~~~~'
96      ENDIF
97
98!!bug gm this should be enough
99!!$      zuf(:,:,jpk) = 0.e0
100!!$      zut(:,:,jpk) = 0.e0
101!!$      zlu(:,:,jpk) = 0.e0
102!!$      zlv(:,:,jpk) = 0.e0
103      zuf(:,:,:) = 0._wp
104      zut(:,:,:) = 0._wp
105      zlu(:,:,:) = 0._wp
106      zlv(:,:,:) = 0._wp
107
108      !                                                ! ===============
109      DO jk = 1, jpkm1                                 ! Horizontal slab
110         !                                             ! ===============
111         ! Laplacian
112         ! ---------
113
114         IF( ln_sco .OR. ln_zps ) THEN   ! s-coordinate or z-coordinate with partial steps
115            zuf(:,:,jk) = rotb(:,:,jk) * fse3f(:,:,jk)
116            DO jj = 2, jpjm1
117               DO ji = fs_2, fs_jpim1   ! vector opt.
118                  zlu(ji,jj,jk) = - ( zuf(ji,jj,jk) - zuf(ji,jj-1,jk) ) / ( e2u(ji,jj) * fse3u(ji,jj,jk) )   &
119                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj,jk) ) / e1u(ji,jj)
120   
121                  zlv(ji,jj,jk) = + ( zuf(ji,jj,jk) - zuf(ji-1,jj,jk) ) / ( e1v(ji,jj) * fse3v(ji,jj,jk) )   &
122                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji,jj,jk) ) / e2v(ji,jj)
123               END DO
124            END DO
125         ELSE                            ! z-coordinate - full step
126            DO jj = 2, jpjm1
127               DO ji = fs_2, fs_jpim1   ! vector opt.
128                  zlu(ji,jj,jk) = - ( rotb (ji  ,jj,jk) - rotb (ji,jj-1,jk) ) / e2u(ji,jj)   &
129                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj  ,jk) ) / e1u(ji,jj)
130   
131                  zlv(ji,jj,jk) = + ( rotb (ji,jj  ,jk) - rotb (ji-1,jj,jk) ) / e1v(ji,jj)   &
132                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji  ,jj,jk) ) / e2v(ji,jj)
133               END DO 
134            END DO 
135         ENDIF
136      END DO
137      CALL lbc_lnk( zlu, 'U', -1. )   ;   CALL lbc_lnk( zlv, 'V', -1. )   ! Boundary conditions
138
139         
140      DO jk = 1, jpkm1
141   
142         ! Third derivative
143         ! ----------------
144         
145         ! Multiply by the eddy viscosity coef. (at u- and v-points)
146         zlu(:,:,jk) = zlu(:,:,jk) * ( fsahmu(:,:,jk) * (1-nkahm_smag) + nkahm_smag) * umask(:,:,jk)
147 
148         zlv(:,:,jk) = zlv(:,:,jk) * ( fsahmv(:,:,jk) * (1-nkahm_smag) + nkahm_smag) * vmask(:,:,jk)
149         
150         ! Contravariant "laplacian"
151         zcu(:,:) = e1u(:,:) * zlu(:,:,jk)
152         zcv(:,:) = e2v(:,:) * zlv(:,:,jk)
153         
154         ! Laplacian curl ( * e3f if s-coordinates or z-coordinate with partial steps)
155         DO jj = 1, jpjm1
156            DO ji = 1, fs_jpim1   ! vector opt.
157               zuf(ji,jj,jk) = fmask(ji,jj,jk) * (  zcv(ji+1,jj  ) - zcv(ji,jj)      &
158                  &                            - zcu(ji  ,jj+1) + zcu(ji,jj)  )   &
159                  &       * fse3f(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) )
160            END DO 
161         END DO 
162
163         ! Laplacian Horizontal fluxes
164         DO jj = 1, jpjm1
165            DO ji = 1, fs_jpim1   ! vector opt.
166               zlu(ji,jj,jk) = e2u(ji,jj) * fse3u(ji,jj,jk) * zlu(ji,jj,jk)
167               zlv(ji,jj,jk) = e1v(ji,jj) * fse3v(ji,jj,jk) * zlv(ji,jj,jk)
168            END DO
169         END DO
170
171         ! Laplacian divergence
172         DO jj = 2, jpj
173            DO ji = fs_2, jpi   ! vector opt.
174               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk)
175               zut(ji,jj,jk) = (  zlu(ji,jj,jk) - zlu(ji-1,jj  ,jk)   &
176                  &             + zlv(ji,jj,jk) - zlv(ji  ,jj-1,jk) ) / zbt * tmask(ji,jj,jk)
177            END DO
178         END DO
179      END DO
180
181
182      ! boundary conditions on the laplacian curl and div (zuf,zut)
183!!bug gm no need to do this 2 following lbc...
184      CALL lbc_lnk( zuf, 'F', 1. )
185      CALL lbc_lnk( zut, 'T', 1. )
186
187      DO jk = 1, jpkm1     
188   
189         ! Bilaplacian
190         ! -----------
191
192         DO jj = 2, jpjm1
193            DO ji = fs_2, fs_jpim1   ! vector opt.
194               ze2u = e2u(ji,jj) * fse3u(ji,jj,jk)
195               ze2v = e1v(ji,jj) * fse3v(ji,jj,jk)
196               ! horizontal biharmonic diffusive trends
197               zua = - ( zuf(ji  ,jj,jk) - zuf(ji,jj-1,jk) ) / ze2u   &
198                  &  + ( zut(ji+1,jj,jk) - zut(ji,jj  ,jk) ) / e1u(ji,jj)
199
200               zva = + ( zuf(ji,jj  ,jk) - zuf(ji-1,jj,jk) ) / ze2v   &
201                  &  + ( zut(ji,jj+1,jk) - zut(ji  ,jj,jk) ) / e2v(ji,jj)
202               ! add it to the general momentum trends
203               ua(ji,jj,jk) = ua(ji,jj,jk) + zua * ( fsahmu(ji,jj,jk)*nkahm_smag +(1 -nkahm_smag )) * umask(ji,jj,jk)
204               va(ji,jj,jk) = va(ji,jj,jk) + zva * ( fsahmv(ji,jj,jk)*nkahm_smag +(1 -nkahm_smag )) * vmask(ji,jj,jk)
205            END DO
206         END DO
207
208         !                                             ! ===============
209      END DO                                           !   End of slab
210      !                                                ! ===============
211      CALL wrk_dealloc( jpi, jpj,      zcu, zcv           )
212      CALL wrk_dealloc( jpi, jpj, jpk, zuf, zut, zlu, zlv ) 
213      !
214      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf_bilap')
215      !
216   END SUBROUTINE dyn_ldf_bilap
217
218   !!======================================================================
219END MODULE dynldf_bilap
Note: See TracBrowser for help on using the repository browser.