source: branches/UKMO/2014_Surge_Modelling/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 5746

Last change on this file since 5746 was 5746, checked in by rfurner, 5 years ago

changes to name restart files with date instead of time stamp

  • Property svn:keywords set to Id
File size: 13.7 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rst_opn    : open the ocean restart file
15   !!   rst_write  : write the ocean restart file
16   !!   rst_read   : read the ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE phycst          ! physical constants
21   USE in_out_manager  ! I/O manager
22   USE iom             ! I/O module
23   USE eosbn2          ! equation of state            (eos bn2 routine)
24   USE trdmld_oce      ! ocean active mixed layer tracers trends variables
25   USE divcur          ! hor. divergence and curl      (div & cur routines)
26   USE sbc_ice, ONLY : lk_lim3
27! for ln_rstdate....
28   USE ioipsl, ONLY : ju2ymds    ! for calendar
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   rst_opn         ! routine called by step module
34   PUBLIC   rst_write       ! routine called by step module
35   PUBLIC   rst_read        ! routine called by istate module
36   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE rst_opn( kt )
49      !!---------------------------------------------------------------------
50      !!                   ***  ROUTINE rst_opn  ***
51      !!                     
52      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
53      !!              + open the restart when we are one time step before nitrst
54      !!                   - restart header is defined when kt = nitrst-1
55      !!                   - restart data  are written when kt = nitrst
56      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt     ! ocean time-step
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ice output restart file name
62! Included for ln_rstdate
63      INTEGER             ::   iyear, imonth, iday
64      REAL (wp)           ::   zsec
65
66      !!----------------------------------------------------------------------
67      !
68      IF( kt == nit000 ) THEN   ! default definitions
69         lrst_oce = .FALSE.   
70         nitrst = nitend
71      ENDIF
72      IF( MOD( kt - 1, nstock ) == 0 ) THEN   
73         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
74         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
75         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
76      ENDIF
77      ! to get better performances with NetCDF format:
78      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
79      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
80      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
81! changes for ln_rstdate....
82!         ! beware of the format used to write kt (default is i8.8, that should be large enough...)
83!         IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
84!         ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
85           IF ( ln_rstdate ) THEN
86              CALL ju2ymds( fjulday + rdttra(1) / rday, iyear, imonth, iday, zsec )           
87              WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
88           ELSE
89              ! beware of the format used to write kt (default is i8.8, that should be large enough...)
90              IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
91              ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
92              ENDIF
93! end
94         ENDIF
95         ! create the file
96         clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
97         IF(lwp) THEN
98            WRITE(numout,*)
99            SELECT CASE ( jprstlib )
100            CASE ( jprstdimg )   ;   WRITE(numout,*) '             open ocean restart binary file: '//clname
101            CASE DEFAULT         ;   WRITE(numout,*) '             open ocean restart NetCDF file: '//clname
102            END SELECT
103            IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
104            IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
105            ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
106            ENDIF
107         ENDIF
108         !
109         CALL iom_open( clname, numrow, ldwrt = .TRUE., kiolib = jprstlib )
110         lrst_oce = .TRUE.
111      ENDIF
112      !
113   END SUBROUTINE rst_opn
114
115
116   SUBROUTINE rst_write( kt )
117      !!---------------------------------------------------------------------
118      !!                   ***  ROUTINE rstwrite  ***
119      !!                     
120      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
121      !!
122      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
123      !!              file, save fields which are necessary for restart
124      !!----------------------------------------------------------------------
125      INTEGER, INTENT(in) ::   kt   ! ocean time-step
126      !!----------------------------------------------------------------------
127
128                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
129                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
130
131                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
132                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
133                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
134                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
135                     CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb      )
136                     CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb     )
137                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
138                     !
139                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
140                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
141                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
142                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
143                     CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn      )
144                     CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn     )
145                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
146                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
147#if defined key_zdfkpp
148                     CALL iom_rstput( kt, nitrst, numrow, 'rhd'    , rhd       )
149#endif
150                  IF( lk_lim3 ) THEN
151                     CALL iom_rstput( kt, nitrst, numrow, 'iatte'  , iatte     ) !clem modif
152                     CALL iom_rstput( kt, nitrst, numrow, 'oatte'  , oatte     ) !clem modif
153                  ENDIF
154      IF( kt == nitrst ) THEN
155         CALL iom_close( numrow )     ! close the restart file (only at last time step)
156         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
157      ENDIF
158      !
159   END SUBROUTINE rst_write
160
161   SUBROUTINE rst_read_open
162      !!----------------------------------------------------------------------
163      !!                   ***  ROUTINE rst_read_open  ***
164      !!
165      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
166      !!
167      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
168      !!                the file has already been opened
169      !!----------------------------------------------------------------------
170      INTEGER  ::   jlibalt = jprstlib
171      LOGICAL  ::   llok
172      !!----------------------------------------------------------------------
173
174      IF( numror .LE. 0 ) THEN
175         IF(lwp) THEN                                             ! Contol prints
176            WRITE(numout,*)
177            SELECT CASE ( jprstlib )
178            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
179            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
180            END SELECT
181            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
182            WRITE(numout,*) '~~~~~~~~'
183         ENDIF
184
185         IF ( jprstlib == jprstdimg ) THEN
186           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
187           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
188           INQUIRE( FILE = TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
189           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
190         ENDIF
191         CALL iom_open( cn_ocerst_in, numror, kiolib = jlibalt )
192      ENDIF
193   END SUBROUTINE rst_read_open
194
195   SUBROUTINE rst_read
196      !!----------------------------------------------------------------------
197      !!                   ***  ROUTINE rst_read  ***
198      !!
199      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
200      !!
201      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
202      !!----------------------------------------------------------------------
203      REAL(wp) ::   zrdt, zrdttra1
204      INTEGER  ::   jk
205      LOGICAL  ::   llok
206      !!----------------------------------------------------------------------
207
208      CALL rst_read_open           ! open restart for reading (if not already opened)
209
210      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
211      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
212         CALL iom_get( numror, 'rdt', zrdt )
213         IF( zrdt /= rdt )   neuler = 0
214      ENDIF
215      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
216         CALL iom_get( numror, 'rdttra1', zrdttra1 )
217         IF( zrdttra1 /= rdttra(1) )   neuler = 0
218      ENDIF
219      !
220      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
221         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
222         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
223         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
224         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
225         CALL iom_get( numror, jpdom_autoglo, 'rotb'   , rotb    )
226         CALL iom_get( numror, jpdom_autoglo, 'hdivb'  , hdivb   )
227         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
228      ELSE
229         neuler = 0
230      ENDIF
231      !
232      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
233      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
234      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
235      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
236      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
237      IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
238         CALL iom_get( numror, jpdom_autoglo, 'rotn'   , rotn    )
239         CALL iom_get( numror, jpdom_autoglo, 'hdivn'  , hdivn   )
240      ELSE
241         CALL div_cur( 0 )                              ! Horizontal divergence & Relative vorticity
242      ENDIF
243      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
244         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
245      ELSE
246         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
247      ENDIF
248#if defined key_zdfkpp
249      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
250         CALL iom_get( numror, jpdom_autoglo, 'rhd'    , rhd     )   ! now    in situ density anomaly
251      ELSE
252         CALL eos( tsn, rhd, fsdept_n(:,:,:) )   ! compute rhd
253      ENDIF
254#endif
255      !
256      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
257         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
258         ub   (:,:,:)   = un   (:,:,:)
259         vb   (:,:,:)   = vn   (:,:,:)
260         rotb (:,:,:)   = rotn (:,:,:)
261         hdivb(:,:,:)   = hdivn(:,:,:)
262         sshb (:,:)     = sshn (:,:)
263      ENDIF
264      !
265      IF( lk_lim3 ) THEN
266         CALL iom_get( numror, jpdom_autoglo, 'iatte' , iatte ) ! clem modif
267         CALL iom_get( numror, jpdom_autoglo, 'oatte' , oatte ) ! clem modif
268      ENDIF
269      !
270   END SUBROUTINE rst_read
271
272   !!=====================================================================
273END MODULE restart
Note: See TracBrowser for help on using the repository browser.